One can now greatly customize syndicate ids. Partially based on https://github.com/ParadiseSS13/Paradise/pull/1686.

baystation12.dme

@@ -643,6 +643,7 @@
 #include "code\game\objects\items\weapons\autopsy.dm"
 #include "code\game\objects\items\weapons\candle.dm"
 #include "code\game\objects\items\weapons\cards_ids.dm"
+#include "code\game\objects\items\weapons\cards_ids_syndicate.dm"
 #include "code\game\objects\items\weapons\cigs_lighters.dm"
 #include "code\game\objects\items\weapons\clown_items.dm"
 #include "code\game\objects\items\weapons\cosmetics.dm"

code/_helpers/lists.dm

@@ -619,10 +619,13 @@ datum/proc/dd_SortValue()
 /datum/alarm/dd_SortValue()
 	return "[sanitize_old(last_name)]"
 
+/proc/subtypes(prototype)
+	return (typesof(prototype) - prototype)
+
 //creates every subtype of prototype (excluding prototype) and adds it to list L.
 //if no list/L is provided, one is created.
 /proc/init_subtypes(prototype, list/L)
 	if(!istype(L))	L = list()
-	for(var/path in (typesof(prototype) - prototype))
+	for(var/path in subtypes(prototype))
 		L += new path()
 	return L

code/game/machinery/alarm.dm

@@ -623,8 +623,8 @@
 
 	return min(..(), .)
 
-/obj/machinery/alarm/Topic(href, href_list, var/nowindow = 0, var/datum/topic_state/state)
-	if(..(href, href_list, nowindow, state))
+/obj/machinery/alarm/Topic(href, href_list, var/datum/topic_state/state)
+	if(..(href, href_list, state))
 		return 1
 
 	// hrefs that can always be called -walter0o

code/game/machinery/camera/tracking.dm

@@ -155,6 +155,11 @@
 	if(!istype(target))	return
 	var/mob/living/silicon/ai/U = usr
 
+	if(target == U.cameraFollow)
+		return
+
+	if(U.cameraFollow)
+		U.ai_cancel_tracking()
 	U.cameraFollow = target
 	U << "Now tracking [target.name] on camera."
 	target.tracking_initiated()
@@ -240,7 +245,8 @@ mob/living/proc/near_camera()
 
 /mob/living/carbon/human/tracking_status()
 	//Cameras can't track people wearing an agent card or a ninja hood.
-	if(wear_id && istype(wear_id.GetID(), /obj/item/weapon/card/id/syndicate))
+	var/obj/item/weapon/card/id/id = GetIdCard(src)
+	if(id && id.prevent_tracking())
 		return TRACKING_TERMINATE
 	if(istype(head, /obj/item/clothing/head/helmet/space/rig))
 		var/obj/item/clothing/head/helmet/space/rig/helmet = head

code/game/machinery/doors/airlock.dm

@@ -674,7 +674,7 @@ About the new airlock wires panel:
 
 	return ..()
 
-/obj/machinery/door/airlock/Topic(href, href_list, var/nowindow = 0)
+/obj/machinery/door/airlock/Topic(href, href_list)
 	if(..())
 		return 1
 

code/game/machinery/portable_turret.dm

@@ -236,7 +236,7 @@ var/list/turret_icons
 	return ..()
 
 
-/obj/machinery/porta_turret/Topic(href, href_list, var/nowindow = 0)
+/obj/machinery/porta_turret/Topic(href, href_list)
 	if(..())
 		return 1
 

code/game/machinery/turret_control.dm

@@ -139,7 +139,7 @@
 		ui.open()
 		ui.set_auto_update(1)
 
-/obj/machinery/turretid/Topic(href, href_list, var/nowindow = 0)
+/obj/machinery/turretid/Topic(href, href_list)
 	if(..())
 		return 1
 

code/game/objects/items/devices/aicard.dm

@@ -46,7 +46,7 @@
 		ui.open()
 		ui.set_auto_update(1)
 
-/obj/item/device/aicard/Topic(href, href_list, nowindow, state)
+/obj/item/device/aicard/Topic(href, href_list, state)
 	if(..())
 		return 1
 

code/game/objects/items/weapons/cards_ids.dm

@@ -104,7 +104,6 @@
 	var/sex = "\[UNSET\]"
 	var/icon/front
 	var/icon/side
-	var/dat
 
 	//alt titles are handled a bit weirdly in order to unobtrusively integrate into existing ID system
 	var/assignment = null	//can be alt title or the actual job
@@ -119,11 +118,14 @@
 	else
 		usr << "<span class='warning'>It is too far away.</span>"
 
+/obj/item/weapon/card/id/proc/prevent_tracking()
+	return 0
+
 /obj/item/weapon/card/id/proc/show(mob/user as mob)
 	user << browse_rsc(front, "front.png")
 	user << browse_rsc(side, "side.png")
 	var/datum/browser/popup = new(user, "idcard", name, 600, 250)
