mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-02-05 05:49:28 +00:00
7a44f10993
## About The Pull Request this pr transforms gutlunchers into basic mobs and gives them a small ranch that ashwalkers can manage. gutlunches come in various colors and sizes! female gutlunches will come in different shades of red and males will come in shades of blue. the child born will have a mix of his parent's colors.  female gutlunches can make various healing milk and medicine from its udder. but it will need to consume ores before it can start making milk, u can either feed it by hand or u can put ores in the wooden trough and they will go eat from it whenever they get hungry. feeding it gold or bluespace ore will improve the healing quality of the milk for a short while  the male gutlunchers are obedient pets. their stats vary from one another in speed, attack and health. a male gutlunchers stats will depend on the stats of his parents, the higher his parent's stats are the better chances he has at rolling higher stats. so u can selectively breed them to make sure they have the best stats possible. they will listen to all ur commands and can mine walls or attack enemies if given the command. also i wanted the farm to have wood fences so i added them to the game, they cost 5 wood planks to make ## Why It's Good For The Game refactors gutlunches into basic mobs. also i turned breeding into a component so it can be applied to all animals and created a breed command, pets that have this command and the component will go breed with a partner u point at. ## Changelog 🆑 refactor: gutlunches have been refactored into basic mobs. please report any bugs add: ashwalkers have a small ranch they can manage fix: wall tearer compnent wont runtime when interacting with mineral walls /🆑
106 lines
3.6 KiB
Plaintext
106 lines
3.6 KiB
Plaintext
|
|
#define TORN_WALL_RUINED 2
|
|
#define TORN_WALL_DAMAGED 1
|
|
#define TORN_WALL_INITIAL 0
|
|
|
|
/**
|
|
* Component applied to a wall to progressively destroy it.
|
|
* If component is applied to something which already has it, stage increases.
|
|
* Wall is destroyed on third application.
|
|
* Can be fixed using a welder
|
|
*/
|
|
/datum/component/torn_wall
|
|
dupe_mode = COMPONENT_DUPE_UNIQUE_PASSARGS
|
|
var/current_stage = TORN_WALL_INITIAL
|
|
|
|
/datum/component/torn_wall/Initialize()
|
|
. = ..()
|
|
if (!isclosedturf(parent) || isindestructiblewall(parent))
|
|
return COMPONENT_INCOMPATIBLE
|
|
|
|
/datum/component/torn_wall/RegisterWithParent()
|
|
RegisterSignal(parent, COMSIG_ATOM_EXAMINE, PROC_REF(on_examined))
|
|
RegisterSignal(parent, COMSIG_ATOM_TOOL_ACT(TOOL_WELDER), PROC_REF(on_welded))
|
|
RegisterSignal(parent, COMSIG_ATOM_UPDATE_OVERLAYS, PROC_REF(on_update_overlays))
|
|
RegisterSignal(parent, COMSIG_TURF_CHANGE, PROC_REF(on_turf_changed))
|
|
apply_visuals()
|
|
|
|
/datum/component/torn_wall/UnregisterFromParent()
|
|
var/atom/atom_parent = parent
|
|
UnregisterSignal(parent, list(
|
|
COMSIG_ATOM_EXAMINE,
|
|
COMSIG_ATOM_TOOL_ACT(TOOL_WELDER),
|
|
COMSIG_ATOM_UPDATE_OVERLAYS,
|
|
COMSIG_TURF_CHANGE,
|
|
))
|
|
atom_parent.update_appearance(UPDATE_ICON)
|
|
|
|
/datum/component/torn_wall/InheritComponent(datum/component/C, i_am_original)
|
|
increase_stage()
|
|
|
|
/// Play a fun animation and make our wall look damaged
|
|
/datum/component/torn_wall/proc/apply_visuals()
|
|
var/atom/atom_parent = parent
|
|
playsound(atom_parent, 'sound/effects/bang.ogg', 50, vary = TRUE)
|
|
atom_parent.update_appearance(UPDATE_ICON)
|
|
atom_parent.Shake(shake_interval = 0.1 SECONDS, duration = 0.5 SECONDS)
|
|
|
|
/// Make the effect more dramatic
|
|
/datum/component/torn_wall/proc/increase_stage()
|
|
current_stage++
|
|
if (current_stage != TORN_WALL_RUINED)
|
|
apply_visuals()
|
|
return
|
|
var/turf/closed/wall/attached_wall = parent
|
|
playsound(attached_wall, 'sound/effects/meteorimpact.ogg', 100, vary = TRUE)
|
|
|
|
if(ismineralturf(attached_wall))
|
|
var/turf/closed/mineral/mineral_turf = attached_wall
|
|
mineral_turf.gets_drilled()
|
|
return
|
|
|
|
attached_wall.dismantle_wall(devastated = TRUE)
|
|
|
|
/// Fix it up on weld
|
|
/datum/component/torn_wall/proc/on_welded(atom/source, mob/user, obj/item/tool)
|
|
SIGNAL_HANDLER
|
|
INVOKE_ASYNC(src, PROC_REF(try_repair), source, user, tool)
|
|
return COMPONENT_BLOCK_TOOL_ATTACK
|
|
|
|
/// Fix us up
|
|
/datum/component/torn_wall/proc/try_repair(atom/source, mob/user, obj/item/tool)
|
|
source.balloon_alert(user, "repairing...")
|
|
if(!tool.use_tool(source, user, 5 SECONDS, amount = 2, volume = 50))
|
|
source.balloon_alert(user, "interrupted!")
|
|
return
|
|
current_stage--
|
|
if (current_stage < TORN_WALL_INITIAL)
|
|
qdel(src)
|
|
return
|
|
source.update_appearance(UPDATE_ICON)
|
|
source.tool_act(user, tool, TOOL_WELDER, is_right_clicking = FALSE) // Keep going
|
|
|
|
/// Give them a hint
|
|
/datum/component/torn_wall/proc/on_examined(atom/source, mob/user, list/examine_list)
|
|
SIGNAL_HANDLER
|
|
var/intensity = (current_stage == TORN_WALL_INITIAL) ? "slightly" : "badly"
|
|
examine_list += span_notice("It looks [intensity] damaged.")
|
|
examine_list += span_info("You may be able to repair it using a welding tool.")
|
|
|
|
/// Show a little crack on here
|
|
/datum/component/torn_wall/proc/on_update_overlays(turf/source, list/overlays)
|
|
SIGNAL_HANDLER
|
|
var/mutable_appearance/crack = mutable_appearance('icons/turf/overlays.dmi', "explodable", source.layer + 0.1)
|
|
if (current_stage == TORN_WALL_INITIAL)
|
|
crack.alpha *= 0.5
|
|
overlays += crack
|
|
|
|
/// If the wall becomes any other turf, delete us. Transforming into a different works fine as a fix.
|
|
/datum/component/torn_wall/proc/on_turf_changed()
|
|
SIGNAL_HANDLER
|
|
qdel(src)
|
|
|
|
#undef TORN_WALL_RUINED
|
|
#undef TORN_WALL_DAMAGED
|
|
#undef TORN_WALL_INITIAL
|