Merge pull request #5737 from Seris02/gargoyle

gargoyles

code/modules/mob/living/carbon/human/species/station/traits_vr/neutral_ch.dm

@@ -79,3 +79,13 @@
 	),
 	autohiss_exempt = list("Vespinae"))
 	excludes = list(/datum/trait/neutral/autohiss_tajaran, /datum/trait/neutral/autohiss_unathi)
+
+/datum/trait/neutral/gargoyle
+	name = "Gargoyle"
+	desc = "You turn into a statue at will, but also whenever you run out of energy. Being a statue replenishes your energy slowly."
+	cost = 0
+	custom_only = TRUE //slimes, xenochimera, diona, proteans, etc, basically anything but custom doesn't make sense (as much as I wanna play a petrifying slime)
+
+/datum/trait/neutral/gargoyle/apply(var/datum/species/S,var/mob/living/carbon/human/H)
+	..(S,H)
+	H.LoadComponent(/datum/component/gargoyle)

modular_chomp/code/datums/components/gargoyle.dm

@@ -0,0 +1,95 @@
+/datum/component/gargoyle
+	var/energy = 100
+	var/transformed = FALSE
+	var/paused = FALSE
+	var/paused_loc
+	var/cooldown
+
+	var/mob/living/carbon/human/gargoyle //easy reference
+	var/obj/structure/gargoyle/statue //another easy ref
+
+/datum/component/gargoyle/Initialize()
+	if (!ishuman(parent))
+		return COMPONENT_INCOMPATIBLE
+	gargoyle = parent
+	gargoyle.verbs += /mob/living/carbon/human/proc/gargoyle_transformation
+	gargoyle.verbs += /mob/living/carbon/human/proc/gargoyle_pause
+	gargoyle.verbs += /mob/living/carbon/human/proc/gargoyle_checkenergy
+	START_PROCESSING(SSprocessing, src)
+
+/datum/component/gargoyle/process()
+	if (!gargoyle)
+		return
+	if (paused && gargoyle.loc != paused_loc)
+		unpause()
+	if (energy > 0)
+		if (!transformed && !paused)
+			energy = max(0,energy-0.05)
+	else if (!transformed && isturf(gargoyle.loc))
+		gargoyle.gargoyle_transformation()
+	if (transformed)
+		if (!statue)
+			transformed = FALSE
+		statue.damage(-0.5)
+		energy = min(energy+0.3, 100)
+
+/datum/component/gargoyle/proc/unpause()
+	if (!paused || transformed)
+		paused = FALSE
+		paused_loc = null
+		UnregisterSignal(gargoyle, COMSIG_ATOM_ENTERING)
+		return
+	if (gargoyle?.loc != paused_loc)
+		paused = FALSE
+		paused_loc = null
+		energy = max(energy - 5, 0)
+		if (energy == 0)
+			gargoyle.gargoyle_transformation()
+		UnregisterSignal(gargoyle, COMSIG_ATOM_ENTERING)
+
+//verbs or action buttons...?
+/mob/living/carbon/human/proc/gargoyle_transformation()
+	set name = "Gargoyle - Petrification"
+	set category = "Abilities"
+	set desc = "Turn yourself into (or back from) being a gargoyle."
+
+	if (stat == DEAD)
+		return
+
+	var/datum/component/gargoyle/comp = GetComponent(/datum/component/gargoyle)
+	if (comp)
+		if (comp.energy <= 0 && isturf(loc))
+			to_chat(src, "<span class='danger'>You suddenly turn into a statue as you run out of energy!</span>")
+		else if (comp.cooldown > world.time)
+			var/time_to_wait = (comp.cooldown - world.time) / (1 SECONDS)
+			to_chat(src, "<span class='warning'>You can't transform just yet again! Wait for another [round(time_to_wait,0.1)] seconds!</span>")
+			return
+	if (istype(loc, /obj/structure/gargoyle))
+		var/obj/structure/gargoyle/statue = loc
+		qdel(statue)
+	else if (isturf(loc))
+		new /obj/structure/gargoyle(loc, src)
+
+/mob/living/carbon/human/proc/gargoyle_pause()
+	set name = "Gargoyle - Pause"
+	set category = "Abilities"
+	set desc = "Pause your energy while standing still, so you don't use up any more, though you will lose a small amount upon moving again."
+
+	if (stat)
+		return
+
+	var/datum/component/gargoyle/comp = GetComponent(/datum/component/gargoyle)
+	if (comp && !comp.transformed && !comp.paused)
+		comp.paused = TRUE
+		comp.paused_loc = loc
+		comp.RegisterSignal(src, COMSIG_ATOM_ENTERING, /datum/component/gargoyle/proc/unpause)
+		to_chat(src, "<span class='notice'>You start conserving your energy.</span>")
+
+/mob/living/carbon/human/proc/gargoyle_checkenergy()
+	set name = "Gargoyle - Check Energy"
+	set category = "Abilities"
+	set desc = "Check how much energy you have remaining as a gargoyle."
+
+	var/datum/component/gargoyle/comp = GetComponent(/datum/component/gargoyle)
+	if (comp)
+		to_chat(src, "<span class='notice'>You have [round(comp.energy,0.01)] energy remaining. It is currently [comp.paused ? "stable" : (comp.transformed ? "increasing" : "decreasing")].</span>")

