Much nicer syringe gun implementation

Makes syringe guns a type of launcher gun, and removes the hack
projectile.
Also moves syringe and dart gun source files into the modules/projectile
folder.

code/modules/projectiles/guns/alien.dm

@@ -1,6 +1,6 @@
 //Vox pinning weapon.
 /obj/item/weapon/gun/launcher/spikethrower
-	name = "Vox spike thrower"
+	name = "vox spike thrower"
 	desc = "A vicious alien projectile weapon. Parts of it quiver gelatinously, as though the thing is insectile and alive."
 
 	var/last_regen = 0

code/modules/projectiles/guns/energy/stun.dm

@@ -49,7 +49,7 @@
 	projectile_type = /obj/item/projectile/energy/dart
 
 /obj/item/weapon/gun/energy/crossbow/largecrossbow
-	name = "Energy Crossbow"
+	name = "energy crossbow"
 	desc = "A weapon favored by mercenary infiltration teams."
 	w_class = 4
 	force = 10

code/modules/projectiles/guns/launcher.dm

@@ -22,14 +22,10 @@
 /obj/item/weapon/gun/launcher/proc/update_release_force(obj/item/projectile)
 	return 0
 
-/obj/item/weapon/gun/launcher/process_projectile(obj/projectile, mob/user, atom/target, var/target_zone, var/params=null, var/pointblank=0, var/reflex=0)
-	if(!istype(projectile, /obj/item)) return 0
-	
-	var/obj/item/I = projectile
-	
-	update_release_force(I)
-	I.loc = get_turf(user)
-	I.throw_at(target, throw_distance, release_force, user)
+/obj/item/weapon/gun/launcher/process_projectile(obj/item/projectile, mob/user, atom/target, var/target_zone, var/params=null, var/pointblank=0, var/reflex=0)
+	update_release_force(projectile)
+	projectile.loc = get_turf(user)
+	projectile.throw_at(target, throw_distance, release_force, user)
 	return 1
 
 /obj/item/weapon/gun/launcher/attack_self(mob/living/user as mob)

code/modules/projectiles/guns/launcher/pneumatic.dm

@@ -62,7 +62,7 @@
 		icon_state = "pneumatic-tank"
 		item_state = "pneumatic-tank"
 		user.update_icons()
-	else if(W.w_class <= max_w_class)
+	else if(istype(W) && W.w_class <= max_w_class)
 		var/total_stored = 0
 		for(var/obj/item/O in src.contents)
 			total_stored += O.w_class

code/modules/projectiles/guns/launcher/syringe_gun.dm

