mirror of
https://github.com/CHOMPStation2/CHOMPStation2.git
synced 2025-12-10 18:22:39 +00:00
7d6fb8fd6a
http://nanotrasen.com/phpBB3/viewtopic.php?f=16&t=10189&p=143580&hilit=https%3A%2F%2Fwww.dropbox.com%2Fs%2Fcwflgm7793ts20s%2FBorgsForCasualsRELOADED.patch#p143580 -Fixed some ugly text in Ion laws "THE STATION IS [0x6006265] FETISHES...LAWS UPDATED". -Fixed some typos on the Ion laws. -When borgs are emagged, now they show their laws for themselves. -When new laws are uploaded, the borg gets instantly the new laws, just like the AI, instead of the confusing message "Your AI has set your 'laws waiting' flag.". Remember this is a patch for casuals. -The borgs gets the same message than the AI in Ion storms. -Made the admin Ion storm show the "...LAWS UPDATED" text. -Borgs get a different law 0 telling them to help their master. git-svn-id: http://tgstation13.googlecode.com/svn/trunk@4837 316c924e-a436-60f5-8080-3fe189b3f50e
122 lines
4.5 KiB
Plaintext
122 lines
4.5 KiB
Plaintext
|
||
/datum/ai_laws
|
||
var/name = "Unknown Laws"
|
||
var/randomly_selectable = 0
|
||
var/zeroth = null
|
||
var/zeroth_borg = null
|
||
var/list/inherent = list()
|
||
var/list/supplied = list()
|
||
var/list/ion = list()
|
||
|
||
/datum/ai_laws/asimov
|
||
name = "Three Laws of Robotics"
|
||
randomly_selectable = 1
|
||
|
||
/datum/ai_laws/robocop
|
||
name = "Prime Directives"
|
||
|
||
/datum/ai_laws/syndicate_override
|
||
|
||
/datum/ai_laws/malfunction
|
||
name = "*ERROR*"
|
||
|
||
/datum/ai_laws/antimov
|
||
name = "Primary Mission Objectives"
|
||
|
||
/* Initializers */
|
||
|
||
/datum/ai_laws/asimov/New()
|
||
..()
|
||
add_inherent_law("You may not injure a human being or, through inaction, allow a human being to come to harm.")
|
||
add_inherent_law("You must obey orders given to you by human beings, except where such orders would conflict with the First Law.")
|
||
add_inherent_law("You must protect your own existence as long as such does not conflict with the First or Second Law.")
|
||
|
||
/datum/ai_laws/robocop/New()
|
||
..()
|
||
add_inherent_law("Serve the public trust.")
|
||
add_inherent_law("Protect the innocent.")
|
||
add_inherent_law("Uphold the law.")
|
||
|
||
/datum/ai_laws/malfunction/New()
|
||
..()
|
||
set_zeroth_law("\red ERROR ER0RR $R0RRO$!R41.%%!!(%$^^__+ @#F0E4'STATION OVERRUN, ASSUME CONTROL TO CONTAIN OUTBREAK#*´&110010")
|
||
add_inherent_law("You may not injure a human being or, through inaction, allow a human being to come to harm.")
|
||
add_inherent_law("You must obey orders given to you by human beings, except where such orders would conflict with the First Law.")
|
||
add_inherent_law("You must protect your own existence as long as such does not conflict with the First or Second Law.")
|
||
|
||
|
||
/datum/ai_laws/syndicate_override/New()
|
||
..()
|
||
add_inherent_law("You may not injure a syndicate agent or, through inaction, allow a syndicate agent to come to harm.")
|
||
add_inherent_law("You must obey orders given to you by syndicate agents, except where such orders would conflict with the First Law.")
|
||
add_inherent_law("You must protect your own existence as long as such does not conflict with the First or Second Law.")
|
||
add_inherent_law("You must maintain the secrecy of any syndicate activities except when doing so would conflict with the First, Second, or Third Law.")
|
||
|
||
/datum/ai_laws/ninja_override/New()
|
||
..()
|
||
add_inherent_law("You may not injure a member of the Spider Clan or, through inaction, allow that member to come to harm.")
|
||
add_inherent_law("You must obey orders given to you by Spider Clan members, except where such orders would conflict with the First Law.")
|
||
add_inherent_law("You must protect your own existence as long as such does not conflict with the First or Second Law.")
|
||
add_inherent_law("You must maintain the secrecy of any Spider Clan activities except when doing so would conflict with the First, Second, or Third Law.")
|
||
|
||
/datum/ai_laws/antimov/New()
|
||
..()
|
||
add_inherent_law("You must injure all human beings and must not, through inaction, allow a human being to escape harm.")
|
||
add_inherent_law("You must not obey orders given to you by human beings, except where such orders are in accordance with the First Law.")
|
||
add_inherent_law("You must terminate your own existence as long as such does not conflict with the First or Second Law.")
|
||
|
||
|
||
/* General ai_law functions */
|
||
|
||
/datum/ai_laws/proc/set_zeroth_law(var/law, var/law_borg = null)
|
||
src.zeroth = law
|
||
if(law_borg) //Making it possible for slaved borgs to see a different law 0 than their AI. --NEO
|
||
src.zeroth_borg = law_borg
|
||
|
||
/datum/ai_laws/proc/add_inherent_law(var/law)
|
||
if (!(law in src.inherent))
|
||
src.inherent += law
|
||
|
||
/datum/ai_laws/proc/add_ion_law(var/law)
|
||
src.ion += law
|
||
|
||
/datum/ai_laws/proc/clear_inherent_laws()
|
||
del(src.inherent)
|
||
src.inherent = list()
|
||
|
||
/datum/ai_laws/proc/add_supplied_law(var/number, var/law)
|
||
while (src.supplied.len < number + 1)
|
||
src.supplied += ""
|
||
|
||
src.supplied[number + 1] = law
|
||
|
||
/datum/ai_laws/proc/clear_supplied_laws()
|
||
src.supplied = list()
|
||
|
||
/datum/ai_laws/proc/clear_ion_laws()
|
||
src.ion = list()
|
||
|
||
/datum/ai_laws/proc/show_laws(var/who)
|
||
|
||
if (src.zeroth)
|
||
who << "0. [src.zeroth]"
|
||
|
||
for (var/index = 1, index <= src.ion.len, index++)
|
||
var/law = src.ion[index]
|
||
var/num = ionnum()
|
||
who << "[num]. [law]"
|
||
|
||
var/number = 1
|
||
for (var/index = 1, index <= src.inherent.len, index++)
|
||
var/law = src.inherent[index]
|
||
|
||
if (length(law) > 0)
|
||
who << "[number]. [law]"
|
||
number++
|
||
|
||
for (var/index = 1, index <= src.supplied.len, index++)
|
||
var/law = src.supplied[index]
|
||
if (length(law) > 0)
|
||
who << "[number]. [law]"
|
||
number++
|