mirror of
https://github.com/CHOMPStation2/CHOMPStation2.git
synced 2026-01-02 13:34:49 +00:00
31349fb7d3
removed extraneous admin attack messages, temporarily disabled much moderator stuff (will be re-enabled in future updates) Conflicts: baystation12.dme code/__HELPERS/type2type.dm code/controllers/configuration.dm code/datums/datumvars.dm code/datums/helper_datums/getrev.dm code/defines/obj.dm code/game/gamemodes/events/black_hole.dm code/game/gamemodes/events/space_ninja.dm code/game/gamemodes/wizard/rightandwrong.dm code/game/jobs/job/captain.dm code/game/jobs/job/job.dm code/game/jobs/job_controller.dm code/game/machinery/bots/medbot.dm code/game/machinery/computer/card.dm code/game/machinery/telecomms/traffic_control.dm code/game/machinery/turrets.dm code/game/machinery/wishgranter.dm code/game/objects/items/blueprints.dm code/game/objects/items/devices/uplinks.dm code/game/objects/items/stacks/stack.dm code/game/objects/items/weapons/surgery_tools.dm code/game/turfs/turf.dm code/game/verbs/ooc.dm code/global.dm code/modules/admin/IsBanned.dm code/modules/admin/admin.dm code/modules/admin/admin_memo.dm code/modules/admin/admin_verbs.dm code/modules/admin/holder2.dm code/modules/admin/player_panel.dm code/modules/admin/verbs/adminpm.dm code/modules/admin/verbs/diagnostics.dm code/modules/assembly/igniter.dm code/modules/client/client defines.dm code/modules/client/client procs.dm code/modules/clothing/spacesuits/miscellaneous.dm code/modules/clothing/suits/armor.dm code/modules/clothing/suits/jobs.dm code/modules/mining/mine_turfs.dm code/modules/mob/living/carbon/human/say.dm code/modules/mob/living/carbon/human/update_icons.dm code/modules/mob/living/living.dm code/modules/mob/living/living_defense.dm code/modules/mob/living/silicon/robot/emote.dm code/modules/mob/living/silicon/robot/life.dm code/modules/mob/mob_cleanup.dm code/modules/mob/new_player/new_player.dm code/modules/mob/new_player/preferences.dm code/modules/paperwork/paper.dm code/modules/paperwork/photocopier.dm code/modules/projectiles/guns/projectile/automatic.dm code/modules/reagents/Chemistry-Machinery.dm code/setup.dm code/stylesheet.dm code/world.dm config/admins.txt config/config.txt html/changelog.html icons/mob/items_lefthand.dmi icons/mob/items_righthand.dmi icons/mob/suit.dmi icons/obj/clothing/suits.dmi icons/turf/areas.dmi Signed-off-by: Cael_Aislinn <cael_aislinn@yahoo.com.au>
83 lines
3.0 KiB
Plaintext
83 lines
3.0 KiB
Plaintext
//This stuff was originally intended to be integrated into the ban-system I was working on
|
|
//but it's safe to say that'll never be finished. So I've merged it into the current player panel.
|
|
//enjoy ~Carn
|
|
|
|
#define NOTESFILE "data/player_notes.sav" //where the player notes are saved
|
|
|
|
datum/admins/proc/notes_show(var/ckey)
|
|
usr << browse("<head><title>Player Notes</title></head><body>[notes_gethtml(ckey)]</body>","window=player_notes;size=700x400")
|
|
|
|
|
|
datum/admins/proc/notes_gethtml(var/ckey)
|
|
var/savefile/notesfile = new(NOTESFILE)
|
|
if(!notesfile) return "<font color='red'>Error: Cannot access [NOTESFILE]</font>"
|
|
if(ckey)
|
|
. = "<b>Notes for <a href='?src=\ref[src];notes=show'>[ckey]</a>:</b> <a href='?src=\ref[src];notes=add;ckey=[ckey]'>\[+\]</a> <a href='?src=\ref[src];notes=remove;ckey=[ckey]'>\[-\]</a><br>"
|
|
notesfile.cd = "/[ckey]"
|
|
var/index = 1
|
|
while( !notesfile.eof )
|
|
var/note
|
|
notesfile >> note
|
|
. += "[note] <a href='?src=\ref[src];notes=remove;ckey=[ckey];from=[index]'>\[-\]</a><br>"
|
|
index++
|
|
else
|
|
. = "<b>All Notes:</b> <a href='?src=\ref[src];notes=add'>\[+\]</a> <a href='?src=\ref[src];notes=remove'>\[-\]</a><br>"
|
|
notesfile.cd = "/"
|
|
for(var/dir in notesfile.dir)
|
|
. += "<a href='?src=\ref[src];notes=show;ckey=[dir]'>[dir]</a><br>"
|
|
return
|
|
|
|
|
|
//handles adding notes to the end of a ckey's buffer
|
|
//originally had seperate entries such as var/by to record who left the note and when
|
|
//but the current bansystem is a heap of dung.
|
|
/proc/notes_add(var/ckey, var/note)
|
|
if(!ckey)
|
|
ckey = ckey(input(usr,"Who would you like to add notes for?","Enter a ckey",null) as text|null)
|
|
if(!ckey) return
|
|
|
|
if(!note)
|
|
note = html_encode(input(usr,"Enter your note:","Enter some text",null) as message|null)
|
|
if(!note) return
|
|
|
|
var/savefile/notesfile = new(NOTESFILE)
|
|
if(!notesfile) return
|
|
notesfile.cd = "/[ckey]"
|
|
notesfile.eof = 1 //move to the end of the buffer
|
|
notesfile << "[time2text(world.realtime,"DD-MMM-YYYY")] | [note][(usr && usr.ckey)?" ~[usr.ckey]":""]"
|
|
return
|
|
|
|
//handles removing entries from the buffer, or removing the entire directory if no start_index is given
|
|
/proc/notes_remove(var/ckey, var/start_index, var/end_index)
|
|
var/savefile/notesfile = new(NOTESFILE)
|
|
if(!notesfile) return
|
|
|
|
if(!ckey)
|
|
notesfile.cd = "/"
|
|
ckey = ckey(input(usr,"Who would you like to remove notes for?","Enter a ckey",null) as null|anything in notesfile.dir)
|
|
if(!ckey) return
|
|
|
|
if(start_index)
|
|
notesfile.cd = "/[ckey]"
|
|
var/list/noteslist = list()
|
|
if(!end_index) end_index = start_index
|
|
var/index = 0
|
|
while( !notesfile.eof )
|
|
index++
|
|
var/temp
|
|
notesfile >> temp
|
|
if( (start_index <= index) && (index <= end_index) )
|
|
continue
|
|
noteslist += temp
|
|
|
|
notesfile.eof = -2 //Move to the start of the buffer and then erase.
|
|
|
|
for( var/note in noteslist )
|
|
notesfile << note
|
|
else
|
|
notesfile.cd = "/"
|
|
if(alert(usr,"Are you sure you want to remove all their notes?","Confirmation","No","Yes - Remove all notes") == "Yes - Remove all notes")
|
|
notesfile.dir.Remove(ckey)
|
|
return
|
|
|
|
#undef NOTESFILE |