mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-12 09:54:03 +00:00
0a1f06a2d1
* This tail refactor turned into an organ refactor. Funny how that works. * Firstly, fixing all the conflicts. * Fixes all our maps (hopefully) * Actually, this should fix pod people hair :) * Almost everything is working, just two major things to fix * Fixed a certain kind of external organ * Cleaning up some more stuff * Turned tail_cat into tail because why the fuck are they separate? * Moved all the tails into tails.dmi because that was just dumb to have like 3 in a different file * Adds relevant_layers to organs to help with rendering * Makes stored_feature_id also check mutant_bodyparts * Fixes the icon_state names of ALL the tails (pain) * Fixes wagging, gotta refactor most mutant bodyparts later on * I Love Added Failures * Fixed some organs that slipped through my searches * This could possibly fix the CI for this? * It doesn't look like it did fix it * This will make it pass, even if it's ugly as sin. * Fixed Felinids having a weird ghost tail * Fixes instances of snouts and tails not being properly colored Co-authored-by: Kapu1178 <75460809+Kapu1178@users.noreply.github.com> Co-authored-by: GoldenAlpharex <jerego1234@hotmail.com>
56 lines
2.4 KiB
Plaintext
56 lines
2.4 KiB
Plaintext
/datum/surgery/stomach_pump
|
|
name = "Stomach Pump"
|
|
steps = list(
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/retract_skin,
|
|
/datum/surgery_step/incise,
|
|
/datum/surgery_step/clamp_bleeders,
|
|
/datum/surgery_step/stomach_pump,
|
|
/datum/surgery_step/close)
|
|
|
|
target_mobtypes = list(/mob/living/carbon/human)
|
|
possible_locs = list(BODY_ZONE_CHEST)
|
|
requires_bodypart_type = TRUE
|
|
ignore_clothes = FALSE
|
|
var/accumulated_experience = 0
|
|
|
|
/datum/surgery/stomach_pump/can_start(mob/user, mob/living/carbon/target)
|
|
var/obj/item/organ/internal/stomach/target_stomach = target.getorganslot(ORGAN_SLOT_STOMACH)
|
|
if(HAS_TRAIT(target, TRAIT_HUSK))
|
|
return FALSE
|
|
if(!target_stomach)
|
|
return FALSE
|
|
return ..()
|
|
|
|
//Working the stomach by hand in such a way that you induce vomiting.
|
|
/datum/surgery_step/stomach_pump
|
|
name = "Pump Stomach"
|
|
accept_hand = TRUE
|
|
repeatable = TRUE
|
|
time = 20
|
|
success_sound = 'sound/surgery/organ2.ogg'
|
|
|
|
/datum/surgery_step/stomach_pump/preop(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
display_results(user, target, span_notice("You begin pumping [target]'s stomach..."),
|
|
span_notice("[user] begins to pump [target]'s stomach."),
|
|
span_notice("[user] begins to press on [target]'s chest."))
|
|
display_pain(target, "You feel a horrible sloshing feeling in your gut! You're going to be sick!")
|
|
|
|
/datum/surgery_step/stomach_pump/success(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery, default_display_results = FALSE)
|
|
if(ishuman(target))
|
|
var/mob/living/carbon/human/target_human = target
|
|
display_results(user, target, span_notice("[user] forces [target_human] to vomit, cleansing their stomach of some chemicals!"),
|
|
span_notice("[user] forces [target_human] to vomit, cleansing their stomach of some chemicals!"),
|
|
"[user] forces [target_human] to vomit!")
|
|
target_human.vomit(20, FALSE, TRUE, 1, TRUE, FALSE, purge_ratio = 0.67) //higher purge ratio than regular vomiting
|
|
return ..()
|
|
|
|
/datum/surgery_step/stomach_pump/failure(mob/user, mob/living/carbon/target, target_zone, obj/item/tool, datum/surgery/surgery)
|
|
if(ishuman(target))
|
|
var/mob/living/carbon/human/target_human = target
|
|
display_results(user, target, span_warning("You screw up, brusing [target_human]'s chest!"),
|
|
span_warning("[user] screws up, brusing [target_human]'s chest!"),
|
|
span_warning("[user] screws up!"))
|
|
target_human.adjustOrganLoss(ORGAN_SLOT_STOMACH, 5)
|
|
target_human.adjustBruteLoss(5)
|