mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-29 02:21:44 +00:00
8983a37320
cl Skoglol code: Added missing typepaths for syndicate implanters. tweak: Stealth implant now comes in a box. spellcheck: Changed the names of some syndicate boxes. /cl Some implanters were specific typepaths, others were basic implanters that had implants put in when the box was created. This makes them all behave the same. I considered removing the boxes for the implants as they aren't strictly needed to hold one thing, but I know some people like using boxes in their atmosphere and inventory management sim so I left them in. Otherwise, specifying that a box contains something that is boxed was silly so I changed that. Except for the space suit, because that feels right. And of course the stealth implant gotta come in a box.
66 lines
1.8 KiB
Plaintext
66 lines
1.8 KiB
Plaintext
/obj/item/implanter
|
|
name = "implanter"
|
|
desc = "A sterile automatic implant injector."
|
|
icon = 'icons/obj/items_and_weapons.dmi'
|
|
icon_state = "implanter0"
|
|
item_state = "syringe_0"
|
|
lefthand_file = 'icons/mob/inhands/equipment/medical_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/equipment/medical_righthand.dmi'
|
|
throw_speed = 3
|
|
throw_range = 5
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
materials = list(MAT_METAL=600, MAT_GLASS=200)
|
|
var/obj/item/implant/imp = null
|
|
var/imp_type = null
|
|
|
|
|
|
/obj/item/implanter/update_icon()
|
|
if(imp)
|
|
icon_state = "implanter1"
|
|
else
|
|
icon_state = "implanter0"
|
|
|
|
|
|
/obj/item/implanter/attack(mob/living/M, mob/user)
|
|
if(!istype(M))
|
|
return
|
|
if(user && imp)
|
|
if(M != user)
|
|
M.visible_message("<span class='warning'>[user] is attempting to implant [M].</span>")
|
|
|
|
var/turf/T = get_turf(M)
|
|
if(T && (M == user || do_mob(user, M, 50)))
|
|
if(src && imp)
|
|
if(imp.implant(M, user))
|
|
if (M == user)
|
|
to_chat(user, "<span class='notice'>You implant yourself.</span>")
|
|
else
|
|
M.visible_message("[user] has implanted [M].", "<span class='notice'>[user] implants you.</span>")
|
|
imp = null
|
|
update_icon()
|
|
else
|
|
to_chat(user, "<span class='warning'>[src] fails to implant [M].</span>")
|
|
|
|
/obj/item/implanter/attackby(obj/item/W, mob/user, params)
|
|
if(istype(W, /obj/item/pen))
|
|
if(!user.is_literate())
|
|
to_chat(user, "<span class='notice'>You prod at [src] with [W]!</span>")
|
|
return
|
|
var/t = stripped_input(user, "What would you like the label to be?", name, null)
|
|
if(user.get_active_held_item() != W)
|
|
return
|
|
if(!user.canUseTopic(src, BE_CLOSE))
|
|
return
|
|
if(t)
|
|
name = "implanter ([t])"
|
|
else
|
|
name = "implanter"
|
|
else
|
|
return ..()
|
|
|
|
/obj/item/implanter/Initialize(mapload)
|
|
. = ..()
|
|
if(imp_type)
|
|
imp = new imp_type(src)
|
|
update_icon()
|