mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-31 20:11:56 +00:00
ae5a4f955d
## About The Pull Request Signals were initially only usable with component listeners, which while no longer the case has lead to outdated documentation, names, and a similar location in code. This pr pulls the two apart. Partially because mso thinks we should, but also because they really aren't directly linked anymore, and having them in this midstate just confuses people. [Renames comp_lookup to listen_lookup, since that's what it does](102b79694f) [Moves signal procs over to their own file](33d07d01fd) [Renames the PREQDELETING and QDELETING comsigs to drop the parent bit since they can hook to more then just comps now](335ea4ad08) [Does something similar to the attackby comsigs (PARENT -> ATOM)](210e57051d) [And finally passes over the examine signals](65917658fb) ## Why It's Good For The Game Code makes more sense, things are better teased apart, s just good imo ## Changelog 🆑 refactor: Pulled apart the last vestiges of names/docs directly linking signals to components /🆑
73 lines
2.5 KiB
Plaintext
73 lines
2.5 KiB
Plaintext
/**
|
|
* Makes anything that it attaches to incapable of producing light
|
|
*/
|
|
/datum/element/light_eaten
|
|
element_flags = ELEMENT_DETACH_ON_HOST_DESTROY // Detach for turfs
|
|
|
|
/datum/element/light_eaten/Attach(atom/target)
|
|
if(!isatom(target))
|
|
return ELEMENT_INCOMPATIBLE
|
|
|
|
. = ..()
|
|
var/atom/atom_target = target
|
|
RegisterSignal(atom_target, COMSIG_ATOM_SET_LIGHT_POWER, PROC_REF(block_light_power))
|
|
RegisterSignal(atom_target, COMSIG_ATOM_SET_LIGHT_RANGE, PROC_REF(block_light_range))
|
|
RegisterSignal(atom_target, COMSIG_ATOM_SET_LIGHT_ON, PROC_REF(block_light_on))
|
|
RegisterSignal(atom_target, COMSIG_ATOM_EXAMINE, PROC_REF(on_examine))
|
|
|
|
/// Because the lighting system does not like movable lights getting set_light() called.
|
|
switch(atom_target.light_system)
|
|
if(STATIC_LIGHT)
|
|
target.set_light(0, 0, null, FALSE)
|
|
else
|
|
target.set_light_power(0)
|
|
target.set_light_range(0)
|
|
target.set_light_on(FALSE)
|
|
|
|
/datum/element/light_eaten/Detach(datum/source)
|
|
UnregisterSignal(source, list(
|
|
COMSIG_ATOM_SET_LIGHT_POWER,
|
|
COMSIG_ATOM_SET_LIGHT_RANGE,
|
|
COMSIG_ATOM_SET_LIGHT_ON,
|
|
COMSIG_ATOM_EXAMINE,
|
|
))
|
|
return ..()
|
|
|
|
/// Prevents the light power of the target atom from exceeding 0 or increasing.
|
|
/datum/element/light_eaten/proc/block_light_power(atom/eaten_light, new_power)
|
|
SIGNAL_HANDLER
|
|
if(new_power > 0)
|
|
return COMPONENT_BLOCK_LIGHT_UPDATE
|
|
if(new_power > eaten_light.light_power)
|
|
return COMPONENT_BLOCK_LIGHT_UPDATE
|
|
return NONE
|
|
|
|
/// Prevents the light range of the target atom from exceeding 0 while the light power is greater than 0.
|
|
/datum/element/light_eaten/proc/block_light_range(atom/eaten_light, new_range)
|
|
SIGNAL_HANDLER
|
|
if(new_range <= 0)
|
|
return NONE
|
|
if(eaten_light.light_power <= 0)
|
|
return NONE
|
|
return COMPONENT_BLOCK_LIGHT_UPDATE
|
|
|
|
/// Prevents the light from turning on while the light power is greater than 0.
|
|
/datum/element/light_eaten/proc/block_light_on(atom/eaten_light, new_on)
|
|
SIGNAL_HANDLER
|
|
if(!new_on)
|
|
return NONE
|
|
if(eaten_light.light_power <= 0)
|
|
return NONE
|
|
return COMPONENT_BLOCK_LIGHT_UPDATE
|
|
|
|
/// Signal handler for light eater flavortext
|
|
/datum/element/light_eaten/proc/on_examine(atom/eaten_light, mob/examiner, list/examine_text)
|
|
SIGNAL_HANDLER
|
|
examine_text += span_warning("It's dark and empty...")
|
|
if(isliving(examiner) && prob(20))
|
|
var/mob/living/target = examiner
|
|
examine_text += span_danger("You can feel something in [eaten_light.p_them()] gnash at your eyes!")
|
|
target.adjust_temp_blindness(10 SECONDS)
|
|
target.set_eye_blur_if_lower(20 SECONDS)
|
|
return NONE
|