mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-03 21:42:06 +00:00
b77fa8c2a2
## About The Pull Request [Implements a setter for starlight variables](af34f06b41) I want to start to modify starlight more, and that means I need a way to hook into everything that uses it and update it, so we can modify it on the fly. This does that, alongside removing space overlays from nearspace (too many false positives) and making the aurora modify all turfs projecting starlight, rather then all turfs in an area. Do still need to figure out handling for the starlight color usage in turf underlays tho (I gave up, we just keep it static. I'll fix it someday but the render_relay strategy just doesn't work with its masking setup) [Reworks how starlight overlays work](9da4bc38e2) Instead of setting color on the overlays directly, we instead store an object with our current settings in every mob's screen, and render_target it down onto our overlays. This lets us update overlay colors VERY trivially. Just need to set color on the overlay var. Makes modifying starlight a lot cheaper. It doesn't work on area overlays, because suffering, and it MIGHT induce extra cost on clients. if it does we can do something about that, we'll play it by ear [Removes parallax starlight coloring.](5f701a1b13) I'm sorta iffy on the color, the effect can be real oppressive in some cases, and I'd like to use starlight color for more events in world, and having it vary can make that looking nice hard. [Adds some visual effects to narsie being summoned](a423cfcb2b) As the rune drawing progresses space (starlight and parallax) go from normal to greyscale. Then, right about when narsie shows up, starlight becomes vibrant red. It's a nice effect. I wanna do more shit like this, I think it'll improve vibes significantly. ## Why It's Good For The Game Can't embed it because of github's upload limit, can show a [link](https://cdn.discordapp.com/attachments/458452245256601615/1160821856358645860/2023-10-08_22-31-22.mp4?ex=65360e99&is=65239999&hm=680e33e4e0026b89e132afc50c04a648a24f869eb662f274a381a5de5c5a36f2&) for the narsie stuff Here's [one](https://cdn.discordapp.com/attachments/326831214667235328/1160813747196141568/2023-10-08_22-34-10.mp4?ex=6536070c&is=6523920c&hm=f8d571d1013da89887f49f3fec99f632251eeeac83085aa7dde97009aee3922f&) for the aurora too. This gives us more pretty starlight shit, and the ABILITY to do more pretty starlight shit. I'm pretty jazzed, and I hope people use this proc more (keeping in mind that it's pretty hard on the lighting system, and needs significant delay between changes) ## Changelog 🆑 add: Narsie summoning has had some effects added to space and starlight del: Removes the link between spacegas color and starlight. It was a slight bit too vibrant and I think impacted the vibe too wildly to be incidental. fix: The aurora event actually... works now. Space lights up and all that /🆑
119 lines
4.1 KiB
Plaintext
119 lines
4.1 KiB
Plaintext
// Causes any affecting light sources to be queued for a visibility update, for example a door got opened.
|
|
/turf/proc/reconsider_lights()
|
|
lighting_corner_NE?.vis_update()
|
|
lighting_corner_SE?.vis_update()
|
|
lighting_corner_SW?.vis_update()
|
|
lighting_corner_NW?.vis_update()
|
|
|
|
/turf/proc/lighting_clear_overlay()
|
|
if (lighting_object)
|
|
qdel(lighting_object, force=TRUE)
|
|
|
|
// Builds a lighting object for us, but only if our area is dynamic.
|
|
/turf/proc/lighting_build_overlay()
|
|
if (lighting_object)
|
|
qdel(lighting_object, force=TRUE) //Shitty fix for lighting objects persisting after death
|
|
|
|
new /datum/lighting_object(src)
|
|
|
|
// Used to get a scaled lumcount.
|
|
/turf/proc/get_lumcount(minlum = 0, maxlum = 1)
|
|
if (!lighting_object)
|
|
return 1
|
|
|
|
var/totallums = 0
|
|
var/datum/lighting_corner/L
|
|
L = lighting_corner_NE
|
|
if (L)
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
L = lighting_corner_SE
|
|
if (L)
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
L = lighting_corner_SW
|
|
if (L)
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
L = lighting_corner_NW
|
|
if (L)
|
|
totallums += L.lum_r + L.lum_b + L.lum_g
|
|
|
|
|
|
totallums /= 12 // 4 corners, each with 3 channels, get the average.
|
|
|
|
totallums = (totallums - minlum) / (maxlum - minlum)
|
|
|
|
totallums += dynamic_lumcount
|
|
|
|
return CLAMP01(totallums)
|
|
|
|
// Returns a boolean whether the turf is on soft lighting.
|
|
// Soft lighting being the threshold at which point the overlay considers
|
|
// itself as too dark to allow sight and see_in_dark becomes useful.
|
|
// So basically if this returns true the tile is unlit black.
|
|
/turf/proc/is_softly_lit()
|
|
if (!lighting_object)
|
|
return FALSE
|
|
|
|
return !(luminosity || dynamic_lumcount)
|
|
|
|
|
|
///Proc to add movable sources of opacity on the turf and let it handle lighting code.
|
|
/turf/proc/add_opacity_source(atom/movable/new_source)
|
|
LAZYADD(opacity_sources, new_source)
|
|
if(opacity)
|
|
return
|
|
recalculate_directional_opacity()
|
|
|
|
|
|
///Proc to remove movable sources of opacity on the turf and let it handle lighting code.
|
|
/turf/proc/remove_opacity_source(atom/movable/old_source)
|
|
LAZYREMOVE(opacity_sources, old_source)
|
|
if(opacity) //Still opaque, no need to worry on updating.
|
|
return
|
|
recalculate_directional_opacity()
|
|
|
|
|
|
///Calculate on which directions this turfs block view.
|
|
/turf/proc/recalculate_directional_opacity()
|
|
. = directional_opacity
|
|
if(opacity)
|
|
directional_opacity = ALL_CARDINALS
|
|
if(. != directional_opacity)
|
|
reconsider_lights()
|
|
return
|
|
directional_opacity = NONE
|
|
if(opacity_sources)
|
|
for(var/atom/movable/opacity_source as anything in opacity_sources)
|
|
if(opacity_source.flags_1 & ON_BORDER_1)
|
|
directional_opacity |= opacity_source.dir
|
|
else //If fulltile and opaque, then the whole tile blocks view, no need to continue checking.
|
|
directional_opacity = ALL_CARDINALS
|
|
break
|
|
if(. != directional_opacity && (. == ALL_CARDINALS || directional_opacity == ALL_CARDINALS))
|
|
reconsider_lights() //The lighting system only cares whether the tile is fully concealed from all directions or not.
|
|
|
|
///Transfer the lighting of one area to another
|
|
/turf/proc/transfer_area_lighting(area/old_area, area/new_area)
|
|
if(SSlighting.initialized && !space_lit)
|
|
if (new_area.static_lighting != old_area.static_lighting)
|
|
if (new_area.static_lighting)
|
|
lighting_build_overlay()
|
|
else
|
|
lighting_clear_overlay()
|
|
|
|
// We will only run this logic on turfs off the prime z layer
|
|
// Since on the prime z layer, we use an overlay on the area instead, to save time
|
|
if(SSmapping.z_level_to_plane_offset[z])
|
|
var/index = SSmapping.z_level_to_plane_offset[z] + 1
|
|
//Inherit overlay of new area
|
|
if(old_area.lighting_effects)
|
|
cut_overlay(old_area.lighting_effects[index])
|
|
if(new_area.lighting_effects)
|
|
add_overlay(new_area.lighting_effects[index])
|
|
|
|
// Manage removing/adding starlight overlays, we'll inherit from the area so we can drop it if the area has it already
|
|
if(space_lit)
|
|
if(!new_area.lighting_effects && old_area.lighting_effects)
|
|
overlays += GLOB.starlight_overlays[GET_TURF_PLANE_OFFSET(src) + 1]
|
|
else if (new_area.lighting_effects && !old_area.lighting_effects)
|
|
overlays -= GLOB.starlight_overlays[GET_TURF_PLANE_OFFSET(src) + 1]
|