mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-30 02:52:30 +00:00
a51f056319
* Moves the plant analyzer chem mode to right click + lets you read out a tray's chemical contents * Update growninedible.dm * Update grown.dm * Create grown.dm Co-authored-by: MrMelbert <51863163+MrMelbert@users.noreply.github.com> Co-authored-by: Gandalf <jzo123@hotmail.com>
47 lines
1.4 KiB
Plaintext
47 lines
1.4 KiB
Plaintext
// **********************
|
|
// Other harvested materials from plants (that are not food)
|
|
// **********************
|
|
|
|
/obj/item/grown // Grown weapons
|
|
name = "grown_weapon"
|
|
icon = 'icons/obj/hydroponics/harvest.dmi'
|
|
resistance_flags = FLAMMABLE
|
|
var/obj/item/seeds/seed = null // type path, gets converted to item on New(). It's safe to assume it's always a seed item.
|
|
|
|
/obj/item/grown/Initialize(mapload, obj/item/seeds/new_seed)
|
|
. = ..()
|
|
create_reagents(100)
|
|
|
|
if(new_seed)
|
|
seed = new_seed.Copy()
|
|
else if(ispath(seed))
|
|
// This is for adminspawn or map-placed growns. They get the default stats of their seed type.
|
|
seed = new seed()
|
|
seed.adjust_potency(50-seed.potency)
|
|
|
|
pixel_x = base_pixel_x + rand(-5, 5)
|
|
pixel_y = base_pixel_y + rand(-5, 5)
|
|
|
|
if(seed)
|
|
// Go through all traits in their genes and call on_new_plant from them.
|
|
for(var/datum/plant_gene/trait/trait in seed.genes)
|
|
trait.on_new_plant(src, loc)
|
|
|
|
if(istype(src, seed.product)) // no adding reagents if it is just a trash item
|
|
seed.prepare_result(src)
|
|
transform *= TRANSFORM_USING_VARIABLE(seed.potency, 100) + 0.5
|
|
add_juice()
|
|
|
|
/obj/item/grown/proc/add_juice()
|
|
if(reagents)
|
|
return TRUE
|
|
return FALSE
|
|
|
|
/obj/item/grown/microwave_act(obj/machinery/microwave/M)
|
|
return
|
|
|
|
/obj/item/grown/on_grind()
|
|
. = ..()
|
|
for(var/i in 1 to grind_results.len)
|
|
grind_results[grind_results[i]] = round(seed.potency)
|