mirror of
https://github.com/Citadel-Station-13/Citadel-Station-13.git
synced 2026-08-24 10:36:50 +01:00
PoojawaandGitHub
cf59ac1c3d
* sync (#3) * shuttle auto call * Merge /vore into /master (#39) * progress * Compile errors fixed No idea if it's test worthy tho as conflicts with race overhaul and narky removal. * Update admins.txt * efforts continue Fuck grab code, seriously * grab code is cancer * Execute the Narkism Do not hesitate. Show no mercy. * holy shit grab code is awful * have I bitched about grab code My bitching, let me show you it * código de agarre es una mierda No really it is * yeah I don't even know anymore. * Lolnope. Fuck grab code * I'm not even sure what to fix anymore * Self eating is not an acceptable fate * Taste the void, son. * My code doesn't pass it's own sanity check. Maybe it's a sign of things to come. * uncommented and notes * It Works and I Don't Know Why (#38) * shuttle auto call * it works and I don't know why * Subsystem 12/21 Most Recent TG subsystem folder * globalvars 12/21 Tossed out the flavor_misc and parallax files * Onclick 12/21 as well as .dme updates * _defines 12/21 ommited old _MC.dm * _HELPERS 12/21 Preserved snowflake placement of furry sprites * _defeines/genetics reapplied narkism holdover for snowflake races. * Oops forgot mutant colors * modules porting 12/21 + Sounds/icons Admin, Client and most of mob life files ommitted * enviroment file * Admin optimizations ahelp log system kept * Mob ports 12/21 Flavor text preserved * datums ported 12/21 * Game ported 12/21 * batch of duplicate fixes/dogborg work Dogborgs need to be modernized to refractored borg standards. * moar fixes * Maps and futher compile fixes
112 lines
3.0 KiB
Plaintext
112 lines
3.0 KiB
Plaintext
#define TANK_DISPENSER_CAPACITY 10
|
|
|
|
/obj/structure/tank_dispenser
|
|
name = "tank dispenser"
|
|
desc = "A simple yet bulky storage device for gas tanks. Holds up to 10 oxygen tanks and 10 plasma tanks."
|
|
icon = 'icons/obj/objects.dmi'
|
|
icon_state = "dispenser"
|
|
density = 1
|
|
anchored = 1
|
|
obj_integrity = 300
|
|
max_integrity = 300
|
|
var/oxygentanks = TANK_DISPENSER_CAPACITY
|
|
var/plasmatanks = TANK_DISPENSER_CAPACITY
|
|
|
|
/obj/structure/tank_dispenser/oxygen
|
|
plasmatanks = 0
|
|
|
|
/obj/structure/tank_dispenser/plasma
|
|
oxygentanks = 0
|
|
|
|
/obj/structure/tank_dispenser/New()
|
|
for(var/i in 1 to oxygentanks)
|
|
new /obj/item/weapon/tank/internals/oxygen(src)
|
|
for(var/i in 1 to plasmatanks)
|
|
new /obj/item/weapon/tank/internals/plasma(src)
|
|
update_icon()
|
|
..()
|
|
/obj/structure/tank_dispenser/update_icon()
|
|
cut_overlays()
|
|
switch(oxygentanks)
|
|
if(1 to 3)
|
|
add_overlay("oxygen-[oxygentanks]")
|
|
if(4 to TANK_DISPENSER_CAPACITY)
|
|
add_overlay("oxygen-4")
|
|
switch(plasmatanks)
|
|
if(1 to 4)
|
|
add_overlay("plasma-[plasmatanks]")
|
|
if(5 to TANK_DISPENSER_CAPACITY)
|
|
add_overlay("plasma-5")
|
|
|
|
/obj/structure/tank_dispenser/attackby(obj/item/I, mob/user, params)
|
|
var/full
|
|
if(istype(I, /obj/item/weapon/tank/internals/plasma))
|
|
if(plasmatanks < TANK_DISPENSER_CAPACITY)
|
|
plasmatanks++
|
|
else
|
|
full = TRUE
|
|
else if(istype(I, /obj/item/weapon/tank/internals/oxygen))
|
|
if(oxygentanks < TANK_DISPENSER_CAPACITY)
|
|
oxygentanks++
|
|
else
|
|
full = TRUE
|
|
else if(istype(I, /obj/item/weapon/wrench))
|
|
default_unfasten_wrench(user, I, time = 20)
|
|
return
|
|
else if(user.a_intent != INTENT_HARM)
|
|
user << "<span class='notice'>[I] does not fit into [src].</span>"
|
|
return
|
|
else
|
|
return ..()
|
|
if(full)
|
|
user << "<span class='notice'>[src] can't hold any more of [I].</span>"
|
|
return
|
|
|
|
if(!user.drop_item())
|
|
return
|
|
I.loc = src
|
|
user << "<span class='notice'>You put [I] in [src].</span>"
|
|
update_icon()
|
|
|
|
/obj/structure/tank_dispenser/ui_interact(mob/user, ui_key = "main", datum/tgui/ui = null, force_open = 0, \
|
|
datum/tgui/master_ui = null, datum/ui_state/state = physical_state)
|
|
ui = SStgui.try_update_ui(user, src, ui_key, ui, force_open)
|
|
if(!ui)
|
|
ui = new(user, src, ui_key, "tank_dispenser", name, 275, 100, master_ui, state)
|
|
ui.open()
|
|
|
|
/obj/structure/tank_dispenser/ui_data(mob/user)
|
|
var/list/data = list()
|
|
data["oxygen"] = oxygentanks
|
|
data["plasma"] = plasmatanks
|
|
|
|
return data
|
|
|
|
/obj/structure/tank_dispenser/ui_act(action, params)
|
|
if(..())
|
|
return
|
|
switch(action)
|
|
if("plasma")
|
|
var/obj/item/weapon/tank/internals/plasma/tank = locate() in src
|
|
if(tank)
|
|
usr.put_in_hands(tank)
|
|
plasmatanks--
|
|
. = TRUE
|
|
if("oxygen")
|
|
var/obj/item/weapon/tank/internals/oxygen/tank = locate() in src
|
|
if(tank)
|
|
usr.put_in_hands(tank)
|
|
oxygentanks--
|
|
. = TRUE
|
|
update_icon()
|
|
|
|
|
|
/obj/structure/tank_dispenser/deconstruct(disassembled = TRUE)
|
|
if(!(flags & NODECONSTRUCT))
|
|
for(var/X in src)
|
|
var/obj/item/I = X
|
|
I.forceMove(loc)
|
|
new /obj/item/stack/sheet/metal (loc, 2)
|
|
qdel(src)
|
|
|
|
#undef TANK_DISPENSER_CAPACITY |