CHOMPStation2/code/game/machinery/adv_med.dm

// Pretty much everything here is stolen from the dna scanner FYI


/obj/machinery/bodyscanner
	var/mob/living/carbon/occupant
	var/locked
	name = "Body Scanner"
	icon = 'icons/obj/Cryogenic2.dmi'
	icon_state = "body_scanner_0"
	density = 1
	anchored = 1

	circuit = /obj/item/weapon/circuitboard/body_scanner

	use_power = 1
	idle_power_usage = 60
	active_power_usage = 10000	//10 kW. It's a big all-body scanner.

	light_color = "#00FF00"

/obj/machinery/bodyscanner/New()
	..()
	spawn( 5 )
		var/obj/machinery/body_scanconsole/C = locate(/obj/machinery/body_scanconsole) in range(2,src)
		if(C)
			C.connected = src

/obj/machinery/bodyscanner/map/New()
	..()
	circuit = new circuit(src)
	component_parts = list()
	component_parts += new /obj/item/weapon/stock_parts/scanning_module(src)
	component_parts += new /obj/item/weapon/stock_parts/scanning_module(src)
	component_parts += new /obj/item/weapon/stock_parts/scanning_module(src)
	component_parts += new /obj/item/stack/material/glass/reinforced(src, 2)
	RefreshParts()

/obj/machinery/bodyscanner/power_change()
	..()
	if(!(stat & (BROKEN|NOPOWER)))
		set_light(2)
	else
		set_light(0)

/obj/machinery/bodyscanner/attackby(var/obj/item/G, user as mob)
	if(default_deconstruction_screwdriver(user, G))
		return
	if(default_deconstruction_crowbar(user, G))
		return

	if(istype(G, /obj/item/weapon/grab))
		var/obj/item/weapon/grab/H = G
		if(panel_open)
			user << "<span class='notice'>Close the maintenance panel first.</span>"
			return
		if(!ismob(H.affecting))
			return
		if(occupant)
			user << "<span class='notice'>The scanner is already occupied!</span>"
			return
		for(var/mob/living/carbon/slime/M in range(1, H.affecting))
			if(M.Victim == H.affecting)
				user << "<span class='danger'>[H.affecting.name] has a fucking slime attached to them, deal with that first.</span>"
				return
		var/mob/M = H.affecting
		if(M.abiotic())
			user << "<span class='notice'>Subject cannot have abiotic items on.</span>"
			return
		M.forceMove(src)
		occupant = M
		icon_state = "body_scanner_1"
		add_fingerprint(user)
		qdel(G)

/obj/machinery/bodyscanner/MouseDrop_T(mob/living/carbon/O, mob/user as mob)
	if(!istype(O))
		return 0 //not a mob
	if(user.incapacitated())
		return 0 //user shouldn't be doing things
	if(O.anchored)
		return 0 //mob is anchored???
	if(get_dist(user, src) > 1 || get_dist(user, O) > 1)
		return 0 //doesn't use adjacent() to allow for non-cardinal (fuck my life)
	if(!ishuman(user) && !isrobot(user))
		return 0 //not a borg or human
	if(panel_open)
		user << "<span class='notice'>Close the maintenance panel first.</span>"
		return 0 //panel open
	if(occupant)
		user << "<span class='notice'>\The [src] is already occupied.</span>"
		return 0 //occupied

	if(O.buckled)
		return 0
	if(O.abiotic())
		user << "<span class='notice'>Subject cannot have abiotic items on.</span>"
		return 0
	for(var/mob/living/carbon/slime/M in range(1, O))
		if(M.Victim == O)
			user << "<span class='danger'>[O] has a fucking slime attached to them, deal with that first.</span>"
			return 0

	if(O == user)
		visible_message("[user] climbs into \the [src].")
	else
		visible_message("[user] puts [O] into the body scanner.")

	O.forceMove(src)
	occupant = O
	icon_state = "body_scanner_1"
	add_fingerprint(user)

/obj/machinery/bodyscanner/relaymove(mob/user as mob)
	if(user.incapacitated())
		return 0 //maybe they should be able to get out with cuffs, but whatever
	go_out()

/obj/machinery/bodyscanner/verb/eject()
	set src in oview(1)
	set category = "Object"
	set name = "Eject Body Scanner"

	if(usr.incapacitated())
		return
	go_out()
	add_fingerprint(usr)

