mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-15 20:22:07 +00:00
c58cbb4dfb
## About The Pull Request This is a port/rework of https://github.com/yogstation13/Yogstation/pull/15735 - I changed a lot of how it acted (some themes are locked behind maintenance apps). The original author allowed this port to happen, and I really liked how it looked there so I'd like to add it here. ### Applications Removes the hardware configurator application, as all it did was show you your space and battery now that all hardware was removed. These are things your PC does by default, so it was just a waste of space. Adds a Theme manager application instead, which allows you to change your PDA's theme at will. Adds a new Maintenance application that will give a new theme, however it will also increase the size of the theme manager app itself as it's bloatware. ### Menu There's now a bar at the top of the menu showing 'special' tablet apps which, for one reason or another, should stand out from the rest of the apps. Currently this is PDA messenger and the Theme manager Flashlight and Flashlight color is now only an icon, and is shown on the same line as Updating you ID https://cdn.discordapp.com/attachments/961874788706574386/1069621173693972551/2023-01-30_09-10-52.mov  ### Themes Adds a lot of themes to choose from, although SOME are hidden behind Maintenance applications, which will give you a random theme. These are bloatware however, so they come with some extra cost to the app's required space storage. Themes are now supported on ALL APPLICATIONS! If you have a computer theme, you will have that theme in EVERY app you enter, rather than just a select few. ALSO also, emagging the tablet will automatically set & unlock the Syndicate theme, which makes your PDA obvious but you can disguise it if you wish through just re-painting it to something else. https://cdn.discordapp.com/attachments/828923843829432340/1069565383155122266/2023-01-30_05-29-53.mov ### Preferences This also adds a pref for theme, reworking the ringtone code to work with it as well. I also removed 2 entirely unused PDA prefs just 'cause. Screenshot not up-to-date, they now have proper names.  ### Other stuff Made defines for device_themes Added support for special app-side checks to download files Fixed programs downloading themselves TWICE because defines all had the same definition Removes the Chemistry computer disk as it was empty due to chemistry app's removal Removes the 'run_emag' proc, since apps can directly refer to the computer to check for emag status instead. Moved over and added better documentation on data computer files, and moved the ordnance ones to the same file as the others. ## Why It's Good For The Game It makes PDAs a lot more customizable while adding more features to maintenance applications. I think the themes look cool and it fits with PDAs being "personal" anyways. I also explained most of my other arguments in the about section, such as the hardware configuration application. ## Changelog 🆑 Chubbygummibear & JohnFulpWillard add: A ton of new NtOS themes, which are accessible by the new Themify application that comes with all PCs. add: Emagging a PC now defaults it to the Syndicate option (and adds it to go back to it if you wish) add: There's a new maintenance app that gives you rarer themes qol: The NtOS Main menu was moved around, added "header" applications that are shown where the Flashlight is, such as your Theme manager and PDA messenger. code: Made defines for device_themes code: Added support for special app-side checks to download files code: Removes the 'run_emag' proc, since apps can directly refer to the computer to check for emag status instead. fix: Programs no longer download twice. del: Removes the Chemistry computer disk as it was empty due to chemistry app's removal /🆑 --------- Co-authored-by: san7890 <the@san7890.com>
92 lines
2.9 KiB
Plaintext
92 lines
2.9 KiB
Plaintext
/**
|
|
* store_file
|
|
*
|
|
* Adds an already initialized file to the computer, checking if one already exists.
|
|
* Returns TRUE if successfully stored, FALSE otherwise.
|
|
*/
|
|
/obj/item/modular_computer/proc/store_file(datum/computer_file/file_storing)
|
|
if(!file_storing || !istype(file_storing))
|
|
return FALSE
|
|
if(!can_store_file(file_storing))
|
|
return FALSE
|
|
|
|
// This file is already stored. Don't store it again.
|
|
if(file_storing in stored_files)
|
|
return FALSE
|
|
|
|
SEND_SIGNAL(file_storing, COMSIG_MODULAR_COMPUTER_FILE_ADDING)
|
|
file_storing.computer = src
|
|
stored_files.Add(file_storing)
|
|
used_capacity += file_storing.size
|
|
SEND_SIGNAL(file_storing, COMSIG_MODULAR_COMPUTER_FILE_ADDED)
|
|
return TRUE
|
|
|
|
/**
|
|
* remove_file
|
|
*
|
|
* Removes a given file from the computer, if possible.
|
|
* Properly checking if the file even exists and is in the computer.
|
|
* Returns TRUE if successfully completed, FALSE otherwise
|
|
*/
|
|
/obj/item/modular_computer/proc/remove_file(datum/computer_file/file_removing)
|
|
if(!file_removing || !istype(file_removing))
|
|
return FALSE
|
|
if(!(file_removing in stored_files))
|
|
return FALSE
|
|
if(istype(file_removing, /datum/computer_file/program))
|
|
var/datum/computer_file/program/program_file = file_removing
|
|
if(program_file.program_state != PROGRAM_STATE_KILLED)
|
|
program_file.kill_program(TRUE)
|
|
if(program_file.program_state == PROGRAM_STATE_ACTIVE)
|
|
active_program = null
|
|
|
|
SEND_SIGNAL(file_removing, COMSIG_MODULAR_COMPUTER_FILE_DELETING)
|
|
stored_files.Remove(file_removing)
|
|
used_capacity -= file_removing.size
|
|
SEND_SIGNAL(file_removing, COMSIG_MODULAR_COMPUTER_FILE_DELETED)
|
|
return TRUE
|
|
|
|
/**
|
|
* can_store_file
|
|
*
|
|
* Checks if a computer can store a file, as computers can only store unique files.
|
|
* returns TRUE if possible, FALSE otherwise.
|
|
*/
|
|
/obj/item/modular_computer/proc/can_store_file(datum/computer_file/file)
|
|
if(!file || !istype(file))
|
|
return FALSE
|
|
if(file in stored_files)
|
|
return FALSE
|
|
if(find_file_by_name(file.filename))
|
|
return FALSE
|
|
// In the unlikely event someone manages to create that many files.
|
|
// BYOND is acting weird with numbers above 999 in loops (infinite loop prevention)
|
|
if(stored_files.len >= 999)
|
|
return FALSE
|
|
if((used_capacity + file.size) > max_capacity)
|
|
return FALSE
|
|
if(!file.can_store_file(src))
|
|
return FALSE
|
|
|
|
return TRUE
|
|
|
|
/**
|
|
* find_file_by_name
|
|
*
|
|
* Will check all applications in a tablet for files and, if they have \
|
|
* the same filename (disregarding extension), will return it.
|
|
* If a computer disk is passed instead, it will check the disk over the computer.
|
|
*/
|
|
/obj/item/modular_computer/proc/find_file_by_name(filename, obj/item/computer_disk/target_disk)
|
|
if(!filename)
|
|
return null
|
|
if(target_disk)
|
|
for(var/datum/computer_file/file as anything in target_disk.stored_files)
|
|
if(file.filename == filename)
|
|
return file
|
|
else
|
|
for(var/datum/computer_file/file as anything in stored_files)
|
|
if(file.filename == filename)
|
|
return file
|
|
return null
|