mirror of
https://github.com/CHOMPStation2/CHOMPStation2.git
synced 2025-12-11 18:53:06 +00:00
63a1dd0143
- Unified pipe *unwrenching* by creating a standard proc along with the `construction_type` var.
- Eliminated the pipe fitting name & icon_state lookup tables by adding `pipe_state` var on atmos machinery and referencing that.
- Each pipe which can be made from a fitting object should override `pipe_state` with the icon state to be used on the pipe fitting object.
- Eliminated the giant switch statement of doom in pipe construction by delegating that work to `on_construction` proc.
- To make this work, every pipe must implement `get_neighbor_nodes_for_init` which returns a list of nodes which should be re-initialized on that pipe's construction.
- Combined the SCRUBBERS, SUPPLY and REGULAR pipe fitting classes together by storing the `piping_layer` variable and using the `setPipingLayer` procs
- Standardized the code for searching for node neighbors into the `can_be_node` proc.
- This proc is also improved in that is a mutual check, `check_connectable` is called on BOTH objects, so they have to mutually agree to connect as nodes. Eliminates lots of special edge case logic.
- Updated all the `amos_init` procs to use `can_be_node`. In the most common cases, even that boilerplate code is consolidated into the `STANDARD_ATMOS_CHOOSE_NODE` macro.
- Implemented `pipe_flags` which lets pipes declare (or override) certain requirements.
- Adds a "pipe_recipe" datum to help out things that construct pipes. By taking it out of the dispenser, we open the road for multiple dispenser types. No, no RPD yet. Soon.
- Enhances the pipe dispenser to operate on pipe recipe datums instead of hard coded lists of pipes it can construct. These datums are also (partially) initialized from the pipe machine types themselves, reducing having to define stuff in multiple places.
- Switched pipe dispenser UI to use browse(). Not a NanoUI, but makes it a bit prettier with low effort.
- Changed pipe dispenser to use a button selector to switch between Regular/Scrubbers/Supply instead of having separate list items.
- Added icon states to HE pipes to support the "connected on neither side" state.
148 lines
4.7 KiB
Plaintext
148 lines
4.7 KiB
Plaintext
//node1, air1, network1 correspond to input
|
|
//node2, air2, network2 correspond to output
|
|
|
|
#define ADIABATIC_EXPONENT 0.667 //Actually adiabatic exponent - 1.
|
|
|
|
/obj/machinery/atmospherics/binary/circulator
|
|
name = "circulator"
|
|
desc = "A gas circulator turbine and heat exchanger."
|
|
icon = 'icons/obj/pipes.dmi'
|
|
icon_state = "circ-off"
|
|
anchored = 0
|
|
pipe_flags = PIPING_DEFAULT_LAYER_ONLY|PIPING_ONE_PER_TURF
|
|
|
|
var/kinetic_efficiency = 0.04 //combined kinetic and kinetic-to-electric efficiency
|
|
var/volume_ratio = 0.2
|
|
|
|
var/recent_moles_transferred = 0
|
|
var/last_heat_capacity = 0
|
|
var/last_temperature = 0
|
|
var/last_pressure_delta = 0
|
|
var/last_worldtime_transfer = 0
|
|
var/last_stored_energy_transferred = 0
|
|
var/volume_capacity_used = 0
|
|
var/stored_energy = 0
|
|
|
|
density = 1
|
|
|
|
/obj/machinery/atmospherics/binary/circulator/New()
|
|
..()
|
|
desc = initial(desc) + " Its outlet port is to the [dir2text(dir)]."
|
|
air1.volume = 400
|
|
|
|
/obj/machinery/atmospherics/binary/circulator/proc/return_transfer_air()
|
|
var/datum/gas_mixture/removed
|
|
if(anchored && !(stat&BROKEN) && network1)
|
|
var/input_starting_pressure = air1.return_pressure()
|
|
var/output_starting_pressure = air2.return_pressure()
|
|
last_pressure_delta = max(input_starting_pressure - output_starting_pressure - 5, 0)
|
|
|
|
//only circulate air if there is a pressure difference (plus 5kPa kinetic, 10kPa static friction)
|
|
if(air1.temperature > 0 && last_pressure_delta > 5)
|
|
|
|
//Calculate necessary moles to transfer using PV = nRT
|
|
recent_moles_transferred = (last_pressure_delta*network1.volume/(air1.temperature * R_IDEAL_GAS_EQUATION))/3 //uses the volume of the whole network, not just itself
|
|
volume_capacity_used = min( (last_pressure_delta*network1.volume/3)/(input_starting_pressure*air1.volume) , 1) //how much of the gas in the input air volume is consumed
|
|
|
|
//Calculate energy generated from kinetic turbine
|
|
stored_energy += 1/ADIABATIC_EXPONENT * min(last_pressure_delta * network1.volume , input_starting_pressure*air1.volume) * (1 - volume_ratio**ADIABATIC_EXPONENT) * kinetic_efficiency
|
|
|
|
//Actually transfer the gas
|
|
removed = air1.remove(recent_moles_transferred)
|
|
if(removed)
|
|
last_heat_capacity = removed.heat_capacity()
|
|
last_temperature = removed.temperature
|
|
|
|
//Update the gas networks.
|
|
network1.update = 1
|
|
|
|
last_worldtime_transfer = world.time
|
|
else
|
|
recent_moles_transferred = 0
|
|
|
|
update_icon()
|
|
return removed
|
|
|
|
/obj/machinery/atmospherics/binary/circulator/proc/return_stored_energy()
|
|
last_stored_energy_transferred = stored_energy
|
|
stored_energy = 0
|
|
return last_stored_energy_transferred
|
|
|
|
/obj/machinery/atmospherics/binary/circulator/process()
|
|
..()
|
|
|
|
if(last_worldtime_transfer < world.time - 50)
|
|
recent_moles_transferred = 0
|
|
update_icon()
|
|
|
|
/obj/machinery/atmospherics/binary/circulator/update_icon()
|
|
if(stat & (BROKEN|NOPOWER) || !anchored)
|
|
icon_state = "circ-p"
|
|
else if(last_pressure_delta > 0 && recent_moles_transferred > 0)
|
|
if(last_pressure_delta > 5*ONE_ATMOSPHERE)
|
|
icon_state = "circ-run"
|
|
else
|
|
icon_state = "circ-slow"
|
|
else
|
|
icon_state = "circ-off"
|
|
|
|
return 1
|
|
|
|
/obj/machinery/atmospherics/binary/circulator/attackby(obj/item/weapon/W as obj, mob/user as mob)
|
|
if(istype(W, /obj/item/weapon/wrench))
|
|
playsound(src, W.usesound, 75, 1)
|
|
anchored = !anchored
|
|
user.visible_message("[user.name] [anchored ? "secures" : "unsecures"] the bolts holding [src.name] to the floor.", \
|
|
"You [anchored ? "secure" : "unsecure"] the bolts holding [src] to the floor.", \
|
|
"You hear a ratchet.")
|
|
|
|
if(anchored)
|
|
if(dir & (NORTH|SOUTH))
|
|
initialize_directions = NORTH|SOUTH
|
|
else if(dir & (EAST|WEST))
|
|
initialize_directions = EAST|WEST
|
|
|
|
atmos_init()
|
|
build_network()
|
|
if (node1)
|
|
node1.atmos_init()
|
|
node1.build_network()
|
|
if (node2)
|
|
node2.atmos_init()
|
|
node2.build_network()
|
|
else
|
|
if(node1)
|
|
node1.disconnect(src)
|
|
qdel(network1)
|
|
if(node2)
|
|
node2.disconnect(src)
|
|
qdel(network2)
|
|
|
|
node1 = null
|
|
node2 = null
|
|
|
|
else
|
|
..()
|
|
|
|
/obj/machinery/atmospherics/binary/circulator/verb/rotate_clockwise()
|
|
set category = "Object"
|
|
set name = "Rotate Circulator (Clockwise)"
|
|
set src in view(1)
|
|
|
|
if (usr.stat || usr.restrained() || anchored)
|
|
return
|
|
|
|
src.set_dir(turn(src.dir, 90))
|
|
desc = initial(desc) + " Its outlet port is to the [dir2text(dir)]."
|
|
|
|
|
|
/obj/machinery/atmospherics/binary/circulator/verb/rotate_anticlockwise()
|
|
set category = "Object"
|
|
set name = "Rotate Circulator (Counterclockwise)"
|
|
set src in view(1)
|
|
|
|
if (usr.stat || usr.restrained() || anchored)
|
|
return
|
|
|
|
src.set_dir(turn(src.dir, -90))
|
|
desc = initial(desc) + " Its outlet port is to the [dir2text(dir)]." |