mirror of
https://github.com/Bubberstation/Bubberstation.git
synced 2026-01-19 05:26:28 +00:00
ff6b41aa07
## About The Pull Request - Afterattack is a very simple proc now: All it does is this, and all it's used for is for having a convenient place to put effects an item does after a successful attack (IE, the attack was not blocked)  - An overwhelming majority of afterattack implementations have been moved to `interact_with_atom` or the new `ranged_interact_with_atom` I have manually tested many of the refactored procs but there was 200+ so it's kinda hard ## Why It's Good For The Game Afterattack is one of the worst parts of the attack chain, as it simultaneously serves as a way of doing random interactions NOT AT ALL related to attacks (despite the name) while ALSO serving as the defacto way to do a ranged interaction with an item This means careless coders (most of them) may throw stuff in afterattack without realizing how wide reaching it is, which causes bugs. By making two well defined, separate procs for handing adjacent vs ranged interactions, it becomes WAY WAY WAY more easy to develop for. If you want to do something when you click on something else and you're adjacent, use `interact_with_atom` If you want to do something when you click on something else and you're not adjacent, use 'ranged_interact_with_atom` This does result in some instances of boilerplate as shown here:  But I think it's acceptable, feel free to oppose if you don't I'm sure we can think of another solution ~~Additionally it makes it easier to implement swing combat. That's a bonus I guess~~ ## Changelog 🆑 Melbert refactor: Over 200 item interactions have been refactored to use a newer, easier-to-use system. Report any oddities with using items on other objects you may see (such as surgery, reagent containers like cups and spray bottles, or construction devices), especially using something at range (such as guns or chisels) refactor: Item-On-Modsuit interactions have changed slightly. While on combat mode, you will attempt to "use" the item on the suit instead of inserting it into the suit's storage. This means being on combat mode while the suit's panel is open will block you from inserting items entirely via click (but other methods such as hotkey, clicking on the storage boxes, and mousedrop will still work). refactor: The detective's scanner will now be inserted into storage items if clicked normally, and will scan the storage item if on combat mode /🆑
216 lines
9.2 KiB
Plaintext
216 lines
9.2 KiB
Plaintext
/obj/structure/plaque //This is a plaque you can craft with gold, then permanently engrave a title and description on, with a fountain pen.
|
|
icon = 'icons/obj/signs.dmi'
|
|
icon_state = "blankplaque"
|
|
name = "blank plaque"
|
|
desc = "A blank plaque, use a fancy pen to engrave it. It can be detatched from the wall with a wrench."
|
|
anchored = TRUE
|
|
opacity = FALSE
|
|
density = FALSE
|
|
layer = SIGN_LAYER
|
|
custom_materials = list(/datum/material/gold =SHEET_MATERIAL_AMOUNT)
|
|
max_integrity = 200 //Twice as durable as regular signs.
|
|
armor_type = /datum/armor/structure_plaque
|
|
///Custom plaque structures and items both start "unengraved", once engraved with a fountain pen their text can't be altered again. Static plaques are already engraved.
|
|
var/engraved = FALSE
|
|
|
|
/datum/armor/structure_plaque
|
|
melee = 50
|
|
fire = 50
|
|
acid = 50
|
|
|
|
/obj/structure/plaque/Initialize(mapload)
|
|
. = ..()
|
|
register_context()
|
|
|
|
/obj/structure/plaque/add_context(atom/source, list/context, obj/item/held_item, mob/user)
|
|
. = ..()
|
|
switch (held_item?.tool_behaviour)
|
|
if (TOOL_WELDER)
|
|
context[SCREENTIP_CONTEXT_LMB] = "Repair"
|
|
return CONTEXTUAL_SCREENTIP_SET
|
|
if (TOOL_WRENCH)
|
|
context[SCREENTIP_CONTEXT_LMB] = "Unfasten"
|
|
return CONTEXTUAL_SCREENTIP_SET
|
|
if(istype(held_item, /obj/item/pen/fountain) && !engraved)
|
|
context[SCREENTIP_CONTEXT_LMB] = "Engrave"
|
|
return CONTEXTUAL_SCREENTIP_SET
|
|
|
|
/obj/structure/plaque/attack_hand(mob/user, list/modifiers)
|
|
. = ..()
|
|
if(. || user.is_blind())
|
|
return
|
|
user.examinate(src)
|
|
|
|
/obj/structure/plaque/wrench_act(mob/living/user, obj/item/wrench/I)
|
|
. = ..()
|
|
user.visible_message(span_notice("[user] starts removing [src]..."), \
|
|
span_notice("You start unfastening [src]."))
|
|
I.play_tool_sound(src)
|
|
if(!I.use_tool(src, user, 4 SECONDS))
|
|
return TRUE
|
|
playsound(src, 'sound/items/deconstruct.ogg', 50, TRUE)
|
|
user.visible_message(span_notice("[user] unfastens [src]."), \
|
|
span_notice("You unfasten [src]."))
|
|
var/obj/item/plaque/unwrenched_plaque = new (get_turf(user))
|
|
if(engraved) //If it's still just a basic unengraved plaque, we can (and should) skip some of the below variable transfers.
|
|
unwrenched_plaque.name = name //Copy over the plaque structure variables to the plaque item we're creating when we unwrench it.
|
|
unwrenched_plaque.desc = desc
|
|
unwrenched_plaque.engraved = engraved
|
|
unwrenched_plaque.icon_state = icon_state
|
|
unwrenched_plaque.update_integrity(get_integrity())
|
|
unwrenched_plaque.setDir(dir)
|
|
qdel(src) //The plaque structure on the wall goes poof and only the plaque item from unwrenching remains.
|
|
return TRUE
|
|
|
|
/obj/structure/plaque/welder_act(mob/living/user, obj/item/I)
|
|
. = ..()
|
|
if(user.combat_mode)
|
|
return FALSE
|
|
if(atom_integrity == max_integrity)
|
|
to_chat(user, span_warning("This plaque is already in perfect condition."))
|
|
return TRUE
|
|
if(!I.tool_start_check(user, amount=1))
|
|
return TRUE
|
|
user.visible_message(span_notice("[user] starts repairing [src]..."), \
|
|
span_notice("You start repairing [src]."))
|
|
if(!I.use_tool(src, user, 4 SECONDS, volume = 50))
|
|
return TRUE
|
|
user.visible_message(span_notice("[user] finishes repairing [src]."), \
|
|
span_notice("You finish repairing [src]."))
|
|
atom_integrity = max_integrity
|
|
return TRUE
|
|
|
|
/obj/structure/plaque/attackby(obj/item/I, mob/user, params)
|
|
if(istype(I, /obj/item/pen/fountain))
|
|
if(engraved)
|
|
to_chat(user, span_warning("This plaque has already been engraved."))
|
|
return
|
|
var/namechoice = tgui_input_text(user, "Title this plaque. (e.g. 'Best HoP Award', 'Great Ashwalker War Memorial')", "Plaque Customization", max_length = MAX_NAME_LEN)
|
|
if(!namechoice)
|
|
return
|
|
var/descriptionchoice = tgui_input_text(user, "Engrave this plaque's text", "Plaque Customization")
|
|
if(!descriptionchoice)
|
|
return
|
|
if(!Adjacent(user)) //Make sure user is adjacent still
|
|
to_chat(user, span_warning("You need to stand next to the plaque to engrave it!"))
|
|
return
|
|
user.visible_message(span_notice("[user] begins engraving [src]."), \
|
|
span_notice("You begin engraving [src]."))
|
|
if(!do_after(user, 4 SECONDS, target = src)) //This spits out a visible message that somebody is engraving a plaque, then has a delay.
|
|
return
|
|
name = "\improper [namechoice]" //We want improper here so examine doesn't get weird if somebody capitalizes the plaque title.
|
|
desc = "The plaque reads: '[descriptionchoice]'"
|
|
engraved = TRUE //The plaque now has a name, description, and can't be altered again.
|
|
user.visible_message(span_notice("[user] engraves [src]."), \
|
|
span_notice("You engrave [src]."))
|
|
return
|
|
if(istype(I, /obj/item/pen))
|
|
if(engraved)
|
|
to_chat(user, span_warning("This plaque has already been engraved, and your pen isn't fancy enough to engrave it anyway! Find a fountain pen."))
|
|
return
|
|
to_chat(user, span_warning("Your pen isn't fancy enough to engrave this! Find a fountain pen.")) //Go steal the Curator's.
|
|
return
|
|
return ..()
|
|
|
|
/obj/item/plaque //The item version of the above.
|
|
icon = 'icons/obj/signs.dmi'
|
|
icon_state = "blankplaque"
|
|
inhand_icon_state = "blankplaque"
|
|
lefthand_file = 'icons/mob/inhands/items_lefthand.dmi'
|
|
righthand_file = 'icons/mob/inhands/items_righthand.dmi'
|
|
name = "blank plaque"
|
|
desc = "A blank plaque, use a fancy pen to engrave it. It can be placed on a wall."
|
|
w_class = WEIGHT_CLASS_NORMAL
|
|
custom_materials = list(/datum/material/gold =SHEET_MATERIAL_AMOUNT)
|
|
max_integrity = 200
|
|
armor_type = /datum/armor/item_plaque
|
|
///This points the item to make the proper structure when placed on a wall.
|
|
var/plaque_path = /obj/structure/plaque
|
|
///Custom plaque structures and items both start "unengraved", once engraved with a fountain pen their text can't be altered again.
|
|
var/engraved = FALSE
|
|
|
|
/datum/armor/item_plaque
|
|
melee = 50
|
|
fire = 50
|
|
acid = 50
|
|
|
|
/obj/item/plaque/welder_act(mob/living/user, obj/item/I)
|
|
. = ..()
|
|
if(user.combat_mode)
|
|
return FALSE
|
|
if(atom_integrity == max_integrity)
|
|
to_chat(user, span_warning("This plaque is already in perfect condition."))
|
|
return TRUE
|
|
if(!I.tool_start_check(user, amount=1))
|
|
return TRUE
|
|
user.visible_message(span_notice("[user] starts repairing [src]..."), \
|
|
span_notice("You start repairing [src]."))
|
|
if(!I.use_tool(src, user, 4 SECONDS, volume = 50))
|
|
return TRUE
|
|
user.visible_message(span_notice("[user] finishes repairing [src]."), \
|
|
span_notice("You finish repairing [src]."))
|
|
atom_integrity = max_integrity
|
|
return TRUE
|
|
|
|
|
|
/obj/item/plaque/attackby(obj/item/I, mob/user, params) //Same as part of the above, except for the item in hand instead of the structure.
|
|
if(istype(I, /obj/item/pen/fountain))
|
|
if(engraved)
|
|
to_chat(user, span_warning("This plaque has already been engraved."))
|
|
return
|
|
var/namechoice = tgui_input_text(user, "Title this plaque. (e.g. 'Best HoP Award', 'Great Ashwalker War Memorial')", "Plaque Customization", max_length = MAX_NAME_LEN)
|
|
if(!namechoice)
|
|
return
|
|
var/descriptionchoice = tgui_input_text(user, "Engrave this plaque's text", "Plaque Customization")
|
|
if(!descriptionchoice)
|
|
return
|
|
if(!Adjacent(user)) //Make sure user is adjacent still
|
|
to_chat(user, span_warning("You need to stand next to the plaque to engrave it!"))
|
|
return
|
|
user.visible_message(span_notice("[user] begins engraving [src]."), \
|
|
span_notice("You begin engraving [src]."))
|
|
if(!do_after(user, 4 SECONDS, target = src)) //This spits out a visible message that somebody is engraving a plaque, then has a delay.
|
|
return
|
|
name = "\improper [namechoice]" //We want improper here so examine doesn't get weird if somebody capitalizes the plaque title.
|
|
desc = "The plaque reads: '[descriptionchoice]'"
|
|
engraved = TRUE //The plaque now has a name, description, and can't be altered again.
|
|
user.visible_message(span_notice("[user] engraves [src]."), \
|
|
span_notice("You engrave [src]."))
|
|
return
|
|
if(istype(I, /obj/item/pen))
|
|
if(engraved)
|
|
to_chat(user, span_warning("This plaque has already been engraved, and your pen isn't fancy enough to engrave it anyway! Find a fountain pen."))
|
|
return
|
|
to_chat(user, span_warning("Your pen isn't fancy enough to engrave this! Find a fountain pen.")) //Go steal the Curator's.
|
|
return
|
|
return ..()
|
|
|
|
/obj/item/plaque/interact_with_atom(atom/interacting_with, mob/living/user, list/modifiers)
|
|
if(!iswallturf(interacting_with))
|
|
return NONE
|
|
var/turf/target_turf = interacting_with
|
|
var/turf/user_turf = get_turf(user)
|
|
var/obj/structure/plaque/placed_plaque = new plaque_path(user_turf) //We place the plaque on the turf the user is standing, and pixel shift it to the target wall, as below.
|
|
//This is to mimic how signs and other wall objects are usually placed by mappers, and so they're only visible from one side of a wall.
|
|
var/dir = get_dir(user_turf, target_turf)
|
|
if(dir & NORTH)
|
|
placed_plaque.pixel_y = 32
|
|
else if(dir & SOUTH)
|
|
placed_plaque.pixel_y = -32
|
|
if(dir & EAST)
|
|
placed_plaque.pixel_x = 32
|
|
else if(dir & WEST)
|
|
placed_plaque.pixel_x = -32
|
|
user.visible_message(span_notice("[user] fastens [src] to [target_turf]."), \
|
|
span_notice("You attach [src] to [target_turf]."))
|
|
playsound(target_turf, 'sound/items/deconstruct.ogg', 50, TRUE)
|
|
if(engraved)
|
|
placed_plaque.name = name
|
|
placed_plaque.desc = desc
|
|
placed_plaque.engraved = engraved
|
|
placed_plaque.icon_state = icon_state
|
|
placed_plaque.update_integrity(get_integrity())
|
|
placed_plaque.setDir(dir)
|
|
qdel(src)
|
|
return ITEM_INTERACT_SUCCESS
|