mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-08-31 17:18:16 +01:00
TiviPlusandGitHub
901bbf7699
What does the PR do This reworks how our rendering is handled, specifically moves away from plane masters as the end solution: Instead we replace plane masters rendering directly to client with planes that render multiple planes onto them as objects in order to be able to affect multiple planes while treating them as a single object. This is done by relaying the plane using a "render relay" onto a "render plate" which acts as a plane master of plane masters of sorts, and since planes are rendered onto it as single objects any filters we apply to them will render over the planes, treating them as a single unit image Also cleaned up unused plane masters and render targets to reduce clutter, as well as removing a useless filter that was resulting from confusion due to said clutter. Clientside performance testing showed no significant change, no effect on serverside performance as this is clientside. Also added the blackness plane master so it can be relayed, side effect is that it can now be used to adjust how blackness is rendered P2 should introduce rendering one plane to multiple render_plates, but i want to get this done before I finish that, though testing shows its feasible Why It's Good For The Game Allows more advanced effects. As an example i made a grav anomaly effect in like 30 seconds for this video i will improve it once im awake properly: https://streamable.com/lu98dz Documentation images should be merged here after this pr is done tgstation/documentation-assets#2 Changelog cl qol: grav anomalies now have a pretty effect refactor: Rendering has been refactored, remember to report bugs /cl
95 lines
3.6 KiB
Plaintext
95 lines
3.6 KiB
Plaintext
///Atom that manages and controls multiple planes. It's an atom so we can hook into add_filter etc. Multiple controllers can control one plane.
|
|
/atom/movable/plane_master_controller
|
|
///List of planes in this controllers control. Initially this is a normal list, but becomes an assoc list of plane numbers as strings | plane instance
|
|
var/list/controlled_planes = list()
|
|
///hud that owns this controller
|
|
var/datum/hud/owner_hud
|
|
|
|
INITIALIZE_IMMEDIATE(/atom/movable/plane_master_controller)
|
|
|
|
///Ensures that all the planes are correctly in the controlled_planes list.
|
|
/atom/movable/plane_master_controller/Initialize(mapload, datum/hud/hud)
|
|
. = ..()
|
|
if(!istype(hud))
|
|
return
|
|
|
|
owner_hud = hud
|
|
var/assoc_controlled_planes = list()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/instance = owner_hud.plane_masters["[i]"]
|
|
if(!instance) //If we looked for a hud that isn't instanced, just keep going
|
|
stack_trace("[i] isn't a valid plane master layer for [owner_hud.type], are you sure it exists in the first place?")
|
|
continue
|
|
assoc_controlled_planes["[i]"] = instance
|
|
controlled_planes = assoc_controlled_planes
|
|
|
|
///Full override so we can just use filterrific
|
|
/atom/movable/plane_master_controller/add_filter(name, priority, list/params)
|
|
. = ..()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
|
|
pm_iterator.add_filter(name, priority, params)
|
|
|
|
///Full override so we can just use filterrific
|
|
/atom/movable/plane_master_controller/remove_filter(name_or_names)
|
|
. = ..()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
|
|
pm_iterator.remove_filter(name_or_names)
|
|
|
|
/atom/movable/plane_master_controller/update_filters()
|
|
. = ..()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
|
|
pm_iterator.update_filters()
|
|
|
|
///Gets all filters for this controllers plane masters
|
|
/atom/movable/plane_master_controller/proc/get_filters(name)
|
|
. = list()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
|
|
. += pm_iterator.get_filter(name)
|
|
|
|
///Transitions all filters owned by this plane master controller
|
|
/atom/movable/plane_master_controller/transition_filter(name, time, list/new_params, easing, loop)
|
|
. = ..()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
|
|
pm_iterator.transition_filter(name, time, new_params, easing, loop)
|
|
|
|
///Full override so we can just use filterrific
|
|
/atom/movable/plane_master_controller/add_atom_colour(coloration, colour_priority)
|
|
. = ..()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
|
|
pm_iterator.add_atom_colour(coloration, colour_priority)
|
|
|
|
|
|
///Removes an instance of colour_type from the atom's atom_colours list
|
|
/atom/movable/plane_master_controller/remove_atom_colour(colour_priority, coloration)
|
|
. = ..()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
|
|
pm_iterator.remove_atom_colour(colour_priority, coloration)
|
|
|
|
|
|
///Resets the atom's color to null, and then sets it to the highest priority colour available
|
|
/atom/movable/plane_master_controller/update_atom_colour()
|
|
for(var/i in controlled_planes)
|
|
var/atom/movable/screen/plane_master/pm_iterator = controlled_planes[i]
|
|
pm_iterator.update_atom_colour()
|
|
|
|
|
|
/atom/movable/plane_master_controller/game
|
|
name = PLANE_MASTERS_GAME
|
|
controlled_planes = list(
|
|
FLOOR_PLANE,
|
|
GAME_PLANE,
|
|
MASSIVE_OBJ_PLANE,
|
|
GHOST_PLANE,
|
|
POINT_PLANE,
|
|
LIGHTING_PLANE,
|
|
)
|
|
|
|
|