TG: - All PM links are now tied to clients and not mobs. What this means is that all

PM links (the links admins get in admin messages which lead to a PM) should now
point directly to the client, if one still exists or report them as
disconnected. This means that there should no longer be problems with clients
which swap mobs.
- Made the player-side admin pm message more visible and obnoxious. Some players
might find it annoying but at least it will not leave much room to complain
about "missing PM-s"
Screenshot:
http://www.kamletos.si/admin%20message%20format.PNG
- Fixed that awkward X in asay messages, which moved whatever mob you were in to
the location of the person who said the message. Replaced it with JMP, which
does the same as the JMP in adminhelps - makes a ghost and moves that ghost to
the location:
Screenshot:
http://www.kamletos.si/admin%20say.PNG
- Ghosts which find themselves locked in any form of container (closets most
commonly) will now (FINALLY) exit the container (and it is any container!) after
they click one of the arrow keys.
Revision: r3121
Author: 	 baloh.matevz

Also some missed things from the config.txt

code/modules/admin/verbs/adminpm.dm

@@ -0,0 +1,107 @@
+//allows right clicking mobs to send an admin PM to their client, forwards the selected mob's client to cmd_admin_pm
+/client/proc/cmd_admin_pm_context(mob/M as mob in world)
+	set category = null
+	set name = "Admin PM Mob"
+	if(!holder)
+		src << "<font color='red'>Error: Admin-PM-Context: Only administrators may use this command.</font>"
+		return
+	if( !ismob(M) || !M.client )	return
+	cmd_admin_pm(M.client,null)
+	feedback_add_details("admin_verb","APMM") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+//shows a list of clients we could send PMs to, then forwards our choice to cmd_admin_pm
+/client/proc/cmd_admin_pm_panel()
+	set category = "Admin"
+	set name = "Admin PM"
+	if(!holder)
+		src << "<font color='red'>Error: Admin-PM-Panel: Only administrators may use this command.</font>"
+		return
+	var/list/client/targets[0]
+	for(var/client/T)
+		if(T.mob)
+			if(istype(T.mob, /mob/new_player))
+				targets["(New Player) - [T]"] = T
+			else if(istype(T.mob, /mob/dead/observer))
+				targets["[T.mob.name](Ghost) - [T]"] = T
+			else
+				targets["[T.mob.real_name](as [T.mob.name]) - [T]"] = T
+		else
+			targets["(No Mob) - [T]"] = T
+	var/list/sorted = sortList(targets)
+	var/target = input(src,"To whom shall we send a message?","Admin PM",null) in sorted|null
+	cmd_admin_pm(targets[target],null)
+	feedback_add_details("admin_verb","APM") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+
+//takes input from cmd_admin_pm_context, cmd_admin_pm_panel or /client/Topic and sends them a PM.
+//Fetching a message if needed. src is the sender and C is the target client
+/client/proc/cmd_admin_pm(var/client/C, var/msg)
+	if(src.muted_complete)
+		src << "<font color='red'>Error: Admin-PM: You are completely muted.</font>"
+		return
+
+	if( !C || !istype(C,/client) )
+		if(holder)		src << "<font color='red'>Error: Admin-PM: Client not found.</font>"
+		else			adminhelp(msg)	//admin we are replying to left. adminhelp instead
+		return
+
+	//get message text, limit it's length.and clean/escape html
+	if(!msg)
+		msg = input(src,"Message:", "Private message to [C.key]") as text|null
+		if(!msg)	return
+		if(!C)
+			if(holder)	src << "<font color='red'>Error: Admin-PM: Client not found.</font>"
+			else		adminhelp(msg)	//admin we are replying to has vanished, adminhelp instead
+			return
+
+	//clean the message if it's not sent by a GA or GM
+	if( !holder || !(holder.rank in list("Game Admin", "Game Master")) )
+		msg = sanitize(copytext(msg,1,MAX_MESSAGE_LEN))
+		if(!msg)	return
+
+	if(C.holder)
+		if(holder)	//both are admins
+			C << "<font color='red'>Admin PM from-<b>[key_name(src, C, 1)]</b>: [msg]</font>"
+			src << "<font color='blue'>Admin PM to-<b>[key_name(C, src, 1)]</b>: [msg]</font>"
+
+		else		//recipient is an admin but sender is not
+			C << "<font color='red'>Reply PM from-<b>[key_name(src, C, 1)]</b>: [msg]</font>"
+			src << "<font color='blue'>PM to-<b>Admins</b>: [msg]</font>"
+
+		//play the recieving admin the adminhelp sound (if they have them enabled)
+		if(C.sound_adminhelp)
+			C << 'adminhelp.ogg'
+
+	else
+		if(holder)	//sender is an admin but recipient is not. Do BIG RED TEXT
+//			C << "<font color='red' size='4'><b>-- Administrator private message --</b></font>"
+			C << "<font color='red'>Admin PM from-<b>[key_name(src, C, 0)]</b>: [msg]</font>"
+			C << "<font color='red'><i>Click on the administrator's name to reply.</i></font>"
+			src << "<font color='blue'>Admin PM to-<b>[key_name(C, src, 1)]</b>: [msg]</font>"
+
+			//always play non-admin recipients the adminhelp sound
+//			C << 'adminhelp.ogg'
+
+			//AdminPM popup for ApocStation and anybody else who wants to use it. Set it with POPUP_ADMIN_PM in config.txt ~Carn
+			if(config.popup_admin_pm)
+				spawn()	//so we don't hold the caller proc up
+					var/sender = src
+					var/sendername = key
+					var/reply = input(C, msg,"Admin PM from-[sendername]", "") as text|null		//show message and await a reply
+					if(C && reply)
+						if(sender)
+							C.cmd_admin_pm(sender,reply)										//sender is still about, let's reply to them
+						else
+							adminhelp(reply)													//sender has left, adminhelp instead
+					return
+
+		else		//neither are admins
+			src << "<font color='red'>Error: Admin-PM: Non-admin to non-admin PM communication is forbidden.</font>"
+			return
+
+	log_admin("PM: [key_name(src)]->[key_name(C)]: [msg]")
+
+	//we don't use message_admins here because the sender/receiver might get it too
+	for(var/client/X)									//there are fewer clients than mobs
+		if(X.holder && X.key!=key && X.key!=C.key)	//check client/X is an admin and isn't the sender or recipient
+			X << "<B><font color='blue'>PM: [key_name(src, X, 0)]-&gt;[key_name(C, X, 0)]:</B> \blue [msg]</font>" //inform X