mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-13 11:12:14 +00:00
f00caffd90
## About The Pull Request Metalgen imprinting is now logged, foam and smoke have better logging and so do plasma metalgenned things, metalgen no longer causes a ton of runtimes on almost everything and foam and smoke no longer affect abstract objects. Also ***hopefully*** solves the issue with infinite hotspot loops, but I don't think anyone knows what exactly occured there. ## Why It's Good For The Game If servers explode, admins need to know who did it and coders need to know how they did it. ## Changelog 🆑 fix: Metalgen foam/smoke no longer cause an absurd amount of runtimes fix: Foam and smoke no longer affect abstract objects like landmarks admin: Metalgen imprinting is now logged admin: Improved logging for foam and smoke, and plasma metalgenned objects /🆑
109 lines
4.6 KiB
Plaintext
109 lines
4.6 KiB
Plaintext
/// Component that floods gas when ignited by fire.
|
|
/datum/component/combustible_flooder
|
|
// Gas type, molar count, and temperature. All self explanatory.
|
|
var/gas_id
|
|
var/gas_amount
|
|
var/temp_amount
|
|
|
|
/datum/component/combustible_flooder/Initialize(initialize_gas_id, initialize_gas_amount, initialize_temp_amount)
|
|
|
|
src.gas_id = initialize_gas_id
|
|
src.gas_amount = initialize_gas_amount
|
|
src.temp_amount = initialize_temp_amount
|
|
|
|
// Any item made of plasma is going to have this component, making it extremely difficult to blacklist fire hazards during create_and_destroy.
|
|
// So let's just completely neuter them during unit tests so we don't burn down the testing area and cause spurious runtimes.
|
|
#ifndef UNIT_TESTS
|
|
RegisterSignal(parent, COMSIG_ATOM_ATTACKBY, PROC_REF(attackby_react))
|
|
RegisterSignal(parent, COMSIG_ATOM_FIRE_ACT, PROC_REF(flame_react))
|
|
RegisterSignal(parent, COMSIG_ATOM_TOUCHED_SPARKS, PROC_REF(sparks_react))
|
|
RegisterSignal(parent, COMSIG_ATOM_BULLET_ACT, PROC_REF(projectile_react))
|
|
RegisterSignal(parent, COMSIG_ATOM_TOOL_ACT(TOOL_WELDER), PROC_REF(welder_react))
|
|
if(isturf(parent))
|
|
RegisterSignal(parent, COMSIG_TURF_EXPOSE, PROC_REF(hotspots_react))
|
|
#endif
|
|
|
|
/datum/component/combustible_flooder/UnregisterFromParent()
|
|
UnregisterSignal(parent, COMSIG_ATOM_ATTACKBY)
|
|
UnregisterSignal(parent, COMSIG_ATOM_FIRE_ACT)
|
|
UnregisterSignal(parent, COMSIG_ATOM_BULLET_ACT)
|
|
UnregisterSignal(parent, COMSIG_ATOM_TOOL_ACT(TOOL_WELDER))
|
|
if(isturf(parent))
|
|
UnregisterSignal(parent, COMSIG_TURF_EXPOSE)
|
|
|
|
/// Do the flooding. Trigger temperature is the temperature we will flood at if we dont have a temp set at the start. Trigger referring to whatever triggered it.
|
|
/datum/component/combustible_flooder/proc/flood(mob/user, trigger_temperature)
|
|
var/delete_parent = TRUE
|
|
var/turf/open/flooded_turf = get_turf(parent)
|
|
|
|
// We do this check early so closed turfs are still be able to flood.
|
|
if(isturf(parent)) // Walls and floors.
|
|
var/turf/parent_turf = parent
|
|
flooded_turf = parent_turf.ScrapeAway(1, CHANGETURF_INHERIT_AIR | CHANGETURF_FORCEOP) // Ensure that we always forcefully replace the turf, even if the baseturf has the same type
|
|
delete_parent = FALSE
|
|
|
|
flooded_turf.atmos_spawn_air("[gas_id]=[gas_amount];[TURF_TEMPERATURE((temp_amount || trigger_temperature))]")
|
|
|
|
// Logging-related
|
|
var/admin_message = "[flooded_turf] ignited in [ADMIN_VERBOSEJMP(flooded_turf)]"
|
|
var/log_message = "ignited [flooded_turf] at [AREACOORD(flooded_turf)]"
|
|
if(user)
|
|
admin_message += " by [ADMIN_LOOKUPFLW(user)] at [ADMIN_COORDJMP(flooded_turf)]"
|
|
user.log_message(log_message, LOG_ATTACK, log_globally = FALSE)//only individual log
|
|
else
|
|
log_message = "[key_name(user)] " + log_message + " by fire at [AREACOORD(flooded_turf)]"
|
|
admin_message += " by fire at [ADMIN_COORDJMP(flooded_turf)]"
|
|
log_attack(log_message)
|
|
message_admins(admin_message)
|
|
|
|
if(delete_parent && !QDELETED(parent))
|
|
if(isobj(parent))
|
|
var/obj/obj_parent = parent
|
|
obj_parent.deconstruct(disassembled = FALSE)
|
|
else
|
|
qdel(parent) // For things with the explodable component like plasma mats this isn't necessary, but there's no harm.
|
|
qdel(src)
|
|
|
|
/// fire_act reaction.
|
|
/datum/component/combustible_flooder/proc/flame_react(datum/source, exposed_temperature, exposed_volume)
|
|
SIGNAL_HANDLER
|
|
|
|
if(exposed_temperature > FIRE_MINIMUM_TEMPERATURE_TO_EXIST)
|
|
flood(null, exposed_temperature)
|
|
|
|
/// sparks_touched reaction.
|
|
/datum/component/combustible_flooder/proc/sparks_react(datum/source, obj/effect/particle_effect/sparks/sparks)
|
|
SIGNAL_HANDLER
|
|
|
|
if(sparks) // this shouldn't ever be false but existence is mysterious
|
|
flood(null, FIRE_MINIMUM_TEMPERATURE_TO_SPREAD)
|
|
|
|
/// Hotspot reaction.
|
|
/datum/component/combustible_flooder/proc/hotspots_react(datum/source, air, exposed_temperature)
|
|
SIGNAL_HANDLER
|
|
|
|
if(exposed_temperature > FIRE_MINIMUM_TEMPERATURE_TO_EXIST)
|
|
flood(null, exposed_temperature)
|
|
|
|
/// Being attacked by something
|
|
/datum/component/combustible_flooder/proc/attackby_react(datum/source, obj/item/thing, mob/user, params)
|
|
SIGNAL_HANDLER
|
|
|
|
if(thing.get_temperature() > FIRE_MINIMUM_TEMPERATURE_TO_EXIST)
|
|
flood(user, thing.get_temperature())
|
|
|
|
/// Shot by something
|
|
/datum/component/combustible_flooder/proc/projectile_react(datum/source, obj/projectile/shot)
|
|
SIGNAL_HANDLER
|
|
|
|
if(shot.damage_type == BURN && shot.damage > 0)
|
|
flood(shot.firer, 2500)
|
|
|
|
/// Welder check. Here because tool_act is higher priority than attackby.
|
|
/datum/component/combustible_flooder/proc/welder_react(datum/source, mob/user, obj/item/tool)
|
|
SIGNAL_HANDLER
|
|
|
|
if(tool.get_temperature() >= FIRE_MINIMUM_TEMPERATURE_TO_EXIST)
|
|
flood(user, tool.get_temperature())
|
|
return ITEM_INTERACT_BLOCKING
|