/obj/machinery/bodyscanner/proc/go_out()
	if ((!( src.occupant ) || src.locked))
		return
	if (src.occupant.client)
		src.occupant.client.eye = src.occupant.client.mob
		src.occupant.client.perspective = MOB_PERSPECTIVE
	src.occupant.loc = src.loc
	src.occupant = null
	src.icon_state = "body_scanner_0"
	return

/obj/machinery/bodyscanner/ex_act(severity)
	switch(severity)
		if(1.0)
			for(var/atom/movable/A as mob|obj in src)
				A.loc = src.loc
				ex_act(severity)
				//Foreach goto(35)
			//SN src = null
			qdel(src)
			return
		if(2.0)
			if (prob(50))
				for(var/atom/movable/A as mob|obj in src)
					A.loc = src.loc
					ex_act(severity)
					//Foreach goto(108)
				//SN src = null
				qdel(src)
				return
		if(3.0)
			if (prob(25))
				for(var/atom/movable/A as mob|obj in src)
					A.loc = src.loc
					ex_act(severity)
					//Foreach goto(181)
				//SN src = null
				qdel(src)
				return
		else
	return

//Body Scan Console
/obj/machinery/body_scanconsole
	var/obj/machinery/bodyscanner/connected
	var/known_implants = list(/obj/item/weapon/implant/chem, /obj/item/weapon/implant/death_alarm, /obj/item/weapon/implant/loyalty, /obj/item/weapon/implant/tracking)
	var/delete
	var/temphtml
	name = "Body Scanner Console"
	icon = 'icons/obj/Cryogenic2.dmi'
	icon_state = "body_scannerconsole"
	dir = 8
	density = 0
	anchored = 1
	circuit = /obj/item/weapon/circuitboard/scanner_console
	var/printing = null
	var/printing_text = null

/obj/machinery/body_scanconsole/New()
	..()
	findscanner()

/obj/machinery/body_scanconsole/attackby(var/obj/item/I, var/mob/user)
	if(istype(I, /obj/item/weapon/screwdriver) && circuit)
		user << "<span class='notice'>You start disconnecting the monitor.</span>"
		playsound(src.loc, 'sound/items/Screwdriver.ogg', 50, 1)
		if(do_after(user, 20))
			var/obj/structure/frame/A = new /obj/structure/frame( src.loc )
			var/obj/item/weapon/circuitboard/M = new circuit( A )
			A.circuit = M
			A.anchored = 1
			A.density = 1
			A.frame_type = M.board_type
			for (var/obj/C in src)
				C.forceMove(loc)
			if (src.stat & BROKEN)
				user << "<span class='notice'>The broken glass falls out.</span>"
				new /obj/item/weapon/material/shard( src.loc )
				A.state = 3
				A.icon_state = "[A.frame_type]_3"
			else
				user << "<span class='notice'>You disconnect the monitor.</span>"
				A.state = 4
				A.icon_state = "[A.frame_type]_4"
			A.pixel_x = pixel_x
			A.pixel_y = pixel_y
			A.dir = dir
			M.deconstruct(src)
			qdel(src)
	else
		src.attack_hand(user)
	return

/obj/machinery/body_scanconsole/power_change()
	if(stat & BROKEN)
		icon_state = "body_scannerconsole-p"
	else if(powered() && !panel_open)
		icon_state = initial(icon_state)
		stat &= ~NOPOWER
	else
		spawn(rand(0, 15))
			src.icon_state = "body_scannerconsole-p"
			stat |= NOPOWER

/obj/machinery/body_scanconsole/ex_act(severity)
	switch(severity)
		if(1.0)
			//SN src = null
			qdel(src)
			return
		if(2.0)
			if (prob(50))
				//SN src = null
				qdel(src)
				return
		else
	return

/obj/machinery/body_scanconsole/proc/findscanner()
	spawn( 5 )
		var/obj/machinery/bodyscanner/bodyscannernew = null
		// Loop through every direction
		for(dir in list(NORTH,EAST,SOUTH,WEST))
			// Try to find a scanner in that direction
			bodyscannernew = locate(/obj/machinery/bodyscanner, get_step(src, dir))
		src.connected = bodyscannernew
		return

/obj/machinery/body_scanconsole/attack_ai(user as mob)
	return attack_hand(user)

/obj/machinery/body_scanconsole/attack_ghost(user as mob)
	return attack_hand(user)

/obj/machinery/body_scanconsole/attack_hand(user as mob)
	if(stat & (NOPOWER|BROKEN))
		return

	if (panel_open)
		user << "<span class='notice'>Close the maintenance panel first.</span>"
		return

	if(!src.connected)
		findscanner()

	ui_interact(user)

