mirror of
https://github.com/CHOMPstation/CHOMPstation.git
synced 2026-07-12 15:42:49 +01:00
Novacat
5addac95ed
* Pathfinder Update - Implimented Pathfinder, Command Exploration role - Added Deluxe Machete for Pathfinders (just a cosmetic reskin) - Added Pathfinder's office, between expedition prep and breifing - Expanded size of expedition shuttle - Ported Pilot and Explorer voidsuit from Baystation - Restored the old air tank on the expedition shuttle - Added a couple starter shelter capsules to exploration - The expedition shuttle now has toggled blast doors to cover the windows - Increases pay of pilots, SARs, and Explorers - Adds box of volunteer headsets to the Pathfinder's locker * Polaris Merge Compatability * Forgot some things * Moves PF from command to science * Requested changes Part 1 * Travis and Access Fix * Requested changes Part 2 * Resetting Maps Part 1 * Resetting Maps Part 2 * Replaces PF office airlock * Requested Changes Part 3 * Remove gateway access * Changes Locker/Door Access Req * Removes blast doors * Pilot voidsuit crate cost tweak
115 lines
4.5 KiB
Plaintext
115 lines
4.5 KiB
Plaintext
/obj/item/weapon/material/butterfly
|
|
name = "butterfly knife"
|
|
desc = "A basic metal blade concealed in a lightweight plasteel grip. Small enough when folded to fit in a pocket."
|
|
icon_state = "butterflyknife"
|
|
item_state = null
|
|
hitsound = null
|
|
var/active = 0
|
|
w_class = ITEMSIZE_SMALL
|
|
attack_verb = list("patted", "tapped")
|
|
force_divisor = 0.25 // 15 when wielded with hardness 60 (steel)
|
|
thrown_force_divisor = 0.25 // 5 when thrown with weight 20 (steel)
|
|
|
|
/obj/item/weapon/material/butterfly/update_force()
|
|
if(active)
|
|
edge = 1
|
|
sharp = 1
|
|
..() //Updates force.
|
|
throwforce = max(3,force-3)
|
|
hitsound = 'sound/weapons/bladeslice.ogg'
|
|
icon_state += "_open"
|
|
w_class = ITEMSIZE_NORMAL
|
|
attack_verb = list("attacked", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
|
|
else
|
|
force = 3
|
|
edge = 0
|
|
sharp = 0
|
|
hitsound = initial(hitsound)
|
|
icon_state = initial(icon_state)
|
|
w_class = initial(w_class)
|
|
attack_verb = initial(attack_verb)
|
|
|
|
/obj/item/weapon/material/butterfly/switchblade
|
|
name = "switchblade"
|
|
desc = "A classic switchblade with gold engraving. Just holding it makes you feel like a gangster."
|
|
icon_state = "switchblade"
|
|
|
|
/obj/item/weapon/material/butterfly/boxcutter
|
|
name = "box cutter"
|
|
desc = "A thin, inexpensive razor-blade knife designed to open cardboard boxes."
|
|
icon_state = "boxcutter"
|
|
force_divisor = 0.1 // 6 when wielded with hardness 60 (steel)
|
|
thrown_force_divisor = 0.2 // 4 when thrown with weight 20 (steel)
|
|
|
|
/obj/item/weapon/material/butterfly/attack_self(mob/user)
|
|
active = !active
|
|
if(active)
|
|
user << "<span class='notice'>You flip out \the [src].</span>"
|
|
playsound(user, 'sound/weapons/flipblade.ogg', 15, 1)
|
|
else
|
|
user << "<span class='notice'>\The [src] can now be concealed.</span>"
|
|
update_force()
|
|
add_fingerprint(user)
|
|
|
|
/*
|
|
* Kitchen knives
|
|
*/
|
|
/obj/item/weapon/material/knife
|
|
name = "kitchen knife"
|
|
icon = 'icons/obj/kitchen.dmi'
|
|
icon_state = "knife"
|
|
desc = "A general purpose Chef's Knife made by SpaceCook Incorporated. Guaranteed to stay sharp for years to come."
|
|
flags = CONDUCT
|
|
sharp = 1
|
|
edge = 1
|
|
force_divisor = 0.15 // 9 when wielded with hardness 60 (steel)
|
|
matter = list(DEFAULT_WALL_MATERIAL = 12000)
|
|
origin_tech = list(TECH_MATERIAL = 1)
|
|
attack_verb = list("slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
|
|
|
|
/obj/item/weapon/material/knife/suicide_act(mob/user)
|
|
var/datum/gender/TU = gender_datums[user.get_visible_gender()]
|
|
viewers(user) << pick("<span class='danger'>\The [user] is slitting [TU.his] wrists with \the [src]! It looks like [TU.hes] trying to commit suicide.</span>", \
|
|
"<span class='danger'>\The [user] is slitting [TU.his] throat with \the [src]! It looks like [TU.hes] trying to commit suicide.</span>", \
|
|
"<span class='danger'>\The [user] is slitting [TU.his] stomach open with \the [src]! It looks like [TU.hes] trying to commit seppuku.</span>")
|
|
return (BRUTELOSS)
|
|
|
|
/obj/item/weapon/material/knife/hook
|
|
name = "meat hook"
|
|
desc = "A sharp, metal hook what sticks into things."
|
|
icon_state = "hook_knife"
|
|
|
|
/obj/item/weapon/material/knife/ritual
|
|
name = "ritual knife"
|
|
desc = "The unearthly energies that once powered this blade are now dormant."
|
|
icon = 'icons/obj/wizard.dmi'
|
|
icon_state = "render"
|
|
applies_material_colour = 0
|
|
|
|
/obj/item/weapon/material/knife/butch
|
|
name = "butcher's cleaver"
|
|
icon_state = "butch"
|
|
desc = "A huge thing used for chopping and chopping up meat. This includes clowns and clown-by-products."
|
|
force_divisor = 0.25 // 15 when wielded with hardness 60 (steel)
|
|
attack_verb = list("cleaved", "slashed", "stabbed", "sliced", "torn", "ripped", "diced", "cut")
|
|
|
|
/obj/item/weapon/material/knife/machete
|
|
name = "machete"
|
|
desc = "A sharp machete often found in survival kits."
|
|
icon_state = "machete"
|
|
force_divisor = 0.3 // 18 when hardness 60 (steel)
|
|
attack_verb = list("slashed", "chopped", "gouged", "ripped", "cut")
|
|
can_cleave = TRUE //Now hatchets inherit from the machete, and thus knives. Tables turned.
|
|
slot_flags = SLOT_BELT
|
|
default_material = "plasteel" //VOREStation Edit
|
|
|
|
/obj/item/weapon/material/knife/tacknife/survival
|
|
name = "survival knife"
|
|
desc = "A hunting grade survival knife."
|
|
icon = 'icons/obj/kitchen.dmi'
|
|
icon_state = "survivalknife"
|
|
item_state = "knife"
|
|
applies_material_colour = FALSE
|
|
default_material = "plasteel" //VOREStation Edit
|
|
toolspeed = 2 // Use a real axe if you want to chop logs.
|