mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-15 12:11:45 +00:00
ff6b41aa07
## About The Pull Request - Afterattack is a very simple proc now: All it does is this, and all it's used for is for having a convenient place to put effects an item does after a successful attack (IE, the attack was not blocked)  - An overwhelming majority of afterattack implementations have been moved to `interact_with_atom` or the new `ranged_interact_with_atom` I have manually tested many of the refactored procs but there was 200+ so it's kinda hard ## Why It's Good For The Game Afterattack is one of the worst parts of the attack chain, as it simultaneously serves as a way of doing random interactions NOT AT ALL related to attacks (despite the name) while ALSO serving as the defacto way to do a ranged interaction with an item This means careless coders (most of them) may throw stuff in afterattack without realizing how wide reaching it is, which causes bugs. By making two well defined, separate procs for handing adjacent vs ranged interactions, it becomes WAY WAY WAY more easy to develop for. If you want to do something when you click on something else and you're adjacent, use `interact_with_atom` If you want to do something when you click on something else and you're not adjacent, use 'ranged_interact_with_atom` This does result in some instances of boilerplate as shown here:  But I think it's acceptable, feel free to oppose if you don't I'm sure we can think of another solution ~~Additionally it makes it easier to implement swing combat. That's a bonus I guess~~ ## Changelog 🆑 Melbert refactor: Over 200 item interactions have been refactored to use a newer, easier-to-use system. Report any oddities with using items on other objects you may see (such as surgery, reagent containers like cups and spray bottles, or construction devices), especially using something at range (such as guns or chisels) refactor: Item-On-Modsuit interactions have changed slightly. While on combat mode, you will attempt to "use" the item on the suit instead of inserting it into the suit's storage. This means being on combat mode while the suit's panel is open will block you from inserting items entirely via click (but other methods such as hotkey, clicking on the storage boxes, and mousedrop will still work). refactor: The detective's scanner will now be inserted into storage items if clicked normally, and will scan the storage item if on combat mode /🆑
94 lines
3.5 KiB
Plaintext
94 lines
3.5 KiB
Plaintext
/**
|
|
* ## On Hit Effect Component!
|
|
*
|
|
* Component for other elements/components to rely on for on-hit effects without duplicating the on-hit code.
|
|
* See Lifesteal, or bane for examples.
|
|
*
|
|
* THIS COULD EASILY SUPPORT COMPONENT_DUPE_ALLOWED but the getcomponent makes it throw errors. if you can figure that out feel free to readd the dupe types
|
|
*/
|
|
/datum/component/on_hit_effect
|
|
///callback used by other components to apply effects
|
|
var/datum/callback/on_hit_callback
|
|
///callback optionally used for more checks
|
|
var/datum/callback/extra_check_callback
|
|
///optionally should we also apply the effect if thrown at something?
|
|
var/thrown_effect
|
|
|
|
/datum/component/on_hit_effect/Initialize(on_hit_callback, extra_check_callback, thrown_effect = FALSE)
|
|
src.on_hit_callback = on_hit_callback
|
|
src.extra_check_callback = extra_check_callback
|
|
if(!(ismachinery(parent) || isstructure(parent) || isgun(parent) || isprojectilespell(parent) || isitem(parent) || isanimal_or_basicmob(parent) || isprojectile(parent)))
|
|
return ELEMENT_INCOMPATIBLE
|
|
src.thrown_effect = thrown_effect
|
|
|
|
/datum/component/on_hit_effect/Destroy(force)
|
|
on_hit_callback = null
|
|
extra_check_callback = null
|
|
return ..()
|
|
|
|
/datum/component/on_hit_effect/RegisterWithParent()
|
|
if(ismachinery(parent) || isstructure(parent) || isgun(parent) || isprojectilespell(parent))
|
|
RegisterSignal(parent, COMSIG_PROJECTILE_ON_HIT, PROC_REF(on_projectile_hit))
|
|
else if(isitem(parent))
|
|
RegisterSignal(parent, COMSIG_ITEM_AFTERATTACK, PROC_REF(item_afterattack))
|
|
else if(isanimal_or_basicmob(parent))
|
|
RegisterSignal(parent, COMSIG_HOSTILE_POST_ATTACKINGTARGET, PROC_REF(hostile_attackingtarget))
|
|
else if(isprojectile(parent))
|
|
RegisterSignal(parent, COMSIG_PROJECTILE_SELF_ON_HIT, PROC_REF(on_projectile_self_hit))
|
|
|
|
if(thrown_effect)
|
|
RegisterSignal(parent, COMSIG_MOVABLE_IMPACT, PROC_REF(on_thrown_hit))
|
|
|
|
/datum/component/on_hit_effect/UnregisterFromParent()
|
|
UnregisterSignal(parent, list(
|
|
COMSIG_PROJECTILE_ON_HIT,
|
|
COMSIG_ITEM_AFTERATTACK,
|
|
COMSIG_HOSTILE_POST_ATTACKINGTARGET,
|
|
COMSIG_PROJECTILE_SELF_ON_HIT,
|
|
COMSIG_MOVABLE_IMPACT,
|
|
))
|
|
|
|
/datum/component/on_hit_effect/proc/item_afterattack(obj/item/source, atom/target, mob/user, proximity_flag, click_parameters)
|
|
SIGNAL_HANDLER
|
|
|
|
if(!proximity_flag)
|
|
return
|
|
|
|
if(extra_check_callback)
|
|
if(!extra_check_callback.Invoke(user, target, source))
|
|
return
|
|
on_hit_callback.Invoke(source, user, target, user.zone_selected)
|
|
|
|
/datum/component/on_hit_effect/proc/hostile_attackingtarget(mob/living/attacker, atom/target, success)
|
|
SIGNAL_HANDLER
|
|
|
|
if(!success)
|
|
return
|
|
|
|
if(extra_check_callback)
|
|
if(!extra_check_callback.Invoke(attacker, target))
|
|
return
|
|
on_hit_callback.Invoke(attacker, attacker, target, attacker.zone_selected)
|
|
|
|
/datum/component/on_hit_effect/proc/on_projectile_hit(datum/fired_from, atom/movable/firer, atom/target, angle, body_zone)
|
|
SIGNAL_HANDLER
|
|
|
|
if(extra_check_callback)
|
|
if(!extra_check_callback.Invoke(firer, target))
|
|
return
|
|
on_hit_callback.Invoke(fired_from, firer, target, body_zone)
|
|
|
|
/datum/component/on_hit_effect/proc/on_projectile_self_hit(datum/source, mob/firer, atom/target, angle, body_zone)
|
|
SIGNAL_HANDLER
|
|
|
|
if(extra_check_callback)
|
|
if(!extra_check_callback.Invoke(firer, target))
|
|
return
|
|
on_hit_callback.Invoke(source, firer, target, body_zone)
|
|
|
|
/datum/component/on_hit_effect/proc/on_thrown_hit(datum/source, atom/hit_atom, datum/thrownthing/throwingdatum)
|
|
SIGNAL_HANDLER
|
|
if(extra_check_callback && !extra_check_callback.Invoke(source, hit_atom))
|
|
return
|
|
on_hit_callback.Invoke(source, source, hit_atom, null)
|