CHOMPStation2/code/modules/economy/Accounts_DB.dm

/obj/machinery/account_database
	name = "Accounts uplink terminal"
	desc = "Access transaction logs, account data and all kinds of other financial records."
	icon = 'icons/obj/computer.dmi'
	icon_state = "account_computer"
	density = TRUE
	req_one_access = list(access_hop, access_captain, access_cent_captain)
	anchored = TRUE
	var/receipt_num
	var/machine_id = ""
	var/obj/item/card/id/held_card
	var/datum/money_account/detailed_account_view
	var/creating_new_account = 0
	var/const/fund_cap = 1000000

/obj/machinery/account_database/proc/get_access_level()
	if(!held_card)
		return 0
	if(access_cent_captain in held_card.access)
		return 2
	else if((access_hop in held_card.access) || (access_captain in held_card.access))
		return 1

/obj/machinery/account_database/proc/create_transation(target, reason, amount)
	var/datum/transaction/T = new()
	T.target_name = target
	T.purpose = reason
	T.amount = amount
	T.date = GLOB.current_date_string
	T.time = stationtime2text()
	T.source_terminal = machine_id
	return T

/obj/machinery/account_database/proc/accounting_letterhead(report_name)
	return {"
		<center><h1><b>[report_name]</b></h1></center>
		<center><small><i>[station_name()] Accounting Report</i></small></center>
		<hr>
		<u>Generated By:</u> [held_card.registered_name], [held_card.assignment]<br>
	"}

/obj/machinery/account_database/Initialize(mapload)
	machine_id = "[station_name()] Acc. DB #[GLOB.num_financial_terminals++]"
	. = ..()

/obj/machinery/account_database/attackby(obj/O, mob/user)
	if(!istype(O, /obj/item/card/id))
		return ..()

	if(!held_card)
		user.drop_item()
		O.loc = src
		held_card = O

		SStgui.update_uis(src)

	attack_hand(user)

/obj/machinery/account_database/attack_hand(mob/user as mob)
	if(stat & (NOPOWER|BROKEN)) return
	tgui_interact(user)

/obj/machinery/account_database/tgui_interact(mob/user, datum/tgui/ui)
	ui = SStgui.try_update_ui(user, src, ui)
	if(!ui)
		ui = new(user, src, "AccountsTerminal", name)
		ui.open()


/obj/machinery/account_database/tgui_data(mob/user, datum/tgui/ui, datum/tgui_state/state)
	var/list/data = ..()

	data["id_inserted"] = !!held_card
	data["id_card"] = held_card ? text("[held_card.registered_name], [held_card.assignment]") : "-----"
	data["access_level"] = get_access_level()
	data["machine_id"] = machine_id
	data["creating_new_account"] = creating_new_account
	data["detailed_account_view"] = !!detailed_account_view
	data["station_account_number"] = GLOB.station_account.account_number

	data["account_number"] = null
	data["owner_name"] = null
	data["money"] = null
	data["suspended"] = null
	data["transactions"] = list()

	if(detailed_account_view)
		data["account_number"] = detailed_account_view.account_number
		data["owner_name"] = detailed_account_view.owner_name
		data["money"] = detailed_account_view.money
		data["suspended"] = detailed_account_view.suspended

		var/list/trx[0]
		for (var/datum/transaction/T in detailed_account_view.transaction_log)
			trx.Add(list(list(\
				"date" = T.date, \
				"time" = T.time, \
				"target_name" = T.target_name, \
				"purpose" = T.purpose, \
				"amount" = T.amount, \
				"source_terminal" = T.source_terminal)))

		data["transactions"] = trx

	var/list/accounts = list()
	for(var/i in 1 to LAZYLEN(GLOB.all_money_accounts))
		var/datum/money_account/D = GLOB.all_money_accounts[i]
		if(D.offmap)
			continue
		accounts.Add(list(list(\
			"account_number"=D.account_number,\
			"owner_name"=D.owner_name,\
			"suspended"=D.suspended ? "SUSPENDED" : "",\
			"account_index"=i)))

	data["accounts"] = accounts

	return data

/obj/machinery/account_database/tgui_act(action, list/params, datum/tgui/ui, datum/tgui_state/state)
	if(..())
		return TRUE

	switch(action)
		if("create_account")
			creating_new_account = 1

		if("add_funds")
			var/amount = tgui_input_number(ui.user, "Enter the amount you wish to add", "Silently add funds")
			if(detailed_account_view)
				detailed_account_view.money = min(detailed_account_view.money + amount, fund_cap)

		if("remove_funds")
			var/amount = tgui_input_number(ui.user, "Enter the amount you wish to remove", "Silently remove funds")
			if(detailed_account_view)
				detailed_account_view.money = max(detailed_account_view.money - amount, -fund_cap)

		if("toggle_suspension")
			if(detailed_account_view)
				detailed_account_view.suspended = !detailed_account_view.suspended
				callHook("change_account_status", list(detailed_account_view))

		if("finalise_create_account")
			var/account_name = params["holder_name"]
			var/starting_funds = max(text2num(params["starting_funds"]), 0)

			starting_funds = CLAMP(starting_funds, 0, GLOB.station_account.money)	// Not authorized to put the station in debt.
			starting_funds = min(starting_funds, fund_cap)						// Not authorized to give more than the fund cap.

			create_account(account_name, starting_funds, src)
			if(starting_funds > 0)
				//subtract the money
				GLOB.station_account.money -= starting_funds

				//create a transaction log entry
				var/trx = create_transation(account_name, "New account activation", "([starting_funds])")
				GLOB.station_account.transaction_log.Add(trx)

				creating_new_account = 0

			creating_new_account = 0
		if("insert_card")
			if(held_card)
				held_card.loc = src.loc

				if(ishuman(ui.user) && !ui.user.get_active_hand())
					ui.user.put_in_hands(held_card)
				held_card = null

			else
				var/obj/item/I = ui.user.get_active_hand()
				if(istype(I, /obj/item/card/id))
					var/obj/item/card/id/C = I
					ui.user.drop_item()
					C.loc = src
					held_card = C

		if("view_account_detail")
			var/index = text2num(params["account_index"])
			if(index && index <= GLOB.all_money_accounts.len)
				detailed_account_view = GLOB.all_money_accounts[index]

		if("view_accounts_list")
			detailed_account_view = null
			creating_new_account = 0

		if("revoke_payroll")
			var/funds = detailed_account_view.money
			var/account_trx = create_transation(GLOB.station_account.owner_name, "Revoke payroll", "([funds])")
			var/station_trx = create_transation(detailed_account_view.owner_name, "Revoke payroll", funds)

			GLOB.station_account.money += funds
			detailed_account_view.money = 0

			detailed_account_view.transaction_log.Add(account_trx)
			GLOB.station_account.transaction_log.Add(station_trx)

			callHook("revoke_payroll", list(detailed_account_view))

		if("print")
			print()

	return TRUE

/obj/machinery/account_database/proc/print()
	var/text
	var/obj/item/paper/P = new(loc)
	if(detailed_account_view)
		P.name = "account #[detailed_account_view.account_number] details"
		var/title = "Account #[detailed_account_view.account_number] Details"
		text = {"
			[accounting_letterhead(title)]
			<u>Holder:</u> [detailed_account_view.owner_name]<br>
			<u>Balance:</u> $[detailed_account_view.money]<br>
			<u>Status:</u> [detailed_account_view.suspended ? "Suspended" : "Active"]<br>
			<u>Transactions:</u> ([detailed_account_view.transaction_log.len])<br>
			<table>
				<thead>
					<tr>
						<td>Timestamp</td>
						<td>Target</td>
						<td>Reason</td>
						<td>Value</td>
						<td>Terminal</td>
					</tr>
				</thead>
				<tbody>
			"}

		for (var/datum/transaction/T in detailed_account_view.transaction_log)
			text += {"
						<tr>
							<td>[T.date] [T.time]</td>
							<td>[T.target_name]</td>
							<td>[T.purpose]</td>
							<td>[T.amount]</td>
							<td>[T.source_terminal]</td>
						</tr>
				"}

		text += {"
				</tbody>
			</table>
			"}

	else
		P.name = "financial account list"
		text = {"
			[accounting_letterhead("Financial Account List")]

			<table>
				<thead>
					<tr>
						<td>Account Number</td>
						<td>Holder</td>
						<td>Balance</td>
						<td>Status</td>
					</tr>
				</thead>
				<tbody>
		"}

		for(var/i=1, i <= GLOB.all_money_accounts.len, i++)
			var/datum/money_account/D = GLOB.all_money_accounts[i]
			text += {"
					<tr>
						<td>#[D.account_number]</td>
						<td>[D.owner_name]</td>
						<td>$[D.money]</td>
						<td>[D.suspended ? "Suspended" : "Active"]</td>
					</tr>
			"}

		text += {"
				</tbody>
			</table>
		"}

	P.info = text
	state("The terminal prints out a report.")