/obj/machinery/body_scanconsole/ui_interact(mob/user, ui_key = "main", var/datum/nanoui/ui = null, var/force_open = 1)
	var/data[0]

	data["connected"] = connected ? 1 : 0

	if(connected)
		data["occupied"] = connected.occupant ? 1 : 0

		var/occupantData[0]
		if(connected.occupant && ishuman(connected.occupant))
			var/mob/living/carbon/human/H = connected.occupant
			occupantData["name"] = H.name
			occupantData["stat"] = H.stat
			occupantData["health"] = H.health

			occupantData["hasVirus"] = H.virus2.len

			occupantData["bruteLoss"] = H.getBruteLoss()
			occupantData["oxyLoss"] = H.getOxyLoss()
			occupantData["toxLoss"] = H.getToxLoss()
			occupantData["fireLoss"] = H.getFireLoss()

			occupantData["radLoss"] = H.radiation
			occupantData["cloneLoss"] = H.getCloneLoss()
			occupantData["brainLoss"] = H.getBrainLoss()
			occupantData["paralysis"] = H.paralysis
			occupantData["paralysisSeconds"] = round(H.paralysis / 4)
			occupantData["bodyTempC"] = H.bodytemperature-T0C
			occupantData["bodyTempF"] = (((H.bodytemperature-T0C) * 1.8) + 32)

			occupantData["hasBorer"] = H.has_brain_worms()

			var/bloodData[0]
			if(H.vessel)
				var/blood_volume = round(H.vessel.get_reagent_amount("blood"))
				bloodData["volume"] = blood_volume
				bloodData["percent"] = round(((blood_volume / 560)*100))

			occupantData["blood"] = bloodData

			var/reagentData[0]
			if(H.reagents.reagent_list.len >= 1)
				for(var/datum/reagent/R in H.reagents.reagent_list)
					reagentData[++reagentData.len] = list("name" = R.name, "amount" = R.volume)
			else
				reagentData = null

			occupantData["reagents"] = reagentData

			var/extOrganData[0]
			for(var/obj/item/organ/external/E in H.organs)
				var/organData[0]
				organData["name"] = E.name
				organData["open"] = E.open
				organData["germ_level"] = E.germ_level
				organData["bruteLoss"] = E.brute_dam
				organData["fireLoss"] = E.burn_dam

				var/implantData[0]
				for(var/obj/I in E.implants)
					var/implantSubData[0]
					implantSubData["name"] = I.name
					if(is_type_in_list(I, known_implants))
						implantSubData["known"] = 1

					implantData.Add(list(implantSubData))

				organData["implants"] = implantData
				organData["implants_len"] = implantData.len

				var/organStatus[0]
				if(E.status & ORGAN_DESTROYED)
					organStatus["destroyed"] = 1
				if(E.status & ORGAN_BROKEN)
					organStatus["broken"] = E.broken_description
				if(E.status & ORGAN_ROBOT)
					organStatus["robotic"] = 1
				if(E.status & ORGAN_SPLINTED)
					organStatus["splinted"] = 1
				if(E.status & ORGAN_BLEEDING)
					organStatus["bleeding"] = 1

				organData["status"] = organStatus

				if(istype(E, /obj/item/organ/external/chest) && H.is_lung_ruptured())
					organData["lungRuptured"] = 1

				for(var/datum/wound/W in E.wounds)
					if(W.internal)
						organData["internalBleeding"] = 1
						break

				extOrganData.Add(list(organData))

			occupantData["extOrgan"] = extOrganData

			var/intOrganData[0]
			for(var/obj/item/organ/I in H.internal_organs)
				var/organData[0]
				organData["name"] = I.name
				if(I.status & ORGAN_ASSISTED)
					organData["desc"] = "Assisted"
				else if(I.robotic >= ORGAN_ROBOT)
					organData["desc"] = "Mechanical"
				else
					organData["desc"] = null
				organData["germ_level"] = I.germ_level
				organData["damage"] = I.damage

				intOrganData.Add(list(organData))

			occupantData["intOrgan"] = intOrganData

			occupantData["blind"] = (H.sdisabilities & BLIND)
			occupantData["nearsighted"] = (H.disabilities & NEARSIGHTED)
			occupantData = attempt_vr(connected,"get_occupant_data_vr",list(occupantData,H)) //VOREStation Insert
		data["occupant"] = occupantData

	ui = nanomanager.try_update_ui(user, src, ui_key, ui, data, force_open)
	if(!ui)
		ui = new(user, src, ui_key, "adv_med.tmpl", "Body Scanner", 690, 800)
		ui.set_initial_data(data)
		ui.open()
		ui.set_auto_update(1)


