mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-27 17:41:50 +00:00
589cf0a904
## About The Pull Request This PR tackles our piss-poor item action handling. Currently in order to make an item only have actions when its equipped to a certain slot you need to override a proc, which I've changed by introducing an action_slots variable. I've also cleaned up a ton of action code, and most importantly moved a lot of Trigger effects on items to do_effect, which allows actions to not call ui_action_click or attack_self on an item without bypassing IsAvailible and comsigs that parent Trigger has. This resolves issues like jump boots being usable from your hands, HUDs being toggleable out of your pockets, etc. Also moved a few actions from relying on attack_self to individual handling on their side. This also stops welding masks/hardhats from showing their action while you hold them, this part of the change is just something I thought didn't make much sense - you can use their action by using them in-hand, and flickering on your action bar can be annoying when reshuffling your backpack. Closes #89653 ## Why It's Good For The Game Makes action handling significantly less ass, allows us to avoid code like this ```js /obj/item/clothing/mask/gas/sechailer/ui_action_click(mob/user, action) if(istype(action, /datum/action/item_action/halt)) halt() else adjust_visor(user) ```
65 lines
1.9 KiB
Plaintext
65 lines
1.9 KiB
Plaintext
/obj/item/teleportation_scroll
|
|
name = "scroll of teleportation"
|
|
desc = "A scroll for moving around."
|
|
icon = 'icons/obj/scrolls.dmi'
|
|
icon_state = "scroll"
|
|
worn_icon_state = "scroll"
|
|
w_class = WEIGHT_CLASS_SMALL
|
|
inhand_icon_state = "paper"
|
|
throw_speed = 3
|
|
throw_range = 7
|
|
resistance_flags = FLAMMABLE
|
|
actions_types = list(/datum/action/cooldown/spell/teleport/area_teleport/wizard/scroll)
|
|
action_slots = ITEM_SLOT_HANDS
|
|
/// Number of uses the scroll gets.
|
|
var/uses = 4
|
|
|
|
/obj/item/teleportation_scroll/Initialize(mapload)
|
|
. = ..()
|
|
// In the future, this can be generalized into just "magic scrolls that give you a specific spell".
|
|
var/datum/action/cooldown/spell/teleport/area_teleport/wizard/scroll/teleport = locate() in actions
|
|
if(!teleport)
|
|
return
|
|
teleport.name = name
|
|
teleport.button_icon = icon
|
|
teleport.button_icon_state = icon_state
|
|
RegisterSignal(teleport, COMSIG_SPELL_AFTER_CAST, PROC_REF(on_spell_cast))
|
|
|
|
/// Deplete charges if spell is cast successfully
|
|
/obj/item/teleportation_scroll/proc/on_spell_cast(datum/action/cooldown/spell/cast_spell, mob/living/cast_on)
|
|
SIGNAL_HANDLER
|
|
uses--
|
|
if(uses > 0)
|
|
return
|
|
to_chat(cast_on, span_warning("[src] runs out of uses and crumbles to dust!"))
|
|
qdel(src)
|
|
|
|
/obj/item/teleportation_scroll/apprentice
|
|
name = "lesser scroll of teleportation"
|
|
uses = 1
|
|
|
|
/obj/item/teleportation_scroll/examine(mob/user)
|
|
. = ..()
|
|
if(uses > 0)
|
|
. += "It has [uses] use\s remaining."
|
|
|
|
/obj/item/teleportation_scroll/attack_self(mob/user)
|
|
. = ..()
|
|
if(.)
|
|
return
|
|
|
|
if(!uses)
|
|
return
|
|
if(!ishuman(user))
|
|
return
|
|
var/mob/living/carbon/human/human_user = user
|
|
if(human_user.incapacitated || !human_user.is_holding(src))
|
|
return
|
|
var/datum/action/cooldown/spell/teleport/area_teleport/wizard/scroll/teleport = locate() in actions
|
|
if(!teleport)
|
|
to_chat(user, span_warning("[src] seems to be a faulty teleportation scroll, and has no magic associated."))
|
|
return
|
|
if(!teleport.Activate(user))
|
|
return
|
|
return TRUE
|