mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-25 16:45:42 +00:00
84fbdbf1f4
* Fix some announcement sounds (#57192) * Fix some announcement sounds Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com>
76 lines
2.7 KiB
Plaintext
76 lines
2.7 KiB
Plaintext
/proc/priority_announce(text, title = "", sound, type , sender_override, has_important_message)
|
|
if(!text)
|
|
return
|
|
|
|
var/announcement
|
|
if(!sound)
|
|
sound = SSstation.announcer.get_rand_alert_sound()
|
|
else if(SSstation.announcer.event_sounds[sound])
|
|
sound = SSstation.announcer.event_sounds[sound]
|
|
|
|
if(type == "Priority")
|
|
announcement += "<h1 class='alert'>Priority Announcement</h1>"
|
|
if (title && length(title) > 0)
|
|
announcement += "<br><h2 class='alert'>[html_encode(title)]</h2>"
|
|
else if(type == "Captain")
|
|
announcement += "<h1 class='alert'>Captain Announces</h1>"
|
|
GLOB.news_network.SubmitArticle(html_encode(text), "Captain's Announcement", "Station Announcements", null)
|
|
|
|
else
|
|
if(!sender_override)
|
|
announcement += "<h1 class='alert'>[command_name()] Update</h1>"
|
|
else
|
|
announcement += "<h1 class='alert'>[sender_override]</h1>"
|
|
if (title && length(title) > 0)
|
|
announcement += "<br><h2 class='alert'>[html_encode(title)]</h2>"
|
|
|
|
if(!sender_override)
|
|
if(title == "")
|
|
GLOB.news_network.SubmitArticle(text, "Central Command Update", "Station Announcements", null)
|
|
else
|
|
GLOB.news_network.SubmitArticle(title + "<br><br>" + text, "Central Command", "Station Announcements", null)
|
|
|
|
///If the announcer overrides alert messages, use that message.
|
|
if(SSstation.announcer.custom_alert_message && !has_important_message)
|
|
announcement += SSstation.announcer.custom_alert_message
|
|
else
|
|
announcement += "<br><span class='alert'>[html_encode(text)]</span><br>"
|
|
announcement += "<br>"
|
|
|
|
var/s = sound(sound)
|
|
for(var/mob/M in GLOB.player_list)
|
|
if(!isnewplayer(M) && M.can_hear())
|
|
to_chat(M, announcement)
|
|
if(M.client.prefs.toggles & SOUND_ANNOUNCEMENTS)
|
|
SEND_SOUND(M, s)
|
|
|
|
/proc/print_command_report(text = "", title = null, announce=TRUE)
|
|
if(!title)
|
|
title = "Classified [command_name()] Update"
|
|
|
|
if(announce)
|
|
priority_announce("A report has been downloaded and printed out at all communications consoles.", "Incoming Classified Message", SSstation.announcer.get_rand_report_sound(), has_important_message = TRUE)
|
|
|
|
var/datum/comm_message/M = new
|
|
M.title = title
|
|
M.content = text
|
|
|
|
SScommunications.send_message(M)
|
|
|
|
/proc/minor_announce(message, title = "Attention:", alert, html_encode = TRUE)
|
|
if(!message)
|
|
return
|
|
|
|
if (html_encode)
|
|
title = html_encode(title)
|
|
message = html_encode(message)
|
|
|
|
for(var/mob/M in GLOB.player_list)
|
|
if(!isnewplayer(M) && M.can_hear())
|
|
to_chat(M, "<span class='minorannounce'><font color = red>[title]</font color><BR>[message]</span><BR>")
|
|
if(M.client.prefs.toggles & SOUND_ANNOUNCEMENTS)
|
|
if(alert)
|
|
SEND_SOUND(M, sound('sound/misc/notice1.ogg'))
|
|
else
|
|
SEND_SOUND(M, sound('sound/misc/notice2.ogg'))
|