mirror of
https://github.com/CHOMPStation2/CHOMPStation2.git
synced 2025-12-10 18:22:39 +00:00
741e02407a
* Added "Display Initialize() Log" admin debug command so you can see it mid-round. * Ported the core of the overlays management subsystem from /tg - Added SSoverlays subsystem for compiling overlay lists and applying them to atoms in a controlled anti-lag subsystem. - Added vars and procs to atom which should eventually replace all direct interaction with BYOND's /atom/overlays var outside the subsystem. - Added OVERLAY_QUEUED flag to var/atom/flags bitfield. - Added small framework for subsystem performance tracking. So far used only by SSoverlays - Added admin debug command "Display overlay Log" to see performance stats mid-round. * Fix runtime on universal pipe adaptor update_icons * Workaround for appearance_bro not initialized Unfortuantely BYOND's initialization order is strange, and the appearance_bro var is only half initialized when map starts to load, causing errors. We temporarily fix by moving it to be a global-scoped global. * Convert fire alarms to use add_overlay() A good first test. * Convert turfs to use add_overlays(), eliminating the turf_overlay_holder! - Converted as much as I could find about turf overlays to use add_overlay(). - This should be enough to stop BYOND from crashing, so we can eliminate the turf_overlay_holder hack. - This also lets us remove the anti-corruption hacks from walls and open space. - ZAS gas overlays can use priority overlays, so this also fixes the gas-goes-away-when-crowbarring-plating issue. - Stuff like that * Convert turf overlay interactions to use add_overlay. Note: This is a plain and simple conversion of existing code to use SSoverlays. However I look at the line changed, and note that that line likely never fully worked as intended, as it has no way of re-applying itself. I would make it use a priority overlay, but there is no code present for *removing* said overlay from neighbors when it is no longer required. That code should be implemented by original author.
305 lines
7.4 KiB
Plaintext
305 lines
7.4 KiB
Plaintext
/turf/simulated/var/zone/zone
|
|
/turf/simulated/var/open_directions
|
|
|
|
/turf/var/needs_air_update = 0
|
|
/turf/var/datum/gas_mixture/air
|
|
|
|
/turf/simulated/proc/update_graphic(list/graphic_add = null, list/graphic_remove = null)
|
|
if(LAZYLEN(graphic_add))
|
|
add_overlay(graphic_add, priority = TRUE)
|
|
if(LAZYLEN(graphic_remove))
|
|
cut_overlay(graphic_remove, priority = TRUE)
|
|
|
|
/turf/proc/update_air_properties()
|
|
var/block = c_airblock(src)
|
|
if(block & AIR_BLOCKED)
|
|
//dbg(blocked)
|
|
return 1
|
|
|
|
#ifdef MULTIZAS
|
|
for(var/d = 1, d < 64, d *= 2)
|
|
#else
|
|
for(var/d = 1, d < 16, d *= 2)
|
|
#endif
|
|
|
|
var/turf/unsim = get_step(src, d)
|
|
|
|
if(!unsim)
|
|
continue
|
|
|
|
block = unsim.c_airblock(src)
|
|
|
|
if(block & AIR_BLOCKED)
|
|
//unsim.dbg(air_blocked, turn(180,d))
|
|
continue
|
|
|
|
var/r_block = c_airblock(unsim)
|
|
|
|
if(r_block & AIR_BLOCKED)
|
|
continue
|
|
|
|
if(istype(unsim, /turf/simulated))
|
|
|
|
var/turf/simulated/sim = unsim
|
|
if(air_master.has_valid_zone(sim))
|
|
|
|
air_master.connect(sim, src)
|
|
|
|
/*
|
|
Simple heuristic for determining if removing the turf from it's zone will not partition the zone (A very bad thing).
|
|
Instead of analyzing the entire zone, we only check the nearest 3x3 turfs surrounding the src turf.
|
|
This implementation may produce false negatives but it (hopefully) will not produce any false postiives.
|
|
*/
|
|
|
|
/turf/simulated/proc/can_safely_remove_from_zone()
|
|
|
|
|
|
if(!zone) return 1
|
|
|
|
var/check_dirs = get_zone_neighbours(src)
|
|
var/unconnected_dirs = check_dirs
|
|
|
|
#ifdef MULTIZAS
|
|
var/to_check = cornerdirsz
|
|
#else
|
|
var/to_check = cornerdirs
|
|
#endif
|
|
|
|
for(var/dir in to_check)
|
|
//for each pair of "adjacent" cardinals (e.g. NORTH and WEST, but not NORTH and SOUTH)
|
|
if((dir & check_dirs) == dir)
|
|
//check that they are connected by the corner turf
|
|
var/connected_dirs = get_zone_neighbours(get_step(src, dir))
|
|
if(connected_dirs && (dir & reverse_dir[connected_dirs]) == dir)
|
|
unconnected_dirs &= ~dir //they are, so unflag the cardinals in question
|
|
|
|
//it is safe to remove src from the zone if all cardinals are connected by corner turfs
|
|
return !unconnected_dirs
|
|
|
|
//helper for can_safely_remove_from_zone()
|
|
/turf/simulated/proc/get_zone_neighbours(turf/simulated/T)
|
|
. = 0
|
|
if(istype(T) && T.zone)
|
|
#ifdef MULTIZAS
|
|
var/to_check = cardinalz
|
|
#else
|
|
var/to_check = cardinal
|
|
#endif
|
|
for(var/dir in to_check)
|
|
var/turf/simulated/other = get_step(T, dir)
|
|
if(istype(other) && other.zone == T.zone && !(other.c_airblock(T) & AIR_BLOCKED) && get_dist(src, other) <= 1)
|
|
. |= dir
|
|
|
|
/turf/simulated/update_air_properties()
|
|
|
|
if(zone && zone.invalid)
|
|
c_copy_air()
|
|
zone = null //Easier than iterating through the list at the zone.
|
|
|
|
var/s_block = c_airblock(src)
|
|
if(s_block & AIR_BLOCKED)
|
|
#ifdef ZASDBG
|
|
if(verbose) world << "Self-blocked."
|
|
//dbg(blocked)
|
|
#endif
|
|
if(zone)
|
|
var/zone/z = zone
|
|
|
|
if(can_safely_remove_from_zone()) //Helps normal airlocks avoid rebuilding zones all the time
|
|
z.remove(src)
|
|
else
|
|
z.rebuild()
|
|
|
|
return 1
|
|
|
|
var/previously_open = open_directions
|
|
open_directions = 0
|
|
|
|
var/list/postponed
|
|
#ifdef MULTIZAS
|
|
for(var/d = 1, d < 64, d *= 2)
|
|
#else
|
|
for(var/d = 1, d < 16, d *= 2)
|
|
#endif
|
|
|
|
var/turf/unsim = get_step(src, d)
|
|
|
|
if(!unsim) //edge of map
|
|
continue
|
|
|
|
var/block = unsim.c_airblock(src)
|
|
if(block & AIR_BLOCKED)
|
|
|
|
#ifdef ZASDBG
|
|
if(verbose) world << "[d] is blocked."
|
|
//unsim.dbg(air_blocked, turn(180,d))
|
|
#endif
|
|
|
|
continue
|
|
|
|
var/r_block = c_airblock(unsim)
|
|
if(r_block & AIR_BLOCKED)
|
|
|
|
#ifdef ZASDBG
|
|
if(verbose) world << "[d] is blocked."
|
|
//dbg(air_blocked, d)
|
|
#endif
|
|
|
|
//Check that our zone hasn't been cut off recently.
|
|
//This happens when windows move or are constructed. We need to rebuild.
|
|
if((previously_open & d) && istype(unsim, /turf/simulated))
|
|
var/turf/simulated/sim = unsim
|
|
if(zone && sim.zone == zone)
|
|
zone.rebuild()
|
|
return
|
|
|
|
continue
|
|
|
|
open_directions |= d
|
|
|
|
if(istype(unsim, /turf/simulated))
|
|
|
|
var/turf/simulated/sim = unsim
|
|
sim.open_directions |= reverse_dir[d]
|
|
|
|
if(air_master.has_valid_zone(sim))
|
|
|
|
//Might have assigned a zone, since this happens for each direction.
|
|
if(!zone)
|
|
|
|
//We do not merge if
|
|
// they are blocking us and we are not blocking them, or if
|
|
// we are blocking them and not blocking ourselves - this prevents tiny zones from forming on doorways.
|
|
if(((block & ZONE_BLOCKED) && !(r_block & ZONE_BLOCKED)) || ((r_block & ZONE_BLOCKED) && !(s_block & ZONE_BLOCKED)))
|
|
#ifdef ZASDBG
|
|
if(verbose) world << "[d] is zone blocked."
|
|
//dbg(zone_blocked, d)
|
|
#endif
|
|
|
|
//Postpone this tile rather than exit, since a connection can still be made.
|
|
if(!postponed) postponed = list()
|
|
postponed.Add(sim)
|
|
|
|
else
|
|
|
|
sim.zone.add(src)
|
|
|
|
#ifdef ZASDBG
|
|
dbg(assigned)
|
|
if(verbose) world << "Added to [zone]"
|
|
#endif
|
|
|
|
else if(sim.zone != zone)
|
|
|
|
#ifdef ZASDBG
|
|
if(verbose) world << "Connecting to [sim.zone]"
|
|
#endif
|
|
|
|
air_master.connect(src, sim)
|
|
|
|
|
|
#ifdef ZASDBG
|
|
else if(verbose) world << "[d] has same zone."
|
|
|
|
else if(verbose) world << "[d] has invalid zone."
|
|
#endif
|
|
|
|
else
|
|
|
|
//Postponing connections to tiles until a zone is assured.
|
|
if(!postponed) postponed = list()
|
|
postponed.Add(unsim)
|
|
|
|
if(!air_master.has_valid_zone(src)) //Still no zone, make a new one.
|
|
var/zone/newzone = new/zone()
|
|
newzone.add(src)
|
|
|
|
#ifdef ZASDBG
|
|
dbg(created)
|
|
|
|
ASSERT(zone)
|
|
#endif
|
|
|
|
//At this point, a zone should have happened. If it hasn't, don't add more checks, fix the bug.
|
|
|
|
for(var/turf/T in postponed)
|
|
air_master.connect(src, T)
|
|
|
|
/turf/proc/post_update_air_properties()
|
|
if(connections) connections.update_all()
|
|
|
|
/turf/assume_air(datum/gas_mixture/giver) //use this for machines to adjust air
|
|
return 0
|
|
|
|
/turf/proc/assume_gas(gasid, moles, temp = 0)
|
|
return 0
|
|
|
|
/turf/return_air()
|
|
//Create gas mixture to hold data for passing
|
|
var/datum/gas_mixture/GM = new
|
|
|
|
GM.adjust_multi("oxygen", oxygen, "carbon_dioxide", carbon_dioxide, "nitrogen", nitrogen, "phoron", phoron)
|
|
GM.temperature = temperature
|
|
|
|
return GM
|
|
|
|
/turf/remove_air(amount as num)
|
|
var/datum/gas_mixture/GM = new
|
|
|
|
var/sum = oxygen + carbon_dioxide + nitrogen + phoron
|
|
if(sum>0)
|
|
GM.gas["oxygen"] = (oxygen/sum)*amount
|
|
GM.gas["carbon_dioxide"] = (carbon_dioxide/sum)*amount
|
|
GM.gas["nitrogen"] = (nitrogen/sum)*amount
|
|
GM.gas["phoron"] = (phoron/sum)*amount
|
|
|
|
GM.temperature = temperature
|
|
GM.update_values()
|
|
|
|
return GM
|
|
|
|
/turf/simulated/assume_air(datum/gas_mixture/giver)
|
|
var/datum/gas_mixture/my_air = return_air()
|
|
my_air.merge(giver)
|
|
|
|
/turf/simulated/assume_gas(gasid, moles, temp = null)
|
|
var/datum/gas_mixture/my_air = return_air()
|
|
|
|
if(isnull(temp))
|
|
my_air.adjust_gas(gasid, moles)
|
|
else
|
|
my_air.adjust_gas_temp(gasid, moles, temp)
|
|
|
|
return 1
|
|
|
|
/turf/simulated/remove_air(amount as num)
|
|
var/datum/gas_mixture/my_air = return_air()
|
|
return my_air.remove(amount)
|
|
|
|
/turf/simulated/return_air()
|
|
if(zone)
|
|
if(!zone.invalid)
|
|
air_master.mark_zone_update(zone)
|
|
return zone.air
|
|
else
|
|
if(!air)
|
|
make_air()
|
|
c_copy_air()
|
|
return air
|
|
else
|
|
if(!air)
|
|
make_air()
|
|
return air
|
|
|
|
/turf/proc/make_air()
|
|
air = new/datum/gas_mixture
|
|
air.temperature = temperature
|
|
air.adjust_multi("oxygen", oxygen, "carbon_dioxide", carbon_dioxide, "nitrogen", nitrogen, "phoron", phoron)
|
|
air.group_multiplier = 1
|
|
air.volume = CELL_VOLUME
|
|
|
|
/turf/simulated/proc/c_copy_air()
|
|
if(!air) air = new/datum/gas_mixture
|
|
air.copy_from(zone.air)
|
|
air.group_multiplier = 1
|