@@ -0,0 +1,135 @@
+/obj/item/weapon/syringe_cartridge
+	name = "compressed gas cartridge"
+	desc = "An impact-triggered compressed gas cartridge that can fitted to a syringe for rapid injection."
+	icon = 'icons/obj/ammo.dmi'
+	icon_state = "syringe-cartridge"
+	var/icon_flight = "syringe-cartridge-flight" //so it doesn't look so weird when shot
+	flags = CONDUCT
+	slot_flags = SLOT_BELT
+	throwforce = 3
+	force = 3
+	w_class = 1
+	var/obj/item/weapon/reagent_containers/syringe/syringe
+	var/primed = 0
+
+/obj/item/weapon/syringe_cartridge/update_icon()
+	underlays.Cut()
+	if(syringe)
+		underlays += image(syringe.icon, src, syringe.icon_state)
+		underlays += syringe.filling
+
+/obj/item/weapon/syringe_cartridge/attackby(obj/item/I, mob/user)
+	if(istype(I, /obj/item/weapon/reagent_containers/syringe))
+		syringe = I
+		user << "<span class='notice'>You carefully insert [syringe] into [src].</span>"
+		user.remove_from_mob(syringe)
+		syringe.loc = src
+		sharp = 1
+		update_icon()
+
+/obj/item/weapon/syringe_cartridge/attack_self(mob/user)
+	if(syringe)
+		user << "<span class='notice'>You remove [syringe] from [src].</span>"
+		user.put_in_hands(syringe)
+		syringe = null
+		sharp = initial(sharp)
+		update_icon()
+
+/obj/item/weapon/syringe_cartridge/proc/prime()
+	//the icon state will revert back when update_icon() is called from throw_impact()
+	icon_state = icon_flight
+	underlays.Cut()
+	primed = 1
+
+/obj/item/weapon/syringe_cartridge/throw_impact(atom/hit_atom, var/speed)
+	..() //handles embedding for us. Should have a decent chance if thrown fast enough
+	if(syringe)
+		//check speed to see if we hit hard enough to trigger the rapid injection
+		//incidentally, this means syringe_cartridges can be used with the pneumatic launcher
+		if(speed >= 10 && primed && isliving(hit_atom))
+			var/mob/living/L = hit_atom
+			//unfortuately we don't know where the dart will actually hit, since that's done by the parent.
+			if(L.can_inject())
+				if(syringe.reagents)
+					syringe.reagents.trans_to(L, 15)
+		
+		syringe.break_syringe(iscarbon(hit_atom)? hit_atom : null)
+		syringe.update_icon()
+	
+	icon_state = initial(icon_state) //reset icon state
+	update_icon()
+
+/obj/item/weapon/gun/launcher/syringe
+	name = "syringe gun"
+	desc = "A spring loaded rifle designed to fit syringes, designed to incapacitate unruly patients from a distance."
+	icon = 'icons/obj/gun.dmi'
+	icon_state = "syringegun"
+	item_state = "syringegun"
+	w_class = 3
+	force = 7
+	matter = list("metal" = 2000)
+	slot_flags = SLOT_BELT
+	
+	fire_sound = 'sound/weapons/empty.ogg'
+	fire_sound_text = "a metallic thunk"
+	recoil = 0
+	release_force = 10
+	throw_distance = 10
+	
+	var/list/darts = list()
+	var/max_darts = 1
+	var/obj/item/weapon/syringe_cartridge/next
+
+/obj/item/weapon/gun/launcher/syringe/consume_next_projectile()
+	if(next)
+		next.prime()
+		return next
+	return null
+
+/obj/item/weapon/gun/launcher/syringe/handle_post_fire()
+	..()
+	darts -= next
+	next = null
+
+/obj/item/weapon/gun/launcher/syringe/attack_self(mob/living/user as mob)
+	if(next)
+		user.visible_message("[user] unlatches and carefully relax the bolt on [src].", "<span class='notice'>You unlatch and carefully relax the bolt on [src], unloading the spring.</span>")
+		next = null
+	else if(darts.len)
+		playsound(src.loc, 'sound/weapons/flipblade.ogg', 50, 1)
+		user.visible_message("[user] draws back the bolt on [src], clicking it into place.", "<span class='warning'>You draw back the bolt on the [src], loading the spring!</span>")
+		next = darts[1]
+
+/obj/item/weapon/gun/launcher/syringe/attack_hand(mob/living/user as mob)
+	if(src in user)
+		if(!darts.len)
+			user << "<span class='warning'>[src] is empty.</span>"
+			return
+		if(next)
+			user << "<span class='warning'>The cover on [src] is locked shut.</span>"
+			return
+		var/obj/item/weapon/syringe_cartridge/C = darts[1]
+		darts -= C
+		user.put_in_hands(C)
+		user.visible_message("[user] removes \a [C] from [src].", "<span class='notice'>You remove \a [C] from [src].</span>")
+	else
+		..()
+
+/obj/item/weapon/gun/launcher/syringe/attackby(var/obj/item/A as obj, mob/user as mob)
+	if(istype(A, /obj/item/weapon/syringe_cartridge))
+		var/obj/item/weapon/syringe_cartridge/C = A
+		if(darts.len >= max_darts)
+			user << "<span class='warning'>[src] is full!</span>"
+			return
+		user.remove_from_mob(C)
+		C.loc = src
+		darts += C //add to the end
+		user.visible_message("[user] inserts \a [C] into [src].", "<span class='notice'>You insert \a [C] into [src].</span>")
+	else
+		..()
+
+/obj/item/weapon/gun/launcher/syringe/rapid
+	name = "rapid syringe gun"
+	desc = "A modification of the syringe gun design, using a rotating cylinder to store up to four syringes. The spring still needs to be drawn between shots."
+	icon_state = "rapidsyringegun"
+	max_darts = 4

