mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-11 18:22:14 +00:00
ca366c3ea1
Replaces like 70-80% of 0 and such, as a side effect cleaned up a bunch of returns Edit: Most left out ones are in mecha which should be done in mecha refactor already Oh my look how clean it is Co-authored-by: TiviPlus <TiviPlus> Co-authored-by: Couls <coul422@gmail.com>
39 lines
1.2 KiB
Plaintext
39 lines
1.2 KiB
Plaintext
//Used to process objects. Fires once every second.
|
|
|
|
SUBSYSTEM_DEF(processing)
|
|
name = "Processing"
|
|
priority = FIRE_PRIORITY_PROCESS
|
|
flags = SS_BACKGROUND|SS_POST_FIRE_TIMING|SS_NO_INIT
|
|
wait = 10
|
|
|
|
var/stat_tag = "P" //Used for logging
|
|
var/list/processing = list()
|
|
var/list/currentrun = list()
|
|
|
|
/datum/controller/subsystem/processing/stat_entry(msg)
|
|
msg = "[stat_tag]:[length(processing)]"
|
|
return ..()
|
|
|
|
/datum/controller/subsystem/processing/fire(resumed = FALSE)
|
|
if (!resumed)
|
|
currentrun = processing.Copy()
|
|
//cache for sanic speed (lists are references anyways)
|
|
var/list/current_run = currentrun
|
|
|
|
while(current_run.len)
|
|
var/datum/thing = current_run[current_run.len]
|
|
current_run.len--
|
|
if(QDELETED(thing))
|
|
processing -= thing
|
|
else if(thing.process(wait) == PROCESS_KILL)
|
|
// fully stop so that a future START_PROCESSING will work
|
|
STOP_PROCESSING(src, thing)
|
|
if (MC_TICK_CHECK)
|
|
return
|
|
|
|
|
|
///This proc is called on a datum if it is being processed in a subsystem. If you override this do not call parent, as it will return PROCESS_KILL. This is done to prevent objects that dont override process() from staying in the processing list
|
|
/datum/proc/process()
|
|
set waitfor = FALSE
|
|
return PROCESS_KILL
|