mirror of
https://github.com/CHOMPStation2/CHOMPStation2.git
synced 2026-08-23 21:27:01 +01:00
Rykka
ed798113d9
Fixes in order: - Removes List of defines in misc_ch.dm that are no longer used - they're defined here for the casino prize dispenser, making these obsolete:  - Fixes relative pathing in mecha_parts_ch.dm - Fixes relative pathing in bodybag.dm - Fixes relative pathing in sahoc_ch.dm - Fixes relative pathing in toys_yw.dm - Fixes def_zone being defined when only the variable was needed in twohanded_ch.dm - Fixes relative pathing in trash_pile_vr_ch.dm - Fixes clip_mask being missing in misc_ch.dm - Fixes relative pathing in tesh_synth_facemask.dm - Fixes absolute path being indented in by one (typo?) - Fixes relative pathing in armor_yw.dm - Fixes unreachable parent call in audible_scream_ch.dm - Fixes VERM_LIZARDS being undefined when it wasn't defined, as VERM_LIZARDMEN was the variable being defined + used in mutants.dm - Removes two un-needed parent calls - these procs have no parent on /obj/structure - thecake_ch.dm - Fixes invalid kword nano_state in protean_blob.dm - Fixes relative pathing in drone_manufacturer_unify.dm - Fixes relative pathing in synx.dm - Removes arguments of drop_item that don't exist (port was from TG and had force_drop = 1 and src defined.) - vox.dm - Added vision_required = TRUE to fix proc argument missing - bigdragon_ch.dm - Added include_robo = TRUE to fix argument missing in demon_ch.dm - Fixes relative pathing in rakshasa_abilities.dm - Adds comment to solargrub.dm, unable to fix operator overload error yet. - Fixes relative pathing in sprite_accessories_extra_ch.dm - Fixes relative pathing in sprite_accessories_yw.dm - Fixes relative pathing in phase.dm - Fixes relative pathing in bluespacecoffee.dm - Fixes relative pathing in other_ch.dm - Fixes relative pathing and ambigious ! in living_ch.dm - Fixes relative pathing in custom_clothes_yw.dm - Fixes relative pathing in custom_rigs_yw.dm - Fixes relative pathing in MadokaSpear.dm - Comments out duplicate #includes in southern_cross.dm as vorestation.dme has them #include'd.
129 lines
3.4 KiB
Plaintext
129 lines
3.4 KiB
Plaintext
/* Two-handed Weapons
|
|
* Contains:
|
|
* Twohanded
|
|
* Fireaxe
|
|
* Double-Bladed Energy Swords
|
|
*/
|
|
|
|
/*##################################################################
|
|
##################### TWO HANDED WEAPONS BE HERE~ -Agouri :3 ########
|
|
####################################################################*/
|
|
|
|
//Rewrote TwoHanded weapons stuff and put it all here. Just copypasta fireaxe to make new ones ~Carn
|
|
//This rewrite means we don't have two variables for EVERY item which are used only by a few weapons.
|
|
//It also tidies stuff up elsewhere.
|
|
|
|
/*
|
|
* Twohanded
|
|
*/
|
|
/obj/item/weapon/oldtwohanded
|
|
var/wielded = 0
|
|
var/force_wielded = 0
|
|
var/wieldsound = null
|
|
var/unwieldsound = null
|
|
var/base_icon
|
|
|
|
/obj/item/weapon/oldtwohanded/proc/unwield()
|
|
wielded = 0
|
|
force = initial(force)
|
|
name = "[initial(name)]"
|
|
update_icon()
|
|
|
|
/obj/item/weapon/oldtwohanded/proc/wield()
|
|
wielded = 1
|
|
force = force_wielded
|
|
name = "[initial(name)] (Wielded)"
|
|
update_icon()
|
|
|
|
/obj/item/weapon/oldtwohanded/New()
|
|
..()
|
|
update_icon()
|
|
|
|
/obj/item/weapon/oldtwohanded/mob_can_equip(M as mob, slot, disable_warning = FALSE)
|
|
//Cannot equip wielded items.
|
|
if(wielded)
|
|
to_chat(M, "<span class='warning'>Unwield the [initial(name)] first!</span>")
|
|
return 0
|
|
|
|
return ..()
|
|
|
|
/obj/item/weapon/oldtwohanded/dropped(mob/user as mob)
|
|
//handles unwielding a twohanded weapon when dropped as well as clearing up the offhand
|
|
if(user)
|
|
var/obj/item/weapon/oldtwohanded/O = user.get_inactive_hand()
|
|
if(istype(O))
|
|
O.unwield()
|
|
return unwield()
|
|
|
|
/obj/item/weapon/oldtwohanded/update_icon()
|
|
icon_state = "[base_icon][wielded]"
|
|
item_state = icon_state
|
|
|
|
/obj/item/weapon/oldtwohanded/pickup(mob/user)
|
|
unwield()
|
|
|
|
/obj/item/weapon/oldtwohanded/attack_self(mob/user as mob)
|
|
..()
|
|
|
|
if(wielded) //Trying to unwield it
|
|
unwield()
|
|
user << "<span class='notice'>You are now carrying the [name] with one hand.</span>"
|
|
if (src.unwieldsound)
|
|
playsound(src.loc, unwieldsound, 50, 1)
|
|
|
|
var/obj/item/weapon/oldtwohanded/offhand/O = user.get_inactive_hand()
|
|
if(O && istype(O))
|
|
O.unwield()
|
|
|
|
else //Trying to wield it
|
|
if(user.get_inactive_hand())
|
|
user << "<span class='warning'>You need your other hand to be empty</span>"
|
|
return
|
|
wield()
|
|
user << "<span class='notice'>You grab the [initial(name)] with both hands.</span>"
|
|
if (src.wieldsound)
|
|
playsound(src.loc, wieldsound, 50, 1)
|
|
|
|
var/obj/item/weapon/oldtwohanded/offhand/O = new(user) ////Let's reserve his other hand~
|
|
O.name = "[initial(name)] - offhand"
|
|
O.desc = "Your second grip on the [initial(name)]"
|
|
user.put_in_inactive_hand(O)
|
|
|
|
if(istype(user,/mob/living/carbon/human))
|
|
var/mob/living/carbon/human/H = user
|
|
H.update_inv_l_hand()
|
|
H.update_inv_r_hand()
|
|
|
|
return
|
|
|
|
///////////OFFHAND///////////////
|
|
/obj/item/weapon/oldtwohanded/offhand
|
|
w_class = 5.0
|
|
icon_state = "offhand"
|
|
name = "offhand"
|
|
|
|
/obj/item/weapon/oldtwohanded/offhand/unwield()
|
|
qdel(src)
|
|
|
|
/obj/item/weapon/oldtwohanded/offhand/wield()
|
|
qdel(src)
|
|
|
|
/obj/item/weapon/oldtwohanded/offhand/update_icon()
|
|
return
|
|
|
|
//spears, bay edition
|
|
/obj/item/weapon/oldtwohanded/spear
|
|
icon_state = "spearglass0"
|
|
base_icon = "spearglass"
|
|
name = "spear"
|
|
desc = "A haphazardly-constructed yet still deadly weapon of ancient design."
|
|
force = 14
|
|
w_class = 4.0
|
|
slot_flags = SLOT_BACK
|
|
force_wielded = 22 // Was 13, Buffed - RR
|
|
throwforce = 20
|
|
throw_speed = 3
|
|
edge = 0
|
|
sharp = 1
|
|
hitsound = 'sound/weapons/bladeslice.ogg'
|
|
attack_verb = list("attacked", "poked", "jabbed", "torn", "gored") |