cyberpresidentvanellope/CHOMPStation2
1
0
Fork 0
mirror of https://github.com/CHOMPStation2/CHOMPStation2.git synced 2026-01-17 12:53:59 +00:00
Code Issues Packages Projects Releases Wiki Activity
Files
f58a3c742bdff8affc266ab45ede9780ccbd4025
CHOMPStation2/code/game/objects/items/bodybag.dm
Rykka ed798113d9 Compiler Fixes 
Fixes in order:
- Removes List of defines in misc_ch.dm that are no longer used - they're defined here for the casino prize dispenser, making these obsolete:
![](https://i.imgur.com/8iCsb98.png)

- Fixes relative pathing in mecha_parts_ch.dm
- Fixes relative pathing in bodybag.dm
- Fixes relative pathing in sahoc_ch.dm
- Fixes relative pathing in toys_yw.dm
- Fixes def_zone being defined when only the variable was needed in twohanded_ch.dm
- Fixes relative pathing in trash_pile_vr_ch.dm
- Fixes clip_mask being missing in misc_ch.dm
- Fixes relative pathing in tesh_synth_facemask.dm
- Fixes absolute path being indented in by one (typo?)
- Fixes relative pathing in armor_yw.dm
- Fixes unreachable parent call in audible_scream_ch.dm
- Fixes VERM_LIZARDS being undefined when it wasn't defined, as VERM_LIZARDMEN was the variable being defined + used in mutants.dm
- Removes two un-needed parent calls - these procs have no parent on /obj/structure - thecake_ch.dm
- Fixes invalid kword nano_state in protean_blob.dm
- Fixes relative pathing in drone_manufacturer_unify.dm
- Fixes relative pathing in synx.dm
- Removes arguments of drop_item that don't exist (port was from TG and had force_drop = 1 and src defined.) - vox.dm
- Added vision_required = TRUE to fix proc argument missing - bigdragon_ch.dm
- Added include_robo = TRUE to fix argument missing in demon_ch.dm
- Fixes relative pathing in rakshasa_abilities.dm
- Adds comment to solargrub.dm, unable to fix operator overload error yet.
- Fixes relative pathing in sprite_accessories_extra_ch.dm
- Fixes relative pathing in sprite_accessories_yw.dm
- Fixes relative pathing in phase.dm
- Fixes relative pathing in bluespacecoffee.dm
- Fixes relative pathing in other_ch.dm
- Fixes relative pathing and ambigious ! in living_ch.dm
- Fixes relative pathing in custom_clothes_yw.dm
- Fixes relative pathing in custom_rigs_yw.dm
- Fixes relative pathing in MadokaSpear.dm
- Comments out duplicate #includes in southern_cross.dm as vorestation.dme has them #include'd.
2021-09-03 17:22:49 -07:00

284 lines
8.9 KiB
Plaintext
Raw Blame History

//Also contains /obj/structure/closet/body_bag because I doubt anyone would think to look for bodybags in /object/structures
/obj/item/bodybag
name = "body bag"
desc = "A folded bag designed for the storage and transportation of cadavers."
icon = 'icons/obj/closets/bodybag.dmi'
icon_state = "bodybag_folded"
w_class = ITEMSIZE_SMALL
/obj/item/bodybag/attack_self(mob/user)
var/obj/structure/closet/body_bag/R = new /obj/structure/closet/body_bag(user.loc)
R.add_fingerprint(user)
qdel(src)
/obj/item/weapon/storage/box/bodybags
name = "body bags"
desc = "This box contains body bags."
icon_state = "bodybags"
starts_with = list(/obj/item/bodybag = 7)
/obj/structure/closet/body_bag
name = "body bag"
desc = "A plastic bag designed for the storage and transportation of cadavers."
icon = 'icons/obj/closets/bodybag.dmi'
closet_appearance = null
open_sound = 'sound/items/zip.ogg'
close_sound = 'sound/items/zip.ogg'
var/item_path = /obj/item/bodybag
density = FALSE
storage_capacity = (MOB_MEDIUM * 2) - 1
var/contains_body = 0
//Yawn add
/obj/item/bodybag/large
name = "mass grave body bag"
desc = "A large folded bag designed for the storage and transportation of cadavers."
icon = 'icons/obj/closets/bodybag_large.dmi'
w_class = ITEMSIZE_LARGE
/obj/item/bodybag/large/attack_self(mob/user)
var/obj/structure/closet/body_bag/large/R = new /obj/structure/closet/body_bag/large(user.loc)
R.add_fingerprint(user)
qdel(src)
/obj/structure/closet/body_bag/large
name = "mass grave body bag"
desc = "A massive body bag that holds as much as it does due to bluespace lining on its zipper. Shockingly compact for its storage."
icon = 'icons/obj/closets/bodybag_large.dmi'
storage_capacity = (MOB_MEDIUM * 12) - 1 //Holds 12 bodys
item_path = /obj/item/bodybag/large
//End of Yawn add
/obj/structure/closet/body_bag/attackby(var/obj/item/W as obj, mob/user as mob)
if (istype(W, /obj/item/weapon/pen))
var/t = input(user, "What would you like the label to be?", text("[]", src.name), null) as text
if (user.get_active_hand() != W)
return
if (!in_range(src, user) && src.loc != user)
return
t = sanitizeSafe(t, MAX_NAME_LEN)
if (t)
src.name = "body bag - "
src.name += t
add_overlay("bodybag_label")
else
src.name = "body bag"
//..() //Doesn't need to run the parent. Since when can fucking bodybags be welded shut? -Agouri
return
else if(W.is_wirecutter())
to_chat(user, "You cut the tag off the bodybag")
src.name = "body bag"
cut_overlays()
return
/obj/structure/closet/body_bag/store_mobs(var/stored_units)
contains_body = ..()
return contains_body
/obj/structure/closet/body_bag/close()
if(..())
density = FALSE
return 1
return 0
/obj/structure/closet/body_bag/MouseDrop(over_object, src_location, over_location)
..()
if((over_object == usr && (in_range(src, usr) || usr.contents.Find(src))))
if(!ishuman(usr)) return 0
if(opened) return 0
if(contents.len) return 0
visible_message("[usr] folds up the [src.name]")
var/folded = new item_path(get_turf(src))
spawn(0)
qdel(src)
return folded
/obj/structure/closet/body_bag/relaymove(mob/user,direction)
if(src.loc != get_turf(src))
src.loc.relaymove(user,direction)
else
..()
/obj/structure/closet/body_bag/proc/get_occupants()
var/list/occupants = list()
for(var/mob/living/carbon/human/H in contents)
occupants += H
return occupants
/obj/structure/closet/body_bag/proc/update(var/broadcast=0)
if(istype(loc, /obj/structure/morgue))
var/obj/structure/morgue/M = loc
M.update(broadcast)
/obj/structure/closet/body_bag/update_icon()
if(opened)
icon_state = "open"
else
icon_state = "closed_unlocked"
cut_overlays()
/* Ours don't have toetags
if(has_label)
add_overlay("bodybag_label")
*/
/obj/item/bodybag/cryobag
name = "stasis bag"
desc = "A non-reusable plastic bag designed to slow down bodily functions such as circulation and breathing, \
especially useful if short on time or in a hostile enviroment."
icon = 'icons/obj/closets/cryobag.dmi'
icon_state = "bodybag_folded"
item_state = "bodybag_cryo_folded"
origin_tech = list(TECH_BIO = 4)
var/obj/item/weapon/reagent_containers/syringe/syringe
/obj/item/bodybag/cryobag/attack_self(mob/user)
var/obj/structure/closet/body_bag/cryobag/R = new /obj/structure/closet/body_bag/cryobag(user.loc)
R.add_fingerprint(user)
if(syringe)
R.syringe = syringe
syringe = null
qdel(src)
/obj/structure/closet/body_bag/cryobag
name = "stasis bag"
desc = "A non-reusable plastic bag designed to slow down bodily functions such as circulation and breathing, \
especially useful if short on time or in a hostile enviroment."
icon = 'icons/obj/closets/cryobag.dmi'
item_path = /obj/item/bodybag/cryobag
store_misc = 0
store_items = 0
var/used = 0
var/obj/item/weapon/tank/tank = null
var/tank_type = /obj/item/weapon/tank/stasis/oxygen
var/stasis_level = 3 //Every 'this' life ticks are applied to the mob (when life_ticks%stasis_level == 1)
var/obj/item/weapon/reagent_containers/syringe/syringe
/obj/structure/closet/body_bag/cryobag/Initialize()
tank = new tank_type(null) //It's in nullspace to prevent ejection when the bag is opened.
..()
/obj/structure/closet/body_bag/cryobag/Destroy()
QDEL_NULL(syringe)
QDEL_NULL(tank)
return ..()
/obj/structure/closet/body_bag/cryobag/attack_hand(mob/living/user)
if(used)
var/confirm = tgui_alert(user, "Are you sure you want to open \the [src]? \The [src] will expire upon opening it.", "Confirm Opening", list("No", "Yes"))
if(confirm == "Yes")
..() // Will call `toggle()` and open the bag.
else
..()
/obj/structure/closet/body_bag/cryobag/open()
. = ..()
if(used)
new /obj/item/usedcryobag(loc)
qdel(src)
/obj/structure/closet/body_bag/cryobag/update_icon()
..()
cut_overlays()
var/image/I = image(icon, "indicator[opened]")
I.appearance_flags = RESET_COLOR
I.color = COLOR_LIME
add_overlay(I)
/obj/structure/closet/body_bag/cryobag/MouseDrop(over_object, src_location, over_location)
. = ..()
if(. && syringe)
var/obj/item/bodybag/cryobag/folded = .
folded.syringe = syringe
syringe = null
/obj/structure/closet/body_bag/cryobag/Entered(atom/movable/AM)
if(ishuman(AM))
var/mob/living/carbon/human/H = AM
H.Stasis(stasis_level)
src.used = 1
inject_occupant(H)
if(istype(AM, /obj/item/organ))
var/obj/item/organ/O = AM
O.preserved = 1
for(var/obj/item/organ/organ in O)
organ.preserved = 1
..()
/obj/structure/closet/body_bag/cryobag/Exited(atom/movable/AM)
if(ishuman(AM))
var/mob/living/carbon/human/H = AM
H.Stasis(0)
if(istype(AM, /obj/item/organ))
var/obj/item/organ/O = AM
O.preserved = 0
for(var/obj/item/organ/organ in O)
organ.preserved = 0
..()
/obj/structure/closet/body_bag/cryobag/return_air() //Used to make stasis bags protect from vacuum.
if(tank)
return tank.air_contents
..()
/obj/structure/closet/body_bag/cryobag/proc/inject_occupant(var/mob/living/carbon/human/H)
if(!syringe)
return
if(H.reagents)
syringe.reagents.trans_to_mob(H, 30, CHEM_BLOOD)
/obj/structure/closet/body_bag/cryobag/examine(mob/user)
. = ..()
if(Adjacent(user)) //The bag's rather thick and opaque from a distance.
. += "<span class='info'>You peer into \the [src].</span>"
if(syringe)
. += "<span class='info'>It has a syringe added to it.</span>"
for(var/mob/living/L in contents)
. += L.examine(user)
/obj/structure/closet/body_bag/cryobag/attackby(obj/item/W, mob/user)
if(opened)
..()
else //Allows the bag to respond to a health analyzer by analyzing the mob inside without needing to open it.
if(istype(W,/obj/item/device/healthanalyzer))
var/obj/item/device/healthanalyzer/analyzer = W
for(var/mob/living/L in contents)
analyzer.attack(L,user)
else if(istype(W,/obj/item/weapon/reagent_containers/syringe))
if(syringe)
to_chat(user,"<span class='warning'>\The [src] already has an injector! Remove it first.</span>")
else
var/obj/item/weapon/reagent_containers/syringe/syringe = W
to_chat(user,"<span class='info'>You insert \the [syringe] into \the [src], and it locks into place.</span>")
user.unEquip(syringe)
src.syringe = syringe
syringe.loc = null
for(var/mob/living/carbon/human/H in contents)
inject_occupant(H)
break
else if(W.is_screwdriver())
if(syringe)
if(used)
to_chat(user,"<span class='warning'>The injector cannot be removed now that the stasis bag has been used!</span>")
else
syringe.forceMove(src.loc)
to_chat(user,"<span class='info'>You pry \the [syringe] out of \the [src].</span>")
syringe = null
else
..()
/obj/item/usedcryobag
name = "used stasis bag"
desc = "Pretty useless now.."
icon_state = "bodybag_used"
icon = 'icons/obj/closets/cryobag.dmi'
Reference in New Issue View Git Blame Copy Permalink