-	popup.set_content(dat)
+	popup.set_content(dat())
 	popup.set_title_image(usr.browse_rsc_icon(src.icon, src.icon_state))
 	popup.open()
 	return
@@ -147,7 +149,8 @@
 	set_id_photo(H)
 	update_name()
 
-	dat = ("<table><tr><td>")
+/obj/item/weapon/card/id/proc/dat()
+	var/dat = ("<table><tr><td>")
 	dat += text("Name: []</A><BR>", registered_name)
 	dat += text("Sex: []</A><BR>\n", sex)
 	dat += text("Age: []</A><BR>\n", age)
@@ -155,8 +158,10 @@
 	dat += text("Fingerprint: []</A><BR>\n", fingerprint_hash)
 	dat += text("Blood Type: []<BR>\n", blood_type)
 	dat += text("DNA Hash: []<BR><BR>\n", dna_hash)
-	dat +="<td align = center valign = top>Photo:<br><img src=front.png height=80 width=80 border=4>	\
-	<img src=side.png height=80 width=80 border=4></td></tr></table>"
+	if(front && side)
+		dat +="<td align = center valign = top>Photo:<br><img src=front.png height=80 width=80 border=4><img src=side.png height=80 width=80 border=4></td>"
+	dat += "</tr></table>"
+	return dat
 
 /obj/item/weapon/card/id/attack_self(mob/user as mob)
 	user.visible_message("\The [user] shows you: \icon[src] [src.name]. The assignment on the card: [src.assignment]",\

code/game/objects/items/weapons/cards_ids_syndicate.dm

@@ -3,9 +3,10 @@ var/global/list/syndicate_ids = list()
 /obj/item/weapon/card/id/syndicate
 	name = "agent card"
 	assignment = "Agent"
-	var/list/initial_access = list(access_maint_tunnels, access_syndicate, access_external_airlocks)
 	origin_tech = list(TECH_ILLEGAL = 3)
+	var/electronic_warfare = 1
 	var/registered_user = null
+	var/list/initial_access = list(access_maint_tunnels, access_syndicate, access_external_airlocks)
 
 /obj/item/weapon/card/id/syndicate/New(mob/user as mob)
 	syndicate_ids += src
@@ -17,26 +18,31 @@ var/global/list/syndicate_ids = list()
 	registered_user = null
 	return ..()
 
+// On mob destruction, ensure any references are cleared
 /mob/Destroy()
-	// On mob destruction, ensure any references are cleared
 	for(var/obj/item/weapon/card/id/syndicate/SID in syndicate_ids)
-		if(SID.registered_user = user)
-			registered_user = null
+		if(SID.registered_user == src)
+			SID.registered_user = null
 	return ..()
 
+/obj/item/weapon/card/id/syndicate/prevent_tracking()
+	return electronic_warfare
+
 /obj/item/weapon/card/id/syndicate/afterattack(var/obj/item/weapon/O as obj, mob/user as mob, proximity)
 	if(!proximity) return
 	if(istype(O, /obj/item/weapon/card/id))
 		var/obj/item/weapon/card/id/I = O
 		src.access |= I.access
 		if(player_is_antag(user))
-			user << "<span class='notice'>\The [src]'s microscanners activate as you pass it over the ID, copying its access.</span>"
+			user << "<span class='notice'>The microscanner activate as you pass it over the ID, copying its access.</span>"
 
 /obj/item/weapon/card/id/syndicate/attack_self(mob/user as mob)
 	if(!registered_user)
 		registered_user = user
+		set_owner_info(user)
+		user << "<span class='notice'>The microscanner marks you as its owner, preventing others some accessing its internals.</span>"
 	if(registered_user == user)
-		switch(alert("Would you like edit the ID, or show it?","Edit","Show"))
+		switch(alert("Would you like edit the ID, or show it?","Show or Edit?", "Edit","Show"))
 			if("Edit")
 				ui_interact(user)
 			if("Show")
@@ -46,7 +52,19 @@ var/global/list/syndicate_ids = list()
 
 /obj/item/weapon/card/id/syndicate/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
 	var/data[0]
-	data["hide_breakers"] = hide_breakers
+	var/entries[0]
+	entries[++entries.len] = list("name" = "Age", 				"value" = age)
+	entries[++entries.len] = list("name" = "Appearance",		"value" = "Set")
+	entries[++entries.len] = list("name" = "Assignment",		"value" = assignment)
+	entries[++entries.len] = list("name" = "Blood Type",		"value" = blood_type)
+	entries[++entries.len] = list("name" = "DNA Hash", 			"value" = dna_hash)
+	entries[++entries.len] = list("name" = "Fingerprint Hash",	"value" = fingerprint_hash)
+	entries[++entries.len] = list("name" = "Name", 				"value" = registered_name)
+	entries[++entries.len] = list("name" = "Photo", 			"value" = "Update")
+	entries[++entries.len] = list("name" = "Sex", 				"value" = sex)
+	entries[++entries.len] = list("name" = "Factory Reset",		"value" = "Use With Care")
+	data["electronic_warfare"] = electronic_warfare
+	data["entries"] = entries
 
 	ui = nanomanager.try_update_ui(user, src, ui_key, ui, data, force_open)
 	if (!ui)
@@ -59,9 +77,128 @@ var/global/list/syndicate_ids = list()
 		return STATUS_CLOSE
 	return ..()
 
-/obj/item/weapon/card/id/syndicate/Topic(href, href_list, var/nowindow = 0, var/datum/topic_state/state)
+/obj/item/weapon/card/id/syndicate/Topic(href, href_list, var/datum/topic_state/state)
 	if(..())
 		return 1
 
-	update_uis(src)
-	return 1
+	var/user = usr
+	if(href_list["electronic_warfare"])
+		electronic_warfare = text2num(href_list["electronic_warfare"])
+		user << "<span class='notice'>Electronic warfare [electronic_warfare ? "enabled" : "disabled"].</span>"
+	else if(href_list["set"])
+		switch(href_list["set"])
+			if("Age")
+				var/new_age = input(user,"What age would you like to put on this card?","Agent Card Age", age) as null|num
+				if(!isnull(new_age) && CanUseTopic(user, state))
+					if(new_age < 0)
+						age = initial(age)
+					else
+						age = new_age
+					user << "<span class='notice'>Age has been set to '[age]'.</span>"
+					. = 1
+			if("Appearance")
+				var/datum/card_state/choice = input(user, "Select the appearance for this card.", "Agent Card Appearance") as null|anything in id_card_states()
+				if(choice && CanUseTopic(user, state))
+					src.icon_state = choice.icon_state
+					src.item_state = choice.item_state
+					usr << "<span class='notice'>Appearance changed to [choice].</span>"
+					. = 1
+			if("Assignment")
+				var/new_job = sanitize(input(user,"What assignment would you like to put on this card?\nChanging assignment will not grant or remove any access levels.","Agent Card Assignment", assignment) as null|text)
+				if(!isnull(new_job) && CanUseTopic(user, state))
+					src.assignment = new_job
+					user << "<span class='notice'>Occupation changed to '[new_job]'.</span>"
+					update_name()
+					. = 1
+			if("Blood Type")
+				var/default = blood_type
+				if(default == initial(blood_type) && ishuman(user))
+					var/mob/living/carbon/human/H = user
+					if(H.dna)
+						default = H.dna.b_type
+				var/new_blood_type = sanitize(input(user,"What blood type would you like to be written on this card?","Agent Card Blood Type",default) as null|text)
+				if(!isnull(new_blood_type) && CanUseTopic(user, state))
+					src.blood_type = new_blood_type
+					user << "<span class='notice'>Blood type changed to '[new_blood_type]'.</span>"
+					. = 1
+			if("DNA Hash")
+				var/default = dna_hash
+				if(default == initial(dna_hash) && ishuman(user))
+					var/mob/living/carbon/human/H = user
+					if(H.dna)
+						default = H.dna.unique_enzymes
+				var/new_dna_hash = sanitize(input(user,"What DNA hash would you like to be written on this card?","Agent Card DNA Hash",default) as null|text)
+				if(!isnull(new_dna_hash) && CanUseTopic(user, state))
+					src.dna_hash = new_dna_hash
+					user << "<span class='notice'>DNA hash changed to '[new_dna_hash]'.</span>"
+					. = 1
+			if("Fingerprint Hash")
+				var/default = fingerprint_hash
+				if(default == initial(fingerprint_hash) && ishuman(user))
+					var/mob/living/carbon/human/H = user
+					if(H.dna)
+						default = md5(H.dna.uni_identity)
+				var/new_fingerprint_hash = sanitize(input(user,"What fingerprint hash would you like to be written on this card?","Agent Card Fingerprint Hash",default) as null|text)
+				if(!isnull(new_fingerprint_hash) && CanUseTopic(user, state))
+					src.fingerprint_hash = new_fingerprint_hash
+					user << "<span class='notice'>Fingerprint hash changed to '[new_fingerprint_hash]'.</span>"
+					. = 1
+			if("Name")
+				var/new_name = sanitizeName(input(user,"What name would you like to put on this card?","Agent Card Name", registered_name) as null|text)
+				if(!isnull(new_name) && CanUseTopic(user, state))
+					src.registered_name = new_name
+					update_name()
+					user << "<span class='notice'>Name changed to '[new_name]'.</span>"
+					. = 1
+			if("Photo")
+				set_id_photo(user)
+				user << "<span class='notice'>Photo changed.</span>"
+				. = 1
+			if("Sex")
+				var/new_sex = sanitize(input(user,"What sex would you like to put on this card?","Agent Card Sex", sex) as null|text)
+				if(!isnull(new_sex) && CanUseTopic(user, state))
+					src.sex = new_sex
+					user << "<span class='notice'>Sex changed to '[new_sex]'.</span>"
+					. = 1
+			if("Factory Reset")
+				if(alert("This will factory reset the card, including access and owner. Continue?", "Factory Reset", "No", "Yes") == "Yes" && CanUseTopic(user, state))
+					age = initial(age)
+					access = initial_access.Copy()
+					assignment = initial(assignment)
+					blood_type = initial(blood_type)
+					dna_hash = initial(dna_hash)
+					electronic_warfare = initial(electronic_warfare)
+					fingerprint_hash = initial(fingerprint_hash)
+					icon_state = initial(icon_state)
+					name = initial(name)
+					registered_name = initial(registered_name)
+					registered_user = null
+					sex = initial(sex)
+					user << "<span class='notice'>All information has been deleted from \the [src].</span>"
+					. = 1
+
+	// Always update the UI, or buttons will spin indefinitely
+	nanomanager.update_uis(src)
+
+/var/global/list/id_card_states
+/proc/id_card_states()
+	if(!id_card_states)
+		id_card_states = list()
+		for(var/path in typesof(/obj/item/weapon/card/id))
+			var/obj/item/weapon/card/id/ID = path
+			var/datum/card_state/CS = new()
+			CS.icon_state = initial(ID.icon_state)
+			CS.item_state = initial(ID.item_state)
+			CS.name = initial(ID.name) + " - " + initial(ID.icon_state)
+			id_card_states += CS
+		id_card_states = dd_sortedObjectList(id_card_states)
+
+	return id_card_states
+
+/datum/card_state
+	var/name
+	var/icon_state
+	var/item_state
+
+/datum/card_state/dd_SortValue()
+	return name

code/game/objects/objs.dm

@@ -19,9 +19,8 @@
 	nanomanager.close_uis(src)
 	return ..()
 
-/obj/Topic(href, href_list, var/nowindow = 0, var/datum/topic_state/state = default_state)
-	// Calling Topic without a corresponding window open causes runtime errors
-	if(!nowindow && ..())
+/obj/Topic(href, href_list, var/datum/topic_state/state = default_state)
+	if(usr && ..())
 		return 1
 
 	// In the far future no checks are made in an overriding Topic() beyond if(..()) return

code/modules/nano/modules/human_appearance.dm

@@ -17,7 +17,7 @@
 	src.whitelist = species_whitelist
 	src.blacklist = species_blacklist
 
-/datum/nano_module/appearance_changer/Topic(ref, href_list, var/nowindow, var/datum/topic_state/state = default_state)
+/datum/nano_module/appearance_changer/Topic(ref, href_list, var/datum/topic_state/state = default_state)
 	if(..())
 		return 1
 

code/modules/nano/nanoui.dm

@@ -479,7 +479,7 @@ nanoui is used to open and update nano browser uis
 		set_map_z_level(text2num(href_list["mapZLevel"]))
 		map_update = 1
 
-	if ((src_object && src_object.Topic(href, href_list, 0, state)) || map_update)
+	if ((src_object && src_object.Topic(href, href_list, state)) || map_update)
 		nanomanager.update_uis(src_object) // update all UIs attached to src_object
 
  /**

code/modules/power/apc.dm

@@ -850,7 +850,7 @@
 			return 0
 	return 1
 
-/obj/machinery/power/apc/Topic(href, href_list, var/nowindow = 0)
+/obj/machinery/power/apc/Topic(href, href_list)
 	if(..())
 		return 1
 

nano/templates/agent_id_card.tmpl

@@ -0,0 +1,21 @@
+<!-- 
+Title: Syndicate Uplink, uses some javascript to change nanoUI up a bit.
+Used In File(s): \code\game\objects\items\devices\uplinks.dm
+ -->
+{{:helper.syndicateMode()}}
+<H1>Available Entries</H1>
+<table>
+{{for data.entries}}
+    <tr>
+		<td>{{:helper.link('', 'gear', {'set' : value.name})}}</td><td>{{:value.name}}</td><td>{{:value.value}}</td>
+	</tr>
+{{/for}}
+</table>
+
+<table>
+    <tr>
+        <td>Electronic warfare:</td>
+        <td>{{:helper.link('Enable', null, {'electronic_warfare' : 1}, data.electronic_warfare ? 'selected' : null)}}</td>
+        <td>{{:helper.link('Disable',null, {'electronic_warfare' : 0}, data.electronic_warfare ? null : 'selected')}}</td>
+    </tr>
+</table>