mirror of
https://github.com/CHOMPStation2/CHOMPStation2.git
synced 2025-12-12 11:13:16 +00:00
114 lines
4.0 KiB
Plaintext
114 lines
4.0 KiB
Plaintext
|
|
/*
|
|
apply_damage(a,b,c)
|
|
args
|
|
a:damage - How much damage to take
|
|
b:damage_type - What type of damage to take, brute, burn
|
|
c:def_zone - Where to take the damage if its brute or burn
|
|
Returns
|
|
standard 0 if fail
|
|
*/
|
|
/mob/living/proc/apply_damage(var/damage = 0,var/damagetype = BRUTE, var/def_zone = null, var/blocked = 0, var/soaked = 0, var/used_weapon = null, var/sharp = 0, var/edge = 0)
|
|
if(Debug2)
|
|
to_world_log("## DEBUG: apply_damage() was called on [src], with [damage] damage, and an armor value of [blocked].")
|
|
if(!damage || (blocked >= 100))
|
|
return 0
|
|
if(soaked)
|
|
if(soaked >= round(damage*0.8))
|
|
damage -= round(damage*0.8)
|
|
else
|
|
damage -= soaked
|
|
blocked = (100-blocked)/100
|
|
switch(damagetype)
|
|
if(BRUTE)
|
|
adjustBruteLoss(damage * blocked)
|
|
if(BURN)
|
|
if(COLD_RESISTANCE in mutations)
|
|
damage = 0
|
|
adjustFireLoss(damage * blocked)
|
|
if(SEARING)
|
|
apply_damage(damage / 3, BURN, def_zone, blocked, soaked, used_weapon, sharp, edge)
|
|
apply_damage(damage / 3 * 2, BRUTE, def_zone, blocked, soaked, used_weapon, sharp, edge)
|
|
if(TOX)
|
|
adjustToxLoss(damage * blocked)
|
|
if(OXY)
|
|
adjustOxyLoss(damage * blocked)
|
|
if(CLONE)
|
|
adjustCloneLoss(damage * blocked)
|
|
if(HALLOSS)
|
|
adjustHalLoss(damage * blocked)
|
|
if(ELECTROCUTE)
|
|
electrocute_act(damage, used_weapon, 1.0, def_zone)
|
|
if(BIOACID)
|
|
if(isSynthetic())
|
|
adjustFireLoss(damage * blocked)
|
|
else
|
|
adjustToxLoss(damage * blocked)
|
|
flash_weak_pain()
|
|
updatehealth()
|
|
return 1
|
|
|
|
|
|
/mob/living/proc/apply_damages(var/brute = 0, var/burn = 0, var/tox = 0, var/oxy = 0, var/clone = 0, var/halloss = 0, var/def_zone = null, var/blocked = 0)
|
|
if(blocked >= 100)
|
|
return 0
|
|
if(brute) apply_damage(brute, BRUTE, def_zone, blocked)
|
|
if(burn) apply_damage(burn, BURN, def_zone, blocked)
|
|
if(tox) apply_damage(tox, TOX, def_zone, blocked)
|
|
if(oxy) apply_damage(oxy, OXY, def_zone, blocked)
|
|
if(clone) apply_damage(clone, CLONE, def_zone, blocked)
|
|
if(halloss) apply_damage(halloss, HALLOSS, def_zone, blocked)
|
|
return 1
|
|
|
|
|
|
|
|
/mob/living/proc/apply_effect(var/effect = 0,var/effecttype = STUN, var/blocked = 0, var/check_protection = 1)
|
|
if(Debug2)
|
|
to_world_log("## DEBUG: apply_effect() was called. The type of effect is [effecttype]. Blocked by [blocked].")
|
|
if(!effect || (blocked >= 100))
|
|
return 0
|
|
blocked = (100-blocked)/100
|
|
|
|
switch(effecttype)
|
|
if(STUN)
|
|
Stun(effect * blocked)
|
|
if(WEAKEN)
|
|
Weaken(effect * blocked)
|
|
if(PARALYZE)
|
|
Paralyse(effect * blocked)
|
|
if(AGONY)
|
|
halloss += max((effect * blocked), 0) // Useful for objects that cause "subdual" damage. PAIN!
|
|
if(IRRADIATE)
|
|
/*
|
|
var/rad_protection = check_protection ? getarmor(null, "rad")/100 : 0
|
|
radiation += max((1-rad_protection)*effect/(blocked+1),0)//Rads auto check armor
|
|
*/
|
|
var/rad_protection = getarmor(null, "rad")
|
|
rad_protection = (100-rad_protection)/100
|
|
radiation += max((effect * rad_protection), 0)
|
|
if(STUTTER)
|
|
if(status_flags & CANSTUN) // stun is usually associated with stutter
|
|
stuttering = max(stuttering,(effect * blocked))
|
|
if(EYE_BLUR)
|
|
eye_blurry = max(eye_blurry,(effect * blocked))
|
|
if(DROWSY)
|
|
drowsyness = max(drowsyness,(effect * blocked))
|
|
updatehealth()
|
|
return 1
|
|
|
|
|
|
/mob/living/proc/apply_effects(var/stun = 0, var/weaken = 0, var/paralyze = 0, var/irradiate = 0, var/stutter = 0, var/eyeblur = 0, var/drowsy = 0, var/agony = 0, var/blocked = 0, var/ignite = 0, var/flammable = 0)
|
|
if(blocked >= 100)
|
|
return 0
|
|
if(stun) apply_effect(stun, STUN, blocked)
|
|
if(weaken) apply_effect(weaken, WEAKEN, blocked)
|
|
if(paralyze) apply_effect(paralyze, PARALYZE, blocked)
|
|
if(irradiate) apply_effect(irradiate, IRRADIATE, blocked)
|
|
if(stutter) apply_effect(stutter, STUTTER, blocked)
|
|
if(eyeblur) apply_effect(eyeblur, EYE_BLUR, blocked)
|
|
if(drowsy) apply_effect(drowsy, DROWSY, blocked)
|
|
if(agony) apply_effect(agony, AGONY, blocked)
|
|
if(flammable) adjust_fire_stacks(flammable)
|
|
if(ignite) IgniteMob()
|
|
return 1
|