/obj/machinery/body_scanconsole/Topic(href, href_list)
	if(..())
		return 1

	if (href_list["print_p"])
		generate_printing_text()

		if (!(printing) && printing_text)
			printing = 1
			visible_message("<span class='notice'>\The [src] rattles and prints out a sheet of paper.</span>")
			var/obj/item/weapon/paper/P = new /obj/item/weapon/paper(loc)
			P.info = "<CENTER><B>Body Scan - [href_list["name"]]</B></CENTER><BR>"
			P.info += "<b>Time of scan:</b> [worldtime2text(world.time)]<br><br>"
			P.info += "[printing_text]"
			P.info += "<br><br><b>Notes:</b><br>"
			P.name = "Body Scan - [href_list["name"]]"
			printing = null
			printing_text = null

/obj/machinery/body_scanconsole/proc/generate_printing_text()
	var/dat = ""

	if(connected)
		var/mob/living/carbon/human/occupant = connected.occupant
		dat = "<font color='blue'><b>Occupant Statistics:</b></font><br>" //Blah obvious
		if(istype(occupant)) //is there REALLY someone in there?
			var/t1
			switch(occupant.stat) // obvious, see what their status is
				if(0)
					t1 = "Conscious"
				if(1)
					t1 = "Unconscious"
				else
					t1 = "*dead*"
			dat += "<font color=[occupant.health > 50 ? "blue" : "red"]>\tHealth %: [occupant.health], ([t1])</font><br>"

			if(occupant.virus2.len)
				dat += "<font color='red'>Viral pathogen detected in blood stream.</font><BR>"

			var/extra_font = null
			extra_font = "<font color=[occupant.getBruteLoss() < 60 ? "blue" : "red"]>"
			dat += "[extra_font]\t-Brute Damage %: [occupant.getBruteLoss()]</font><br>"

			extra_font = "<font color=[occupant.getOxyLoss() < 60 ? "blue" : "red"]>"
			dat += "[extra_font]\t-Respiratory Damage %: [occupant.getOxyLoss()]</font><br>"

			extra_font = "<font color=[occupant.getToxLoss() < 60 ? "blue" : "red"]>"
			dat += "[extra_font]\t-Toxin Content %: [occupant.getToxLoss()]</font><br>"

			extra_font = "<font color=[occupant.getFireLoss() < 60 ? "blue" : "red"]>"
			dat += "[extra_font]\t-Burn Severity %: [occupant.getFireLoss()]</font><br>"

			extra_font = "<font color=[occupant.radiation < 10 ? "blue" : "red"]>"
			dat += "[extra_font]\tRadiation Level %: [occupant.radiation]</font><br>"

			extra_font = "<font color=[occupant.getCloneLoss() < 1 ? "blue" : "red"]>"
			dat += "[extra_font]\tGenetic Tissue Damage %: [occupant.getCloneLoss()]</font><br>"

			extra_font = "<font color=[occupant.getBrainLoss() < 1 ? "blue" : "red"]>"
			dat += "[extra_font]\tApprox. Brain Damage %: [occupant.getBrainLoss()]</font><br>"

			dat += "Paralysis Summary %: [occupant.paralysis] ([round(occupant.paralysis / 4)] seconds left!)<br>"
			dat += "Body Temperature: [occupant.bodytemperature-T0C]&deg;C ([occupant.bodytemperature*1.8-459.67]&deg;F)<br>"

			dat += "<hr>"

			if(occupant.has_brain_worms())
				dat += "Large growth detected in frontal lobe, possibly cancerous. Surgical removal is recommended.<br>"

			if(occupant.vessel)
				var/blood_volume = round(occupant.vessel.get_reagent_amount("blood"))
				var/blood_percent =  blood_volume / 560
				blood_percent *= 100

				extra_font = "<font color=[blood_volume > 448 ? "blue" : "red"]>"
				dat += "[extra_font]\tBlood Level %: [blood_percent] ([blood_volume] units)</font><br>"

			if(occupant.reagents)
				for(var/datum/reagent/R in occupant.reagents)
					dat += "Reagent: [R.name], Amount: [R.volume]<br>"

			dat += "<hr><table border='1'>"
			dat += "<tr>"
			dat += "<th>Organ</th>"
			dat += "<th>Burn Damage</th>"
			dat += "<th>Brute Damage</th>"
			dat += "<th>Other Wounds</th>"
			dat += "</tr>"

			for(var/obj/item/organ/external/e in occupant.organs)
				dat += "<tr>"
				var/AN = ""
				var/open = ""
				var/infected = ""
				var/robot = ""
				var/imp = ""
				var/bled = ""
				var/splint = ""
				var/internal_bleeding = ""
				var/lung_ruptured = ""
				for(var/datum/wound/W in e.wounds) if(W.internal)
					internal_bleeding = "<br>Internal bleeding"
					break
				if(istype(e, /obj/item/organ/external/chest) && occupant.is_lung_ruptured())
					lung_ruptured = "Lung ruptured:"
				if(e.status & ORGAN_SPLINTED)
					splint = "Splinted:"
				if(e.status & ORGAN_BLEEDING)
					bled = "Bleeding:"
				if(e.status & ORGAN_BROKEN)
					AN = "[e.broken_description]:"
				if(e.status & ORGAN_ROBOT)
					robot = "Prosthetic:"
				if(e.open)
					open = "Open:"
				switch (e.germ_level)
					if (INFECTION_LEVEL_ONE to INFECTION_LEVEL_ONE + 200)
						infected = "Mild Infection:"
					if (INFECTION_LEVEL_ONE + 200 to INFECTION_LEVEL_ONE + 300)
						infected = "Mild Infection+:"
					if (INFECTION_LEVEL_ONE + 300 to INFECTION_LEVEL_ONE + 400)
						infected = "Mild Infection++:"
					if (INFECTION_LEVEL_TWO to INFECTION_LEVEL_TWO + 200)
						infected = "Acute Infection:"
					if (INFECTION_LEVEL_TWO + 200 to INFECTION_LEVEL_TWO + 300)
						infected = "Acute Infection+:"
					if (INFECTION_LEVEL_TWO + 300 to INFECTION_LEVEL_TWO + 400)
						infected = "Acute Infection++:"
					if (INFECTION_LEVEL_THREE to INFINITY)
						infected = "Septic:"

				var/unknown_body = 0
				for(var/I in e.implants)
					if(is_type_in_list(I,known_implants))
						imp += "[I] implanted:"
					else
						unknown_body++

				if(unknown_body)
					imp += "Unknown body present:"
				if(!AN && !open && !infected & !imp)
					AN = "None:"
				if(!(e.status & ORGAN_DESTROYED))
					dat += "<td>[e.name]</td><td>[e.burn_dam]</td><td>[e.brute_dam]</td><td>[robot][bled][AN][splint][open][infected][imp][internal_bleeding][lung_ruptured]</td>"
				else
					dat += "<td>[e.name]</td><td>-</td><td>-</td><td>Not Found</td>"
				dat += "</tr>"
			for(var/obj/item/organ/i in occupant.internal_organs)
				var/mech = ""
				if(i.status & ORGAN_ASSISTED)
					mech = "Assisted:"
				if(i.robotic >= ORGAN_ROBOT)
					mech = "Mechanical:"
				var/infection = "None"
				switch (i.germ_level)
					if (1 to INFECTION_LEVEL_ONE + 200)
						infection = "Mild Infection:"
					if (INFECTION_LEVEL_ONE + 200 to INFECTION_LEVEL_ONE + 300)
						infection = "Mild Infection+:"
					if (INFECTION_LEVEL_ONE + 300 to INFECTION_LEVEL_ONE + 400)
						infection = "Mild Infection++:"
					if (INFECTION_LEVEL_TWO to INFECTION_LEVEL_TWO + 200)
						infection = "Acute Infection:"
					if (INFECTION_LEVEL_TWO + 200 to INFECTION_LEVEL_TWO + 300)
						infection = "Acute Infection+:"
					if (INFECTION_LEVEL_TWO + 300 to INFINITY)
						infection = "Acute Infection++:"

				dat += "<tr>"
				dat += "<td>[i.name]</td><td>N/A</td><td>[i.damage]</td><td>[infection]:[mech]</td><td></td>"
				dat += "</tr>"
			dat += "</table>"
			if(occupant.sdisabilities & BLIND)
				dat += "<font color='red'>Cataracts detected.</font><BR>"
			if(occupant.disabilities & NEARSIGHTED)
				dat += "<font color='red'>Retinal misalignment detected.</font><BR>"
		else
			dat += "\The [src] is empty."
	else
		dat = "<font color='red'> Error: No Body Scanner connected.</font>"

	printing_text = dat