mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-24 08:31:54 +00:00
53518e043b
## About The Pull Request This PR introduces a number of minor quality of life improvements to already existing circuit components, and adds three new components. <img width="600" alt="preview" src="https://github.com/tgstation/tgstation/assets/80724828/85d39b6d-b055-430e-8996-0da088616887"> ## Why It's Good For The Game This improves the overall experience for circuits. ### UI changes <img width="550" alt="grid aligned" src="https://github.com/tgstation/tgstation/assets/80724828/cc7b43b5-292f-4643-beab-e01ae675fb19"> Grid align is now an option for circuit designers. It will round objects to the nearest 10px units internally, and can be toggled on/off by the new additional button beside the component menu button. This makes circuits easier on the eyes as things are pixel perfect aligned. <img width="814" alt="tooltips" src="https://github.com/tgstation/tgstation/assets/80724828/0d31c98f-3be9-46e0-ab37-20bac3799112"> All three buttons have been given tool tips. ### Tweaked Components <img width="136" alt="voice activator" src="https://github.com/tgstation/tgstation/assets/80724828/21dd0f65-cb98-4bd5-aeb0-63315e842cb6"> * Adds a on/off flag to the voice activator component -- This saves power for circuits as you're not forced to use a compare flag check to turn off voice activation <img width="136" alt="speech" src="https://github.com/tgstation/tgstation/assets/80724828/9137b76c-3077-4597-8411-2d9694b39e9e"> * Adds a quiet mode flag to speech component -- This is ideal when you want a device to speak, but don't want other people to hear. A good example would be a handheld translator that you only want to hear yourself. ### New Components <img width="136" alt="ntnet list literal" src="https://github.com/tgstation/tgstation/assets/80724828/657c851b-d442-4a63-8650-410cb8e76089"> * An NTNet Send component that allows everything to be input much like the list literal component -- This makes sending stuff over NTNet easier for the user, and use less power as it won't require an additional list literal component <img width="136" alt="compare health state" src="https://github.com/tgstation/tgstation/assets/80724828/0bed076c-3aa1-4931-af90-2b9eb8e1ae9a"> * A health comparison component that checks the entity's health state, and can return true or false depending if the entity is alive, sleeping, unconscious, critical or dead -- This could be achieved by using a health sensor and a compare component, however it lacks the ability to know when a entity is unconscious or sleeping <img width="136" alt="toggle" src="https://github.com/tgstation/tgstation/assets/80724828/7017b6bf-937a-42ad-87f3-4f1134853ac3"> * A quick toggle component to allow the switching between a true and false state -- This could be achieved by using a logic component and self linking, however this makes it far easier for newcomers to make something as simple as an on/off switch (such as a handheld translator which uses the front button to turn on/off) ## Changelog 🆑 qol: Add tooltips to circuit editor buttons qol: Add grid alignment mode to circuit editor add: Added new compare health state component add: Added new NTNet send list literal component add: Added new toggle component qol: Added activity toggle to voice activator component qol: Added quiet mode to speech component qol: NTNet send component will not use power/trigger if NTNet is offline /🆑
57 lines
1.6 KiB
Plaintext
57 lines
1.6 KiB
Plaintext
/**
|
|
* # Compare Health State Component
|
|
*
|
|
* Returns true when state matches entity.
|
|
*/
|
|
|
|
/obj/item/circuit_component/compare/health_state
|
|
display_name = "Compare Health State"
|
|
desc = "A component that compares the health state of an organism, and returns true or false."
|
|
category = "Entity"
|
|
|
|
/// The input port
|
|
var/datum/port/input/input_port
|
|
|
|
/// Compare state option
|
|
var/datum/port/input/option/state_option
|
|
|
|
var/max_range = 5
|
|
|
|
/obj/item/circuit_component/compare/health_state/get_ui_notices()
|
|
. = ..()
|
|
. += create_ui_notice("Maximum Range: [max_range] tiles", "orange", "info")
|
|
|
|
/obj/item/circuit_component/compare/health_state/populate_options()
|
|
input_port = add_input_port("Organism", PORT_TYPE_ATOM)
|
|
|
|
var/static/component_options = list(
|
|
"Alive",
|
|
"Asleep",
|
|
"Critical",
|
|
"Unconscious",
|
|
"Deceased",
|
|
)
|
|
state_option = add_option_port("Comparison Option", component_options)
|
|
|
|
/obj/item/circuit_component/compare/health_state/do_comparisons()
|
|
var/mob/living/organism = input_port.value
|
|
var/turf/current_turf = get_location()
|
|
if(!istype(organism) || current_turf.z != organism.z || get_dist(current_turf, organism) > max_range)
|
|
return FALSE
|
|
|
|
var/current_option = state_option.value
|
|
var/state = organism.stat
|
|
switch(current_option)
|
|
if("Alive")
|
|
return state != DEAD
|
|
if("Asleep")
|
|
return !!organism.IsSleeping() && !organism.IsUnconscious()
|
|
if("Critical")
|
|
return state == SOFT_CRIT || state == HARD_CRIT
|
|
if("Unconscious")
|
|
return state == UNCONSCIOUS || state == HARD_CRIT || !!organism.IsUnconscious()
|
|
if("Deceased")
|
|
return state == DEAD
|
|
//Unknown state, something fucked up really bad - just return false
|
|
return FALSE
|