mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-13 03:02:38 +00:00
58501dce77
## About The Pull Request <details> - renamed ai folder to announcer -- announcer -- - moved vox_fem to announcer - moved approachingTG to announcer - separated the ambience folder into ambience and instrumental -- ambience -- - created holy folder moved all related sounds there - created engineering folder and moved all related sounds there - created security folder and moved ambidet there - created general folder and moved ambigen there - created icemoon folder and moved all icebox-related ambience there - created medical folder and moved all medbay-related ambi there - created ruin folder and moves all ruins ambi there - created beach folder and moved seag and shore there - created lavaland folder and moved related ambi there - created aurora_caelus folder and placed its ambi there - created misc folder and moved the rest of the files that don't have a specific category into it -- instrumental -- - moved traitor folder here - created lobby_music folder and placed our songs there (title0 not used anywhere? - server-side modification?) -- items -- - moved secdeath to hailer - moved surgery to handling -- effects -- - moved chemistry into effects - moved hallucinations into effects - moved health into effects - moved magic into effects -- vehicles -- - moved mecha into vehicles created mobs folder -- mobs -- - moved creatures folder into mobs - moved voice into mobs renamed creatures to non-humanoids renamed voice to humanoids -- non-humanoids-- created cyborg folder created hiss folder moved harmalarm.ogg to cyborg -- humanoids -- -- misc -- moved ghostwhisper to misc moved insane_low_laugh to misc I give up trying to document this. </details> - [X] ambience - [x] announcer - [x] effects - [X] instrumental - [x] items - [x] machines - [x] misc - [X] mobs - [X] runtime - [X] vehicles - [ ] attributions ## Why It's Good For The Game This folder is so disorganized that it's vomit inducing, will make it easier to find and add new sounds, providng a minor structure to the sound folder. ## Changelog 🆑 grungussuss refactor: the sound folder in the source code has been reorganized, please report any oddities with sounds playing or not playing server: lobby music has been repathed to sound/music/lobby_music /🆑
52 lines
1.5 KiB
Plaintext
52 lines
1.5 KiB
Plaintext
/// Applied to living mobs.
|
|
/// Adds a force threshold for which attacks will be blocked entirely.
|
|
/// IE, if they are hit with an attack that deals less than X damage, the attack does nothing.
|
|
/datum/element/damage_threshold
|
|
element_flags = ELEMENT_BESPOKE
|
|
argument_hash_start_idx = 2
|
|
/// Incoming attacks beneath this threshold, inclusive, will be blocked entirely
|
|
var/force_threshold = -1
|
|
|
|
/datum/element/damage_threshold/Attach(datum/target, threshold)
|
|
. = ..()
|
|
if(!isliving(target))
|
|
return ELEMENT_INCOMPATIBLE
|
|
if(!isnum(threshold) || threshold <= 0)
|
|
return ELEMENT_INCOMPATIBLE
|
|
|
|
RegisterSignal(target, COMSIG_LIVING_CHECK_BLOCK, PROC_REF(check_block))
|
|
force_threshold = threshold
|
|
|
|
/datum/element/damage_threshold/Detach(datum/source, ...)
|
|
. = ..()
|
|
UnregisterSignal(source, COMSIG_LIVING_CHECK_BLOCK)
|
|
|
|
/datum/element/damage_threshold/proc/check_block(
|
|
mob/living/source,
|
|
atom/hitby,
|
|
damage,
|
|
attack_text,
|
|
attack_type,
|
|
armour_penetration,
|
|
damage_type,
|
|
attack_flag,
|
|
)
|
|
SIGNAL_HANDLER
|
|
|
|
if(damage <= 0) // Already handled
|
|
return NONE
|
|
|
|
if(damage <= force_threshold)
|
|
var/obj/item/item_hitting = hitby
|
|
var/tap_vol = istype(item_hitting) ? item_hitting.get_clamped_volume() : 50
|
|
source.visible_message(
|
|
span_warning("[source] looks unharmed!"),
|
|
span_warning("[attack_text] deals no damage to you!"),
|
|
span_hear("You hear a thud."),
|
|
COMBAT_MESSAGE_RANGE,
|
|
)
|
|
playsound(source, 'sound/items/weapons/tap.ogg', tap_vol, TRUE, -1)
|
|
return SUCCESSFUL_BLOCK
|
|
|
|
return NONE
|