mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-06-06 06:40:42 +01:00
ArcaneMusic
f2fd69a49a
Ladies, Gentlemen, Gamers. You're probably wondering why I've called you all here (through the automatic reviewer request system). So, mineral balance! Mineral balance is less a balance and more of a nervous white dude juggling spinning plates on a high-wire on his first day. The fact it hasn't failed after going on this long is a miracle in and of itself. This PR does not change mineral balance. What this does is moves over every individual cost, both in crafting recipes attached to an object over to a define based system. We have 3 defines: `sheet_material_amount=2000` . Stock standard mineral sheet. This being our central mineral unit, this is used for all costs 2000+. `half_sheet_material_amount=1000` . Same as above, but using iron rods as our inbetween for costs of 1000-1999. `small_material_amount=100` . This hits 1-999. This covers... a startlingly large amount of the codebase. It's feast or famine out here in terms of mineral costs as a result, items are either sheets upon sheets, or some fraction of small mats. Shout out to riot darts for being the worst material cost in the game. I will not elaborate. Regardless, this has no functional change, but it sets the groundwork for making future changes to material costs much, MUCH easier, and moves over to a single, standardized set of units to help enforce coding standards on new items, and will bring up lots of uncomfortable balance questions down the line. For now though, this serves as some rough boundaries on how items costs are related, and will make adjusting these values easier going forward. Except for foam darts. I did round up foam darts. Adjusting mineral balance on the macro scale will be as simple as changing the aforementioned mineral defines, where the alternative is a rats nest of magic number defines. ~~No seriously, 11.25 iron for a foam dart are you kidding me what is the POINT WHY NOT JUST MAKE IT 11~~ Items individual numbers have not been adjusted yet, but we can standardize how the conversation can be held and actually GET SOMEWHERE on material balance as opposed to throwing our hands up or ignoring it for another 10 years.
98 lines
4.1 KiB
Plaintext
98 lines
4.1 KiB
Plaintext
//Bluespace crystals, used in telescience and when crushed it will blink you to a random turf.
|
|
/obj/item/stack/ore/bluespace_crystal
|
|
name = "bluespace crystal"
|
|
desc = "A glowing bluespace crystal, not much is known about how they work. It looks very delicate."
|
|
icon = 'icons/obj/telescience.dmi'
|
|
icon_state = "bluespace_crystal"
|
|
singular_name = "bluespace crystal"
|
|
dye_color = DYE_COSMIC
|
|
w_class = WEIGHT_CLASS_TINY
|
|
mats_per_unit = list(/datum/material/bluespace=SHEET_MATERIAL_AMOUNT)
|
|
points = 50
|
|
refined_type = /obj/item/stack/sheet/bluespace_crystal
|
|
grind_results = list(/datum/reagent/bluespace = 20)
|
|
scan_state = "rock_BScrystal"
|
|
merge_type = /obj/item/stack/ore/bluespace_crystal
|
|
/// The teleport range when crushed/thrown at someone.
|
|
var/blink_range = 8
|
|
|
|
/obj/item/stack/ore/bluespace_crystal/refined
|
|
name = "refined bluespace crystal"
|
|
points = 0
|
|
refined_type = null
|
|
merge_type = /obj/item/stack/ore/bluespace_crystal/refined
|
|
|
|
/obj/item/stack/ore/bluespace_crystal/Initialize(mapload, new_amount, merge = TRUE, list/mat_override=null, mat_amt=1)
|
|
. = ..()
|
|
pixel_x = rand(-5, 5)
|
|
pixel_y = rand(-5, 5)
|
|
|
|
/obj/item/stack/ore/bluespace_crystal/get_part_rating()
|
|
return 1
|
|
|
|
/obj/item/stack/ore/bluespace_crystal/attack_self(mob/user)
|
|
user.visible_message(span_warning("[user] crushes [src]!"), span_danger("You crush [src]!"))
|
|
new /obj/effect/particle_effect/sparks(loc)
|
|
playsound(loc, SFX_SPARKS, 50, TRUE, SHORT_RANGE_SOUND_EXTRARANGE)
|
|
blink_mob(user)
|
|
use(1)
|
|
|
|
/obj/item/stack/ore/bluespace_crystal/proc/blink_mob(mob/living/L)
|
|
do_teleport(L, get_turf(L), blink_range, asoundin = 'sound/effects/phasein.ogg', channel = TELEPORT_CHANNEL_BLUESPACE)
|
|
|
|
/obj/item/stack/ore/bluespace_crystal/throw_impact(atom/hit_atom, datum/thrownthing/throwingdatum)
|
|
if(!..()) // not caught in mid-air
|
|
visible_message(span_notice("[src] fizzles and disappears upon impact!"))
|
|
var/turf/T = get_turf(hit_atom)
|
|
new /obj/effect/particle_effect/sparks(T)
|
|
playsound(loc, SFX_SPARKS, 50, TRUE, SHORT_RANGE_SOUND_EXTRARANGE)
|
|
if(isliving(hit_atom))
|
|
blink_mob(hit_atom)
|
|
use(1)
|
|
|
|
//Artificial bluespace crystal, doesn't give you much research.
|
|
/obj/item/stack/ore/bluespace_crystal/artificial
|
|
name = "artificial bluespace crystal"
|
|
desc = "An artificially made bluespace crystal, it looks delicate."
|
|
mats_per_unit = list(/datum/material/bluespace=SHEET_MATERIAL_AMOUNT*0.5)
|
|
blink_range = 4 // Not as good as the organic stuff!
|
|
points = 0 //nice try
|
|
refined_type = null
|
|
grind_results = list(/datum/reagent/bluespace = 10, /datum/reagent/silicon = 20)
|
|
merge_type = /obj/item/stack/ore/bluespace_crystal/artificial
|
|
|
|
//Polycrystals, aka stacks
|
|
/obj/item/stack/sheet/bluespace_crystal
|
|
name = "bluespace polycrystal"
|
|
icon = 'icons/obj/telescience.dmi'
|
|
icon_state = "polycrystal"
|
|
inhand_icon_state = null
|
|
singular_name = "bluespace polycrystal"
|
|
desc = "A stable polycrystal, made of fused-together bluespace crystals. You could probably break one off."
|
|
mats_per_unit = list(/datum/material/bluespace=SHEET_MATERIAL_AMOUNT)
|
|
attack_verb_continuous = list("bluespace polybashes", "bluespace polybatters", "bluespace polybludgeons", "bluespace polythrashes", "bluespace polysmashes")
|
|
attack_verb_simple = list("bluespace polybash", "bluespace polybatter", "bluespace polybludgeon", "bluespace polythrash", "bluespace polysmash")
|
|
novariants = TRUE
|
|
grind_results = list(/datum/reagent/bluespace = 20)
|
|
point_value = 30
|
|
merge_type = /obj/item/stack/sheet/bluespace_crystal
|
|
var/crystal_type = /obj/item/stack/ore/bluespace_crystal/refined
|
|
|
|
/obj/item/stack/sheet/bluespace_crystal/attack_self(mob/user)// to prevent the construction menu from ever happening
|
|
to_chat(user, span_warning("You cannot crush the polycrystal in-hand, try breaking one off."))
|
|
|
|
//ATTACK HAND IGNORING PARENT RETURN VALUE
|
|
/obj/item/stack/sheet/bluespace_crystal/attack_hand(mob/user, list/modifiers)
|
|
if(user.get_inactive_held_item() == src)
|
|
if(is_zero_amount(delete_if_zero = TRUE))
|
|
return
|
|
var/BC = new crystal_type(src)
|
|
user.put_in_hands(BC)
|
|
use(1)
|
|
if(!amount)
|
|
to_chat(user, span_notice("You break the final crystal off."))
|
|
else
|
|
to_chat(user, span_notice("You break off a crystal."))
|
|
else
|
|
..()
|