mirror of
https://github.com/evilew/GS13-Citadel.git
synced 2026-08-31 09:09:58 +01:00
PoojawaandGitHub
cf59ac1c3d
* sync (#3) * shuttle auto call * Merge /vore into /master (#39) * progress * Compile errors fixed No idea if it's test worthy tho as conflicts with race overhaul and narky removal. * Update admins.txt * efforts continue Fuck grab code, seriously * grab code is cancer * Execute the Narkism Do not hesitate. Show no mercy. * holy shit grab code is awful * have I bitched about grab code My bitching, let me show you it * código de agarre es una mierda No really it is * yeah I don't even know anymore. * Lolnope. Fuck grab code * I'm not even sure what to fix anymore * Self eating is not an acceptable fate * Taste the void, son. * My code doesn't pass it's own sanity check. Maybe it's a sign of things to come. * uncommented and notes * It Works and I Don't Know Why (#38) * shuttle auto call * it works and I don't know why * Subsystem 12/21 Most Recent TG subsystem folder * globalvars 12/21 Tossed out the flavor_misc and parallax files * Onclick 12/21 as well as .dme updates * _defines 12/21 ommited old _MC.dm * _HELPERS 12/21 Preserved snowflake placement of furry sprites * _defeines/genetics reapplied narkism holdover for snowflake races. * Oops forgot mutant colors * modules porting 12/21 + Sounds/icons Admin, Client and most of mob life files ommitted * enviroment file * Admin optimizations ahelp log system kept * Mob ports 12/21 Flavor text preserved * datums ported 12/21 * Game ported 12/21 * batch of duplicate fixes/dogborg work Dogborgs need to be modernized to refractored borg standards. * moar fixes * Maps and futher compile fixes
86 lines
2.5 KiB
Plaintext
86 lines
2.5 KiB
Plaintext
/obj/item/weapon/gun/magic
|
|
name = "staff of nothing"
|
|
desc = "This staff is boring to watch because even though it came first you've seen everything it can do in other staves for years."
|
|
icon = 'icons/obj/guns/magic.dmi'
|
|
icon_state = "staffofnothing"
|
|
item_state = "staff"
|
|
fire_sound = 'sound/weapons/emitter.ogg'
|
|
flags = CONDUCT
|
|
w_class = WEIGHT_CLASS_HUGE
|
|
var/max_charges = 6
|
|
var/charges = 0
|
|
var/recharge_rate = 4
|
|
var/charge_tick = 0
|
|
var/can_charge = 1
|
|
var/ammo_type
|
|
var/no_den_usage
|
|
origin_tech = null
|
|
clumsy_check = 0
|
|
trigger_guard = TRIGGER_GUARD_ALLOW_ALL // Has no trigger at all, uses magic instead
|
|
pin = /obj/item/device/firing_pin/magic
|
|
|
|
lefthand_file = 'icons/mob/inhands/items_lefthand.dmi' //not really a gun and some toys use these inhands
|
|
righthand_file = 'icons/mob/inhands/items_righthand.dmi'
|
|
|
|
/obj/item/weapon/gun/magic/afterattack(atom/target, mob/living/user, flag)
|
|
if(no_den_usage)
|
|
var/area/A = get_area(user)
|
|
if(istype(A, /area/wizard_station))
|
|
user << "<span class='warning'>You know better than to violate the security of The Den, best wait until you leave to use [src].<span>"
|
|
return
|
|
else
|
|
no_den_usage = 0
|
|
..()
|
|
|
|
/obj/item/weapon/gun/magic/can_shoot()
|
|
return charges
|
|
|
|
/obj/item/weapon/gun/magic/recharge_newshot()
|
|
if (charges && chambered && !chambered.BB)
|
|
chambered.newshot()
|
|
|
|
/obj/item/weapon/gun/magic/process_chamber()
|
|
if(chambered && !chambered.BB) //if BB is null, i.e the shot has been fired...
|
|
charges--//... drain a charge
|
|
recharge_newshot()
|
|
|
|
/obj/item/weapon/gun/magic/New()
|
|
..()
|
|
charges = max_charges
|
|
chambered = new ammo_type(src)
|
|
if(can_charge)
|
|
START_PROCESSING(SSobj, src)
|
|
|
|
|
|
/obj/item/weapon/gun/magic/Destroy()
|
|
if(can_charge)
|
|
STOP_PROCESSING(SSobj, src)
|
|
return ..()
|
|
|
|
|
|
/obj/item/weapon/gun/magic/process()
|
|
charge_tick++
|
|
if(charge_tick < recharge_rate || charges >= max_charges)
|
|
return 0
|
|
charge_tick = 0
|
|
charges++
|
|
if(charges == 1)
|
|
recharge_newshot()
|
|
return 1
|
|
|
|
/obj/item/weapon/gun/magic/update_icon()
|
|
return
|
|
|
|
/obj/item/weapon/gun/magic/shoot_with_empty_chamber(mob/living/user as mob|obj)
|
|
user << "<span class='warning'>The [name] whizzles quietly.<span>"
|
|
|
|
/obj/item/weapon/gun/magic/suicide_act(mob/user)
|
|
user.visible_message("<span class='suicide'>[user] is twisting [src] above [user.p_their()] head, releasing a magical blast! It looks like [user.p_theyre()] trying to commit suicide!</span>")
|
|
playsound(loc, fire_sound, 50, 1, -1)
|
|
return (FIRELOSS)
|
|
|
|
/obj/item/weapon/gun/magic/vv_edit_var(var_name, var_value)
|
|
. = ..()
|
|
switch (var_name)
|
|
if ("charges")
|
|
recharge_newshot() |