mirror of
https://github.com/CHOMPStation2/CHOMPStation2.git
synced 2025-12-11 18:53:06 +00:00
776b221828
- Moved pipe construction defines into __defines/construction.dm
- Unified pipe *unwrenching* by creating a standard proc along with the `construction_type` var.
- Eliminated the pipe fitting name & icon_state lookup tables by adding `pipe_state` var on atmos machinery and referencing that.
- Each pipe which can be made from a fitting object should override `pipe_state` with the icon state to be used on the pipe fitting object.
- Eliminated the giant switch statement of doom in pipe construction by delegating that work to `on_construction` proc.
- To make this work, every pipe must implement `get_neighbor_nodes_for_init` which returns a list of nodes which should be re-initialized on that pipe's construction.
- Combined the SCRUBBERS, SUPPLY and REGULAR pipe fitting classes together by storing the `piping_layer` variable and using the `setPipingLayer` procs
- Standardized the code for searching for node neighbors into the `can_be_node` proc.
- This proc is also improved in that is a mutual check, `check_connectable` is called on BOTH objects, so they have to mutually agree to connect as nodes. Eliminates lots of special edge case logic.
- Updated all the `amos_init` procs to use `can_be_node`. In the most common cases, even that boilerplate code is consolidated into the `STANDARD_ATMOS_CHOOSE_NODE` macro.
- Implemented `pipe_flags` which lets pipes declare (or override) certain requirements.
- Adds a "pipe_recipe" datum to help out things that construct pipes. By taking it out of the dispenser, we open the road for multiple dispenser types. No, no RPD yet. Soon.
- Enhances the pipe dispenser to operate on pipe recipe datums instead of hard coded lists of pipes it can construct. These datums are also (partially) initialized from the pipe machine types themselves, reducing having to define stuff in multiple places.
- Switched pipe dispenser UI to use browse(). Not a NanoUI, but makes it a bit prettier with low effort.
- Changed pipe dispenser to use a button selector to switch between Regular/Scrubbers/Supply instead of having separate list items.
- Added icon states to HE pipes to support the "connected on neither side" state.
171 lines
5.2 KiB
Plaintext
171 lines
5.2 KiB
Plaintext
//TODO: Put this under a common parent type with freezers to cut down on the copypasta
|
|
#define HEATER_PERF_MULT 2.5
|
|
|
|
/obj/machinery/atmospherics/unary/heater
|
|
name = "gas heating system"
|
|
desc = "Heats gas when connected to a pipe network"
|
|
icon = 'icons/obj/Cryogenic2.dmi'
|
|
icon_state = "heater_0"
|
|
density = 1
|
|
anchored = 1
|
|
use_power = 0
|
|
idle_power_usage = 5 //5 Watts for thermostat related circuitry
|
|
circuit = /obj/item/weapon/circuitboard/unary_atmos/heater
|
|
|
|
var/max_temperature = T20C + 680
|
|
var/internal_volume = 600 //L
|
|
|
|
var/max_power_rating = 20000 //power rating when the usage is turned up to 100
|
|
var/power_setting = 100
|
|
|
|
var/set_temperature = T20C //thermostat
|
|
var/heating = 0 //mainly for icon updates
|
|
|
|
/obj/machinery/atmospherics/unary/heater/New()
|
|
..()
|
|
component_parts = list()
|
|
component_parts += new /obj/item/weapon/stock_parts/matter_bin(src)
|
|
component_parts += new /obj/item/weapon/stock_parts/capacitor(src)
|
|
component_parts += new /obj/item/weapon/stock_parts/capacitor(src)
|
|
component_parts += new /obj/item/stack/cable_coil(src, 5)
|
|
|
|
RefreshParts()
|
|
|
|
/obj/machinery/atmospherics/unary/heater/atmos_init()
|
|
if(node)
|
|
return
|
|
|
|
var/node_connect = dir
|
|
|
|
//check that there is something to connect to
|
|
for(var/obj/machinery/atmospherics/target in get_step(src, node_connect))
|
|
if(can_be_node(target, 1))
|
|
node = target
|
|
break
|
|
|
|
if(check_for_obstacles())
|
|
node = null
|
|
|
|
if(node)
|
|
update_icon()
|
|
|
|
|
|
/obj/machinery/atmospherics/unary/heater/update_icon()
|
|
if(node)
|
|
if(use_power && heating)
|
|
icon_state = "heater_1"
|
|
else
|
|
icon_state = "heater"
|
|
else
|
|
icon_state = "heater_0"
|
|
return
|
|
|
|
|
|
/obj/machinery/atmospherics/unary/heater/process()
|
|
..()
|
|
|
|
if(stat & (NOPOWER|BROKEN) || !use_power)
|
|
heating = 0
|
|
update_icon()
|
|
return
|
|
|
|
if(network && air_contents.total_moles && air_contents.temperature < set_temperature)
|
|
air_contents.add_thermal_energy(power_rating * HEATER_PERF_MULT)
|
|
use_power(power_rating)
|
|
|
|
heating = 1
|
|
network.update = 1
|
|
else
|
|
heating = 0
|
|
|
|
update_icon()
|
|
|
|
/obj/machinery/atmospherics/unary/heater/attack_ai(mob/user as mob)
|
|
ui_interact(user)
|
|
|
|
/obj/machinery/atmospherics/unary/heater/attack_hand(mob/user as mob)
|
|
ui_interact(user)
|
|
|
|
/obj/machinery/atmospherics/unary/heater/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
|
|
// this is the data which will be sent to the ui
|
|
var/data[0]
|
|
data["on"] = use_power ? 1 : 0
|
|
data["gasPressure"] = round(air_contents.return_pressure())
|
|
data["gasTemperature"] = round(air_contents.temperature)
|
|
data["minGasTemperature"] = 0
|
|
data["maxGasTemperature"] = round(max_temperature)
|
|
data["targetGasTemperature"] = round(set_temperature)
|
|
data["powerSetting"] = power_setting
|
|
|
|
var/temp_class = "normal"
|
|
if(air_contents.temperature > (T20C+40))
|
|
temp_class = "bad"
|
|
data["gasTemperatureClass"] = temp_class
|
|
|
|
// update the ui if it exists, returns null if no ui is passed/found
|
|
ui = nanomanager.try_update_ui(user, src, ui_key, ui, data, force_open)
|
|
if(!ui)
|
|
// the ui does not exist, so we'll create a new() one
|
|
// for a list of parameters and their descriptions see the code docs in \code\modules\nano\nanoui.dm
|
|
ui = new(user, src, ui_key, "freezer.tmpl", "Gas Heating System", 440, 300)
|
|
// when the ui is first opened this is the data it will use
|
|
ui.set_initial_data(data)
|
|
// open the new ui window
|
|
ui.open()
|
|
// auto update every Master Controller tick
|
|
ui.set_auto_update(1)
|
|
|
|
/obj/machinery/atmospherics/unary/heater/Topic(href, href_list)
|
|
if(..())
|
|
return 1
|
|
if(href_list["toggleStatus"])
|
|
use_power = !use_power
|
|
update_icon()
|
|
if(href_list["temp"])
|
|
var/amount = text2num(href_list["temp"])
|
|
if(amount > 0)
|
|
set_temperature = min(set_temperature + amount, max_temperature)
|
|
else
|
|
set_temperature = max(set_temperature + amount, 0)
|
|
if(href_list["setPower"]) //setting power to 0 is redundant anyways
|
|
var/new_setting = between(0, text2num(href_list["setPower"]), 100)
|
|
set_power_level(new_setting)
|
|
|
|
add_fingerprint(usr)
|
|
|
|
//upgrading parts
|
|
/obj/machinery/atmospherics/unary/heater/RefreshParts()
|
|
..()
|
|
var/cap_rating = 0
|
|
var/bin_rating = 0
|
|
|
|
for(var/obj/item/weapon/stock_parts/P in component_parts)
|
|
if(istype(P, /obj/item/weapon/stock_parts/capacitor))
|
|
cap_rating += P.rating
|
|
if(istype(P, /obj/item/weapon/stock_parts/matter_bin))
|
|
bin_rating += P.rating
|
|
|
|
max_power_rating = initial(max_power_rating) * cap_rating / 2
|
|
max_temperature = max(initial(max_temperature) - T20C, 0) * ((bin_rating * 4 + cap_rating) / 5) + T20C
|
|
air_contents.volume = max(initial(internal_volume) - 200, 0) + 200 * bin_rating
|
|
set_power_level(power_setting)
|
|
|
|
/obj/machinery/atmospherics/unary/heater/proc/set_power_level(var/new_power_setting)
|
|
power_setting = new_power_setting
|
|
power_rating = max_power_rating * (power_setting/100)
|
|
|
|
/obj/machinery/atmospherics/unary/heater/attackby(var/obj/item/O as obj, var/mob/user as mob)
|
|
if(default_deconstruction_screwdriver(user, O))
|
|
return
|
|
if(default_deconstruction_crowbar(user, O))
|
|
return
|
|
if(default_part_replacement(user, O))
|
|
return
|
|
|
|
..()
|
|
|
|
/obj/machinery/atmospherics/unary/heater/examine(mob/user)
|
|
..(user)
|
|
if(panel_open)
|
|
user << "The maintenance hatch is open."
|