mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-29 18:40:42 +00:00
88e17d3ff4
cl Toolby balance: Power tools now perform construction slower than the toolarm implant (but still incredibly faster than normal tools) balance: This is to promote trusting a player rather than safely printing off an item via techfab. /cl Reasoning: As said in the Advanced Surgery PR, The act of trusting an individual who could possibly be able to kill you should supercede the mineral cost difference (we do not balance those) and techweb cost difference (sorta balanced those) between powertools and toolarm implant. This will also mean that the CE now has a vested interest in Science/Medical efforts since he can get better tools, while still making powertools a considerably better item than normal tools (30% increase and less storage slots). Also said in the Advanced Surgery PR, if construction is insufferable with both number-wise we can look at beefing down the numbers (with the implant still being preferred option).
110 lines
3.9 KiB
Plaintext
110 lines
3.9 KiB
Plaintext
/obj/item/wrench
|
|
name = "wrench"
|
|
desc = "A wrench with common uses. Can be found in your hand."
|
|
icon = 'icons/obj/tools.dmi'
|
|
icon_state = "wrench"
|
|
lefthand_file = 'icons/mob/inhands/equipment/tools_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/equipment/tools_righthand.dmi'
|
|
flags_1 = CONDUCT_1
|
|
slot_flags = ITEM_SLOT_BELT
|
|
force = 5
|
|
throwforce = 7
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
usesound = 'sound/items/ratchet.ogg'
|
|
materials = list(MAT_METAL=150)
|
|
|
|
attack_verb = list("bashed", "battered", "bludgeoned", "whacked")
|
|
tool_behaviour = TOOL_WRENCH
|
|
toolspeed = 1
|
|
armor = list("melee" = 0, "bullet" = 0, "laser" = 0, "energy" = 0, "bomb" = 0, "bio" = 0, "rad" = 0, "fire" = 50, "acid" = 30)
|
|
|
|
/obj/item/wrench/suicide_act(mob/user)
|
|
user.visible_message("<span class='suicide'>[user] is beating [user.p_them()]self to death with [src]! It looks like [user.p_theyre()] trying to commit suicide!</span>")
|
|
playsound(loc, 'sound/weapons/genhit.ogg', 50, 1, -1)
|
|
return (BRUTELOSS)
|
|
|
|
/obj/item/wrench/cyborg
|
|
name = "automatic wrench"
|
|
desc = "An advanced robotic wrench. Can be found in construction cyborgs."
|
|
toolspeed = 0.5
|
|
|
|
/obj/item/wrench/brass
|
|
name = "brass wrench"
|
|
desc = "A brass wrench. It's faintly warm to the touch."
|
|
resistance_flags = FIRE_PROOF | ACID_PROOF
|
|
icon_state = "wrench_brass"
|
|
toolspeed = 0.5
|
|
|
|
/obj/item/wrench/abductor
|
|
name = "alien wrench"
|
|
desc = "A polarized wrench. It causes anything placed between the jaws to turn."
|
|
icon = 'icons/obj/abductor.dmi'
|
|
icon_state = "wrench"
|
|
usesound = 'sound/effects/empulse.ogg'
|
|
toolspeed = 0.1
|
|
|
|
|
|
/obj/item/wrench/power
|
|
name = "hand drill"
|
|
desc = "A simple powered hand drill. It's fitted with a bolt bit."
|
|
icon_state = "drill_bolt"
|
|
item_state = "drill"
|
|
lefthand_file = 'icons/mob/inhands/equipment/tools_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/equipment/tools_righthand.dmi'
|
|
usesound = 'sound/items/drill_use.ogg'
|
|
materials = list(MAT_METAL=150,MAT_SILVER=50,MAT_TITANIUM=25)
|
|
//done for balance reasons, making them high value for research, but harder to get
|
|
force = 8 //might or might not be too high, subject to change
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
throwforce = 8
|
|
attack_verb = list("drilled", "screwed", "jabbed")
|
|
toolspeed = 0.7
|
|
|
|
/obj/item/wrench/power/attack_self(mob/user)
|
|
playsound(get_turf(user),'sound/items/change_drill.ogg',50,1)
|
|
var/obj/item/wirecutters/power/s_drill = new /obj/item/screwdriver/power(drop_location())
|
|
to_chat(user, "<span class='notice'>You attach the screw driver bit to [src].</span>")
|
|
qdel(src)
|
|
user.put_in_active_hand(s_drill)
|
|
|
|
/obj/item/wrench/power/suicide_act(mob/user)
|
|
user.visible_message("<span class='suicide'>[user] is pressing [src] against [user.p_their()] head! It looks like [user.p_theyre()] trying to commit suicide!</span>")
|
|
return (BRUTELOSS)
|
|
|
|
/obj/item/wrench/medical
|
|
name = "medical wrench"
|
|
desc = "A medical wrench with common(medical?) uses. Can be found in your hand."
|
|
icon_state = "wrench_medical"
|
|
force = 2 //MEDICAL
|
|
throwforce = 4
|
|
|
|
attack_verb = list("wrenched", "medicaled", "tapped", "jabbed", "whacked")
|
|
|
|
/obj/item/wrench/medical/suicide_act(mob/living/user)
|
|
user.visible_message("<span class='suicide'>[user] is praying to the medical wrench to take [user.p_their()] soul. It looks like [user.p_theyre()] trying to commit suicide!</span>")
|
|
// TODO Make them glow with the power of the M E D I C A L W R E N C H
|
|
// during their ascension
|
|
|
|
// Stun stops them from wandering off
|
|
user.Stun(100, ignore_canstun = TRUE)
|
|
playsound(loc, 'sound/effects/pray.ogg', 50, 1, -1)
|
|
|
|
// Let the sound effect finish playing
|
|
sleep(20)
|
|
|
|
if(!user)
|
|
return
|
|
|
|
for(var/obj/item/W in user)
|
|
user.dropItemToGround(W)
|
|
|
|
var/obj/item/wrench/medical/W = new /obj/item/wrench/medical(loc)
|
|
W.add_fingerprint(user)
|
|
W.desc += " For some reason, it reminds you of [user.name]."
|
|
|
|
if(!user)
|
|
return
|
|
|
|
user.dust()
|
|
|
|
return OXYLOSS |