mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-16 03:56:20 +00:00
cf7e8aa9ec
* Qdels all queries, adds sleep handling * DB Core messages admins about undeleted queries * Compile fixes. Adds missing set waitfor * Remove world/New shennanigans. Add DBQuery/BlockingExecute() * Less spammy notifications to admins about undeleted queries * Increase dbcore fire time to 1 minute * Upgrade undeleted query warning * Better place of death * Fix build * Remove BlockingExecute, see BSQL PR for why * Yep, missed that one. * Psyche, that's the WRONG QUERY!!
102 lines
2.8 KiB
Plaintext
102 lines
2.8 KiB
Plaintext
//Speech verbs.
|
|
/mob/verb/say_verb(message as text)
|
|
set name = "Say"
|
|
set category = "IC"
|
|
if(GLOB.say_disabled) //This is here to try to identify lag problems
|
|
to_chat(usr, "<span class='danger'>Speech is currently admin-disabled.</span>")
|
|
return
|
|
if(message)
|
|
say(message)
|
|
|
|
|
|
/mob/verb/whisper_verb(message as text)
|
|
set name = "Whisper"
|
|
set category = "IC"
|
|
if(GLOB.say_disabled) //This is here to try to identify lag problems
|
|
to_chat(usr, "<span class='danger'>Speech is currently admin-disabled.</span>")
|
|
return
|
|
whisper(message)
|
|
|
|
/mob/proc/whisper(message, datum/language/language=null)
|
|
say(message, language) //only living mobs actually whisper, everything else just talks
|
|
|
|
/mob/verb/me_verb(message as text)
|
|
set name = "Me"
|
|
set category = "IC"
|
|
|
|
if(GLOB.say_disabled) //This is here to try to identify lag problems
|
|
to_chat(usr, "<span class='danger'>Speech is currently admin-disabled.</span>")
|
|
return
|
|
|
|
message = trim(copytext(sanitize(message), 1, MAX_MESSAGE_LEN))
|
|
|
|
usr.emote("me",1,message)
|
|
|
|
/mob/proc/say_dead(var/message)
|
|
var/name = real_name
|
|
var/alt_name = ""
|
|
|
|
if(GLOB.say_disabled) //This is here to try to identify lag problems
|
|
to_chat(usr, "<span class='danger'>Speech is currently admin-disabled.</span>")
|
|
return
|
|
|
|
var/jb = jobban_isbanned(src, "OOC")
|
|
if(QDELETED(src))
|
|
return
|
|
|
|
if(jb)
|
|
to_chat(src, "<span class='danger'>You have been banned from deadchat.</span>")
|
|
return
|
|
|
|
|
|
|
|
if (src.client)
|
|
if(src.client.prefs.muted & MUTE_DEADCHAT)
|
|
to_chat(src, "<span class='danger'>You cannot talk in deadchat (muted).</span>")
|
|
return
|
|
|
|
if(src.client.handle_spam_prevention(message,MUTE_DEADCHAT))
|
|
return
|
|
|
|
var/mob/dead/observer/O = src
|
|
if(isobserver(src) && O.deadchat_name)
|
|
name = "[O.deadchat_name]"
|
|
else
|
|
if(mind && mind.name)
|
|
name = "[mind.name]"
|
|
else
|
|
name = real_name
|
|
if(name != real_name)
|
|
alt_name = " (died as [real_name])"
|
|
|
|
var/K
|
|
|
|
if(key)
|
|
K = src.key
|
|
|
|
message = src.say_quote(message, get_spans())
|
|
var/rendered = "<span class='game deadsay'><span class='prefix'>DEAD:</span> <span class='name'>[name]</span>[alt_name] <span class='message'>[message]</span></span>"
|
|
log_message("DEAD: [message]", INDIVIDUAL_SAY_LOG)
|
|
deadchat_broadcast(rendered, follow_target = src, speaker_key = K)
|
|
|
|
/mob/proc/check_emote(message)
|
|
if(copytext(message, 1, 2) == "*")
|
|
emote(copytext(message, 2))
|
|
return 1
|
|
|
|
/mob/proc/hivecheck()
|
|
return 0
|
|
|
|
/mob/proc/lingcheck()
|
|
return LINGHIVE_NONE
|
|
|
|
/mob/proc/get_message_mode(message)
|
|
var/key = copytext(message, 1, 2)
|
|
if(key == "#")
|
|
return MODE_WHISPER
|
|
else if(key == ";")
|
|
return MODE_HEADSET
|
|
else if(length(message) > 2 && (key in GLOB.department_radio_prefixes))
|
|
var/key_symbol = lowertext(copytext(message, 2, 3))
|
|
return GLOB.department_radio_keys[key_symbol]
|