mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-10 17:52:36 +00:00
cb3b675bae
* Tablets don't close their UI when changing program (and some fixes) (#73635) ## About The Pull Request - Tablets now refresh their page when changing programs, this means the UI will no longer close and reopen itself several times (or even have several UIs open if shit broke hard enough). - Removed tablet's attack self because interact already does everything it had to do. - Header programs now close when minimized (as there's no button to close them in the main menu. - Removed a lot of program UI stuff, it's now handled by the PC itself, such as header data and ui host. - Cut off asset sending from TGUI into it's own proc so I can re-send assets when changing programs - Added an ejection button for machine computers - Fixed ID not ejecting into the user's hand when using 'Eject ID' - Fixes a minor runtime when opening the MODsuit application without a MODsuit already connected. ## Why It's Good For The Game Fixes some bugs that I found with tablets UIS now won't be flickering as bad in front of them, or have inconsistent placement (like when you move your main menu UI, go to Messenger, then it's back to the center of the screen). Video of it in action https://user-images.githubusercontent.com/53777086/221301417-78321149-0c10-475e-bd29-79f5a4ba0597.mp4 ## Changelog 🆑 fix: Being in an application now properly uses the tablet's battery. fix: Messenger and Themify apps now close when minimized, so don't count towards the running app limit. fix: Tablet UIs will now no longer spam open/close the UI when changing applications fix: Using the Eject ID button on tablets now ejects into your hand. fix: Computers now have an Eject ID button refactor: Cut down a lot of copy paste in tablet & program code, now it's mostly done by the tablet. /🆑 * Tablets don't close their UI when changing program (and some fixes) * Update contractor_tablet.dm * wew --------- Co-authored-by: John Willard <53777086+JohnFulpWillard@users.noreply.github.com> Co-authored-by: Zonespace <41448081+Zonespace27@users.noreply.github.com> Co-authored-by: Gandalf <9026500+Gandalf2k15@users.noreply.github.com>
108 lines
3.5 KiB
Plaintext
108 lines
3.5 KiB
Plaintext
//normal computer version is located in code\modules\power\monitor.dm, /obj/machinery/computer/monitor
|
|
|
|
/datum/computer_file/program/power_monitor
|
|
filename = "ampcheck"
|
|
filedesc = "AmpCheck"
|
|
category = PROGRAM_CATEGORY_ENGI
|
|
program_icon_state = "power_monitor"
|
|
extended_desc = "This program connects to sensors around the station to provide information about electrical systems"
|
|
ui_header = "power_norm.gif"
|
|
transfer_access = list(ACCESS_ENGINEERING)
|
|
usage_flags = PROGRAM_CONSOLE
|
|
requires_ntnet = FALSE
|
|
size = 8
|
|
tgui_id = "NtosPowerMonitor"
|
|
program_icon = "plug"
|
|
detomatix_resistance = DETOMATIX_RESIST_MINOR
|
|
|
|
var/has_alert = 0
|
|
var/datum/weakref/attached_wire_ref
|
|
var/datum/weakref/local_apc_ref
|
|
var/list/history = list()
|
|
var/record_size = 60
|
|
var/record_interval = 50
|
|
var/next_record = 0
|
|
|
|
|
|
/datum/computer_file/program/power_monitor/on_start(mob/living/user)
|
|
. = ..(user)
|
|
search()
|
|
history["supply"] = list()
|
|
history["demand"] = list()
|
|
|
|
|
|
/datum/computer_file/program/power_monitor/process_tick(delta_time)
|
|
if(!get_powernet())
|
|
search()
|
|
else
|
|
record()
|
|
|
|
/datum/computer_file/program/power_monitor/proc/search() //keep in sync with /obj/machinery/computer/monitor's version
|
|
var/turf/T = get_turf(computer)
|
|
attached_wire_ref = WEAKREF(locate(/obj/structure/cable) in T)
|
|
if(attached_wire_ref)
|
|
return
|
|
var/area/A = get_area(computer) //if the computer isn't directly connected to a wire, attempt to find the APC powering it to pull it's powernet instead
|
|
if(!A)
|
|
return
|
|
var/obj/machinery/power/apc/local_apc = A.apc
|
|
if(!local_apc)
|
|
return
|
|
if(!local_apc.terminal) //this really shouldn't happen without badminnery.
|
|
local_apc = null
|
|
local_apc_ref = WEAKREF(local_apc)
|
|
|
|
/datum/computer_file/program/power_monitor/proc/get_powernet() //keep in sync with /obj/machinery/computer/monitor's version
|
|
var/obj/structure/cable/attached_wire = attached_wire_ref?.resolve()
|
|
var/obj/machinery/power/apc/local_apc = local_apc_ref?.resolve()
|
|
if(attached_wire || (local_apc?.terminal))
|
|
return attached_wire ? attached_wire.powernet : local_apc.terminal.powernet
|
|
return FALSE
|
|
|
|
/datum/computer_file/program/power_monitor/proc/record() //keep in sync with /obj/machinery/computer/monitor's version
|
|
if(world.time >= next_record)
|
|
next_record = world.time + record_interval
|
|
|
|
var/datum/powernet/connected_powernet = get_powernet()
|
|
|
|
var/list/supply = history["supply"]
|
|
if(connected_powernet)
|
|
supply += connected_powernet.viewavail
|
|
if(supply.len > record_size)
|
|
supply.Cut(1, 2)
|
|
|
|
var/list/demand = history["demand"]
|
|
if(connected_powernet)
|
|
demand += connected_powernet.viewload
|
|
if(demand.len > record_size)
|
|
demand.Cut(1, 2)
|
|
|
|
/datum/computer_file/program/power_monitor/ui_data()
|
|
var/list/data = list()
|
|
var/datum/powernet/connected_powernet = get_powernet()
|
|
data["stored"] = record_size
|
|
data["interval"] = record_interval / 10
|
|
data["attached"] = connected_powernet ? TRUE : FALSE
|
|
if(connected_powernet)
|
|
data["supply"] = display_power(connected_powernet.viewavail)
|
|
data["demand"] = display_power(connected_powernet.viewload)
|
|
data["history"] = history
|
|
|
|
data["areas"] = list()
|
|
if(connected_powernet)
|
|
for(var/obj/machinery/power/terminal/term in connected_powernet.nodes)
|
|
var/obj/machinery/power/apc/A = term.master
|
|
if(istype(A))
|
|
data["areas"] += list(list(
|
|
"name" = A.area.name,
|
|
"charge" = A.cell ? A.cell.percent() : 0,
|
|
"load" = display_power(A.lastused_total),
|
|
"charging" = A.charging,
|
|
"eqp" = A.equipment,
|
|
"lgt" = A.lighting,
|
|
"env" = A.environ
|
|
))
|
|
|
|
return data
|
|
|