mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2025-12-31 20:11:56 +00:00
0f435d5dff
Done using this command sed -Ei 's/(\s*\S+)\s*\t+/\1 /g' code/**/*.dm We have countless examples in the codebase with this style gone wrong, and defines and such being on hideously different levels of indentation. Fixing this to keep the alignment involves tainting the blames of code your PR doesn't need to be touching at all. And ultimately, it's hideous. There are some files that this sed makes uglier. I can fix these when they are pointed out, but I believe this is ultimately for the greater good of readability. I'm more concerned with if any strings relied on this. Hi codeowners! Co-authored-by: Jared-Fogle <35135081+Jared-Fogle@users.noreply.github.com>
77 lines
2.0 KiB
Plaintext
77 lines
2.0 KiB
Plaintext
// Normal strength
|
|
|
|
/datum/round_event_control/meteor_wave
|
|
name = "Meteor Wave: Normal"
|
|
typepath = /datum/round_event/meteor_wave
|
|
weight = 4
|
|
min_players = 15
|
|
max_occurrences = 3
|
|
earliest_start = 25 MINUTES
|
|
|
|
/datum/round_event/meteor_wave
|
|
startWhen = 6
|
|
endWhen = 66
|
|
announceWhen = 1
|
|
var/list/wave_type
|
|
var/wave_name = "normal"
|
|
|
|
/datum/round_event/meteor_wave/New()
|
|
..()
|
|
if(!wave_type)
|
|
determine_wave_type()
|
|
|
|
/datum/round_event/meteor_wave/proc/determine_wave_type()
|
|
if(!wave_name)
|
|
wave_name = pickweight(list(
|
|
"normal" = 50,
|
|
"threatening" = 40,
|
|
"catastrophic" = 10))
|
|
switch(wave_name)
|
|
if("normal")
|
|
wave_type = GLOB.meteors_normal
|
|
if("threatening")
|
|
wave_type = GLOB.meteors_threatening
|
|
if("catastrophic")
|
|
if(SSevents.holidays && SSevents.holidays[HALLOWEEN])
|
|
wave_type = GLOB.meteorsSPOOKY
|
|
else
|
|
wave_type = GLOB.meteors_catastrophic
|
|
if("meaty")
|
|
wave_type = GLOB.meteorsB
|
|
if("space dust")
|
|
wave_type = GLOB.meteorsC
|
|
if("halloween")
|
|
wave_type = GLOB.meteorsSPOOKY
|
|
else
|
|
WARNING("Wave name of [wave_name] not recognised.")
|
|
kill()
|
|
|
|
/datum/round_event/meteor_wave/announce(fake)
|
|
priority_announce("Meteors have been detected on collision course with the station.", "Meteor Alert", ANNOUNCER_METEORS)
|
|
|
|
/datum/round_event/meteor_wave/tick()
|
|
if(ISMULTIPLE(activeFor, 3))
|
|
spawn_meteors(5, wave_type) //meteor list types defined in gamemode/meteor/meteors.dm
|
|
|
|
/datum/round_event_control/meteor_wave/threatening
|
|
name = "Meteor Wave: Threatening"
|
|
typepath = /datum/round_event/meteor_wave/threatening
|
|
weight = 5
|
|
min_players = 20
|
|
max_occurrences = 3
|
|
earliest_start = 35 MINUTES
|
|
|
|
/datum/round_event/meteor_wave/threatening
|
|
wave_name = "threatening"
|
|
|
|
/datum/round_event_control/meteor_wave/catastrophic
|
|
name = "Meteor Wave: Catastrophic"
|
|
typepath = /datum/round_event/meteor_wave/catastrophic
|
|
weight = 7
|
|
min_players = 25
|
|
max_occurrences = 3
|
|
earliest_start = 45 MINUTES
|
|
|
|
/datum/round_event/meteor_wave/catastrophic
|
|
wave_name = "catastrophic"
|