modular_chomp/code/game/objects/structures/gargoyle.dm

@@ -0,0 +1,169 @@
+/obj/structure/gargoyle
+	name = "statue"
+	desc = "A very lifelike carving."
+	density = TRUE
+	anchored = TRUE
+	var/mob/living/carbon/human/gargoyle
+	var/initial_sleep
+	var/initial_blind
+	var/initial_is_shifted
+	var/initial_lying
+	var/initial_lying_prev
+	var/wagging
+	var/flapping
+	var/obj_integrity = 100
+	var/original_int = 100
+	var/max_integrity = 100
+	var/stored_examine
+
+/obj/structure/gargoyle/Initialize(mapload, var/mob/living/carbon/human/H)
+	. = ..()
+	if (isspace(loc) || isopenspace(loc))
+		anchored = FALSE
+	if (!istype(H) || !isturf(H.loc))
+		return
+	var/datum/component/gargoyle/comp = H.GetComponent(/datum/component/gargoyle)
+	if (comp)
+		comp.cooldown = world.time + (15 SECONDS)
+		comp.statue = src
+		comp.transformed = TRUE
+		comp.paused = FALSE
+	gargoyle = H
+
+	max_integrity = H.getMaxHealth() + 100
+	obj_integrity = H.health + 100
+	original_int = obj_integrity
+	name = "statue of [H.name]"
+	desc = "A very lifelike statue."
+	stored_examine = H.examine()
+	description_fluff = H.get_description_fluff()
+
+	if (H.buckled)
+		H.buckled.unbuckle_mob(H, TRUE)
+	icon = H.icon
+	copy_overlays(H)
+	color = list(rgb(77,77,77), rgb(150,150,150), rgb(28,28,28), rgb(0,0,0))
+	initial_sleep = H.sleeping
+	initial_blind = H.eye_blind
+	initial_is_shifted = H.is_shifted
+	transform = H.transform
+	layer = H.layer
+	pixel_x = H.pixel_x
+	pixel_y = H.pixel_y
+	dir = H.dir
+	initial_lying = H.lying
+	initial_lying_prev = H.lying_prev
+	H.sdisabilities |= MUTE
+	if (H.appearance_flags & PIXEL_SCALE)
+		appearance_flags |= PIXEL_SCALE
+	wagging = H.wagging
+	H.transforming = TRUE
+	flapping = H.flapping
+	H.toggle_tail(FALSE, FALSE)
+	H.toggle_wing(FALSE, FALSE)
+	H.visible_message("<span class='warning'>[H]'s skin rapidly turns to stone!</span>", "<span class='warning'>Your skin abruptly hardens as you turn to stone!</span>")
+	H.forceMove(src)
+	H.SetBlinded(0)
+	H.SetSleeping(0)
+	H.status_flags |= GODMODE
+	H.updatehealth()
+	H.canmove = 0
+
+/obj/structure/gargoyle/Destroy()
+	unpetrify()
+	. = ..()
+
+/obj/structure/gargoyle/examine_icon()
+	var/icon/examine_icon = ..()
+	examine_icon.MapColors(rgb(77,77,77), rgb(150,150,150), rgb(28,28,28), rgb(0,0,0))
+	return examine_icon
+
+/obj/structure/gargoyle/get_description_info()
+	if (gargoyle)
+		if (isspace(loc) || isopenspace(loc))
+			return
+		return "It can be [anchored ? "un" : ""]anchored with a wrench."
+
+/obj/structure/gargoyle/examine(mob/user)
+	. = ..()
+	if (gargoyle && stored_examine)
+		. += "The statue seems to have a bit more to them..."
+		. += stored_examine
+	return
+
+/obj/structure/gargoyle/proc/unpetrify()
+	if (!gargoyle)
+		return
+	var/datum/component/gargoyle/comp = gargoyle.GetComponent(/datum/component/gargoyle)
+	if (comp)
+		comp.cooldown = world.time + (15 SECONDS)
+		comp.statue = null
+		comp.transformed = FALSE
+	gargoyle.forceMove(loc)
+	gargoyle.transform = transform
+	gargoyle.pixel_x = pixel_x
+	gargoyle.pixel_y = pixel_y
+	gargoyle.is_shifted = initial_is_shifted
+	gargoyle.dir = dir
+	gargoyle.lying = initial_lying
+	gargoyle.lying_prev = initial_lying_prev
+	gargoyle.toggle_tail(wagging, FALSE)
+	gargoyle.toggle_wing(flapping, FALSE)
+	gargoyle.sdisabilities &= ~MUTE //why is there no ADD_TRAIT etc here that's actually ussssed
+	gargoyle.status_flags &= ~GODMODE
+	gargoyle.SetBlinded(initial_blind)
+	gargoyle.SetSleeping(initial_sleep)
+	gargoyle.transforming = FALSE
+	gargoyle.canmove = 1
+	gargoyle.update_canmove()
+	var/hurtmessage = ""
+	if (obj_integrity < original_int)
+		var/f = (original_int - obj_integrity) / 10
+		for (var/x in 1 to 10)
+			gargoyle.adjustBruteLoss(f)
+		hurtmessage = " <b>You feel your body take the damage that was dealt while being stone!</b>"
+	gargoyle.updatehealth()
+	alpha = 0
+	gargoyle.visible_message("<span class='warning'>[gargoyle]'s skin rapidly softens, returning them to normal!</span>", "<span class='warning'>Your skin softens, freeing your movement once more![hurtmessage]</span>")
+
+/obj/structure/gargoyle/return_air()
+	return return_air_for_internal_lifeform()
+
+/obj/structure/gargoyle/return_air_for_internal_lifeform(var/mob/living/lifeform)
+	var/air_type = /datum/gas_mixture/belly_air
+	if(istype(lifeform))
+		air_type = lifeform.get_perfect_belly_air_type()
+	var/air = new air_type(1000)
+	return air
+
+/obj/structure/gargoyle/proc/damage(var/damage)
+	obj_integrity = min(obj_integrity-damage, max_integrity)
+	if(obj_integrity <= 0)
+		qdel(src)
+
+/obj/structure/gargoyle/take_damage(var/damage)
+	damage(damage)
+
+/obj/structure/gargoyle/attack_generic(var/mob/user, var/damage, var/attack_message = "hits")
+	user.do_attack_animation(src)
+	visible_message("<span class='danger'>[user] [attack_message] the [src]!</span>")
+	damage(damage)
+
+/obj/structure/gargoyle/attackby(var/obj/item/weapon/W as obj, var/mob/user as mob)
+	if(W.is_wrench())
+		if (isspace(loc) || isopenspace(loc))
+			to_chat(user, "<span class='warning'>You can't anchor that here!</span>")
+			anchored = FALSE
+			return ..()
+		playsound(src, W.usesound, 50, 1)
+		if (do_after(user, (2 SECONDS) * W.toolspeed, target = src))
+			to_chat("<span class='notice'>You [anchored ? "un" : ""]anchor the [src].</span>")
+			anchored = !anchored
+	else if (!(W.flags & NOBLUDGEON))
+		user.setClickCooldown(user.get_attack_speed(W))
+		if(W.damtype == BRUTE || W.damtype == BURN)
+			user.do_attack_animation(src)
+			playsound(src, W.hitsound, 50, 1)
+			damage(W.force)
+	else
+		return ..()

vorestation.dme

@@ -4522,6 +4522,7 @@
 #include "modular_chomp\code\datums\autolathe\arms.dm"
 #include "modular_chomp\code\datums\autolathe\engineering_ch.dm"
 #include "modular_chomp\code\datums\autolathe\general_ch.dm"
+#include "modular_chomp\code\datums\components\gargoyle.dm"
 #include "modular_chomp\code\datums\outfits\jobs\noncrew.dm"
 #include "modular_chomp\code\datums\supplypacks\medical.dm"
 #include "modular_chomp\code\game\dna\dna2.dm"
@@ -4532,6 +4533,7 @@
 #include "modular_chomp\code\game\machinery\autolathe_armory.dm"
 #include "modular_chomp\code\game\objects\items\clockwork\ratvarian_spear.dm"
 #include "modular_chomp\code\game\objects\structures\desert_planet_structures.dm"
+#include "modular_chomp\code\game\objects\structures\gargoyle.dm"
 #include "modular_chomp\code\game\objects\structures\loot_pile.dm"
 #include "modular_chomp\code\game\objects\structures\watercloset_ch.dm"
 #include "modular_chomp\code\game\objects\structures\crate_lockers\largecrate.dm"