code/modules/projectiles/guns/projectile.dm

@@ -78,12 +78,12 @@
 		switch(AM.mag_type)
 			if(MAGAZINE)
 				if(ammo_magazine)
-					user << "<span class='warning'>[src] already has a magazine loaded!</span>" //already a magazine here
+					user << "<span class='warning'>[src] already has a magazine loaded.</span>" //already a magazine here
 					return
 				user.remove_from_mob(AM)
 				AM.loc = src
 				ammo_magazine = AM
-				user.visible_message("[user] inserts [AM] into [src].", "<span class='notice'>You insert [AM] into [src]!</span>")
+				user.visible_message("[user] inserts [AM] into [src].", "<span class='notice'>You insert [AM] into [src].</span>")
 				playsound(src.loc, 'sound/weapons/flipblade.ogg', 50, 1)
 			if(SPEEDLOADER)
 				if(loaded.len >= max_shells)
@@ -99,7 +99,7 @@
 						AM.stored_ammo -= C //should probably go inside an ammo_magazine proc, but I guess less proc calls this way...
 						count++
 				if(count)
-					user.visible_message("[user] reloads [src].", "<span class='notice'>You load [count] round\s into [src]!</span>")
+					user.visible_message("[user] reloads [src].", "<span class='notice'>You load [count] round\s into [src].</span>")
 					playsound(src.loc, 'sound/weapons/empty.ogg', 50, 1)
 		AM.update_icon()
 	else if(istype(A, /obj/item/ammo_casing))
@@ -107,13 +107,13 @@
 		if(!(load_method & SINGLE_CASING) || caliber != C.caliber)
 			return //incompatible
 		if(loaded.len >= max_shells)
-			user << "<span class='warning'>[src] is full!</span>"
+			user << "<span class='warning'>[src] is full.</span>"
 			return
 
 		user.remove_from_mob(C)
 		C.loc = src
 		loaded.Insert(1, C) //add to the head of the list
-		user.visible_message("[user] inserts \a [C] into [src].", "<span class='notice'>You insert \a [C] into [src]!</span>")
+		user.visible_message("[user] inserts \a [C] into [src].", "<span class='notice'>You insert \a [C] into [src].</span>")
 		playsound(src.loc, 'sound/weapons/empty.ogg', 50, 1)
 
 	update_icon()
@@ -123,7 +123,7 @@
 /obj/item/weapon/gun/projectile/proc/unload_ammo(mob/user, var/allow_dump=1)
 	if(ammo_magazine)
 		user.put_in_hands(ammo_magazine)
-		user.visible_message("[user] removes [ammo_magazine] from [src].", "<span class='notice'>You remove [ammo_magazine] from [src]!</span>")
+		user.visible_message("[user] removes [ammo_magazine] from [src].", "<span class='notice'>You remove [ammo_magazine] from [src].</span>")
 		playsound(src.loc, 'sound/weapons/empty.ogg', 50, 1)
 		ammo_magazine.update_icon()
 		ammo_magazine = null
@@ -138,14 +138,14 @@
 					count++
 				loaded.Cut()
 			if(count)
-				user.visible_message("[user] unloads [src].", "<span class='notice'>You unload [count] round\s from [src]!</span>")
+				user.visible_message("[user] unloads [src].", "<span class='notice'>You unload [count] round\s from [src].</span>")
 		else if(load_method & SINGLE_CASING)
 			var/obj/item/ammo_casing/C = loaded[loaded.len]
 			loaded.len--
 			user.put_in_hands(C)
-			user.visible_message("[user] removes \a [C] from [src].", "<span class='notice'>You remove \a [C] from [src]!</span>")
+			user.visible_message("[user] removes \a [C] from [src].", "<span class='notice'>You remove \a [C] from [src].</span>")
 	else
-		user << "<span class='warning'>[src] is empty!</span>"
+		user << "<span class='warning'>[src] is empty.</span>"
 	update_icon()
 
 /obj/item/weapon/gun/projectile/attackby(var/obj/item/A as obj, mob/user as mob)

code/modules/projectiles/guns/projectile/dartgun.dm

