mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-29 02:51:41 +00:00
e03cd1aada
Enter(), Entered(), Exit() and Exited() all passed the old loc forward, but everything except a single a case cared about the direction of the movement more than about the specific source. Since moving multi-tile objects will have multiple sources of movement but a single direction, this change makes it easier to track their movement. Cleaned up a lot of code around and made proc inputs compatible. I'll add opacity support for multi-tile objects in a different PR after this is merged, as this has grown large enough and I don't want to compromise the reviewability. Tested this locally and as expected it didn't impair movement nor produced any runtimes.
43 lines
1.3 KiB
Plaintext
43 lines
1.3 KiB
Plaintext
/**
|
|
* Attached to movable atoms with opacity. Listens to them move and updates their old and new turf loc's opacity accordingly.
|
|
*/
|
|
/datum/element/light_blocking
|
|
element_flags = ELEMENT_DETACH
|
|
|
|
|
|
/datum/element/light_blocking/Attach(datum/target)
|
|
. = ..()
|
|
if(!ismovable(target))
|
|
return ELEMENT_INCOMPATIBLE
|
|
RegisterSignal(target, COMSIG_MOVABLE_MOVED, .proc/on_target_move)
|
|
var/atom/movable/movable_target = target
|
|
if(!isturf(movable_target.loc))
|
|
return
|
|
for(var/turf/turf_loc as anything in movable_target.locs)
|
|
turf_loc.add_opacity_source(target)
|
|
|
|
|
|
/datum/element/light_blocking/Detach(datum/target)
|
|
. = ..()
|
|
UnregisterSignal(target, list(COMSIG_MOVABLE_MOVED))
|
|
var/atom/movable/movable_target = target
|
|
if(!isturf(movable_target.loc))
|
|
return
|
|
for(var/turf/turf_loc as anything in movable_target.locs)
|
|
turf_loc.remove_opacity_source(target)
|
|
|
|
|
|
///Updates old and new turf loc opacities.
|
|
/datum/element/light_blocking/proc/on_target_move(atom/movable/source, atom/old_loc, dir, forced, list/old_locs)
|
|
SIGNAL_HANDLER
|
|
if(isturf(old_loc))
|
|
if(old_locs)
|
|
for(var/turf/old_turf as anything in old_locs)
|
|
old_turf.remove_opacity_source(source)
|
|
else
|
|
var/turf/old_turf = old_loc
|
|
old_turf.remove_opacity_source(source)
|
|
if(isturf(source.loc))
|
|
for(var/turf/new_turf as anything in source.locs)
|
|
new_turf.add_opacity_source(source)
|