@@ -0,0 +1,197 @@
+/obj/item/projectile/bullet/chemdart
+	name = "dart"
+	icon_state = "cbbolt"
+	damage = 3
+	sharp = 1
+	embed = 1
+	var/reagent_amount = 15
+	kill_count = 10 //short range
+
+/obj/item/projectile/bullet/chemdart/New()
+	reagents = new/datum/reagents(reagent_amount)
+	reagents.my_atom = src
+
+/obj/item/projectile/bullet/chemdart/on_hit(var/atom/target, var/blocked = 0, var/def_zone = null)
+	if(blocked < 2 && isliving(target))
+		var/mob/living/L = target
+		if(L.can_inject(target_zone=def_zone))
+			reagents.trans_to(L, reagent_amount)
+
+/obj/item/ammo_casing/chemdart
+	name = "chemical dart"
+	desc = "A small hollow dart."
+	icon_state = "dart"
+	caliber = "dart"
+	projectile_type = /obj/item/projectile/bullet/chemdart
+
+/obj/item/ammo_magazine/chemdart
+	name = "dart cartridge"
+	desc = "A rack of hollow darts."
+	icon_state = "darts"
+	item_state = "rcdammo"
+	origin_tech = "materials=2"
+	mag_type = MAGAZINE
+	caliber = "dart"
+	max_ammo = 5
+	multiple_sprites = 1
+
+/obj/item/weapon/gun/projectile/dartgun
+	name = "dart gun"
+	desc = "A small gas-powered dartgun, capable of delivering chemical cocktails swiftly across short distances."
+	icon_state = "dartgun-empty"
+
+	caliber = "dart"
+	fire_sound = 'sound/weapons/empty.ogg'
+	fire_sound_text = "a metallic click"
+	recoil = 0
+	silenced = 1
+	load_method = MAGAZINE
+	magazine_type = /obj/item/ammo_magazine/chemdart
+	auto_eject = 0
+
+	var/list/beakers = list() //All containers inside the gun.
+	var/list/mixing = list() //Containers being used for mixing.
+	var/max_beakers = 3
+	var/dart_reagent_amount = 15
+	var/container_type = /obj/item/weapon/reagent_containers/glass/beaker
+	var/list/starting_chems = null
+
+/obj/item/weapon/gun/projectile/dartgun/dartgun/New()
+	..()
+	if(starting_chems)
+		for(var/chem in starting_chems)
+			var/obj/B = new container_type(src)
+			B.reagents.add_reagent(chem, 60)
+			beakers += B
+	update_icon()
+
+/obj/item/weapon/gun/projectile/dartgun/update_icon()
+	if(!ammo_magazine)
+		icon_state = "dartgun-empty"
+		return 1
+
+	if(!ammo_magazine.stored_ammo || ammo_magazine.stored_ammo.len)
+		icon_state = "dartgun-0"
+	else if(ammo_magazine.stored_ammo.len > 5)
+		icon_state = "dartgun-5"
+	else
+		icon_state = "dartgun-[ammo_magazine.stored_ammo.len]"
+	return 1
+
+/obj/item/weapon/gun/projectile/dartgun/consume_next_projectile()
+	. = ..()
+	var/obj/item/projectile/bullet/chemdart/dart = .
+	if(istype(dart))
+		fill_dart(dart)
+
+/obj/item/weapon/gun/projectile/dartgun/examine(mob/user)
+	//update_icon()
+	//if (!..(user, 2))
+	//	return
+	..()
+	if (beakers.len)
+		user << "\blue [src] contains:"
+		for(var/obj/item/weapon/reagent_containers/glass/beaker/B in beakers)
+			if(B.reagents && B.reagents.reagent_list.len)
+				for(var/datum/reagent/R in B.reagents.reagent_list)
+					user << "\blue [R.volume] units of [R.name]"
+
+/obj/item/weapon/gun/projectile/dartgun/attackby(obj/item/I as obj, mob/user as mob)
+	if(istype(I, /obj/item/weapon/reagent_containers/glass))
+		if(!istype(I, container_type))
+			user << "\blue [I] doesn't seem to fit into [src]."
+			return
+		if(beakers.len >= max_beakers)
+			user << "\blue [src] already has [max_beakers] beakers in it - another one isn't going to fit!"
+			return
+		var/obj/item/weapon/reagent_containers/glass/beaker/B = I
+		user.drop_item()
+		B.loc = src
+		beakers += B
+		user << "\blue You slot [B] into [src]."
+		src.updateUsrDialog()
+	..()
+
+//fills the given dart with reagents
+/obj/item/weapon/gun/projectile/dartgun/proc/fill_dart(var/obj/item/projectile/bullet/chemdart/dart)
+	if(mixing.len)
+		var/mix_amount = dart.reagent_amount/mixing.len
+		for(var/obj/item/weapon/reagent_containers/glass/beaker/B in mixing)
+			B.reagents.trans_to(dart, mix_amount)
+
+/obj/item/weapon/gun/projectile/dartgun/attack_self(mob/user)
+	user.set_machine(src)
+	var/dat = "<b>[src] mixing control:</b><br><br>"
+
+	if (beakers.len)
+		var/i = 1
+		for(var/obj/item/weapon/reagent_containers/glass/beaker/B in beakers)
+			dat += "Beaker [i] contains: "
+			if(B.reagents && B.reagents.reagent_list.len)
+				for(var/datum/reagent/R in B.reagents.reagent_list)
+					dat += "<br>    [R.volume] units of [R.name], "
+				if (check_beaker_mixing(B))
+					dat += text("<A href='?src=\ref[src];stop_mix=[i]'><font color='green'>Mixing</font></A> ")
+				else
+					dat += text("<A href='?src=\ref[src];mix=[i]'><font color='red'>Not mixing</font></A> ")
+			else
+				dat += "nothing."
+			dat += " \[<A href='?src=\ref[src];eject=[i]'>Eject</A>\]<br>"
+			i++
+	else
+		dat += "There are no beakers inserted!<br><br>"
+
+	if(ammo_magazine)
+		if(ammo_magazine.stored_ammo && ammo_magazine.stored_ammo.len)
+			dat += "The dart cartridge has [ammo_magazine.stored_ammo.len] shots remaining."
+		else
+			dat += "<font color='red'>The dart cartridge is empty!</font>"
+		dat += " \[<A href='?src=\ref[src];eject_cart=1'>Eject</A>\]"
+
+	user << browse(dat, "window=dartgun")
+	onclose(user, "dartgun", src)
+
+/obj/item/weapon/gun/projectile/dartgun/proc/check_beaker_mixing(var/obj/item/B)
+	if(!mixing || !beakers)
+		return 0
+	for(var/obj/item/M in mixing)
+		if(M == B)
+			return 1
+	return 0
+
+/obj/item/weapon/gun/projectile/dartgun/Topic(href, href_list)
+	src.add_fingerprint(usr)
+	if(href_list["stop_mix"])
+		var/index = text2num(href_list["stop_mix"])
+		if(index <= beakers.len)
+			for(var/obj/item/M in mixing)
+				if(M == beakers[index])
+					mixing -= M
+					break
+	else if (href_list["mix"])
+		var/index = text2num(href_list["mix"])
+		if(index <= beakers.len)
+			mixing += beakers[index]
+	else if (href_list["eject"])
+		var/index = text2num(href_list["eject"])
+		if(index <= beakers.len)
+			if(beakers[index])
+				var/obj/item/weapon/reagent_containers/glass/beaker/B = beakers[index]
+				usr << "You remove [B] from [src]."
+				mixing -= B
+				beakers -= B
+				B.loc = get_turf(src)
+	else if (href_list["eject_cart"])
+		unload_ammo(usr)
+	src.updateUsrDialog()
+	return
+
+/obj/item/weapon/gun/projectile/dartgun/vox
+	name = "alien dart gun"
+	desc = "A small gas-powered dartgun, fitted for nonhuman hands."
+
+/obj/item/weapon/gun/projectile/dartgun/vox/medical
+	starting_chems = list("kelotane","bicaridine","anti_toxin")
+
+/obj/item/weapon/gun/projectile/dartgun/vox/raider
+	starting_chems = list("space_drugs","stoxin","impedrezene")