Uploading all files.

code/modules/admin/verbs/BrokenInhands.dm

@@ -0,0 +1,35 @@
+/proc/getbrokeninhands()
+	var/text
+	for(var/A in typesof(/obj/item))
+		var/obj/item/O = new A( locate(1,1,1) )
+		if(!O)
+			continue
+		var/icon/IL = new(O.lefthand_file)
+		var/list/Lstates = IL.IconStates()
+		var/icon/IR = new(O.righthand_file)
+		var/list/Rstates = IR.IconStates()
+		var/icon/J = new(O.icon)
+		var/list/istates = J.IconStates()
+		if(!Lstates.Find(O.icon_state) && !Lstates.Find(O.item_state))
+			if(O.icon_state)
+				text += "[O.type] WANTS IN LEFT HAND CALLED\n\"[O.icon_state]\".\n"
+		if(!Rstates.Find(O.icon_state) && !Rstates.Find(O.item_state))
+			if(O.icon_state)
+				text += "[O.type] WANTS IN RIGHT HAND CALLED\n\"[O.icon_state]\".\n"
+
+
+		if(O.icon_state)
+			if(!istates.Find(O.icon_state))
+				text += "[O.type] MISSING NORMAL ICON CALLED\n\"[O.icon_state]\" IN \"[O.icon]\"\n"
+		if(O.item_state)
+			if(!istates.Find(O.item_state))
+				text += "[O.type] MISSING NORMAL ICON CALLED\n\"[O.item_state]\" IN \"[O.icon]\"\n"
+		text+="\n"
+		qdel(O)
+	if(text)
+		var/F = file("broken_icons.txt")
+		fdel(F)
+		WRITE_FILE(F, text)
+		to_chat(world, "Completely successfully and written to [F]")
+
+

code/modules/admin/verbs/SDQL2/SDQL_2_parser.dm

@@ -0,0 +1,634 @@
+//I'm pretty sure that this is a recursive [s]descent[/s] ascent parser.
+
+
+//Spec
+
+//////////
+//
+//	query				:	select_query | delete_query | update_query | call_query | explain
+//	explain				:	'EXPLAIN' query
+//	select_query		:	'SELECT' object_selectors
+//	delete_query		:	'DELETE' object_selectors
+//	update_query		:	'UPDATE' object_selectors 'SET' assignments
+//	call_query			:	'CALL' variable 'ON' object_selectors // Note here: 'variable' does function calls. This simplifies parsing.
+//
+//	select_item			:	'*' | object_type
+//
+//  object_selectors    :   select_item [('FROM' | 'IN') from_item] [modifier_list]
+//  modifier_list       :   ('WHERE' bool_expression | 'MAP' expression) [modifier_list]
+//
+//	from_item			:	'world' | expression
+//
+//	call_function		:	<function name> '(' [arguments] ')'
+//	arguments			:	expression [',' arguments]
+//
+//	object_type			:	<type path>
+//
+//	assignments			:	assignment [',' assignments]
+//	assignment			:	<variable name> '=' expression
+//	variable			:	<variable name> | <variable name> '.' variable | '[' <hex number> ']' | '[' <hex number> ']' '.' variable
+//
+//	bool_expression		:	expression comparitor expression  [bool_operator bool_expression]
+//	expression			:	( unary_expression | '(' expression ')' | value ) [binary_operator expression]
+//	unary_expression	:	unary_operator ( unary_expression | value | '(' expression ')' )
+//	comparitor			:	'=' | '==' | '!=' | '<>' | '<' | '<=' | '>' | '>='
+//	value				:	variable | string | number | 'null' | object_type
+//	unary_operator		:	'!' | '-' | '~'
+//	binary_operator		:	comparitor | '+' | '-' | '/' | '*' | '&' | '|' | '^' | '%'
+//	bool_operator		:	'AND' | '&&' | 'OR' | '||'
+//
+//	string				:	''' <some text> ''' | '"' <some text > '"'
+//	number				:	<some digits>
+//
+//////////
+
+/datum/SDQL_parser
+	var/query_type
+	var/error = 0
+
+	var/list/query
+	var/list/tree
+
+	var/list/boolean_operators = list("and", "or", "&&", "||")
+	var/list/unary_operators = list("!", "-", "~")
+	var/list/binary_operators = list("+", "-", "/", "*", "&", "|", "^", "%")
+	var/list/comparitors = list("=", "==", "!=", "<>", "<", "<=", ">", ">=")
+
+/datum/SDQL_parser/New(query_list)
+	query = query_list
+
+/datum/SDQL_parser/proc/parse_error(error_message)
+	error = 1
+	to_chat(usr, "<span class='warning'>SQDL2 Parsing Error: [error_message]</span>")
+	return query.len + 1
+
+/datum/SDQL_parser/proc/parse()
+	tree = list()
+	query_options(1, tree)
+
+	if(error)
+		return list()
+	else
+		return tree
+
+/datum/SDQL_parser/proc/token(i)
+	if(i <= query.len)
+		return query[i]
+
+	else
+		return null
+
+/datum/SDQL_parser/proc/tokens(i, num)
+	if(i + num <= query.len)
+		return query.Copy(i, i + num)
+
+	else
+		return null
+
+/datum/SDQL_parser/proc/tokenl(i)
+	return lowertext(token(i))
+
+/datum/SDQL_parser/proc/query_options(i, list/node)
+	var/list/options = list()
+	if(tokenl(i) == "using")
+		i = option_assignments(i + 1, node, options)
+	query(i, node)
+	if(length(options))
+		node["options"] = options
+
+//option_assignment:	query_option '=' define
+/datum/SDQL_parser/proc/option_assignment(i, list/node, list/assignment_list = list())
+	var/type = tokenl(i)
+	if(!(type in SDQL2_VALID_OPTION_TYPES))
+		parse_error("Invalid option type: [type]")
+	if(!(token(i + 1) == "="))
+		parse_error("Invalid option assignment symbol: [token(i + 1)]")
+	var/val = tokenl(i + 2)
+	if(!(val in SDQL2_VALID_OPTION_VALUES))
+		parse_error("Invalid optoin value: [val]")
+	assignment_list[type] = val
+	return (i + 3)
+
+//option_assignments: option_assignment, [',' option_assignments]
+/datum/SDQL_parser/proc/option_assignments(i, list/node, list/store)
+	i = option_assignment(i, node, store)
+
+	if(token(i) == ",")
+		i = option_assignments(i + 1, node, store)
+
+	return i
+
+//query:	select_query | delete_query | update_query
+/datum/SDQL_parser/proc/query(i, list/node)
+	query_type = tokenl(i)
+
+	switch(query_type)
+		if("select")
+			select_query(i, node)
+
+		if("delete")
+			delete_query(i, node)
+
+		if("update")
+			update_query(i, node)
+
+		if("call")
+			call_query(i, node)
+
+		if("explain")
+			node += "explain"
+			node["explain"] = list()
+			query(i + 1, node["explain"])
+
+
+//	select_query:	'SELECT' object_selectors
+/datum/SDQL_parser/proc/select_query(i, list/node)
+	var/list/select = list()
+	i = object_selectors(i + 1, select)
+
+	node["select"] = select
+	return i
+
+
+//delete_query:	'DELETE' object_selectors
+/datum/SDQL_parser/proc/delete_query(i, list/node)
+	var/list/select = list()
+	i = object_selectors(i + 1, select)
+
+	node["delete"] = select
+
+	return i
+
+
+//update_query:	'UPDATE' object_selectors 'SET' assignments
+/datum/SDQL_parser/proc/update_query(i, list/node)
+	var/list/select = list()
+	i = object_selectors(i + 1, select)
+
+	node["update"] = select
+
+	if(tokenl(i) != "set")
+		i = parse_error("UPDATE has misplaced SET")
+
+	var/list/set_assignments = list()
+	i = assignments(i + 1, set_assignments)
+
+	node["set"] = set_assignments
+
+	return i
+
+
+//call_query:	'CALL' call_function ['ON' object_selectors]
+/datum/SDQL_parser/proc/call_query(i, list/node)
+	var/list/func = list()
+	i = variable(i + 1, func) // Yes technically does anything variable() matches but I don't care, if admins fuck up this badly then they shouldn't be allowed near SDQL.
+
+	node["call"] = func
+
+	if(tokenl(i) != "on")
+		return parse_error("You need to specify what to call ON.")
+
+	var/list/select = list()
+	i = object_selectors(i + 1, select)
+
+	node["on"] = select
+
+	return i
+
+// object_selectors: select_item [('FROM' | 'IN') from_item] [modifier_list]
+/datum/SDQL_parser/proc/object_selectors(i, list/node)
+	i = select_item(i, node)
+
+	if (tokenl(i) == "from" || tokenl(i) == "in")
+		i++
+		var/list/from = list()
+		i = from_item(i, from)
+		node[++node.len] = from
+
+	else
+		node[++node.len] = list("world")
+
+	i = modifier_list(i, node)
+	return i
+
+// modifier_list: ('WHERE' bool_expression | 'MAP' expression) [modifier_list]
+/datum/SDQL_parser/proc/modifier_list(i, list/node)
+	while (TRUE)
+		if (tokenl(i) == "where")
+			i++
+			node += "where"
+			var/list/expr = list()
+			i = bool_expression(i, expr)
+			node[++node.len] = expr
+
+		else if (tokenl(i) == "map")
+			i++
+			node += "map"
+			var/list/expr = list()
+			i = expression(i, expr)
+			node[++node.len] = expr
+
+		else
+			return i
+
+//select_list:select_item [',' select_list]
+/datum/SDQL_parser/proc/select_list(i, list/node)
+	i = select_item(i, node)
+
+	if(token(i) == ",")
+		i = select_list(i + 1, node)
+
+	return i
+
+//assignments:	assignment, [',' assignments]
+/datum/SDQL_parser/proc/assignments(i, list/node)
+	i = assignment(i, node)
+
+	if(token(i) == ",")
+		i = assignments(i + 1, node)
+
+	return i
+
+
+//select_item:	'*' | select_function | object_type
+/datum/SDQL_parser/proc/select_item(i, list/node)
+	if (token(i) == "*")
+		node += "*"
+		i++
+
+	else if (copytext(token(i), 1, 2) == "/")
+		i = object_type(i, node)
+
+	else
+		i = parse_error("Expected '*' or type path for select item")
+
+	return i
+
+// Standardized method for handling the IN/FROM and WHERE options.
+/datum/SDQL_parser/proc/selectors(i, list/node)
+	while (token(i))
+		var/tok = tokenl(i)
+		if (tok in list("from", "in"))
+			var/list/from = list()
+			i = from_item(i + 1, from)
+
+			node["from"] = from
+			continue
+
+		if (tok == "where")
+			var/list/where = list()
+			i = bool_expression(i + 1, where)
+
+			node["where"] = where
+			continue
+
+		parse_error("Expected either FROM, IN or WHERE token, found [token(i)] instead.")
+		return i + 1
+
+	if (!node.Find("from"))
+		node["from"] = list("world")
+
+	return i
+
+//from_item:	'world' | expression
+/datum/SDQL_parser/proc/from_item(i, list/node)
+	if(token(i) == "world")
+		node += "world"
+		i++
+
+	else
+		i = expression(i, node)
+
+	return i
+
+
+//bool_expression:	expression [bool_operator bool_expression]
+/datum/SDQL_parser/proc/bool_expression(i, list/node)
+
+	var/list/bool = list()
+	i = expression(i, bool)
+
+	node[++node.len] = bool
+
+	if(tokenl(i) in boolean_operators)
+		i = bool_operator(i, node)
+		i = bool_expression(i, node)
+
+	return i
+
+
+//assignment:	<variable name> '=' expression
+/datum/SDQL_parser/proc/assignment(var/i, var/list/node, var/list/assignment_list = list())
+	assignment_list += token(i)
+
+	if(token(i + 1) == ".")
+		i = assignment(i + 2, node, assignment_list)
+
+	else if(token(i + 1) == "=")
+		var/exp_list = list()
+		node[assignment_list] = exp_list
+
+		i = expression(i + 2, exp_list)
+
+	else
+		parse_error("Assignment expected, but no = found")
+
+	return i
+
+
+//variable:	<variable name> | <variable name> '.' variable | '[' <hex number> ']' | '[' <hex number> ']' '.' variable
+/datum/SDQL_parser/proc/variable(i, list/node)
+	var/list/L = list(token(i))
+	node[++node.len] = L
+
+	if(token(i) == "{")
+		L += token(i + 1)
+		i += 2
+
+		if(token(i) != "}")
+			parse_error("Missing } at end of pointer.")
+
+	if(token(i + 1) == ".")
+		L += "."
+		i = variable(i + 2, L)
+
+	else if (token(i + 1) == "(") // OH BOY PROC
+		var/list/arguments = list()
+		i = call_function(i, null, arguments)
+		L += ":"
+		L[++L.len] = arguments
+
+	else if (token(i + 1) == "\[")
+		var/list/expression = list()
+		i = expression(i + 2, expression)
+		if (token(i) != "]")
+			parse_error("Missing ] at the end of list access.")
+
+		L += "\["
+		L[++L.len] = expression
+		i++
+
+	else
+		i++
+
+	return i
+
+
+//object_type:	<type path>
+/datum/SDQL_parser/proc/object_type(i, list/node)
+
+	if (copytext(token(i), 1, 2) != "/")
+		return parse_error("Expected type, but it didn't begin with /")
+
+	var/path = text2path(token(i))
+	if (path == null)
+		return parse_error("Nonexistant type path: [token(i)]")
+
+	node += path
+
+	return i + 1
+
+
+//comparitor:	'=' | '==' | '!=' | '<>' | '<' | '<=' | '>' | '>='
+/datum/SDQL_parser/proc/comparitor(i, list/node)
+
+	if(token(i) in list("=", "==", "!=", "<>", "<", "<=", ">", ">="))
+		node += token(i)
+
+	else
+		parse_error("Unknown comparitor [token(i)]")
+
+	return i + 1
+
+
+//bool_operator:	'AND' | '&&' | 'OR' | '||'
+/datum/SDQL_parser/proc/bool_operator(i, list/node)
+
+	if(tokenl(i) in list("and", "or", "&&", "||"))
+		node += token(i)
+
+	else
+		parse_error("Unknown comparitor [token(i)]")
+
+	return i + 1
+
+
+//string:	''' <some text> ''' | '"' <some text > '"'
+/datum/SDQL_parser/proc/string(i, list/node)
+
+	if(copytext(token(i), 1, 2) in list("'", "\""))
+		node += token(i)
+
+	else
+		parse_error("Expected string but found '[token(i)]'")
+
+	return i + 1
+
+//array:	'[' expression, expression, ... ']'
+/datum/SDQL_parser/proc/array(var/i, var/list/node)
+	// Arrays get turned into this: list("[", list(exp_1a = exp_1b, ...), ...), "[" is to mark the next node as an array.
+	if(copytext(token(i), 1, 2) != "\[")
+		parse_error("Expected an array but found '[token(i)]'")
+		return i + 1
+
+	node += token(i) // Add the "["
+
+	var/list/expression_list = list()
+
+	i++
+	if(token(i) != "]")
+		var/list/temp_expression_list = list()
+		var/tok
+		do
+			tok = token(i)
+			if (tok == "," || tok == ":")
+				if (temp_expression_list == null)
+					parse_error("Found ',' or ':' without expression in an array.")
+					return i + 1
+
+				expression_list[++expression_list.len] = temp_expression_list
+				temp_expression_list = null
+				if (tok == ":")
+					temp_expression_list = list()
+					i = expression(i + 1, temp_expression_list)
+					expression_list[expression_list[expression_list.len]] = temp_expression_list
+					temp_expression_list = null
+					tok = token(i)
+					if (tok != ",")
+						if (tok == "]")
+							break
+
+						parse_error("Expected ',' or ']' after array assoc value, but found '[token(i)]'")
+						return i
+
+
+				i++
+				continue
+
+			temp_expression_list = list()
+			i = expression(i, temp_expression_list)
+
+			// Ok, what the fuck BYOND?
+			// Not having these lines here causes the parser to die
+			// on an error saying that list/token() doesn't exist as a proc.
+			// These lines prevent that.
+			// I assume the compiler/VM is shitting itself and swapping out some variables internally?
+			// While throwing in debug logging it disappeared
+			// And these 3 lines prevent it from happening while being quiet.
+			// So.. it works.
+			// Don't touch it.
+			var/whatthefuck = i
+			whatthefuck = src.type
+			whatthefuck = whatthefuck
+
+		while(token(i) && token(i) != "]")
+
+		if (temp_expression_list)
+			expression_list[++expression_list.len] = temp_expression_list
+
+	node[++node.len] = expression_list
+
+	return i + 1
+
+//call_function:	<function name> ['(' [arguments] ')']
+/datum/SDQL_parser/proc/call_function(i, list/node, list/arguments)
+	if(length(tokenl(i)))
+		var/procname = ""
+		if(tokenl(i) == "global" && token(i + 1) == ".") // Global proc.
+			i += 2
+			procname = "global."
+		node += procname + token(i++)
+		if(token(i) != "(")
+			parse_error("Expected ( but found '[token(i)]'")
+
+		else if(token(i + 1) != ")")
+			var/list/temp_expression_list = list()
+			do
+				i = expression(i + 1, temp_expression_list)
+				if(token(i) == ",")
+					arguments[++arguments.len] = temp_expression_list
+					temp_expression_list = list()
+					continue
+
+			while(token(i) && token(i) != ")")
+
+			arguments[++arguments.len] = temp_expression_list // The code this is copy pasted from won't be executed when it's the last param, this fixes that.
+		else
+			i++
+	else
+		parse_error("Expected a function but found nothing")
+	return i + 1
+
+
+//expression:	( unary_expression | '(' expression ')' | value ) [binary_operator expression]
+/datum/SDQL_parser/proc/expression(i, list/node)
+
+	if(token(i) in unary_operators)
+		i = unary_expression(i, node)
+
+	else if(token(i) == "(")
+		var/list/expr = list()
+
+		i = expression(i + 1, expr)
+
+		if(token(i) != ")")
+			parse_error("Missing ) at end of expression.")
+
+		else
+			i++
+
+		node[++node.len] = expr
+
+	else
+		i = value(i, node)
+
+	if(token(i) in binary_operators)
+		i = binary_operator(i, node)
+		i = expression(i, node)
+
+	else if(token(i) in comparitors)
+		i = binary_operator(i, node)
+
+		var/list/rhs = list()
+		i = expression(i, rhs)
+
+		node[++node.len] = rhs
+
+
+	return i
+
+
+//unary_expression:	unary_operator ( unary_expression | value | '(' expression ')' )
+/datum/SDQL_parser/proc/unary_expression(i, list/node)
+
+	if(token(i) in unary_operators)
+		var/list/unary_exp = list()
+
+		unary_exp += token(i)
+		i++
+
+		if(token(i) in unary_operators)
+			i = unary_expression(i, unary_exp)
+
+		else if(token(i) == "(")
+			var/list/expr = list()
+
+			i = expression(i + 1, expr)
+
+			if(token(i) != ")")
+				parse_error("Missing ) at end of expression.")
+
+			else
+				i++
+
+			unary_exp[++unary_exp.len] = expr
+
+		else
+			i = value(i, unary_exp)
+
+		node[++node.len] = unary_exp
+
+
+	else
+		parse_error("Expected unary operator but found '[token(i)]'")
+
+	return i
+
+
+//binary_operator:	comparitor | '+' | '-' | '/' | '*' | '&' | '|' | '^' | '%'
+/datum/SDQL_parser/proc/binary_operator(i, list/node)
+
+	if(token(i) in (binary_operators + comparitors))
+		node += token(i)
+
+	else
+		parse_error("Unknown binary operator [token(i)]")
+
+	return i + 1
+
+
+//value:	variable | string | number | 'null' | object_type
+/datum/SDQL_parser/proc/value(i, list/node)
+	if(token(i) == "null")
+		node += "null"
+		i++
+
+	else if(lowertext(copytext(token(i), 1, 3)) == "0x" && isnum(hex2num(copytext(token(i), 3))))
+		node += hex2num(copytext(token(i), 3))
+		i++
+
+	else if(isnum(text2num(token(i))))
+		node += text2num(token(i))
+		i++
+
+	else if(copytext(token(i), 1, 2) in list("'", "\""))
+		i = string(i, node)
+
+	else if(copytext(token(i), 1, 2) == "\[") // Start a list.
+		i = array(i, node)
+	else if(copytext(token(i), 1, 2) == "/")
+		i = object_type(i, node)
+	else
+		i = variable(i, node)
+
+	return i

code/modules/admin/verbs/SDQL2/SDQL_2_wrappers.dm

@@ -0,0 +1,223 @@
+// Wrappers for BYOND default procs which can't directly be called by call().
+
+/proc/_abs(A)
+	return abs(A)
+
+/proc/_animate(atom/A, set_vars, time = 10, loop = 1, easing = LINEAR_EASING, flags = null)
+	var/mutable_appearance/MA = new()
+	for(var/v in set_vars)
+		MA.vars[v] = set_vars[v]
+	animate(A, appearance = MA, time, loop, easing, flags)
+
+/proc/_acrccos(A)
+	return arccos(A)
+
+/proc/_arcsin(A)
+	return arcsin(A)
+
+/proc/_ascii2text(A)
+	return ascii2text(A)
+
+/proc/_block(Start, End)
+	return block(Start, End)
+
+/proc/_ckey(Key)
+	return ckey(Key)
+
+/proc/_ckeyEx(Key)
+	return ckeyEx(Key)
+
+/proc/_copytext(T, Start = 1, End = 0)
+	return copytext(T, Start, End)
+
+/proc/_cos(X)
+	return cos(X)
+
+/proc/_get_dir(Loc1, Loc2)
+	return get_dir(Loc1, Loc2)
+
+/proc/_get_dist(Loc1, Loc2)
+	return get_dist(Loc1, Loc2)
+
+/proc/_get_step(Ref, Dir)
+	return get_step(Ref, Dir)
+
+/proc/_hearers(Depth = world.view, Center = usr)
+	return hearers(Depth, Center)
+
+/proc/_image(icon, loc, icon_state, layer, dir)
+	return image(icon, loc, icon_state, layer, dir)
+
+/proc/_istype(object, type)
+	return istype(object, type)
+
+/proc/_ispath(path, type)
+	return ispath(path, type)
+
+/proc/_length(E)
+	return length(E)
+
+/proc/_link(thing, url)
+	thing << link(url)
+
+/proc/_locate(X, Y, Z)
+	if (isnull(Y)) // Assuming that it's only a single-argument call.
+		return locate(X)
+
+	return locate(X, Y, Z)
+
+/proc/_log(X, Y)
+	return log(X, Y)
+
+/proc/_lowertext(T)
+	return lowertext(T)
+
+/proc/_matrix(a, b, c, d, e, f)
+	return matrix(a, b, c, d, e, f)
+
+/proc/_max(...)
+	return max(arglist(args))
+
+/proc/_md5(T)
+	return md5(T)
+
+/proc/_min(...)
+	return min(arglist(args))
+
+/proc/_new(type, arguments)
+	return new type (arglist(arguments))
+
+/proc/_num2text(N, SigFig = 6)
+	return num2text(N, SigFig)
+
+/proc/_ohearers(Dist, Center = usr)
+	return ohearers(Dist, Center)
+
+/proc/_orange(Dist, Center = usr)
+	return orange(Dist, Center)
+
+/proc/_output(thing, msg, control)
+	thing << output(msg, control)
+
+/proc/_oview(Dist, Center = usr)
+	return oview(Dist, Center)
+
+/proc/_oviewers(Dist, Center = usr)
+	return oviewers(Dist, Center)
+
+/proc/_params2list(Params)
+	return params2list(Params)
+
+/proc/_pick(...)
+	return pick(arglist(args))
+
+/proc/_prob(P)
+	return prob(P)
+
+/proc/_rand(L = 0, H = 1)
+	return rand(L, H)
+
+/proc/_range(Dist, Center = usr)
+	return range(Dist, Center)
+
+/proc/_regex(pattern, flags)
+	return regex(pattern, flags)
+
+/proc/_REGEX_QUOTE(text)
+	return REGEX_QUOTE(text)
+
+/proc/_REGEX_QUOTE_REPLACEMENT(text)
+	return REGEX_QUOTE_REPLACEMENT(text)
+
+/proc/_replacetext(Haystack, Needle, Replacement, Start = 1,End = 0)
+	return replacetext(Haystack, Needle, Replacement, Start, End)
+
+/proc/_replacetextEx(Haystack, Needle, Replacement, Start = 1,End = 0)
+	return replacetextEx(Haystack, Needle, Replacement, Start, End)
+
+/proc/_rgb(R, G, B)
+	return rgb(R, G, B)
+
+/proc/_rgba(R, G, B, A)
+	return rgb(R, G, B, A)
+
+/proc/_roll(dice)
+	return roll(dice)
+
+/proc/_round(A, B = 1)
+	return round(A, B)
+
+/proc/_sin(X)
+	return sin(X)
+
+/proc/_list_add(list/L, ...)
+	if (args.len < 2)
+		return
+	L += args.Copy(2)
+
+/proc/_list_copy(list/L, Start = 1, End = 0)
+	return L.Copy(Start, End)
+
+/proc/_list_cut(list/L, Start = 1, End = 0)
+	L.Cut(Start, End)
+
+/proc/_list_find(list/L, Elem, Start = 1, End = 0)
+	return L.Find(Elem, Start, End)
+
+/proc/_list_insert(list/L, Index, Item)
+	return L.Insert(Index, Item)
+
+/proc/_list_join(list/L, Glue, Start = 0, End = 1)
+	return L.Join(Glue, Start, End)
+
+/proc/_list_remove(list/L, ...)
+	if (args.len < 2)
+		return
+	L -= args.Copy(2)
+
+/proc/_list_set(list/L, key, value)
+	L[key] = value
+
+/proc/_list_numerical_add(L, key, num)
+	L[key] += num
+
+/proc/_list_swap(list/L, Index1, Index2)
+	L.Swap(Index1, Index2)
+
+/proc/_list_get(list/L, index)
+	return L[index]
+
+/proc/_walk(ref, dir, lag)
+	walk(ref, dir, lag)
+
+/proc/_walk_towards(ref, trg, lag)
+	walk_towards(ref, trg, lag)
+
+/proc/_walk_to(ref, trg, min, lag)
+	walk_to(ref, trg, min, lag)
+
+/proc/_walk_away(ref, trg, max, lag)
+	walk_away(ref, trg, max, lag)
+
+/proc/_walk_rand(ref, lag)
+	walk_rand(ref, lag)
+
+/proc/_step(ref, dir)
+	step(ref, dir)
+
+/proc/_step_rand(ref)
+	step_rand(ref)
+
+/proc/_step_to(ref, trg, min)
+	step_to(ref, trg, min)
+
+/proc/_step_towards(ref, trg)
+	step_towards(ref, trg)
+
+/proc/_step_away(ref, trg, max)
+	step_away(ref, trg, max)
+
+/proc/_instantiate_at(thing, location)
+	new thing(location)
+
+

code/modules/admin/verbs/adminhelp.dm

@@ -0,0 +1,698 @@
+/client/var/adminhelptimerid = 0	//a timer id for returning the ahelp verb
+/client/var/datum/admin_help/current_ticket	//the current ticket the (usually) not-admin client is dealing with
+
+//
+//TICKET MANAGER
+//
+
+GLOBAL_DATUM_INIT(ahelp_tickets, /datum/admin_help_tickets, new)
+
+/datum/admin_help_tickets
+	var/list/active_tickets = list()
+	var/list/closed_tickets = list()
+	var/list/resolved_tickets = list()
+
+	var/obj/effect/statclick/ticket_list/astatclick = new(null, null, AHELP_ACTIVE)
+	var/obj/effect/statclick/ticket_list/cstatclick = new(null, null, AHELP_CLOSED)
+	var/obj/effect/statclick/ticket_list/rstatclick = new(null, null, AHELP_RESOLVED)
+
+/datum/admin_help_tickets/Destroy()
+	QDEL_LIST(active_tickets)
+	QDEL_LIST(closed_tickets)
+	QDEL_LIST(resolved_tickets)
+	QDEL_NULL(astatclick)
+	QDEL_NULL(cstatclick)
+	QDEL_NULL(rstatclick)
+	return ..()
+
+/datum/admin_help_tickets/proc/TicketByID(id)
+	var/list/lists = list(active_tickets, closed_tickets, resolved_tickets)
+	for(var/I in lists)
+		for(var/J in I)
+			var/datum/admin_help/AH = J
+			if(AH.id == id)
+				return J
+
+/datum/admin_help_tickets/proc/TicketsByCKey(ckey)
+	. = list()
+	var/list/lists = list(active_tickets, closed_tickets, resolved_tickets)
+	for(var/I in lists)
+		for(var/J in I)
+			var/datum/admin_help/AH = J
+			if(AH.initiator_ckey == ckey)
+				. += AH
+
+//private
+/datum/admin_help_tickets/proc/ListInsert(datum/admin_help/new_ticket)
+	var/list/ticket_list
+	switch(new_ticket.state)
+		if(AHELP_ACTIVE)
+			ticket_list = active_tickets
+		if(AHELP_CLOSED)
+			ticket_list = closed_tickets
+		if(AHELP_RESOLVED)
+			ticket_list = resolved_tickets
+		else
+			CRASH("Invalid ticket state: [new_ticket.state]")
+	var/num_closed = ticket_list.len
+	if(num_closed)
+		for(var/I in 1 to num_closed)
+			var/datum/admin_help/AH = ticket_list[I]
+			if(AH.id > new_ticket.id)
+				ticket_list.Insert(I, new_ticket)
+				return
+	ticket_list += new_ticket
+
+//opens the ticket listings for one of the 3 states
+/datum/admin_help_tickets/proc/BrowseTickets(state)
+	var/list/l2b
+	var/title
+	switch(state)
+		if(AHELP_ACTIVE)
+			l2b = active_tickets
+			title = "Active Tickets"
+		if(AHELP_CLOSED)
+			l2b = closed_tickets
+			title = "Closed Tickets"
+		if(AHELP_RESOLVED)
+			l2b = resolved_tickets
+			title = "Resolved Tickets"
+	if(!l2b)
+		return
+	var/list/dat = list("<html><head><title>[title]</title></head>")
+	dat += "<A href='?_src_=holder;[HrefToken()];ahelp_tickets=[state]'>Refresh</A><br><br>"
+	for(var/I in l2b)
+		var/datum/admin_help/AH = I
+		dat += "<span class='adminnotice'><span class='adminhelp'>Ticket #[AH.id]</span>: <A href='?_src_=holder;[HrefToken()];ahelp=[REF(AH)];ahelp_action=ticket'>[AH.initiator_key_name]: [AH.name]</A></span><br>"
+
+	usr << browse(dat.Join(), "window=ahelp_list[state];size=600x480")
+
+//Tickets statpanel
+/datum/admin_help_tickets/proc/stat_entry()
+	var/num_disconnected = 0
+	stat("Active Tickets:", astatclick.update("[active_tickets.len]"))
+	for(var/I in active_tickets)
+		var/datum/admin_help/AH = I
+		if(AH.initiator)
+			stat("#[AH.id]. [AH.initiator_key_name]:", AH.statclick.update())
+		else
+			++num_disconnected
+	if(num_disconnected)
+		stat("Disconnected:", astatclick.update("[num_disconnected]"))
+	stat("Closed Tickets:", cstatclick.update("[closed_tickets.len]"))
+	stat("Resolved Tickets:", rstatclick.update("[resolved_tickets.len]"))
+
+//Reassociate still open ticket if one exists
+/datum/admin_help_tickets/proc/ClientLogin(client/C)
+	C.current_ticket = CKey2ActiveTicket(C.ckey)
+	if(C.current_ticket)
+		C.current_ticket.initiator = C
+		C.current_ticket.AddInteraction("Client reconnected.")
+
+//Dissasociate ticket
+/datum/admin_help_tickets/proc/ClientLogout(client/C)
+	if(C.current_ticket)
+		C.current_ticket.AddInteraction("Client disconnected.")
+		C.current_ticket.initiator = null
+		C.current_ticket = null
+
+//Get a ticket given a ckey
+/datum/admin_help_tickets/proc/CKey2ActiveTicket(ckey)
+	for(var/I in active_tickets)
+		var/datum/admin_help/AH = I
+		if(AH.initiator_ckey == ckey)
+			return AH
+
+//
+//TICKET LIST STATCLICK
+//
+
+/obj/effect/statclick/ticket_list
+	var/current_state
+
+/obj/effect/statclick/ticket_list/New(loc, name, state)
+	current_state = state
+	..()
+
+/obj/effect/statclick/ticket_list/Click()
+	GLOB.ahelp_tickets.BrowseTickets(current_state)
+
+//
+//TICKET DATUM
+//
+
+/datum/admin_help
+	var/id
+	var/name
+	var/state = AHELP_ACTIVE
+
+	var/opened_at
+	var/closed_at
+
+	var/client/initiator	//semi-misnomer, it's the person who ahelped/was bwoinked
+	var/initiator_ckey
+	var/initiator_key_name
+	var/heard_by_no_admins = FALSE
+
+	var/list/_interactions	//use AddInteraction() or, preferably, admin_ticket_log()
+
+	var/obj/effect/statclick/ahelp/statclick
+
+	var/static/ticket_counter = 0
+
+//call this on its own to create a ticket, don't manually assign current_ticket
+//msg is the title of the ticket: usually the ahelp text
+//is_bwoink is TRUE if this ticket was started by an admin PM
+/datum/admin_help/New(msg, client/C, is_bwoink)
+	//clean the input msg
+	msg = sanitize(copytext(msg,1,MAX_MESSAGE_LEN))
+	if(!msg || !C || !C.mob)
+		qdel(src)
+		return
+
+	id = ++ticket_counter
+	opened_at = world.time
+
+	name = msg
+
+	initiator = C
+	initiator_ckey = initiator.ckey
+	initiator_key_name = key_name(initiator, FALSE, TRUE)
+	if(initiator.current_ticket)	//This is a bug
+		stack_trace("Multiple ahelp current_tickets")
+		initiator.current_ticket.AddInteraction("Ticket erroneously left open by code")
+		initiator.current_ticket.Close()
+	initiator.current_ticket = src
+
+	TimeoutVerb()
+
+	statclick = new(null, src)
+	_interactions = list()
+
+	if(is_bwoink)
+		AddInteraction("<font color='blue'>[key_name_admin(usr)] PM'd [LinkedReplyName()]</font>")
+		message_admins("<font color='blue'>Ticket [TicketHref("#[id]")] created</font>")
+	else
+		MessageNoRecipient(msg)
+
+		//send it to irc if nobody is on and tell us how many were on
+		var/admin_number_present = send2irc_adminless_only(initiator_ckey, "Ticket #[id]: [name]")
+		log_admin_private("Ticket #[id]: [key_name(initiator)]: [name] - heard by [admin_number_present] non-AFK admins who have +BAN.")
+		if(admin_number_present <= 0)
+			to_chat(C, "<span class='notice'>No active admins are online, your adminhelp was sent to the admin irc.</span>")
+			heard_by_no_admins = TRUE
+
+	GLOB.ahelp_tickets.active_tickets += src
+
+/datum/admin_help/Destroy()
+	RemoveActive()
+	GLOB.ahelp_tickets.closed_tickets -= src
+	GLOB.ahelp_tickets.resolved_tickets -= src
+	return ..()
+
+/datum/admin_help/proc/AddInteraction(formatted_message)
+	if(heard_by_no_admins && usr && usr.ckey != initiator_ckey)
+		heard_by_no_admins = FALSE
+		send2irc(initiator_ckey, "Ticket #[id]: Answered by [key_name(usr)]")
+	_interactions += "[TIME_STAMP("hh:mm:ss", FALSE)]: [formatted_message]"
+
+//Removes the ahelp verb and returns it after 2 minutes
+/datum/admin_help/proc/TimeoutVerb()
+	initiator.verbs -= /client/verb/adminhelp
+	initiator.adminhelptimerid = addtimer(CALLBACK(initiator, /client/proc/giveadminhelpverb), 1200, TIMER_STOPPABLE) //2 minute cooldown of admin helps
+
+//private
+/datum/admin_help/proc/FullMonty(ref_src)
+	if(!ref_src)
+		ref_src = "[REF(src)]"
+	. = ADMIN_FULLMONTY_NONAME(initiator.mob)
+	if(state == AHELP_ACTIVE)
+		. += ClosureLinks(ref_src)
+
+//private
+/datum/admin_help/proc/ClosureLinks(ref_src)
+	if(!ref_src)
+		ref_src = "[REF(src)]"
+	. = " (<A HREF='?_src_=holder;[HrefToken(TRUE)];ahelp=[ref_src];ahelp_action=reject'>REJT</A>)"
+	. += " (<A HREF='?_src_=holder;[HrefToken(TRUE)];ahelp=[ref_src];ahelp_action=icissue'>IC</A>)"
+	. += " (<A HREF='?_src_=holder;[HrefToken(TRUE)];ahelp=[ref_src];ahelp_action=close'>CLOSE</A>)"
+	. += " (<A HREF='?_src_=holder;[HrefToken(TRUE)];ahelp=[ref_src];ahelp_action=resolve'>RSLVE</A>)"
+	. += " (<A HREF='?_src_=holder;[HrefToken(TRUE)];ahelp=[ref_src];ahelp_action=handleissue'>HANDLE</A>)"
+
+//private
+/datum/admin_help/proc/LinkedReplyName(ref_src)
+	if(!ref_src)
+		ref_src = "[REF(src)]"
+	return "<A HREF='?_src_=holder;[HrefToken(TRUE)];ahelp=[ref_src];ahelp_action=reply'>[initiator_key_name]</A>"
+
+//private
+/datum/admin_help/proc/TicketHref(msg, ref_src, action = "ticket")
+	if(!ref_src)
+		ref_src = "[REF(src)]"
+	return "<A HREF='?_src_=holder;[HrefToken(TRUE)];ahelp=[ref_src];ahelp_action=[action]'>[msg]</A>"
+
+//message from the initiator without a target, all admins will see this
+//won't bug irc
+/datum/admin_help/proc/MessageNoRecipient(msg)
+	var/ref_src = "[REF(src)]"
+	//Message to be sent to all admins
+	var/admin_msg = "<span class='adminnotice'><span class='adminhelp'>Ticket [TicketHref("#[id]", ref_src)]</span><b>: [LinkedReplyName(ref_src)] [FullMonty(ref_src)]:</b> <span class='linkify'>[keywords_lookup(msg)]</span></span>"
+
+	AddInteraction("<font color='red'>[LinkedReplyName(ref_src)]: [msg]</font>")
+
+	//send this msg to all admins
+	for(var/client/X in GLOB.admins)
+		if(X.prefs.toggles & SOUND_ADMINHELP)
+			SEND_SOUND(X, sound('sound/effects/adminhelp.ogg'))
+		window_flash(X, ignorepref = TRUE)
+		to_chat(X, admin_msg)
+
+	//show it to the person adminhelping too
+	to_chat(initiator, "<span class='adminnotice'>PM to-<b>Admins</b>: <span class='linkify'>[msg]</span></span>")
+
+//Reopen a closed ticket
+/datum/admin_help/proc/Reopen()
+	if(state == AHELP_ACTIVE)
+		to_chat(usr, "<span class='warning'>This ticket is already open.</span>")
+		return
+
+	if(GLOB.ahelp_tickets.CKey2ActiveTicket(initiator_ckey))
+		to_chat(usr, "<span class='warning'>This user already has an active ticket, cannot reopen this one.</span>")
+		return
+
+	statclick = new(null, src)
+	GLOB.ahelp_tickets.active_tickets += src
+	GLOB.ahelp_tickets.closed_tickets -= src
+	GLOB.ahelp_tickets.resolved_tickets -= src
+	switch(state)
+		if(AHELP_CLOSED)
+			SSblackbox.record_feedback("tally", "ahelp_stats", -1, "closed")
+		if(AHELP_RESOLVED)
+			SSblackbox.record_feedback("tally", "ahelp_stats", -1, "resolved")
+	state = AHELP_ACTIVE
+	closed_at = null
+	if(initiator)
+		initiator.current_ticket = src
+
+	AddInteraction("<font color='purple'>Reopened by [key_name_admin(usr)]</font>")
+	var/msg = "<span class='adminhelp'>Ticket [TicketHref("#[id]")] reopened by [key_name_admin(usr)].</span>"
+	message_admins(msg)
+	log_admin_private(msg)
+	SSblackbox.record_feedback("tally", "ahelp_stats", 1, "reopened")
+	TicketPanel()	//can only be done from here, so refresh it
+
+//private
+/datum/admin_help/proc/RemoveActive()
+	if(state != AHELP_ACTIVE)
+		return
+	closed_at = world.time
+	QDEL_NULL(statclick)
+	GLOB.ahelp_tickets.active_tickets -= src
+	if(initiator && initiator.current_ticket == src)
+		initiator.current_ticket = null
+
+//Mark open ticket as closed/meme
+/datum/admin_help/proc/Close(key_name = key_name_admin(usr), silent = FALSE)
+	if(state != AHELP_ACTIVE)
+		return
+	RemoveActive()
+	state = AHELP_CLOSED
+	GLOB.ahelp_tickets.ListInsert(src)
+	AddInteraction("<font color='red'>Closed by [key_name].</font>")
+	if(!silent)
+		SSblackbox.record_feedback("tally", "ahelp_stats", 1, "closed")
+		var/msg = "Ticket [TicketHref("#[id]")] closed by [key_name]."
+		message_admins(msg)
+		log_admin_private(msg)
+
+//Mark open ticket as resolved/legitimate, returns ahelp verb
+/datum/admin_help/proc/Resolve(key_name = key_name_admin(usr), silent = FALSE)
+	if(state != AHELP_ACTIVE)
+		return
+	RemoveActive()
+	state = AHELP_RESOLVED
+	GLOB.ahelp_tickets.ListInsert(src)
+
+	addtimer(CALLBACK(initiator, /client/proc/giveadminhelpverb), 50)
+
+	AddInteraction("<font color='green'>Resolved by [key_name].</font>")
+	to_chat(initiator, "<span class='adminhelp'>Your ticket has been resolved by an admin. The Adminhelp verb will be returned to you shortly.</span>")
+	if(!silent)
+		SSblackbox.record_feedback("tally", "ahelp_stats", 1, "resolved")
+		var/msg = "Ticket [TicketHref("#[id]")] resolved by [key_name]"
+		message_admins(msg)
+		log_admin_private(msg)
+
+//Close and return ahelp verb, use if ticket is incoherent
+/datum/admin_help/proc/Reject(key_name = key_name_admin(usr))
+	if(state != AHELP_ACTIVE)
+		return
+
+	if(initiator)
+		initiator.giveadminhelpverb()
+
+		SEND_SOUND(initiator, sound('sound/effects/adminhelp.ogg'))
+
+		to_chat(initiator, "<font color='red' size='4'><b>- AdminHelp Rejected! -</b></font>")
+		to_chat(initiator, "<font color='red'><b>Your admin help was rejected.</b> The adminhelp verb has been returned to you so that you may try again.</font>")
+		to_chat(initiator, "Please try to be calm, clear, and descriptive in admin helps, do not assume the admin has seen any related events, and clearly state the names of anybody you are reporting.")
+
+	SSblackbox.record_feedback("tally", "ahelp_stats", 1, "rejected")
+	var/msg = "Ticket [TicketHref("#[id]")] rejected by [key_name]"
+	message_admins(msg)
+	log_admin_private(msg)
+	AddInteraction("Rejected by [key_name].")
+	Close(silent = TRUE)
+
+//Resolve ticket with IC Issue message
+/datum/admin_help/proc/ICIssue(key_name = key_name_admin(usr))
+	if(state != AHELP_ACTIVE)
+		return
+
+	var/msg = "<font color='red' size='4'><b>- AdminHelp marked as IC issue! -</b></font><br>"
+	msg += "<font color='red'><b>Losing is part of the game!</b></font><br>"
+	msg += "<font color='red'>It is also possible that your ahelp is unable to be answered properly, due to events occurring in the round.</font>"
+	if(initiator)
+		to_chat(initiator, msg)
+
+	SSblackbox.record_feedback("tally", "ahelp_stats", 1, "IC")
+	msg = "Ticket [TicketHref("#[id]")] marked as IC by [key_name]"
+	message_admins(msg)
+	log_admin_private(msg)
+	AddInteraction("Marked as IC issue by [key_name]")
+	Resolve(silent = TRUE)
+
+//Let the initiator know their ahelp is being handled
+/datum/admin_help/proc/HandleIssue(key_name = key_name_admin(usr))
+	if(state != AHELP_ACTIVE)
+		return
+
+	var/msg = "<span class ='adminhelp'>Your ticket is now being handled by an admin. Please be patient.</span>"
+
+	if(initiator)
+		to_chat(initiator, msg)
+
+	SSblackbox.record_feedback("tally", "ahelp_stats", 1, "handling")
+	msg = "Ticket [TicketHref("#[id]")] is being handled by [key_name]"
+	message_admins(msg)
+	log_admin_private(msg)
+	AddInteraction("Being handled by [key_name]")
+
+//Show the ticket panel
+/datum/admin_help/proc/TicketPanel()
+	var/list/dat = list("<html><head><title>Ticket #[id]</title></head>")
+	var/ref_src = "[REF(src)]"
+	dat += "<h4>Admin Help Ticket #[id]: [LinkedReplyName(ref_src)]</h4>"
+	dat += "<b>State: "
+	switch(state)
+		if(AHELP_ACTIVE)
+			dat += "<font color='red'>OPEN</font>"
+		if(AHELP_RESOLVED)
+			dat += "<font color='green'>RESOLVED</font>"
+		if(AHELP_CLOSED)
+			dat += "CLOSED"
+		else
+			dat += "UNKNOWN"
+	dat += "</b>[GLOB.TAB][TicketHref("Refresh", ref_src)][GLOB.TAB][TicketHref("Re-Title", ref_src, "retitle")]"
+	if(state != AHELP_ACTIVE)
+		dat += "[GLOB.TAB][TicketHref("Reopen", ref_src, "reopen")]"
+	dat += "<br><br>Opened at: [GAMETIMESTAMP("hh:mm:ss", closed_at)] (Approx [DisplayTimeText(world.time - opened_at)] ago)"
+	if(closed_at)
+		dat += "<br>Closed at: [GAMETIMESTAMP("hh:mm:ss", closed_at)] (Approx [DisplayTimeText(world.time - closed_at)] ago)"
+	dat += "<br><br>"
+	if(initiator)
+		dat += "<b>Actions:</b> [FullMonty(ref_src)]<br>"
+	else
+		dat += "<b>DISCONNECTED</b>[GLOB.TAB][ClosureLinks(ref_src)]<br>"
+	dat += "<br><b>Log:</b><br><br>"
+	for(var/I in _interactions)
+		dat += "[I]<br>"
+
+	usr << browse(dat.Join(), "window=ahelp[id];size=620x480")
+
+/datum/admin_help/proc/Retitle()
+	var/new_title = input(usr, "Enter a title for the ticket", "Rename Ticket", name) as text|null
+	if(new_title)
+		name = new_title
+		//not saying the original name cause it could be a long ass message
+		var/msg = "Ticket [TicketHref("#[id]")] titled [name] by [key_name_admin(usr)]"
+		message_admins(msg)
+		log_admin_private(msg)
+	TicketPanel()	//we have to be here to do this
+
+//Forwarded action from admin/Topic
+/datum/admin_help/proc/Action(action)
+	testing("Ahelp action: [action]")
+	switch(action)
+		if("ticket")
+			TicketPanel()
+		if("retitle")
+			Retitle()
+		if("reject")
+			Reject()
+		if("reply")
+			usr.client.cmd_ahelp_reply(initiator)
+		if("icissue")
+			ICIssue()
+		if("close")
+			Close()
+		if("resolve")
+			Resolve()
+		if("handleissue")
+			HandleIssue()
+		if("reopen")
+			Reopen()
+
+//
+// TICKET STATCLICK
+//
+
+/obj/effect/statclick/ahelp
+	var/datum/admin_help/ahelp_datum
+
+/obj/effect/statclick/ahelp/Initialize(mapload, datum/admin_help/AH)
+	ahelp_datum = AH
+	. = ..()
+
+/obj/effect/statclick/ahelp/update()
+	return ..(ahelp_datum.name)
+
+/obj/effect/statclick/ahelp/Click()
+	ahelp_datum.TicketPanel()
+
+/obj/effect/statclick/ahelp/Destroy()
+	ahelp_datum = null
+	return ..()
+
+//
+// CLIENT PROCS
+//
+
+/client/proc/giveadminhelpverb()
+	src.verbs |= /client/verb/adminhelp
+	deltimer(adminhelptimerid)
+	adminhelptimerid = 0
+
+// Used for methods where input via arg doesn't work
+/client/proc/get_adminhelp()
+	var/msg = input(src, "Please describe your problem concisely and an admin will help as soon as they're able.", "Adminhelp contents") as text
+	adminhelp(msg)
+
+/client/verb/adminhelp(msg as text)
+	set category = "Admin"
+	set name = "Adminhelp"
+
+	if(GLOB.say_disabled)	//This is here to try to identify lag problems
+		to_chat(usr, "<span class='danger'>Speech is currently admin-disabled.</span>")
+		return
+
+	//handle muting and automuting
+	if(prefs.muted & MUTE_ADMINHELP)
+		to_chat(src, "<span class='danger'>Error: Admin-PM: You cannot send adminhelps (Muted).</span>")
+		return
+	if(handle_spam_prevention(msg,MUTE_ADMINHELP))
+		return
+
+	msg = trim(msg)
+
+	if(!msg)
+		return
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Adminhelp") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+	if(current_ticket)
+		if(alert(usr, "You already have a ticket open. Is this for the same issue?",,"Yes","No") != "No")
+			if(current_ticket)
+				current_ticket.MessageNoRecipient(msg)
+				current_ticket.TimeoutVerb()
+				return
+			else
+				to_chat(usr, "<span class='warning'>Ticket not found, creating new one...</span>")
+		else
+			current_ticket.AddInteraction("[key_name_admin(usr)] opened a new ticket.")
+			current_ticket.Close()
+
+	new /datum/admin_help(msg, src, FALSE)
+
+//
+// LOGGING
+//
+
+//Use this proc when an admin takes action that may be related to an open ticket on what
+//what can be a client, ckey, or mob
+/proc/admin_ticket_log(what, message)
+	var/client/C
+	var/mob/Mob = what
+	if(istype(Mob))
+		C = Mob.client
+	else
+		C = what
+	if(istype(C) && C.current_ticket)
+		C.current_ticket.AddInteraction(message)
+		return C.current_ticket
+	if(istext(what))	//ckey
+		var/datum/admin_help/AH = GLOB.ahelp_tickets.CKey2ActiveTicket(what)
+		if(AH)
+			AH.AddInteraction(message)
+			return AH
+
+//
+// HELPER PROCS
+//
+
+/proc/get_admin_counts(requiredflags = R_BAN)
+	. = list("total" = list(), "noflags" = list(), "afk" = list(), "stealth" = list(), "present" = list())
+	for(var/client/X in GLOB.admins)
+		.["total"] += X
+		if(requiredflags != 0 && !check_rights_for(X, requiredflags))
+			.["noflags"] += X
+		else if(X.is_afk())
+			.["afk"] += X
+		else if(X.holder.fakekey)
+			.["stealth"] += X
+		else
+			.["present"] += X
+
+/proc/send2irc_adminless_only(source, msg, requiredflags = R_BAN)
+	var/list/adm = get_admin_counts(requiredflags)
+	var/list/activemins = adm["present"]
+	. = activemins.len
+	if(. <= 0)
+		var/final = ""
+		var/list/afkmins = adm["afk"]
+		var/list/stealthmins = adm["stealth"]
+		var/list/powerlessmins = adm["noflags"]
+		var/list/allmins = adm["total"]
+		if(!afkmins.len && !stealthmins.len && !powerlessmins.len)
+			final = "[msg] - No admins online"
+		else
+			final = "[msg] - All admins stealthed\[[english_list(stealthmins)]\], AFK\[[english_list(afkmins)]\], or lacks +BAN\[[english_list(powerlessmins)]\]! Total: [allmins.len] "
+		send2irc(source,final)
+		send2otherserver(source,final)
+
+
+/proc/send2irc(msg,msg2)
+	msg = replacetext(replacetext(msg, "\proper", ""), "\improper", "")
+	msg2 = replacetext(replacetext(msg2, "\proper", ""), "\improper", "")
+	world.TgsTargetedChatBroadcast("[msg] | [msg2]", TRUE)
+
+/proc/send2otherserver(source,msg,type = "Ahelp")
+	var/comms_key = CONFIG_GET(string/comms_key)
+	if(!comms_key)
+		return
+	var/list/message = list()
+	message["message_sender"] = source
+	message["message"] = msg
+	message["source"] = "([CONFIG_GET(string/cross_comms_name)])"
+	message["key"] = comms_key
+	message += type
+
+	var/list/servers = CONFIG_GET(keyed_list/cross_server)
+	for(var/I in servers)
+		world.Export("[servers[I]]?[list2params(message)]")
+
+
+/proc/ircadminwho()
+	var/list/message = list("Admins: ")
+	var/list/admin_keys = list()
+	for(var/adm in GLOB.admins)
+		var/client/C = adm
+		admin_keys += "[C][C.holder.fakekey ? "(Stealth)" : ""][C.is_afk() ? "(AFK)" : ""]"
+
+	for(var/admin in admin_keys)
+		if(LAZYLEN(message) > 1)
+			message += ", [admin]"
+		else
+			message += "[admin]"
+
+	return jointext(message, "")
+
+/proc/keywords_lookup(msg,irc)
+
+	//This is a list of words which are ignored by the parser when comparing message contents for names. MUST BE IN LOWER CASE!
+	var/list/adminhelp_ignored_words = list("unknown","the","a","an","of","monkey","alien","as", "i")
+
+	//explode the input msg into a list
+	var/list/msglist = splittext(msg, " ")
+
+	//generate keywords lookup
+	var/list/surnames = list()
+	var/list/forenames = list()
+	var/list/ckeys = list()
+	var/founds = ""
+	for(var/mob/M in GLOB.mob_list)
+		var/list/indexing = list(M.real_name, M.name)
+		if(M.mind)
+			indexing += M.mind.name
+
+		for(var/string in indexing)
+			var/list/L = splittext(string, " ")
+			var/surname_found = 0
+			//surnames
+			for(var/i=L.len, i>=1, i--)
+				var/word = ckey(L[i])
+				if(word)
+					surnames[word] = M
+					surname_found = i
+					break
+			//forenames
+			for(var/i=1, i<surname_found, i++)
+				var/word = ckey(L[i])
+				if(word)
+					forenames[word] = M
+			//ckeys
+			ckeys[M.ckey] = M
+
+	var/ai_found = 0
+	msg = ""
+	var/list/mobs_found = list()
+	for(var/original_word in msglist)
+		var/word = ckey(original_word)
+		if(word)
+			if(!(word in adminhelp_ignored_words))
+				if(word == "ai")
+					ai_found = 1
+				else
+					var/mob/found = ckeys[word]
+					if(!found)
+						found = surnames[word]
+						if(!found)
+							found = forenames[word]
+					if(found)
+						if(!(found in mobs_found))
+							mobs_found += found
+							if(!ai_found && isAI(found))
+								ai_found = 1
+							var/is_antag = 0
+							if(found.mind && found.mind.special_role)
+								is_antag = 1
+							founds += "Name: [found.name]([found.real_name]) Key: [found.key] Ckey: [found.ckey] [is_antag ? "(Antag)" : null] "
+							msg += "[original_word]<font size='1' color='[is_antag ? "red" : "black"]'>(<A HREF='?_src_=holder;[HrefToken(TRUE)];adminmoreinfo=[REF(found)]'>?</A>|<A HREF='?_src_=holder;[HrefToken(TRUE)];adminplayerobservefollow=[REF(found)]'>F</A>)</font> "
+							continue
+		msg += "[original_word] "
+	if(irc)
+		if(founds == "")
+			return "Search Failed"
+		else
+			return founds
+
+	return msg

code/modules/admin/verbs/adminjump.dm

@@ -0,0 +1,157 @@
+/client/proc/jumptoarea(area/A in GLOB.sortedAreas)
+	set name = "Jump to Area"
+	set desc = "Area to jump to"
+	set category = "Admin"
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+
+	if(!A)
+		return
+
+	var/list/turfs = list()
+	for(var/turf/T in A)
+		if(T.density)
+			continue
+		turfs.Add(T)
+
+	var/turf/T = safepick(turfs)
+	if(!T)
+		to_chat(src, "Nowhere to jump to!")
+		return
+	usr.forceMove(T)
+	log_admin("[key_name(usr)] jumped to [AREACOORD(A)]")
+	message_admins("[key_name_admin(usr)] jumped to [AREACOORD(A)]")
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Jump To Area") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/jumptoturf(turf/T in world)
+	set name = "Jump to Turf"
+	set category = "Admin"
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+
+	log_admin("[key_name(usr)] jumped to [AREACOORD(T)]")
+	message_admins("[key_name_admin(usr)] jumped to [AREACOORD(T)]")
+	usr.forceMove(T)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Jump To Turf") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+	return
+
+/client/proc/jumptomob(mob/M in GLOB.mob_list)
+	set category = "Admin"
+	set name = "Jump to Mob"
+
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+
+	log_admin("[key_name(usr)] jumped to [key_name(M)]")
+	message_admins("[key_name_admin(usr)] jumped to [ADMIN_LOOKUPFLW(M)] at [AREACOORD(M)]")
+	if(src.mob)
+		var/mob/A = src.mob
+		var/turf/T = get_turf(M)
+		if(T && isturf(T))
+			SSblackbox.record_feedback("tally", "admin_verb", 1, "Jump To Mob") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+			A.forceMove(M.loc)
+		else
+			to_chat(A, "This mob is not located in the game world.")
+
+/client/proc/jumptocoord(tx as num, ty as num, tz as num)
+	set category = "Admin"
+	set name = "Jump to Coordinate"
+
+	if (!holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+
+	if(src.mob)
+		var/mob/A = src.mob
+		var/turf/T = locate(tx,ty,tz)
+		A.forceMove(T)
+		SSblackbox.record_feedback("tally", "admin_verb", 1, "Jump To Coordiate") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+	message_admins("[key_name_admin(usr)] jumped to coordinates [tx], [ty], [tz]")
+
+/client/proc/jumptokey()
+	set category = "Admin"
+	set name = "Jump to Key"
+
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+
+	var/list/keys = list()
+	for(var/mob/M in GLOB.player_list)
+		keys += M.client
+	var/client/selection = input("Please, select a player!", "Admin Jumping", null, null) as null|anything in sortKey(keys)
+	if(!selection)
+		to_chat(src, "No keys found.")
+		return
+	var/mob/M = selection.mob
+	log_admin("[key_name(usr)] jumped to [key_name(M)]")
+	message_admins("[key_name_admin(usr)] jumped to [ADMIN_LOOKUPFLW(M)]")
+
+	usr.forceMove(M.loc)
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Jump To Key") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/Getmob(mob/M in GLOB.mob_list - GLOB.dummy_mob_list)
+	set category = "Admin"
+	set name = "Get Mob"
+	set desc = "Mob to teleport"
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+
+	var/atom/loc = get_turf(usr)
+	log_admin("[key_name(usr)] teleported [key_name(M)] to [AREACOORD(loc)]")
+	var/msg = "[key_name_admin(usr)] teleported [ADMIN_LOOKUPFLW(M)] to [ADMIN_VERBOSEJMP(loc)]"
+	message_admins(msg)
+	admin_ticket_log(M, msg)
+	M.forceMove(loc)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Get Mob") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/Getkey()
+	set category = "Admin"
+	set name = "Get Key"
+	set desc = "Key to teleport"
+
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+
+	var/list/keys = list()
+	for(var/mob/M in GLOB.player_list)
+		keys += M.client
+	var/client/selection = input("Please, select a player!", "Admin Jumping", null, null) as null|anything in sortKey(keys)
+	if(!selection)
+		return
+	var/mob/M = selection.mob
+
+	if(!M)
+		return
+	log_admin("[key_name(usr)] teleported [key_name(M)]")
+	var/msg = "[key_name_admin(usr)] teleported [ADMIN_LOOKUPFLW(M)]"
+	message_admins(msg)
+	admin_ticket_log(M, msg)
+	if(M)
+		M.forceMove(get_turf(usr))
+		usr.forceMove(M.loc)
+		SSblackbox.record_feedback("tally", "admin_verb", 1, "Get Key") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/sendmob(mob/M in sortmobs())
+	set category = "Admin"
+	set name = "Send Mob"
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+	var/area/A = input(usr, "Pick an area.", "Pick an area") in GLOB.sortedAreas|null
+	if(A && istype(A))
+		if(M.forceMove(safepick(get_area_turfs(A))))
+
+			log_admin("[key_name(usr)] teleported [key_name(M)] to [AREACOORD(A)]")
+			var/msg = "[key_name_admin(usr)] teleported [ADMIN_LOOKUPFLW(M)] to [AREACOORD(A)]"
+			message_admins(msg)
+			admin_ticket_log(M, msg)
+		else
+			to_chat(src, "Failed to move mob to a valid location.")
+		SSblackbox.record_feedback("tally", "admin_verb", 1, "Send Mob") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!

code/modules/admin/verbs/adminpm.dm

@@ -0,0 +1,325 @@
+#define IRCREPLYCOUNT 2
+
+
+//allows right clicking mobs to send an admin PM to their client, forwards the selected mob's client to cmd_admin_pm
+/client/proc/cmd_admin_pm_context(mob/M in GLOB.mob_list)
+	set category = null
+	set name = "Admin PM Mob"
+	if(!holder)
+		to_chat(src, "<span class='danger'>Error: Admin-PM-Context: Only administrators may use this command.</span>")
+		return
+	if( !ismob(M) || !M.client )
+		return
+	cmd_admin_pm(M.client,null)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Admin PM Mob") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+//shows a list of clients we could send PMs to, then forwards our choice to cmd_admin_pm
+/client/proc/cmd_admin_pm_panel()
+	set category = "Admin"
+	set name = "Admin PM"
+	if(!holder)
+		to_chat(src, "<span class='danger'>Error: Admin-PM-Panel: Only administrators may use this command.</span>")
+		return
+	var/list/client/targets[0]
+	for(var/client/T)
+		if(T.mob)
+			if(isnewplayer(T.mob))
+				targets["(New Player) - [T]"] = T
+			else if(isobserver(T.mob))
+				targets["[T.mob.name](Ghost) - [T]"] = T
+			else
+				targets["[T.mob.real_name](as [T.mob.name]) - [T]"] = T
+		else
+			targets["(No Mob) - [T]"] = T
+	var/target = input(src,"To whom shall we send a message?","Admin PM",null) as null|anything in sortList(targets)
+	cmd_admin_pm(targets[target],null)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Admin PM") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/cmd_ahelp_reply(whom)
+	if(prefs.muted & MUTE_ADMINHELP)
+		to_chat(src, "<span class='danger'>Error: Admin-PM: You are unable to use admin PM-s (muted).</span>")
+		return
+	var/client/C
+	if(istext(whom))
+		if(cmptext(copytext(whom,1,2),"@"))
+			whom = findStealthKey(whom)
+		C = GLOB.directory[whom]
+	else if(istype(whom, /client))
+		C = whom
+	if(!C)
+		if(holder)
+			to_chat(src, "<span class='danger'>Error: Admin-PM: Client not found.</span>")
+		return
+
+	var/datum/admin_help/AH = C.current_ticket
+
+	if(AH)
+		message_admins("[key_name_admin(src)] has started replying to [key_name(C, 0, 0)]'s admin help.")
+	var/msg = input(src,"Message:", "Private message to [key_name(C, 0, 0)]") as message|null
+	if (!msg)
+		message_admins("[key_name_admin(src)] has cancelled their reply to [key_name(C, 0, 0)]'s admin help.")
+		return
+	cmd_admin_pm(whom, msg)
+
+//takes input from cmd_admin_pm_context, cmd_admin_pm_panel or /client/Topic and sends them a PM.
+//Fetching a message if needed. src is the sender and C is the target client
+/client/proc/cmd_admin_pm(whom, msg)
+	if(prefs.muted & MUTE_ADMINHELP)
+		to_chat(src, "<span class='danger'>Error: Admin-PM: You are unable to use admin PM-s (muted).</span>")
+		return
+
+	if(!holder && !current_ticket)	//no ticket? https://www.youtube.com/watch?v=iHSPf6x1Fdo
+		to_chat(src, "<span class='danger'>You can no longer reply to this ticket, please open another one by using the Adminhelp verb if need be.</span>")
+		to_chat(src, "<span class='notice'>Message: [msg]</span>")
+		return
+
+	var/client/recipient
+	var/irc = 0
+	if(istext(whom))
+		if(cmptext(copytext(whom,1,2),"@"))
+			whom = findStealthKey(whom)
+		if(whom == "IRCKEY")
+			irc = 1
+		else
+			recipient = GLOB.directory[whom]
+	else if(istype(whom, /client))
+		recipient = whom
+
+
+	if(irc)
+		if(!ircreplyamount)	//to prevent people from spamming irc
+			return
+		if(!msg)
+			msg = input(src,"Message:", "Private message to Administrator") as text|null
+
+		if(!msg)
+			return
+		if(holder)
+			to_chat(src, "<span class='danger'>Error: Use the admin IRC channel, nerd.</span>")
+			return
+
+
+	else
+		if(!recipient)
+			if(holder)
+				to_chat(src, "<span class='danger'>Error: Admin-PM: Client not found.</span>")
+				if(msg)
+					to_chat(src, msg)
+				return
+			else if(msg) // you want to continue if there's no message instead of returning now
+				current_ticket.MessageNoRecipient(msg)
+				return
+
+		//get message text, limit it's length.and clean/escape html
+		if(!msg)
+			msg = input(src,"Message:", "Private message to [key_name(recipient, 0, 0)]") as message|null
+			msg = trim(msg)
+			if(!msg)
+				return
+
+			if(prefs.muted & MUTE_ADMINHELP)
+				to_chat(src, "<span class='danger'>Error: Admin-PM: You are unable to use admin PM-s (muted).</span>")
+				return
+
+			if(!recipient)
+				if(holder)
+					to_chat(src, "<span class='danger'>Error: Admin-PM: Client not found.</span>")
+				else
+					current_ticket.MessageNoRecipient(msg)
+				return
+
+	if (src.handle_spam_prevention(msg,MUTE_ADMINHELP))
+		return
+
+	//clean the message if it's not sent by a high-rank admin
+	if(!check_rights(R_SERVER|R_DEBUG,0)||irc)//no sending html to the poor bots
+		msg = trim(sanitize(copytext(msg,1,MAX_MESSAGE_LEN)))
+		if(!msg)
+			return
+
+	var/rawmsg = msg
+
+	if(holder)
+		msg = emoji_parse(msg)
+
+	var/keywordparsedmsg = keywords_lookup(msg)
+
+	if(irc)
+		to_chat(src, "<span class='notice'>PM to-<b>Admins</b>: <span class='linkify'>[rawmsg]</span></span>")
+		var/datum/admin_help/AH = admin_ticket_log(src, "<font color='red'>Reply PM from-<b>[key_name(src, TRUE, TRUE)] to <i>IRC</i>: [keywordparsedmsg]</font>")
+		ircreplyamount--
+		send2irc("[AH ? "#[AH.id] " : ""]Reply: [ckey]", rawmsg)
+	else
+		if(recipient.holder)
+			if(holder)	//both are admins
+				to_chat(recipient, "<span class='danger'>Admin PM from-<b>[key_name(src, recipient, 1)]</b>: <span class='linkify'>[keywordparsedmsg]</span></span>")
+				to_chat(src, "<span class='notice'>Admin PM to-<b>[key_name(recipient, src, 1)]</b>: <span class='linkify'>[keywordparsedmsg]</span></span>")
+
+				//omg this is dumb, just fill in both their tickets
+				var/interaction_message = "<font color='purple'>PM from-<b>[key_name(src, recipient, 1)]</b> to-<b>[key_name(recipient, src, 1)]</b>: [keywordparsedmsg]</font>"
+				admin_ticket_log(src, interaction_message)
+				if(recipient != src)	//reeee
+					admin_ticket_log(recipient, interaction_message)
+
+			else		//recipient is an admin but sender is not
+				var/replymsg = "Reply PM from-<b>[key_name(src, recipient, 1)]</b>: <span class='linkify'>[keywordparsedmsg]</span>"
+				admin_ticket_log(src, "<font color='red'>[replymsg]</font>")
+				to_chat(recipient, "<span class='danger'>[replymsg]</span>")
+				to_chat(src, "<span class='notice'>PM to-<b>Admins</b>: <span class='linkify'>[msg]</span></span>")
+
+			//play the receiving admin the adminhelp sound (if they have them enabled)
+			if(recipient.prefs.toggles & SOUND_ADMINHELP)
+				SEND_SOUND(recipient, sound('sound/effects/adminhelp.ogg'))
+
+		else
+			if(holder)	//sender is an admin but recipient is not. Do BIG RED TEXT
+				if(!recipient.current_ticket)
+					new /datum/admin_help(msg, recipient, TRUE)
+
+				to_chat(recipient, "<font color='red' size='4'><b>-- Administrator private message --</b></font>")
+				to_chat(recipient, "<span class='danger'>Admin PM from-<b>[key_name(src, recipient, 0)]</b>: <span class='linkify'>[msg]</span></span>")
+				to_chat(recipient, "<span class='danger'><i>Click on the administrator's name to reply.</i></span>")
+				to_chat(src, "<span class='notice'>Admin PM to-<b>[key_name(recipient, src, 1)]</b>: <span class='linkify'>[msg]</span></span>")
+
+				admin_ticket_log(recipient, "<font color='purple'>PM From [key_name_admin(src)]: [keywordparsedmsg]</font>")
+
+				//always play non-admin recipients the adminhelp sound
+				SEND_SOUND(recipient, sound('sound/effects/adminhelp.ogg'))
+
+				//AdminPM popup for ApocStation and anybody else who wants to use it. Set it with POPUP_ADMIN_PM in config.txt ~Carn
+				if(CONFIG_GET(flag/popup_admin_pm))
+					spawn()	//so we don't hold the caller proc up
+						var/sender = src
+						var/sendername = key
+						var/reply = input(recipient, msg,"Admin PM from-[sendername]", "") as text|null		//show message and await a reply
+						if(recipient && reply)
+							if(sender)
+								recipient.cmd_admin_pm(sender,reply)										//sender is still about, let's reply to them
+							else
+								adminhelp(reply)													//sender has left, adminhelp instead
+						return
+
+			else		//neither are admins
+				to_chat(src, "<span class='danger'>Error: Admin-PM: Non-admin to non-admin PM communication is forbidden.</span>")
+				return
+
+	if(irc)
+		log_admin_private("PM: [key_name(src)]->IRC: [rawmsg]")
+		for(var/client/X in GLOB.admins)
+			to_chat(X, "<span class='notice'><B>PM: [key_name(src, X, 0)]-&gt;IRC:</B> [keywordparsedmsg]</span>")
+	else
+		window_flash(recipient, ignorepref = TRUE)
+		log_admin_private("PM: [key_name(src)]->[key_name(recipient)]: [rawmsg]")
+		//we don't use message_admins here because the sender/receiver might get it too
+		for(var/client/X in GLOB.admins)
+			if(X.key!=key && X.key!=recipient.key)	//check client/X is an admin and isn't the sender or recipient
+				to_chat(X, "<span class='notice'><B>PM: [key_name(src, X, 0)]-&gt;[key_name(recipient, X, 0)]:</B> [keywordparsedmsg]</span>" )
+
+
+
+#define IRC_AHELP_USAGE "Usage: ticket <close|resolve|icissue|reject|reopen \[ticket #\]|list>"
+/proc/IrcPm(target,msg,sender)
+	target = ckey(target)
+	var/client/C = GLOB.directory[target]
+
+	var/datum/admin_help/ticket = C ? C.current_ticket : GLOB.ahelp_tickets.CKey2ActiveTicket(target)
+	var/compliant_msg = trim(lowertext(msg))
+	var/irc_tagged = "[sender](IRC)"
+	var/list/splits = splittext(compliant_msg, " ")
+	if(splits.len && splits[1] == "ticket")
+		if(splits.len < 2)
+			return IRC_AHELP_USAGE
+		switch(splits[2])
+			if("close")
+				if(ticket)
+					ticket.Close(irc_tagged)
+					return "Ticket #[ticket.id] successfully closed"
+			if("resolve")
+				if(ticket)
+					ticket.Resolve(irc_tagged)
+					return "Ticket #[ticket.id] successfully resolved"
+			if("icissue")
+				if(ticket)
+					ticket.ICIssue(irc_tagged)
+					return "Ticket #[ticket.id] successfully marked as IC issue"
+			if("reject")
+				if(ticket)
+					ticket.Reject(irc_tagged)
+					return "Ticket #[ticket.id] successfully rejected"
+			if("reopen")
+				if(ticket)
+					return "Error: [target] already has ticket #[ticket.id] open"
+				var/fail = splits.len < 3 ? null : -1
+				if(!isnull(fail))
+					fail = text2num(splits[3])
+				if(isnull(fail))
+					return "Error: No/Invalid ticket id specified. [IRC_AHELP_USAGE]"
+				var/datum/admin_help/AH = GLOB.ahelp_tickets.TicketByID(fail)
+				if(!AH)
+					return "Error: Ticket #[fail] not found"
+				if(AH.initiator_ckey != target)
+					return "Error: Ticket #[fail] belongs to [AH.initiator_ckey]"
+				AH.Reopen()
+				return "Ticket #[ticket.id] successfully reopened"
+			if("list")
+				var/list/tickets = GLOB.ahelp_tickets.TicketsByCKey(target)
+				if(!tickets.len)
+					return "None"
+				. = ""
+				for(var/I in tickets)
+					var/datum/admin_help/AH = I
+					if(.)
+						. += ", "
+					if(AH == ticket)
+						. += "Active: "
+					. += "#[AH.id]"
+				return
+			else
+				return IRC_AHELP_USAGE
+		return "Error: Ticket could not be found"
+
+	var/static/stealthkey
+	var/adminname = CONFIG_GET(flag/show_irc_name) ? irc_tagged : "Administrator"
+
+	if(!C)
+		return "Error: No client"
+
+	if(!stealthkey)
+		stealthkey = GenIrcStealthKey()
+
+	msg = sanitize(copytext(msg,1,MAX_MESSAGE_LEN))
+	if(!msg)
+		return "Error: No message"
+
+	message_admins("IRC message from [sender] to [key_name_admin(C)] : [msg]")
+	log_admin_private("IRC PM: [sender] -> [key_name(C)] : [msg]")
+	msg = emoji_parse(msg)
+
+	to_chat(C, "<font color='red' size='4'><b>-- Administrator private message --</b></font>")
+	to_chat(C, "<span class='adminsay'>Admin PM from-<b><a href='?priv_msg=[stealthkey]'>[adminname]</A></b>: [msg]</span>")
+	to_chat(C, "<span class='adminsay'><i>Click on the administrator's name to reply.</i></span>")
+
+	admin_ticket_log(C, "<font color='purple'>PM From [irc_tagged]: [msg]</font>")
+
+	window_flash(C, ignorepref = TRUE)
+	//always play non-admin recipients the adminhelp sound
+	SEND_SOUND(C, 'sound/effects/adminhelp.ogg')
+
+	C.ircreplyamount = IRCREPLYCOUNT
+
+	return "Message Successful"
+
+/proc/GenIrcStealthKey()
+	var/num = (rand(0,1000))
+	var/i = 0
+	while(i == 0)
+		i = 1
+		for(var/P in GLOB.stealthminID)
+			if(num == GLOB.stealthminID[P])
+				num++
+				i = 0
+	var/stealth = "@[num2text(num)]"
+	GLOB.stealthminID["IRCKEY"] = stealth
+	return	stealth
+
+#undef IRCREPLYCOUNT

code/modules/admin/verbs/adminsay.dm

@@ -0,0 +1,22 @@
+/client/proc/cmd_admin_say(msg as text)
+	set category = "Special Verbs"
+	set name = "Asay" //Gave this shit a shorter name so you only have to time out "asay" rather than "admin say" to use it --NeoFite
+	set hidden = 1
+	if(!check_rights(0))
+		return
+
+	msg = copytext(sanitize(msg), 1, MAX_MESSAGE_LEN)
+	if(!msg)
+		return
+	msg = emoji_parse(msg)
+	mob.log_talk(msg, LOG_ASAY)
+
+	msg = keywords_lookup(msg)
+	msg = "<span class='adminsay'><span class='prefix'>ADMIN:</span> <EM>[key_name(usr, 1)]</EM> [ADMIN_FLW(mob)]: <span class='message linkify'>[msg]</span></span>"
+	to_chat(GLOB.admins, msg)
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Asay") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/get_admin_say()
+	var/msg = input(src, null, "asay \"text\"") as text
+	cmd_admin_say(msg)

code/modules/admin/verbs/ak47s.dm

@@ -0,0 +1,22 @@
+GLOBAL_VAR_INIT(terrorism, FALSE)
+/client/proc/ak47s() // For when you just can't summon guns worthy of a firefight
+	if(!SSticker.HasRoundStarted())
+		alert("The game hasn't started yet!")
+		return
+	GLOB.terrorism = TRUE
+
+	for(var/mob/living/carbon/human/H in GLOB.player_list)
+		if(H.stat == DEAD || !(H.client))
+			continue
+		H.make_terrorism()
+
+	send_to_playing_players("<span class='boldannounce'><font size=6>MOTHER RUSSIA ARMS THE MOB!</font></span>")
+
+/mob/living/carbon/human/proc/make_terrorism()
+	for(var/obj/item/I in held_items)
+		qdel(I)
+	var/obj/item/gun/energy/laser/LaserAK/AK = new(src)
+	if(!GLOB.terrorism)
+		AK.flags_1 |= ADMIN_SPAWNED_1 //To prevent announcing
+	put_in_hands(AK)
+	AK.pickup(src) //For the stun shielding

code/modules/admin/verbs/atmosdebug.dm

@@ -0,0 +1,41 @@
+/client/proc/atmosscan()
+	set category = "Mapping"
+	set name = "Check Plumbing"
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Check Plumbing") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+	//all plumbing - yes, some things might get stated twice, doesn't matter.
+	for (var/obj/machinery/atmospherics/plumbing in GLOB.machines)
+		if (plumbing.nodealert)
+			to_chat(usr, "Unconnected [plumbing.name] located at [ADMIN_VERBOSEJMP(plumbing)]")
+
+	//Manifolds
+	for (var/obj/machinery/atmospherics/pipe/manifold/pipe in GLOB.machines)
+		if (!pipe.nodes[1] || !pipe.nodes[2] || !pipe.nodes[3])
+			to_chat(usr, "Unconnected [pipe.name] located at [ADMIN_VERBOSEJMP(pipe)]")
+
+	//Pipes
+	for (var/obj/machinery/atmospherics/pipe/simple/pipe in GLOB.machines)
+		if (!pipe.nodes[1] || !pipe.nodes[2])
+			to_chat(usr, "Unconnected [pipe.name] located at [ADMIN_VERBOSEJMP(pipe)]")
+
+/client/proc/powerdebug()
+	set category = "Mapping"
+	set name = "Check Power"
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Check Power") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+	for (var/datum/powernet/PN in GLOB.powernets)
+		if (!PN.nodes || !PN.nodes.len)
+			if(PN.cables && (PN.cables.len > 1))
+				var/obj/structure/cable/C = PN.cables[1]
+				to_chat(usr, "Powernet with no nodes! (number [PN.number]) - example cable at [ADMIN_VERBOSEJMP(C)]")
+
+		if (!PN.cables || (PN.cables.len < 10))
+			if(PN.cables && (PN.cables.len > 1))
+				var/obj/structure/cable/C = PN.cables[1]
+				to_chat(usr, "Powernet with fewer than 10 cables! (number [PN.number]) - example cable at [ADMIN_VERBOSEJMP(C)]")

code/modules/admin/verbs/bluespacearty.dm

@@ -0,0 +1,26 @@
+/client/proc/bluespace_artillery(mob/M in GLOB.mob_list)
+	if(!holder || !check_rights(R_FUN))
+		return
+
+	var/mob/living/target = M
+
+	if(!isliving(target))
+		to_chat(usr, "This can only be used on instances of type /mob/living")
+		return
+
+	explosion(target.loc, 0, 0, 0, 0)
+
+	var/turf/open/floor/T = get_turf(target)
+	if(istype(T))
+		if(prob(80))
+			T.break_tile_to_plating()
+		else
+			T.break_tile()
+
+	if(target.health <= 1)
+		target.gib(1, 1)
+	else
+		target.adjustBruteLoss(min(99,(target.health - 1)))
+		target.Knockdown(400)
+		target.stuttering = 20
+

code/modules/admin/verbs/borgpanel.dm

@@ -0,0 +1,216 @@
+/datum/admins/proc/open_borgopanel(borgo in GLOB.silicon_mobs)
+	set category = "Admin"
+	set name = "Show Borg Panel"
+	set desc = "Show borg panel"
+
+	if(!check_rights(R_ADMIN))
+		return
+
+	if (!istype(borgo, /mob/living/silicon/robot))
+		borgo = input("Select a borg", "Select a borg", null, null) as null|anything in GLOB.silicon_mobs
+	if (!istype(borgo, /mob/living/silicon/robot))
+		to_chat(usr, "<span class='warning'>Borg is required for borgpanel</span>")
+
+	var/datum/borgpanel/borgpanel = new(usr, borgo)
+
+	borgpanel.ui_interact(usr)
+
+
+
+/datum/borgpanel
+	var/mob/living/silicon/robot/borg
+	var/user
+
+/datum/borgpanel/New(to_user, mob/living/silicon/robot/to_borg)
+	if(!istype(to_borg))
+		CRASH("Borg panel is only available for borgs")
+		qdel(src)
+
+	user = CLIENT_FROM_VAR(to_user)
+
+	if (!user)
+		CRASH("Borg panel attempted to open to a mob without a client")
+
+	borg = to_borg
+
+/datum/borgpanel/ui_interact(mob/user, ui_key = "main", datum/tgui/ui = null, force_open = FALSE, datum/tgui/master_ui = null, datum/ui_state/state = GLOB.admin_state)
+	ui = SStgui.try_update_ui(user, src, ui_key, ui, force_open)
+	if(!ui)
+		ui = new(user, src, ui_key, "borgopanel", "Borg Panel", 700, 700, master_ui, state)
+		ui.open()
+
+/datum/borgpanel/ui_data(mob/user)
+	. = list()
+	.["borg"] = list(
+		"ref" = REF(borg),
+		"name" = "[borg]",
+		"emagged" = borg.emagged,
+		"active_module" = "[borg.module.type]",
+		"lawupdate" = borg.lawupdate,
+		"lockdown" = borg.lockcharge,
+		"scrambledcodes" = borg.scrambledcodes
+	)
+	.["upgrades"] = list()
+	for (var/upgradetype in subtypesof(/obj/item/borg/upgrade)-/obj/item/borg/upgrade/hypospray) //hypospray is a dummy parent for hypospray upgrades
+		var/obj/item/borg/upgrade/upgrade = upgradetype
+		if (initial(upgrade.module_type) && !istype(borg.module, initial(upgrade.module_type))) // Upgrade requires a different module
+			continue
+		var/installed = FALSE
+		if (locate(upgradetype) in borg)
+			installed = TRUE
+		.["upgrades"] += list(list("name" = initial(upgrade.name), "installed" = installed, "type" = upgradetype))
+	.["laws"] = borg.laws ? borg.laws.get_law_list(include_zeroth = TRUE) : list()
+	.["channels"] = list()
+	for (var/k in GLOB.radiochannels)
+		if (k == RADIO_CHANNEL_COMMON)
+			continue
+		.["channels"] += list(list("name" = k, "installed" = (k in borg.radio.channels)))
+	.["cell"] = borg.cell ? list("missing" = FALSE, "maxcharge" = borg.cell.maxcharge, "charge" = borg.cell.charge) : list("missing" = TRUE, "maxcharge" = 1, "charge" = 0)
+	.["modules"] = list()
+	for(var/moduletype in typesof(/obj/item/robot_module))
+		var/obj/item/robot_module/module = moduletype
+		.["modules"] += list(list(
+			"name" = initial(module.name),
+			"type" = "[module]"
+		))
+	.["ais"] = list(list("name" = "None", "ref" = "null", "connected" = isnull(borg.connected_ai)))
+	for(var/mob/living/silicon/ai/ai in GLOB.ai_list)
+		.["ais"] += list(list("name" = ai.name, "ref" = REF(ai), "connected" = (borg.connected_ai == ai)))
+
+
+/datum/borgpanel/ui_act(action, params)
+	if(..())
+		return
+	switch (action)
+		if ("set_charge")
+			var/newcharge = input("New charge (0-[borg.cell.maxcharge]):", borg.name, borg.cell.charge) as num|null
+			if (newcharge)
+				borg.cell.charge = CLAMP(newcharge, 0, borg.cell.maxcharge)
+				message_admins("[key_name_admin(user)] set the charge of [ADMIN_LOOKUPFLW(borg)] to [borg.cell.charge].")
+				log_admin("[key_name(user)] set the charge of [key_name(borg)] to [borg.cell.charge].")
+		if ("remove_cell")
+			QDEL_NULL(borg.cell)
+			message_admins("[key_name_admin(user)] deleted the cell of [ADMIN_LOOKUPFLW(borg)].")
+			log_admin("[key_name(user)] deleted the cell of [key_name(borg)].")
+		if ("change_cell")
+			var/chosen = pick_closest_path(null, make_types_fancy(typesof(/obj/item/stock_parts/cell)))
+			if (!ispath(chosen))
+				chosen = text2path(chosen)
+			if (chosen)
+				if (borg.cell)
+					QDEL_NULL(borg.cell)
+				var/new_cell = new chosen(borg)
+				borg.cell = new_cell
+				borg.cell.charge = borg.cell.maxcharge
+				borg.diag_hud_set_borgcell()
+				message_admins("[key_name_admin(user)] changed the cell of [ADMIN_LOOKUPFLW(borg)] to [new_cell].")
+				log_admin("[key_name(user)] changed the cell of [key_name(borg)] to [new_cell].")
+		if ("toggle_emagged")
+			borg.SetEmagged(!borg.emagged)
+			if (borg.emagged)
+				message_admins("[key_name_admin(user)] emagged [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] emagged [key_name(borg)].")
+			else
+				message_admins("[key_name_admin(user)] un-emagged [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] un-emagged [key_name(borg)].")
+		if ("toggle_lawupdate")
+			borg.lawupdate = !borg.lawupdate
+			if (borg.lawupdate)
+				message_admins("[key_name_admin(user)] enabled lawsync on [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] enabled lawsync on [key_name(borg)].")
+			else
+				message_admins("[key_name_admin(user)] disabled lawsync on [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] disabled lawsync on [key_name(borg)].")
+		if ("toggle_lockdown")
+			borg.SetLockdown(!borg.lockcharge)
+			if (borg.lockcharge)
+				message_admins("[key_name_admin(user)] locked down [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] locked down [key_name(borg)].")
+			else
+				message_admins("[key_name_admin(user)] released [ADMIN_LOOKUPFLW(borg)] from lockdown.")
+				log_admin("[key_name(user)] released [key_name(borg)] from lockdown.")
+		if ("toggle_scrambledcodes")
+			borg.scrambledcodes = !borg.scrambledcodes
+			if (borg.scrambledcodes)
+				message_admins("[key_name_admin(user)] enabled scrambled codes on [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] enabled scrambled codes on [key_name(borg)].")
+			else
+				message_admins("[key_name_admin(user)] disabled scrambled codes on [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] disabled scrambled codes on [key_name(borg)].")
+		if ("rename")
+			var/new_name = stripped_input(user,"What would you like to name this cyborg?","Input a name",borg.real_name,MAX_NAME_LEN)
+			if(!new_name)
+				return
+			message_admins("[key_name_admin(user)] renamed [ADMIN_LOOKUPFLW(borg)] to [new_name].")
+			log_admin("[key_name(user)] renamed [key_name(borg)] to [new_name].")
+			borg.fully_replace_character_name(borg.real_name,new_name)
+		if ("toggle_upgrade")
+			var/upgradepath = text2path(params["upgrade"])
+			var/obj/item/borg/upgrade/installedupgrade = locate(upgradepath) in borg
+			if (installedupgrade)
+				installedupgrade.deactivate(borg, user)
+				borg.upgrades -= installedupgrade
+				message_admins("[key_name_admin(user)] removed the [installedupgrade] upgrade from [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] removed the [installedupgrade] upgrade from [key_name(borg)].")
+				qdel(installedupgrade)
+			else
+				var/obj/item/borg/upgrade/upgrade = new upgradepath(borg)
+				upgrade.action(borg, user)
+				borg.upgrades += upgrade
+				message_admins("[key_name_admin(user)] added the [upgrade] borg upgrade to [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] added the [upgrade] borg upgrade to [key_name(borg)].")
+		if ("toggle_radio")
+			var/channel = params["channel"]
+			if (channel in borg.radio.channels) // We're removing a channel
+				if (!borg.radio.keyslot) // There's no encryption key. This shouldn't happen but we can cope
+					borg.radio.channels -= channel
+					if (channel == RADIO_CHANNEL_SYNDICATE)
+						borg.radio.syndie = FALSE
+					else if (channel == RADIO_CHANNEL_CENTCOM)
+						borg.radio.independent = FALSE
+				else
+					borg.radio.keyslot.channels -= channel
+					if (channel == RADIO_CHANNEL_SYNDICATE)
+						borg.radio.keyslot.syndie = FALSE
+					else if (channel == RADIO_CHANNEL_CENTCOM)
+						borg.radio.keyslot.independent = FALSE
+				message_admins("[key_name_admin(user)] removed the [channel] radio channel from [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] removed the [channel] radio channel from [key_name(borg)].")
+			else	// We're adding a channel
+				if (!borg.radio.keyslot) // Assert that an encryption key exists
+					borg.radio.keyslot = new (borg.radio)
+				borg.radio.keyslot.channels[channel] = 1
+				if (channel == RADIO_CHANNEL_SYNDICATE)
+					borg.radio.keyslot.syndie = TRUE
+				else if (channel == RADIO_CHANNEL_CENTCOM)
+					borg.radio.keyslot.independent = TRUE
+				message_admins("[key_name_admin(user)] added the [channel] radio channel to [ADMIN_LOOKUPFLW(borg)].")
+				log_admin("[key_name(user)] added the [channel] radio channel to [key_name(borg)].")
+			borg.radio.recalculateChannels()
+		if ("setmodule")
+			var/newmodulepath = text2path(params["module"])
+			if (ispath(newmodulepath))
+				borg.module.transform_to(newmodulepath)
+				message_admins("[key_name_admin(user)] changed the module of [ADMIN_LOOKUPFLW(borg)] to [newmodulepath].")
+				log_admin("[key_name(user)] changed the module of [key_name(borg)] to [newmodulepath].")
+		if ("slavetoai")
+			var/mob/living/silicon/ai/newai = locate(params["slavetoai"]) in GLOB.ai_list
+			if (newai && newai != borg.connected_ai)
+				borg.notify_ai(DISCONNECT)
+				if(borg.shell)
+					borg.undeploy()
+				borg.connected_ai = newai
+				borg.notify_ai(TRUE)
+				message_admins("[key_name_admin(user)] slaved [ADMIN_LOOKUPFLW(borg)] to the AI [ADMIN_LOOKUPFLW(newai)].")
+				log_admin("[key_name(user)] slaved [key_name(borg)] to the AI [key_name(newai)].")
+			else if (params["slavetoai"] == "null")
+				borg.notify_ai(DISCONNECT)
+				if(borg.shell)
+					borg.undeploy()
+				borg.connected_ai = null
+				message_admins("[key_name_admin(user)] freed [ADMIN_LOOKUPFLW(borg)] from being slaved to an AI.")
+				log_admin("[key_name(user)] freed [key_name(borg)] from being slaved to an AI.")
+			if (borg.lawupdate)
+				borg.lawsync()
+
+	. = TRUE

code/modules/admin/verbs/cinematic.dm

@@ -0,0 +1,11 @@
+/client/proc/cinematic()
+	set name = "cinematic"
+	set category = "Fun"
+	set desc = "Shows a cinematic."	// Intended for testing but I thought it might be nice for events on the rare occasion Feel free to comment it out if it's not wanted.
+	set hidden = 1
+	if(!SSticker)
+		return
+
+	var/datum/cinematic/choice = input(src,"Cinematic","Choose",null) as anything in subtypesof(/datum/cinematic)
+	if(choice)
+		Cinematic(initial(choice.id),world,null)

code/modules/admin/verbs/deadsay.dm

@@ -0,0 +1,36 @@
+/client/proc/dsay(msg as text)
+	set category = "Special Verbs"
+	set name = "Dsay"
+	set hidden = 1
+	if(!src.holder)
+		to_chat(src, "Only administrators may use this command.")
+		return
+	if(!src.mob)
+		return
+	if(prefs.muted & MUTE_DEADCHAT)
+		to_chat(src, "<span class='danger'>You cannot send DSAY messages (muted).</span>")
+		return
+
+	if (src.handle_spam_prevention(msg,MUTE_DEADCHAT))
+		return
+
+	msg = copytext(sanitize(msg), 1, MAX_MESSAGE_LEN)
+	mob.log_talk(msg, LOG_DSAY)
+
+	if (!msg)
+		return
+	var/static/nicknames = world.file2list("[global.config.directory]/admin_nicknames.txt")
+
+	var/rendered = "<span class='game deadsay'><span class='prefix'>DEAD:</span> <span class='name'>[uppertext(holder.rank)]([src.holder.fakekey ? pick(nicknames) : src.key])</span> says, <span class='message'>\"[emoji_parse(msg)]\"</span></span>"
+
+	for (var/mob/M in GLOB.player_list)
+		if(isnewplayer(M))
+			continue
+		if (M.stat == DEAD || (M.client && M.client.holder && (M.client.prefs.chat_toggles & CHAT_DEAD))) //admins can toggle deadchat on and off. This is a proc in admin.dm and is only give to Administrators and above
+			to_chat(M, rendered)
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Dsay") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/get_dead_say()
+	var/msg = input(src, null, "dsay \"text\"") as text
+	dsay(msg)

code/modules/admin/verbs/diagnostics.dm

@@ -0,0 +1,97 @@
+/proc/show_air_status_to(turf/target, mob/user)
+	var/datum/gas_mixture/env = target.return_air()
+	var/list/env_gases = env.gases
+	var/burning = FALSE
+	if(isopenturf(target))
+		var/turf/open/T = target
+		if(T.active_hotspot)
+			burning = TRUE
+
+	var/list/lines = list("<span class='adminnotice'>[AREACOORD(target)]: [env.temperature] K ([env.temperature - T0C] C), [env.return_pressure()] kPa[(burning)?(", <font color='red'>burning</font>"):(null)]</span>")
+	for(var/id in env_gases)
+		var/moles = env_gases[id]
+		if (moles >= 0.00001)
+			lines += "[GLOB.meta_gas_names[id]]: [moles] mol"
+	to_chat(usr, lines.Join("\n"))
+
+/client/proc/air_status(turf/target)
+	set category = "Debug"
+	set name = "Display Air Status"
+
+	if(!isturf(target))
+		return
+	show_air_status_to(target, usr)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Show Air Status") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/fix_next_move()
+	set category = "Debug"
+	set name = "Unfreeze Everyone"
+	var/largest_move_time = 0
+	var/largest_click_time = 0
+	var/mob/largest_move_mob = null
+	var/mob/largest_click_mob = null
+	for(var/mob/M in world)
+		if(!M.client)
+			continue
+		if(M.next_move >= largest_move_time)
+			largest_move_mob = M
+			if(M.next_move > world.time)
+				largest_move_time = M.next_move - world.time
+			else
+				largest_move_time = 1
+		if(M.next_click >= largest_click_time)
+			largest_click_mob = M
+			if(M.next_click > world.time)
+				largest_click_time = M.next_click - world.time
+			else
+				largest_click_time = 0
+		log_admin("DEBUG: [key_name(M)]  next_move = [M.next_move]  lastDblClick = [M.next_click]  world.time = [world.time]")
+		M.next_move = 1
+		M.next_click = 0
+	message_admins("[ADMIN_LOOKUPFLW(largest_move_mob)] had the largest move delay with [largest_move_time] frames / [DisplayTimeText(largest_move_time)]!")
+	message_admins("[ADMIN_LOOKUPFLW(largest_click_mob)] had the largest click delay with [largest_click_time] frames / [DisplayTimeText(largest_click_time)]!")
+	message_admins("world.time = [world.time]")
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Unfreeze Everyone") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+	return
+
+/client/proc/radio_report()
+	set category = "Debug"
+	set name = "Radio report"
+
+	var/output = "<b>Radio Report</b><hr>"
+	for (var/fq in SSradio.frequencies)
+		output += "<b>Freq: [fq]</b><br>"
+		var/list/datum/radio_frequency/fqs = SSradio.frequencies[fq]
+		if (!fqs)
+			output += "&nbsp;&nbsp;<b>ERROR</b><br>"
+			continue
+		for (var/filter in fqs.devices)
+			var/list/f = fqs.devices[filter]
+			if (!f)
+				output += "&nbsp;&nbsp;[filter]: ERROR<br>"
+				continue
+			output += "&nbsp;&nbsp;[filter]: [f.len]<br>"
+			for (var/device in f)
+				if (istype(device, /atom))
+					var/atom/A = device
+					output += "&nbsp;&nbsp;&nbsp;&nbsp;[device] ([AREACOORD(A)])<br>"
+				else
+					output += "&nbsp;&nbsp;&nbsp;&nbsp;[device]<br>"
+
+	usr << browse(output,"window=radioreport")
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Show Radio Report") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/reload_admins()
+	set name = "Reload Admins"
+	set category = "Admin"
+
+	if(!src.holder)
+		return
+
+	var/confirm = alert(src, "Are you sure you want to reload all admins?", "Confirm", "Yes", "No")
+	if(confirm !="Yes")
+		return
+
+	load_admins()
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Reload All Admins") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+	message_admins("[key_name_admin(usr)] manually reloaded admins")

code/modules/admin/verbs/dice.dm

@@ -0,0 +1,25 @@
+/client/proc/roll_dices()
+	set category = "Fun"
+	set name = "Roll Dice"
+	if(!check_rights(R_FUN))
+		return
+
+	var/sum = input("How many times should we throw?") as num
+	var/side = input("Select the number of sides.") as num
+	if(!side)
+		side = 6
+	if(!sum)
+		sum = 2
+
+	var/dice = num2text(sum) + "d" + num2text(side)
+
+	if(alert("Do you want to inform the world about your game?",,"Yes", "No") == "Yes")
+		to_chat(world, "<h2 style=\"color:#A50400\">The dice have been rolled by Gods!</h2>")
+
+	var/result = roll(dice)
+
+	if(alert("Do you want to inform the world about the result?",,"Yes", "No") == "Yes")
+		to_chat(world, "<h2 style=\"color:#A50400\">Gods rolled [dice], result is [result]</h2>")
+
+	message_admins("[key_name_admin(src)] rolled dice [dice], result is [result]")
+	log_admin("[key_name_admin(src)] rolled dice [dice], result is [result]")

code/modules/admin/verbs/fps.dm

@@ -0,0 +1,26 @@
+//replaces the old Ticklag verb, fps is easier to understand
+/client/proc/set_server_fps()
+	set category = "Debug"
+	set name = "Set Server FPS"
+	set desc = "Sets game speed in frames-per-second. Can potentially break the game"
+
+	if(!check_rights(R_DEBUG))
+		return
+
+	var/cfg_fps = CONFIG_GET(number/fps)
+	var/new_fps = round(input("Sets game frames-per-second. Can potentially break the game (default: [cfg_fps])","FPS", world.fps) as num|null)
+
+	if(new_fps <= 0)
+		to_chat(src, "<span class='danger'>Error: set_server_fps(): Invalid world.fps value. No changes made.</span>")
+		return
+	if(new_fps > cfg_fps * 1.5)
+		if(alert(src, "You are setting fps to a high value:\n\t[new_fps] frames-per-second\n\tconfig.fps = [cfg_fps]","Warning!","Confirm","ABORT-ABORT-ABORT") != "Confirm")
+			return
+
+	var/msg = "[key_name(src)] has modified world.fps to [new_fps]"
+	log_admin(msg, 0)
+	message_admins(msg, 0)
+	SSblackbox.record_feedback("nested tally", "admin_toggle", 1, list("Set Server FPS", "[new_fps]")) //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+	CONFIG_SET(number/fps, new_fps)
+	world.fps = new_fps

code/modules/admin/verbs/getlogs.dm

@@ -0,0 +1,35 @@
+//This proc allows download of past server logs saved within the data/logs/ folder.
+/client/proc/getserverlogs()
+	set name = "Get Server Logs"
+	set desc = "View/retrieve logfiles."
+	set category = "Admin"
+
+	browseserverlogs()
+
+/client/proc/getcurrentlogs()
+	set name = "Get Current Logs"
+	set desc = "View/retrieve logfiles for the current round."
+	set category = "Admin"
+
+	browseserverlogs("[GLOB.log_directory]/")
+
+/client/proc/browseserverlogs(path = "data/logs/")
+	path = browse_files(path)
+	if(!path)
+		return
+
+	if(file_spam_check())
+		return
+
+	message_admins("[key_name_admin(src)] accessed file: [path]")
+	switch(alert("View (in game), Open (in your system's text editor), or Download?", path, "View", "Open", "Download"))
+		if ("View")
+			src << browse("<pre style='word-wrap: break-word;'>[html_encode(file2text(file(path)))]</pre>", list2params(list("window" = "viewfile.[path]")))
+		if ("Open")
+			src << run(file(path))
+		if ("Download")
+			src << ftp(file(path))
+		else
+			return
+	to_chat(src, "Attempting to send [path], this may take a fair few minutes if the file is very large.")
+	return

code/modules/admin/verbs/individual_logging.dm

@@ -0,0 +1,67 @@
+/proc/show_individual_logging_panel(mob/M, source = LOGSRC_CLIENT, type = INDIVIDUAL_ATTACK_LOG)
+	if(!M || !ismob(M))
+		return
+
+	var/ntype = text2num(type)
+
+	//Add client links
+	var/dat = ""
+	if(M.client)
+		dat += "<center><p>Client</p></center>"
+		dat += "<center>"
+		dat += individual_logging_panel_link(M, INDIVIDUAL_ATTACK_LOG, LOGSRC_CLIENT, "Attack Log", source, ntype)
+		dat += " | "
+		dat += individual_logging_panel_link(M, INDIVIDUAL_SAY_LOG, LOGSRC_CLIENT, "Say Log", source, ntype)
+		dat += " | "
+		dat += individual_logging_panel_link(M, INDIVIDUAL_EMOTE_LOG, LOGSRC_CLIENT, "Emote Log", source, ntype)
+		dat += " | "
+		dat += individual_logging_panel_link(M, INDIVIDUAL_COMMS_LOG, LOGSRC_CLIENT, "Comms Log", source, ntype)
+		dat += " | "
+		dat += individual_logging_panel_link(M, INDIVIDUAL_OOC_LOG, LOGSRC_CLIENT, "OOC Log", source, ntype)
+		dat += " | "
+		dat += individual_logging_panel_link(M, INDIVIDUAL_SHOW_ALL_LOG, LOGSRC_CLIENT, "Show All", source, ntype)
+		dat += "</center>"
+	else
+		dat += "<p> No client attached to mob </p>"
+
+	dat += "<hr style='background:#000000; border:0; height:1px'>"
+	dat += "<center><p>Mob</p></center>"
+	//Add the links for the mob specific log
+	dat += "<center>"
+	dat += individual_logging_panel_link(M, INDIVIDUAL_ATTACK_LOG, LOGSRC_MOB, "Attack Log", source, ntype)
+	dat += " | "
+	dat += individual_logging_panel_link(M, INDIVIDUAL_SAY_LOG, LOGSRC_MOB, "Say Log", source, ntype)
+	dat += " | "
+	dat += individual_logging_panel_link(M, INDIVIDUAL_EMOTE_LOG, LOGSRC_MOB, "Emote Log", source, ntype)
+	dat += " | "
+	dat += individual_logging_panel_link(M, INDIVIDUAL_COMMS_LOG, LOGSRC_MOB, "Comms Log", source, ntype)
+	dat += " | "
+	dat += individual_logging_panel_link(M, INDIVIDUAL_OOC_LOG, LOGSRC_MOB, "OOC Log", source, ntype)
+	dat += " | "
+	dat += individual_logging_panel_link(M, INDIVIDUAL_SHOW_ALL_LOG, LOGSRC_MOB, "Show All", source, ntype)
+	dat += "</center>"
+
+	dat += "<hr style='background:#000000; border:0; height:1px'>"
+
+	var/log_source = M.logging;
+	if(source == LOGSRC_CLIENT && M.client) //if client doesn't exist just fall back to the mob log
+		log_source = M.client.player_details.logging //should exist, if it doesn't that's a bug, don't check for it not existing
+
+	for(var/log_type in log_source)
+		var/nlog_type = text2num(log_type)
+		if(nlog_type & ntype)
+			var/list/reversed = log_source[log_type]
+			if(islist(reversed))
+				reversed = reverseRange(reversed.Copy())
+				for(var/entry in reversed)
+					dat += "<font size=2px><b>[entry]</b><br>[reversed[entry]]</font><br>"
+			dat += "<hr>"
+
+	usr << browse(dat, "window=invidual_logging_[key_name(M)];size=600x480")
+
+/proc/individual_logging_panel_link(mob/M, log_type, log_src, label, selected_src, selected_type)
+	var/slabel = label
+	if(selected_type == log_type && selected_src == log_src)
+		slabel = "<b>\[[label]\]</b>"
+
+	return "<a href='?_src_=holder;[HrefToken()];individuallog=[REF(M)];log_type=[log_type];log_src=[log_src]'>[slabel]</a>"

code/modules/admin/verbs/machine_upgrade.dm

@@ -0,0 +1,13 @@
+/proc/machine_upgrade(obj/machinery/M in world)
+	set name = "Tweak Component Ratings"
+	set category = "Debug"
+	if (!istype(M))
+		return
+
+	var/new_rating = input("Enter new rating:","Num") as num
+	if(new_rating && M.component_parts)
+		for(var/obj/item/stock_parts/P in M.component_parts)
+			P.rating = new_rating
+		M.RefreshParts()
+
+	SSblackbox.record_feedback("nested tally", "admin_toggle", 1, list("Machine Upgrade", "[new_rating]")) //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!

code/modules/admin/verbs/manipulate_organs.dm

@@ -0,0 +1,74 @@
+/client/proc/manipulate_organs(mob/living/carbon/C in world)
+	set name = "Manipulate Organs"
+	set category = "Debug"
+	var/operation = input("Select organ operation.", "Organ Manipulation", "cancel") as null|anything in list("add organ", "add implant", "drop organ/implant", "remove organ/implant", "cancel")
+	if (!operation)
+		return
+
+	var/list/organs = list()
+	switch(operation)
+		if("add organ")
+			for(var/path in subtypesof(/obj/item/organ))
+				var/dat = replacetext("[path]", "/obj/item/organ/", ":")
+				organs[dat] = path
+
+			var/obj/item/organ/organ = input("Select organ type:", "Organ Manipulation", null) as null|anything in organs
+			if(!organ)
+				return
+			organ = organs[organ]
+			organ = new organ
+			organ.Insert(C)
+			log_admin("[key_name(usr)] has added organ [organ.type] to [key_name(C)]")
+			message_admins("[key_name_admin(usr)] has added organ [organ.type] to [ADMIN_LOOKUPFLW(C)]")
+
+		if("add implant")
+			for(var/path in subtypesof(/obj/item/implant))
+				var/dat = replacetext("[path]", "/obj/item/implant/", ":")
+				organs[dat] = path
+
+			var/obj/item/implant/organ = input("Select implant type:", "Organ Manipulation", null) as null|anything in organs
+			if(!organ)
+				return
+			organ = organs[organ]
+			organ = new organ
+			organ.implant(C)
+			log_admin("[key_name(usr)] has added implant [organ.type] to [key_name(C)]")
+			message_admins("[key_name_admin(usr)] has added implant [organ.type] to [ADMIN_LOOKUPFLW(C)]")
+
+		if("drop organ/implant", "remove organ/implant")
+			for(var/X in C.internal_organs)
+				var/obj/item/organ/I = X
+				organs["[I.name] ([I.type])"] = I
+
+			for(var/X in C.implants)
+				var/obj/item/implant/I = X
+				organs["[I.name] ([I.type])"] = I
+
+			var/obj/item/organ = input("Select organ/implant:", "Organ Manipulation", null) as null|anything in organs
+			if(!organ)
+				return
+			organ = organs[organ]
+			if(!organ)
+				return
+			var/obj/item/organ/O
+			var/obj/item/implant/I
+
+			log_admin("[key_name(usr)] has removed [organ.type] from [key_name(C)]")
+			message_admins("[key_name_admin(usr)] has removed [organ.type] from [ADMIN_LOOKUPFLW(C)]")
+
+			if(isorgan(organ))
+				O = organ
+				O.Remove(C)
+			else
+				I = organ
+				I.removed(C)
+
+			organ.forceMove(get_turf(C))
+
+			if(operation == "remove organ/implant")
+				qdel(organ)
+			else if(I) // Put the implant in case.
+				var/obj/item/implantcase/case = new(get_turf(C))
+				case.imp = I
+				I.forceMove(case)
+				case.update_icon()

code/modules/admin/verbs/map_template_loadverb.dm

@@ -0,0 +1,67 @@
+/client/proc/map_template_load()
+	set category = "Debug"
+	set name = "Map template - Place"
+
+	var/datum/map_template/template
+
+	var/map = input(src, "Choose a Map Template to place at your CURRENT LOCATION","Place Map Template") as null|anything in SSmapping.map_templates
+	if(!map)
+		return
+	template = SSmapping.map_templates[map]
+
+	var/turf/T = get_turf(mob)
+	if(!T)
+		return
+
+	var/list/preview = list()
+	for(var/S in template.get_affected_turfs(T,centered = TRUE))
+		var/image/item = image('icons/turf/overlays.dmi',S,"greenOverlay")
+		item.plane = ABOVE_LIGHTING_PLANE
+		preview += item
+	images += preview
+	if(alert(src,"Confirm location.","Template Confirm","Yes","No") == "Yes")
+		if(template.load(T, centered = TRUE))
+			message_admins("<span class='adminnotice'>[key_name_admin(src)] has placed a map template ([template.name]) at [ADMIN_COORDJMP(T)]</span>")
+		else
+			to_chat(src, "Failed to place map")
+	images -= preview
+
+/client/proc/map_template_upload()
+	set category = "Debug"
+	set name = "Map Template - Upload"
+
+	var/map = input(src, "Choose a Map Template to upload to template storage","Upload Map Template") as null|file
+	if(!map)
+		return
+	if(copytext("[map]",-4) != ".dmm")
+		to_chat(src, "<span class='warning'>Filename must end in '.dmm': [map]</span>")
+		return
+	var/datum/map_template/M
+	switch(alert(src, "What kind of map is this?", "Map type", "Normal", "Shuttle", "Cancel"))
+		if("Normal")
+			M = new /datum/map_template(map, "[map]", TRUE)
+		if("Shuttle")
+			M = new /datum/map_template/shuttle(map, "[map]", TRUE)
+		else
+			return
+	if(!M.cached_map)
+		to_chat(src, "<span class='warning'>Map template '[map]' failed to parse properly.</span>")
+		return
+
+	var/datum/map_report/report = M.cached_map.check_for_errors()
+	var/report_link
+	if(report)
+		report.show_to(src)
+		report_link = " - <a href='?src=[REF(report)];[HrefToken(TRUE)];show=1'>validation report</a>"
+		to_chat(src, "<span class='warning'>Map template '[map]' <a href='?src=[REF(report)];[HrefToken()];show=1'>failed validation</a>.</span>")
+		if(report.loadable)
+			var/response = alert(src, "The map failed validation, would you like to load it anyways?", "Map Errors", "Cancel", "Upload Anyways")
+			if(response != "Upload Anyways")
+				return
+		else
+			alert(src, "The map failed validation and cannot be loaded.", "Map Errors", "Oh Darn")
+			return
+
+	SSmapping.map_templates[M.name] = M
+	message_admins("<span class='adminnotice'>[key_name_admin(src)] has uploaded a map template '[map]' ([M.width]x[M.height])[report_link].</span>")
+	to_chat(src, "<span class='notice'>Map template '[map]' ready to place ([M.width]x[M.height])</span>")

code/modules/admin/verbs/mapping.dm

@@ -0,0 +1,358 @@
+//- Are all the floors with or without air, as they should be? (regular or airless)
+//- Does the area have an APC?
+//- Does the area have an Air Alarm?
+//- Does the area have a Request Console?
+//- Does the area have lights?
+//- Does the area have a light switch?
+//- Does the area have enough intercoms?
+//- Does the area have enough security cameras? (Use the 'Camera Range Display' verb under Debug)
+//- Is the area connected to the scrubbers air loop?
+//- Is the area connected to the vent air loop? (vent pumps)
+//- Is everything wired properly?
+//- Does the area have a fire alarm and firedoors?
+//- Do all pod doors work properly?
+//- Are accesses set properly on doors, pod buttons, etc.
+//- Are all items placed properly? (not below vents, scrubbers, tables)
+//- Does the disposal system work properly from all the disposal units in this room and all the units, the pipes of which pass through this room?
+//- Check for any misplaced or stacked piece of pipe (air and disposal)
+//- Check for any misplaced or stacked piece of wire
+//- Identify how hard it is to break into the area and where the weak points are
+//- Check if the area has too much empty space. If so, make it smaller and replace the rest with maintenance tunnels.
+
+GLOBAL_PROTECT(admin_verbs_debug_mapping)
+GLOBAL_LIST_INIT(admin_verbs_debug_mapping, list(
+	/client/proc/camera_view, 				//-errorage
+	/client/proc/sec_camera_report, 		//-errorage
+	/client/proc/intercom_view, 			//-errorage
+	/client/proc/air_status, //Air things
+	/client/proc/Cell, //More air things
+	/client/proc/atmosscan, //check plumbing
+	/client/proc/powerdebug, //check power
+	/client/proc/count_objects_on_z_level,
+	/client/proc/count_objects_all,
+	/client/proc/cmd_assume_direct_control,	//-errorage
+	/client/proc/startSinglo,
+	/client/proc/set_server_fps,	//allows you to set the ticklag.
+	/client/proc/cmd_admin_grantfullaccess,
+	/client/proc/cmd_admin_areatest_all,
+	/client/proc/cmd_admin_areatest_station,
+	/client/proc/cmd_admin_test_atmos_controllers,
+	/client/proc/cmd_admin_rejuvenate,
+	/datum/admins/proc/show_traitor_panel,
+	/client/proc/disable_communication,
+	/client/proc/cmd_show_at_list,
+	/client/proc/cmd_show_at_markers,
+	/client/proc/manipulate_organs,
+	/client/proc/start_line_profiling,
+	/client/proc/stop_line_profiling,
+	/client/proc/show_line_profiling,
+	/client/proc/create_mapping_job_icons,
+	/client/proc/debug_z_levels,
+	/client/proc/place_ruin
+))
+
+/obj/effect/debugging/mapfix_marker
+	name = "map fix marker"
+	icon = 'icons/mob/screen_gen.dmi'
+	icon_state = "mapfixmarker"
+	desc = "I am a mappers mistake."
+
+/obj/effect/debugging/marker
+	icon = 'icons/turf/areas.dmi'
+	icon_state = "yellow"
+
+/obj/effect/debugging/marker/Move()
+	return 0
+
+/client/proc/camera_view()
+	set category = "Mapping"
+	set name = "Camera Range Display"
+
+	var/on = FALSE
+	for(var/turf/T in world)
+		if(T.maptext)
+			on = TRUE
+		T.maptext = null
+
+	if(!on)
+		var/list/seen = list()
+		for(var/obj/machinery/camera/C in GLOB.cameranet.cameras)
+			for(var/turf/T in C.can_see())
+				seen[T]++
+		for(var/turf/T in seen)
+			T.maptext = "[seen[T]]"
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Show Camera Range") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Show Camera Range")
+
+
+
+/client/proc/sec_camera_report()
+	set category = "Mapping"
+	set name = "Camera Report"
+
+	if(!Master)
+		alert(usr,"Master_controller not found.","Sec Camera Report")
+		return 0
+
+	var/list/obj/machinery/camera/CL = list()
+
+	for(var/obj/machinery/camera/C in GLOB.cameranet.cameras)
+		CL += C
+
+	var/output = {"<B>Camera Abnormalities Report</B><HR>
+<B>The following abnormalities have been detected. The ones in red need immediate attention: Some of those in black may be intentional.</B><BR><ul>"}
+
+	for(var/obj/machinery/camera/C1 in CL)
+		for(var/obj/machinery/camera/C2 in CL)
+			if(C1 != C2)
+				if(C1.c_tag == C2.c_tag)
+					output += "<li><font color='red'>c_tag match for cameras at [ADMIN_VERBOSEJMP(C1)] and [ADMIN_VERBOSEJMP(C2)] - c_tag is [C1.c_tag]</font></li>"
+				if(C1.loc == C2.loc && C1.dir == C2.dir && C1.pixel_x == C2.pixel_x && C1.pixel_y == C2.pixel_y)
+					output += "<li><font color='red'>FULLY overlapping cameras at [ADMIN_VERBOSEJMP(C1)] Networks: [json_encode(C1.network)] and [json_encode(C2.network)]</font></li>"
+				if(C1.loc == C2.loc)
+					output += "<li>Overlapping cameras at [ADMIN_VERBOSEJMP(C1)] Networks: [json_encode(C1.network)] and [json_encode(C2.network)]</li>"
+		var/turf/T = get_step(C1,turn(C1.dir,180))
+		if(!T || !isturf(T) || !T.density )
+			if(!(locate(/obj/structure/grille) in T))
+				var/window_check = 0
+				for(var/obj/structure/window/W in T)
+					if (W.dir == turn(C1.dir,180) || W.dir in list(5,6,9,10) )
+						window_check = 1
+						break
+				if(!window_check)
+					output += "<li><font color='red'>Camera not connected to wall at [ADMIN_VERBOSEJMP(C1)] Network: [json_encode(C1.network)]</font></li>"
+
+	output += "</ul>"
+	usr << browse(output,"window=airreport;size=1000x500")
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Show Camera Report") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/intercom_view()
+	set category = "Mapping"
+	set name = "Intercom Range Display"
+
+	var/static/intercom_range_display_status = FALSE
+	intercom_range_display_status = !intercom_range_display_status //blame cyberboss if this breaks something
+
+	for(var/obj/effect/debugging/marker/M in world)
+		qdel(M)
+
+	if(intercom_range_display_status)
+		for(var/obj/item/radio/intercom/I in world)
+			for(var/turf/T in orange(7,I))
+				var/obj/effect/debugging/marker/F = new/obj/effect/debugging/marker(T)
+				if (!(F in view(7,I.loc)))
+					qdel(F)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Show Intercom Range") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/cmd_show_at_list()
+	set category = "Mapping"
+	set name = "Show roundstart AT list"
+	set desc = "Displays a list of active turfs coordinates at roundstart"
+
+	var/dat = {"<b>Coordinate list of Active Turfs at Roundstart</b>
+	 <br>Real-time Active Turfs list you can see in Air Subsystem at active_turfs var<br>"}
+
+	for(var/t in GLOB.active_turfs_startlist)
+		var/turf/T = t
+		dat += "[ADMIN_VERBOSEJMP(T)]\n"
+		dat += "<br>"
+
+	usr << browse(dat, "window=at_list")
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Show Roundstart Active Turfs") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/cmd_show_at_markers()
+	set category = "Mapping"
+	set name = "Show roundstart AT markers"
+	set desc = "Places a marker on all active-at-roundstart turfs"
+
+	var/count = 0
+	for(var/obj/effect/abstract/marker/at/AT in GLOB.all_abstract_markers)
+		qdel(AT)
+		count++
+
+	if(count)
+		to_chat(usr, "[count] AT markers removed.")
+	else
+		for(var/t in GLOB.active_turfs_startlist)
+			new /obj/effect/abstract/marker/at(t)
+			count++
+		to_chat(usr, "[count] AT markers placed.")
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Show Roundstart Active Turf Markers")
+
+/client/proc/enable_debug_verbs()
+	set category = "Debug"
+	set name = "Debug verbs - Enable"
+	if(!check_rights(R_DEBUG))
+		return
+	verbs -= /client/proc/enable_debug_verbs
+	verbs.Add(/client/proc/disable_debug_verbs, GLOB.admin_verbs_debug_mapping)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Enable Debug Verbs") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/disable_debug_verbs()
+	set category = "Debug"
+	set name = "Debug verbs - Disable"
+	verbs.Remove(/client/proc/disable_debug_verbs, GLOB.admin_verbs_debug_mapping)
+	verbs += /client/proc/enable_debug_verbs
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Disable Debug Verbs") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/count_objects_on_z_level()
+	set category = "Mapping"
+	set name = "Count Objects On Level"
+	var/level = input("Which z-level?","Level?") as text
+	if(!level)
+		return
+	var/num_level = text2num(level)
+	if(!num_level)
+		return
+	if(!isnum(num_level))
+		return
+
+	var/type_text = input("Which type path?","Path?") as text
+	if(!type_text)
+		return
+	var/type_path = text2path(type_text)
+	if(!type_path)
+		return
+
+	var/count = 0
+
+	var/list/atom/atom_list = list()
+
+	for(var/atom/A in world)
+		if(istype(A,type_path))
+			var/atom/B = A
+			while(!(isturf(B.loc)))
+				if(B && B.loc)
+					B = B.loc
+				else
+					break
+			if(B)
+				if(B.z == num_level)
+					count++
+					atom_list += A
+
+	to_chat(world, "There are [count] objects of type [type_path] on z-level [num_level]")
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Count Objects Zlevel") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/count_objects_all()
+	set category = "Mapping"
+	set name = "Count Objects All"
+
+	var/type_text = input("Which type path?","") as text
+	if(!type_text)
+		return
+	var/type_path = text2path(type_text)
+	if(!type_path)
+		return
+
+	var/count = 0
+
+	for(var/atom/A in world)
+		if(istype(A,type_path))
+			count++
+
+	to_chat(world, "There are [count] objects of type [type_path] in the game world")
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Count Objects All") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+
+//This proc is intended to detect lag problems relating to communication procs
+GLOBAL_VAR_INIT(say_disabled, FALSE)
+/client/proc/disable_communication()
+	set category = "Mapping"
+	set name = "Disable all communication verbs"
+
+	GLOB.say_disabled = !GLOB.say_disabled
+	if(GLOB.say_disabled)
+		message_admins("[key] used 'Disable all communication verbs', killing all communication methods.")
+	else
+		message_admins("[key] used 'Disable all communication verbs', restoring all communication methods.")
+
+//This generates the icon states for job starting location landmarks.
+/client/proc/create_mapping_job_icons()
+	set name = "Generate job landmarks icons"
+	set category = "Mapping"
+	var/icon/final = icon()
+	var/mob/living/carbon/human/dummy/D = new(locate(1,1,1)) //spawn on 1,1,1 so we don't have runtimes when items are deleted
+	D.setDir(SOUTH)
+	for(var/job in subtypesof(/datum/job))
+		var/datum/job/JB = new job
+		switch(JB.title)
+			if("AI")
+				final.Insert(icon('icons/mob/ai.dmi', "ai", SOUTH, 1), "AI")
+			if("Cyborg")
+				final.Insert(icon('icons/mob/robots.dmi', "robot", SOUTH, 1), "Cyborg")
+			else
+				for(var/obj/item/I in D)
+					qdel(I)
+				randomize_human(D)
+				JB.equip(D, TRUE, FALSE)
+				COMPILE_OVERLAYS(D)
+				var/icon/I = icon(getFlatIcon(D), frame = 1)
+				final.Insert(I, JB.title)
+	qdel(D)
+	//Also add the x
+	for(var/x_number in 1 to 4)
+		final.Insert(icon('icons/mob/screen_gen.dmi', "x[x_number == 1 ? "" : x_number]"), "x[x_number == 1 ? "" : x_number]")
+	fcopy(final, "icons/mob/landmarks.dmi")
+
+/client/proc/debug_z_levels()
+	set name = "Debug Z-Levels"
+	set category = "Mapping"
+
+	var/list/z_list = SSmapping.z_list
+	var/list/messages = list()
+	messages += "<b>World</b>: [world.maxx] x [world.maxy] x [world.maxz]<br>"
+
+	var/list/linked_levels = list()
+	var/min_x = INFINITY
+	var/min_y = INFINITY
+	var/max_x = -INFINITY
+	var/max_y = -INFINITY
+
+	for(var/z in 1 to max(world.maxz, z_list.len))
+		if (z > z_list.len)
+			messages += "<b>[z]</b>: Unmanaged (out of bounds)<br>"
+			continue
+		var/datum/space_level/S = z_list[z]
+		if (!S)
+			messages += "<b>[z]</b>: Unmanaged (null)<br>"
+			continue
+		var/linkage
+		switch (S.linkage)
+			if (UNAFFECTED)
+				linkage = "no linkage"
+			if (SELFLOOPING)
+				linkage = "self-looping"
+			if (CROSSLINKED)
+				linkage = "linked at ([S.xi], [S.yi])"
+				linked_levels += S
+				min_x = min(min_x, S.xi)
+				min_y = min(min_y, S.yi)
+				max_x = max(max_x, S.xi)
+				max_y = max(max_y, S.yi)
+			else
+				linkage = "unknown linkage '[S.linkage]'"
+
+		messages += "<b>[z]</b>: [S.name], [linkage], traits: [json_encode(S.traits)]<br>"
+		if (S.z_value != z)
+			messages += "-- z_value is [S.z_value], should be [z]<br>"
+		if (S.name == initial(S.name))
+			messages += "-- name not set<br>"
+		if (z > world.maxz)
+			messages += "-- exceeds max z"
+
+	var/grid[max_x - min_x + 1][max_y - min_y + 1]
+	for(var/datum/space_level/S in linked_levels)
+		grid[S.xi - min_x + 1][S.yi - min_y + 1] = S.z_value
+
+	messages += "<table border='1'>"
+	for(var/y in max_y to min_y step -1)
+		var/list/part = list()
+		for(var/x in min_x to max_x)
+			part += "[grid[x - min_x + 1][y - min_y + 1]]"
+		messages += "<tr><td>[part.Join("</td><td>")]</td></tr>"
+	messages += "</table>"
+
+	to_chat(src, messages.Join(""))

code/modules/admin/verbs/maprotation.dm

@@ -0,0 +1,44 @@
+/client/proc/forcerandomrotate()
+	set category = "Server"
+	set name = "Trigger Random Map Rotation"
+	var/rotate = alert("Force a random map rotation to trigger?", "Rotate map?", "Yes", "Cancel")
+	if (rotate != "Yes")
+		return
+	message_admins("[key_name_admin(usr)] is forcing a random map rotation.")
+	log_admin("[key_name(usr)] is forcing a random map rotation.")
+	SSticker.maprotatechecked = 1
+	SSmapping.maprotate()
+
+/client/proc/adminchangemap()
+	set category = "Server"
+	set name = "Change Map"
+	var/list/maprotatechoices = list()
+	for (var/map in config.maplist)
+		var/datum/map_config/VM = config.maplist[map]
+		var/mapname = VM.map_name
+		if (VM == config.defaultmap)
+			mapname += " (Default)"
+
+		if (VM.config_min_users > 0 || VM.config_max_users > 0)
+			mapname += " \["
+			if (VM.config_min_users > 0)
+				mapname += "[VM.config_min_users]"
+			else
+				mapname += "0"
+			mapname += "-"
+			if (VM.config_max_users > 0)
+				mapname += "[VM.config_max_users]"
+			else
+				mapname += "inf"
+			mapname += "\]"
+
+		maprotatechoices[mapname] = VM
+	var/chosenmap = input("Choose a map to change to", "Change Map")  as null|anything in maprotatechoices
+	if (!chosenmap)
+		return
+	SSticker.maprotatechecked = 1
+	var/datum/map_config/VM = maprotatechoices[chosenmap]
+	message_admins("[key_name_admin(usr)] is changing the map to [VM.map_name]")
+	log_admin("[key_name(usr)] is changing the map to [VM.map_name]")
+	if (SSmapping.changemap(VM) == 0)
+		message_admins("[key_name_admin(usr)] has changed the map to [VM.map_name]")

code/modules/admin/verbs/massmodvar.dm

@@ -0,0 +1,265 @@
+/client/proc/cmd_mass_modify_object_variables(atom/A, var_name)
+	set category = "Debug"
+	set name = "Mass Edit Variables"
+	set desc="(target) Edit all instances of a target item's variables"
+
+	var/method = 0	//0 means strict type detection while 1 means this type and all subtypes (IE: /obj/item with this set to 1 will set it to ALL items)
+
+	if(!check_rights(R_VAREDIT))
+		return
+
+	if(A && A.type)
+		method = vv_subtype_prompt(A.type)
+
+	src.massmodify_variables(A, var_name, method)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Mass Edit Variables") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/massmodify_variables(datum/O, var_name = "", method = 0)
+	if(!check_rights(R_VAREDIT))
+		return
+	if(!istype(O))
+		return
+
+	var/variable = ""
+	if(!var_name)
+		var/list/names = list()
+		for (var/V in O.vars)
+			names += V
+
+		names = sortList(names)
+
+		variable = input("Which var?", "Var") as null|anything in names
+	else
+		variable = var_name
+
+	if(!variable || !O.can_vv_get(variable))
+		return
+	var/default
+	var/var_value = O.vars[variable]
+
+	if(variable in GLOB.VVckey_edit)
+		to_chat(src, "It's forbidden to mass-modify ckeys. It'll crash everyone's client you dummy.")
+		return
+	if(variable in GLOB.VVlocked)
+		if(!check_rights(R_DEBUG))
+			return
+	if(variable in GLOB.VVicon_edit_lock)
+		if(!check_rights(R_FUN|R_DEBUG))
+			return
+	if(variable in GLOB.VVpixelmovement)
+		if(!check_rights(R_DEBUG))
+			return
+		var/prompt = alert(src, "Editing this var may irreparably break tile gliding for the rest of the round. THIS CAN'T BE UNDONE", "DANGER", "ABORT ", "Continue", " ABORT")
+		if (prompt != "Continue")
+			return
+
+	default = vv_get_class(variable, var_value)
+
+	if(isnull(default))
+		to_chat(src, "Unable to determine variable type.")
+	else
+		to_chat(src, "Variable appears to be <b>[uppertext(default)]</b>.")
+
+	to_chat(src, "Variable contains: [var_value]")
+
+	if(default == VV_NUM)
+		var/dir_text = ""
+		if(var_value > 0 && var_value < 16)
+			if(var_value & 1)
+				dir_text += "NORTH"
+			if(var_value & 2)
+				dir_text += "SOUTH"
+			if(var_value & 4)
+				dir_text += "EAST"
+			if(var_value & 8)
+				dir_text += "WEST"
+
+		if(dir_text)
+			to_chat(src, "If a direction, direction is: [dir_text]")
+
+	var/value = vv_get_value(default_class = default)
+	var/new_value = value["value"]
+	var/class = value["class"]
+
+	if(!class || !new_value == null && class != VV_NULL)
+		return
+
+	if (class == VV_MESSAGE)
+		class = VV_TEXT
+
+	if (value["type"])
+		class = VV_NEW_TYPE
+
+	var/original_name = "[O]"
+
+	var/rejected = 0
+	var/accepted = 0
+
+	switch(class)
+		if(VV_RESTORE_DEFAULT)
+			to_chat(src, "Finding items...")
+			var/list/items = get_all_of_type(O.type, method)
+			to_chat(src, "Changing [items.len] items...")
+			for(var/thing in items)
+				if (!thing)
+					continue
+				var/datum/D = thing
+				if (D.vv_edit_var(variable, initial(D.vars[variable])) != FALSE)
+					accepted++
+				else
+					rejected++
+				CHECK_TICK
+
+		if(VV_TEXT)
+			var/list/varsvars = vv_parse_text(O, new_value)
+			var/pre_processing = new_value
+			var/unique
+			if (varsvars && varsvars.len)
+				unique = alert(usr, "Process vars unique to each instance, or same for all?", "Variable Association", "Unique", "Same")
+				if(unique == "Unique")
+					unique = TRUE
+				else
+					unique = FALSE
+					for(var/V in varsvars)
+						new_value = replacetext(new_value,"\[[V]]","[O.vars[V]]")
+
+			to_chat(src, "Finding items...")
+			var/list/items = get_all_of_type(O.type, method)
+			to_chat(src, "Changing [items.len] items...")
+			for(var/thing in items)
+				if (!thing)
+					continue
+				var/datum/D = thing
+				if(unique)
+					new_value = pre_processing
+					for(var/V in varsvars)
+						new_value = replacetext(new_value,"\[[V]]","[D.vars[V]]")
+
+				if (D.vv_edit_var(variable, new_value) != FALSE)
+					accepted++
+				else
+					rejected++
+				CHECK_TICK
+
+		if (VV_NEW_TYPE)
+			var/many = alert(src, "Create only one [value["type"]] and assign each or a new one for each thing", "How Many", "One", "Many", "Cancel")
+			if (many == "Cancel")
+				return
+			if (many == "Many")
+				many = TRUE
+			else
+				many = FALSE
+
+			var/type = value["type"]
+			to_chat(src, "Finding items...")
+			var/list/items = get_all_of_type(O.type, method)
+			to_chat(src, "Changing [items.len] items...")
+			for(var/thing in items)
+				if (!thing)
+					continue
+				var/datum/D = thing
+				if(many && !new_value)
+					new_value = new type()
+
+				if (D.vv_edit_var(variable, new_value) != FALSE)
+					accepted++
+				else
+					rejected++
+				new_value = null
+				CHECK_TICK
+
+		else
+			to_chat(src, "Finding items...")
+			var/list/items = get_all_of_type(O.type, method)
+			to_chat(src, "Changing [items.len] items...")
+			for(var/thing in items)
+				if (!thing)
+					continue
+				var/datum/D = thing
+				if (D.vv_edit_var(variable, new_value) != FALSE)
+					accepted++
+				else
+					rejected++
+				CHECK_TICK
+
+
+	var/count = rejected+accepted
+	if (!count)
+		to_chat(src, "No objects found")
+		return
+	if (!accepted)
+		to_chat(src, "Every object rejected your edit")
+		return
+	if (rejected)
+		to_chat(src, "[rejected] out of [count] objects rejected your edit")
+
+	log_world("### MassVarEdit by [src]: [O.type] (A/R [accepted]/[rejected]) [variable]=[html_encode("[O.vars[variable]]")]([list2params(value)])")
+	log_admin("[key_name(src)] mass modified [original_name]'s [variable] to [O.vars[variable]] ([accepted] objects modified)")
+	message_admins("[key_name_admin(src)] mass modified [original_name]'s [variable] to [O.vars[variable]] ([accepted] objects modified)")
+
+
+/proc/get_all_of_type(var/T, subtypes = TRUE)
+	var/list/typecache = list()
+	typecache[T] = 1
+	if (subtypes)
+		typecache = typecacheof(typecache)
+	. = list()
+	if (ispath(T, /mob))
+		for(var/mob/thing in GLOB.mob_list)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /obj/machinery/door))
+		for(var/obj/machinery/door/thing in GLOB.airlocks)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /obj/machinery))
+		for(var/obj/machinery/thing in GLOB.machines)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /obj))
+		for(var/obj/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /atom/movable))
+		for(var/atom/movable/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /turf))
+		for(var/turf/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /atom))
+		for(var/atom/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /client))
+		for(var/client/thing in GLOB.clients)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else if (ispath(T, /datum))
+		for(var/datum/thing)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK
+
+	else
+		for(var/datum/thing in world)
+			if (typecache[thing.type])
+				. += thing
+			CHECK_TICK

code/modules/admin/verbs/modifyvariables.dm

@@ -0,0 +1,644 @@
+GLOBAL_LIST_INIT(VVlocked, list("vars", "datum_flags", "client", "virus", "viruses", "cuffed", "last_eaten", "unlock_content", "force_ending"))
+GLOBAL_PROTECT(VVlocked)
+GLOBAL_LIST_INIT(VVicon_edit_lock, list("icon", "icon_state", "overlays", "underlays", "resize"))
+GLOBAL_PROTECT(VVicon_edit_lock)
+GLOBAL_LIST_INIT(VVckey_edit, list("key", "ckey"))
+GLOBAL_PROTECT(VVckey_edit)
+GLOBAL_LIST_INIT(VVpixelmovement, list("step_x", "step_y", "bound_height", "bound_width", "bound_x", "bound_y"))
+GLOBAL_PROTECT(VVpixelmovement)
+
+
+/client/proc/vv_get_class(var/var_name, var/var_value)
+	if(isnull(var_value))
+		. = VV_NULL
+
+	else if (isnum(var_value))
+		if (var_name in GLOB.bitfields)
+			. = VV_BITFIELD
+		else
+			. = VV_NUM
+
+	else if (istext(var_value))
+		if (findtext(var_value, "\n"))
+			. = VV_MESSAGE
+		else
+			. = VV_TEXT
+
+	else if (isicon(var_value))
+		. = VV_ICON
+
+	else if (ismob(var_value))
+		. = VV_MOB_REFERENCE
+
+	else if (isloc(var_value))
+		. = VV_ATOM_REFERENCE
+
+	else if (istype(var_value, /client))
+		. = VV_CLIENT
+
+	else if (istype(var_value, /datum))
+		. = VV_DATUM_REFERENCE
+
+	else if (ispath(var_value))
+		if (ispath(var_value, /atom))
+			. = VV_ATOM_TYPE
+		else if (ispath(var_value, /datum))
+			. = VV_DATUM_TYPE
+		else
+			. = VV_TYPE
+
+	else if (islist(var_value))
+		. = VV_LIST
+
+	else if (isfile(var_value))
+		. = VV_FILE
+	else
+		. = VV_NULL
+
+/client/proc/vv_get_value(class, default_class, current_value, list/restricted_classes, list/extra_classes, list/classes, var_name)
+	. = list("class" = class, "value" = null)
+	if (!class)
+		if (!classes)
+			classes = list (
+				VV_NUM,
+				VV_TEXT,
+				VV_MESSAGE,
+				VV_ICON,
+				VV_ATOM_REFERENCE,
+				VV_DATUM_REFERENCE,
+				VV_MOB_REFERENCE,
+				VV_CLIENT,
+				VV_ATOM_TYPE,
+				VV_DATUM_TYPE,
+				VV_TYPE,
+				VV_FILE,
+				VV_NEW_ATOM,
+				VV_NEW_DATUM,
+				VV_NEW_TYPE,
+				VV_NEW_LIST,
+				VV_NULL,
+				VV_RESTORE_DEFAULT
+				)
+
+		if(holder && holder.marked_datum && !(VV_MARKED_DATUM in restricted_classes))
+			classes += "[VV_MARKED_DATUM] ([holder.marked_datum.type])"
+		if (restricted_classes)
+			classes -= restricted_classes
+
+		if (extra_classes)
+			classes += extra_classes
+
+		.["class"] = input(src, "What kind of data?", "Variable Type", default_class) as null|anything in classes
+		if (holder && holder.marked_datum && .["class"] == "[VV_MARKED_DATUM] ([holder.marked_datum.type])")
+			.["class"] = VV_MARKED_DATUM
+
+
+	switch(.["class"])
+		if (VV_TEXT)
+			.["value"] = input("Enter new text:", "Text", current_value) as null|text
+			if (.["value"] == null)
+				.["class"] = null
+				return
+		if (VV_MESSAGE)
+			.["value"] = input("Enter new text:", "Text", current_value) as null|message
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+
+		if (VV_NUM)
+			.["value"] = input("Enter new number:", "Num", current_value) as null|num
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+		if (VV_BITFIELD)
+			.["value"] = input_bitfield(usr, "Editing bitfield: [var_name]", var_name, current_value)
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+		if (VV_ATOM_TYPE)
+			.["value"] = pick_closest_path(FALSE)
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+		if (VV_DATUM_TYPE)
+			.["value"] = pick_closest_path(FALSE, get_fancy_list_of_datum_types())
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+		if (VV_TYPE)
+			var/type = current_value
+			var/error = ""
+			do
+				type = input("Enter type:[error]", "Type", type) as null|text
+				if (!type)
+					break
+				type = text2path(type)
+				error = "\nType not found, Please try again"
+			while(!type)
+			if (!type)
+				.["class"] = null
+				return
+			.["value"] = type
+
+
+		if (VV_ATOM_REFERENCE)
+			var/type = pick_closest_path(FALSE)
+			var/subtypes = vv_subtype_prompt(type)
+			if (subtypes == null)
+				.["class"] = null
+				return
+			var/list/things = vv_reference_list(type, subtypes)
+			var/value = input("Select reference:", "Reference", current_value) as null|anything in things
+			if (!value)
+				.["class"] = null
+				return
+			.["value"] = things[value]
+
+		if (VV_DATUM_REFERENCE)
+			var/type = pick_closest_path(FALSE, get_fancy_list_of_datum_types())
+			var/subtypes = vv_subtype_prompt(type)
+			if (subtypes == null)
+				.["class"] = null
+				return
+			var/list/things = vv_reference_list(type, subtypes)
+			var/value = input("Select reference:", "Reference", current_value) as null|anything in things
+			if (!value)
+				.["class"] = null
+				return
+			.["value"] = things[value]
+
+		if (VV_MOB_REFERENCE)
+			var/type = pick_closest_path(FALSE, make_types_fancy(typesof(/mob)))
+			var/subtypes = vv_subtype_prompt(type)
+			if (subtypes == null)
+				.["class"] = null
+				return
+			var/list/things = vv_reference_list(type, subtypes)
+			var/value = input("Select reference:", "Reference", current_value) as null|anything in things
+			if (!value)
+				.["class"] = null
+				return
+			.["value"] = things[value]
+
+
+
+		if (VV_CLIENT)
+			.["value"] = input("Select reference:", "Reference", current_value) as null|anything in GLOB.clients
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+
+		if (VV_FILE)
+			.["value"] = input("Pick file:", "File") as null|file
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+
+		if (VV_ICON)
+			.["value"] = input("Pick icon:", "Icon") as null|icon
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+
+		if (VV_MARKED_DATUM)
+			.["value"] = holder.marked_datum
+			if (.["value"] == null)
+				.["class"] = null
+				return
+
+
+		if (VV_NEW_ATOM)
+			var/type = pick_closest_path(FALSE)
+			if (!type)
+				.["class"] = null
+				return
+			.["type"] = type
+			var/atom/newguy = new type()
+			newguy.datum_flags |= DF_VAR_EDITED
+			.["value"] = newguy
+
+		if (VV_NEW_DATUM)
+			var/type = pick_closest_path(FALSE, get_fancy_list_of_datum_types())
+			if (!type)
+				.["class"] = null
+				return
+			.["type"] = type
+			var/datum/newguy = new type()
+			newguy.datum_flags |= DF_VAR_EDITED
+			.["value"] = newguy
+
+		if (VV_NEW_TYPE)
+			var/type = current_value
+			var/error = ""
+			do
+				type = input("Enter type:[error]", "Type", type) as null|text
+				if (!type)
+					break
+				type = text2path(type)
+				error = "\nType not found, Please try again"
+			while(!type)
+			if (!type)
+				.["class"] = null
+				return
+			.["type"] = type
+			var/datum/newguy = new type()
+			if(istype(newguy))
+				newguy.datum_flags |= DF_VAR_EDITED
+			.["value"] = newguy
+
+
+		if (VV_NEW_LIST)
+			.["value"] = list()
+			.["type"] = /list
+
+/client/proc/vv_parse_text(O, new_var)
+	if(O && findtext(new_var,"\["))
+		var/process_vars = alert(usr,"\[] detected in string, process as variables?","Process Variables?","Yes","No")
+		if(process_vars == "Yes")
+			. = string2listofvars(new_var, O)
+
+//do they want you to include subtypes?
+//FALSE = no subtypes, strict exact type pathing (or the type doesn't have subtypes)
+//TRUE = Yes subtypes
+//NULL = User cancelled at the prompt or invalid type given
+/client/proc/vv_subtype_prompt(var/type)
+	if (!ispath(type))
+		return
+	var/list/subtypes = subtypesof(type)
+	if (!subtypes || !subtypes.len)
+		return FALSE
+	if (subtypes && subtypes.len)
+		switch(alert("Strict object type detection?", "Type detection", "Strictly this type","This type and subtypes", "Cancel"))
+			if("Strictly this type")
+				return FALSE
+			if("This type and subtypes")
+				return TRUE
+			else
+				return
+
+/client/proc/vv_reference_list(type, subtypes)
+	. = list()
+	var/list/types = list(type)
+	if (subtypes)
+		types = typesof(type)
+
+	var/list/fancytypes = make_types_fancy(types)
+
+	for(var/fancytype in fancytypes) //swap the assoication
+		types[fancytypes[fancytype]] = fancytype
+
+	var/things = get_all_of_type(type, subtypes)
+
+	var/i = 0
+	for(var/thing in things)
+		var/datum/D = thing
+		i++
+		//try one of 3 methods to shorten the type text:
+		//	fancy type,
+		//	fancy type with the base type removed from the begaining,
+		//	the type with the base type removed from the begaining
+		var/fancytype = types[D.type]
+		if (findtext(fancytype, types[type]))
+			fancytype = copytext(fancytype, lentext(types[type])+1)
+		var/shorttype = copytext("[D.type]", lentext("[type]")+1)
+		if (lentext(shorttype) > lentext(fancytype))
+			shorttype = fancytype
+		if (!lentext(shorttype))
+			shorttype = "/"
+
+		.["[D]([shorttype])[REF(D)]#[i]"] = D
+
+/client/proc/mod_list_add_ass(atom/O) //hehe
+
+	var/list/L = vv_get_value(restricted_classes = list(VV_RESTORE_DEFAULT))
+	var/class = L["class"]
+	if (!class)
+		return
+	var/var_value = L["value"]
+
+	if(class == VV_TEXT || class == VV_MESSAGE)
+		var/list/varsvars = vv_parse_text(O, var_value)
+		for(var/V in varsvars)
+			var_value = replacetext(var_value,"\[[V]]","[O.vars[V]]")
+
+	return var_value
+
+
+/client/proc/mod_list_add(list/L, atom/O, original_name, objectvar)
+	var/list/LL = vv_get_value(restricted_classes = list(VV_RESTORE_DEFAULT))
+	var/class = LL["class"]
+	if (!class)
+		return
+	var/var_value = LL["value"]
+
+	if(class == VV_TEXT || class == VV_MESSAGE)
+		var/list/varsvars = vv_parse_text(O, var_value)
+		for(var/V in varsvars)
+			var_value = replacetext(var_value,"\[[V]]","[O.vars[V]]")
+
+	if (O)
+		L = L.Copy()
+
+	L += var_value
+
+	switch(alert("Would you like to associate a value with the list entry?",,"Yes","No"))
+		if("Yes")
+			L[var_value] = mod_list_add_ass(O) //hehe
+	if (O)
+		if (O.vv_edit_var(objectvar, L) == FALSE)
+			to_chat(src, "Your edit was rejected by the object.")
+			return
+	log_world("### ListVarEdit by [src]: [(O ? O.type : "/list")] [objectvar]: ADDED=[var_value]")
+	log_admin("[key_name(src)] modified [original_name]'s [objectvar]: ADDED=[var_value]")
+	message_admins("[key_name_admin(src)] modified [original_name]'s [objectvar]: ADDED=[var_value]")
+
+/client/proc/mod_list(list/L, atom/O, original_name, objectvar, index, autodetect_class = FALSE)
+	if(!check_rights(R_VAREDIT))
+		return
+	if(!istype(L, /list))
+		to_chat(src, "Not a List.")
+		return
+
+	if(L.len > 1000)
+		var/confirm = alert(src, "The list you're trying to edit is very long, continuing may crash the server.", "Warning", "Continue", "Abort")
+		if(confirm != "Continue")
+			return
+
+
+
+	var/list/names = list()
+	for (var/i in 1 to L.len)
+		var/key = L[i]
+		var/value
+		if (IS_NORMAL_LIST(L) && !isnum(key))
+			value = L[key]
+		if (value == null)
+			value = "null"
+		names["#[i] [key] = [value]"] = i
+	if (!index)
+		var/variable = input("Which var?","Var") as null|anything in names + "(ADD VAR)" + "(CLEAR NULLS)" + "(CLEAR DUPES)" + "(SHUFFLE)"
+
+		if(variable == null)
+			return
+
+		if(variable == "(ADD VAR)")
+			mod_list_add(L, O, original_name, objectvar)
+			return
+
+		if(variable == "(CLEAR NULLS)")
+			L = L.Copy()
+			listclearnulls(L)
+			if (!O.vv_edit_var(objectvar, L))
+				to_chat(src, "Your edit was rejected by the object.")
+				return
+			log_world("### ListVarEdit by [src]: [O.type] [objectvar]: CLEAR NULLS")
+			log_admin("[key_name(src)] modified [original_name]'s [objectvar]: CLEAR NULLS")
+			message_admins("[key_name_admin(src)] modified [original_name]'s list [objectvar]: CLEAR NULLS")
+			return
+
+		if(variable == "(CLEAR DUPES)")
+			L = uniqueList(L)
+			if (!O.vv_edit_var(objectvar, L))
+				to_chat(src, "Your edit was rejected by the object.")
+				return
+			log_world("### ListVarEdit by [src]: [O.type] [objectvar]: CLEAR DUPES")
+			log_admin("[key_name(src)] modified [original_name]'s [objectvar]: CLEAR DUPES")
+			message_admins("[key_name_admin(src)] modified [original_name]'s list [objectvar]: CLEAR DUPES")
+			return
+
+		if(variable == "(SHUFFLE)")
+			L = shuffle(L)
+			if (!O.vv_edit_var(objectvar, L))
+				to_chat(src, "Your edit was rejected by the object.")
+				return
+			log_world("### ListVarEdit by [src]: [O.type] [objectvar]: SHUFFLE")
+			log_admin("[key_name(src)] modified [original_name]'s [objectvar]: SHUFFLE")
+			message_admins("[key_name_admin(src)] modified [original_name]'s list [objectvar]: SHUFFLE")
+			return
+
+		index = names[variable]
+
+
+	var/assoc_key
+	if (index == null)
+		return
+	var/assoc = 0
+	var/prompt = alert(src, "Do you want to edit the key or its assigned value?", "Associated List", "Key", "Assigned Value", "Cancel")
+	if (prompt == "Cancel")
+		return
+	if (prompt == "Assigned Value")
+		assoc = 1
+		assoc_key = L[index]
+	var/default
+	var/variable
+	if (assoc)
+		variable = L[assoc_key]
+	else
+		variable = L[index]
+
+	default = vv_get_class(objectvar, variable)
+
+	to_chat(src, "Variable appears to be <b>[uppertext(default)]</b>.")
+
+	to_chat(src, "Variable contains: [variable]")
+
+	if(default == VV_NUM)
+		var/dir_text = ""
+		var/tdir = variable
+		if(tdir > 0 && tdir < 16)
+			if(tdir & 1)
+				dir_text += "NORTH"
+			if(tdir & 2)
+				dir_text += "SOUTH"
+			if(tdir & 4)
+				dir_text += "EAST"
+			if(tdir & 8)
+				dir_text += "WEST"
+
+		if(dir_text)
+			to_chat(usr, "If a direction, direction is: [dir_text]")
+
+	var/original_var = variable
+
+	if (O)
+		L = L.Copy()
+	var/class
+	if(autodetect_class)
+		if (default == VV_TEXT)
+			default = VV_MESSAGE
+		class = default
+	var/list/LL = vv_get_value(default_class = default, current_value = original_var, restricted_classes = list(VV_RESTORE_DEFAULT), extra_classes = list(VV_LIST, "DELETE FROM LIST"))
+	class = LL["class"]
+	if (!class)
+		return
+	var/new_var = LL["value"]
+
+	if(class == VV_MESSAGE)
+		class = VV_TEXT
+
+	switch(class) //Spits a runtime error if you try to modify an entry in the contents list. Dunno how to fix it, yet.
+		if(VV_LIST)
+			mod_list(variable, O, original_name, objectvar)
+
+		if("DELETE FROM LIST")
+			L.Cut(index, index+1)
+			if (O)
+				if (O.vv_edit_var(objectvar, L))
+					to_chat(src, "Your edit was rejected by the object.")
+					return
+			log_world("### ListVarEdit by [src]: [O.type] [objectvar]: REMOVED=[html_encode("[original_var]")]")
+			log_admin("[key_name(src)] modified [original_name]'s [objectvar]: REMOVED=[original_var]")
+			message_admins("[key_name_admin(src)] modified [original_name]'s [objectvar]: REMOVED=[original_var]")
+			return
+
+		if(VV_TEXT)
+			var/list/varsvars = vv_parse_text(O, new_var)
+			for(var/V in varsvars)
+				new_var = replacetext(new_var,"\[[V]]","[O.vars[V]]")
+
+
+	if(assoc)
+		L[assoc_key] = new_var
+	else
+		L[index] = new_var
+	if (O)
+		if (O.vv_edit_var(objectvar, L) == FALSE)
+			to_chat(src, "Your edit was rejected by the object.")
+			return
+	log_world("### ListVarEdit by [src]: [(O ? O.type : "/list")] [objectvar]: [original_var]=[new_var]")
+	log_admin("[key_name(src)] modified [original_name]'s [objectvar]: [original_var]=[new_var]")
+	message_admins("[key_name_admin(src)] modified [original_name]'s varlist [objectvar]: [original_var]=[new_var]")
+
+/proc/vv_varname_lockcheck(param_var_name)
+	if(param_var_name in GLOB.VVlocked)
+		if(!check_rights(R_DEBUG))
+			return FALSE
+	if(param_var_name in GLOB.VVckey_edit)
+		if(!check_rights(R_SPAWN|R_DEBUG))
+			return FALSE
+	if(param_var_name in GLOB.VVicon_edit_lock)
+		if(!check_rights(R_FUN|R_DEBUG))
+			return FALSE
+	if(param_var_name in GLOB.VVpixelmovement)
+		if(!check_rights(R_DEBUG))
+			return FALSE
+		var/prompt = alert(usr, "Editing this var may irreparably break tile gliding for the rest of the round. THIS CAN'T BE UNDONE", "DANGER", "ABORT ", "Continue", " ABORT")
+		if (prompt != "Continue")
+			return FALSE
+	return TRUE
+	
+
+/client/proc/modify_variables(atom/O, param_var_name = null, autodetect_class = 0)
+	if(!check_rights(R_VAREDIT))
+		return
+
+	var/class
+	var/variable
+	var/var_value
+
+	if(param_var_name)
+		if(!param_var_name in O.vars)
+			to_chat(src, "A variable with this name ([param_var_name]) doesn't exist in this datum ([O])")
+			return
+		variable = param_var_name
+
+	else
+		var/list/names = list()
+		for (var/V in O.vars)
+			names += V
+
+		names = sortList(names)
+
+		variable = input("Which var?","Var") as null|anything in names
+		if(!variable)
+			return
+
+	if(!O.can_vv_get(variable))
+		return
+
+	var_value = O.vars[variable]
+	if(!vv_varname_lockcheck(variable))
+		return
+	if(istype(O, /datum/armor))
+		var/prompt = alert(src, "Editing this var changes this value on potentially thousands of items that share the same combination of armor values. If you want to edit the armor of just one item, use the \"Modify armor values\" dropdown item", "DANGER", "ABORT ", "Continue", " ABORT")
+		if (prompt != "Continue")
+			return
+
+
+	var/default = vv_get_class(variable, var_value)
+
+	if(isnull(default))
+		to_chat(src, "Unable to determine variable type.")
+	else
+		to_chat(src, "Variable appears to be <b>[uppertext(default)]</b>.")
+
+	to_chat(src, "Variable contains: [var_value]")
+
+	if(default == VV_NUM)
+		var/dir_text = ""
+		if(var_value > 0 && var_value < 16)
+			if(var_value & 1)
+				dir_text += "NORTH"
+			if(var_value & 2)
+				dir_text += "SOUTH"
+			if(var_value & 4)
+				dir_text += "EAST"
+			if(var_value & 8)
+				dir_text += "WEST"
+
+		if(dir_text)
+			to_chat(src, "If a direction, direction is: [dir_text]")
+
+	if(autodetect_class && default != VV_NULL)
+		if (default == VV_TEXT)
+			default = VV_MESSAGE
+		class = default
+
+	var/list/value = vv_get_value(class, default, var_value, extra_classes = list(VV_LIST), var_name = variable)
+	class = value["class"]
+
+	if (!class)
+		return
+	var/var_new = value["value"]
+
+	if(class == VV_MESSAGE)
+		class = VV_TEXT
+
+	var/original_name = "[O]"
+
+	switch(class)
+		if(VV_LIST)
+			if(!islist(var_value))
+				mod_list(list(), O, original_name, variable)
+
+			mod_list(var_value, O, original_name, variable)
+			return
+
+		if(VV_RESTORE_DEFAULT)
+			var_new = initial(O.vars[variable])
+
+		if(VV_TEXT)
+			var/list/varsvars = vv_parse_text(O, var_new)
+			for(var/V in varsvars)
+				var_new = replacetext(var_new,"\[[V]]","[O.vars[V]]")
+
+
+	if (O.vv_edit_var(variable, var_new) == FALSE)
+		to_chat(src, "Your edit was rejected by the object.")
+		return
+	vv_update_display(O, "varedited", VV_MSG_EDITED)
+	SEND_GLOBAL_SIGNAL(COMSIG_GLOB_VAR_EDIT, args)
+	log_world("### VarEdit by [key_name(src)]: [O.type] [variable]=[var_value] => [var_new]")
+	log_admin("[key_name(src)] modified [original_name]'s [variable] from [html_encode("[var_value]")] to [html_encode("[var_new]")]")
+	var/msg = "[key_name_admin(src)] modified [original_name]'s [variable] from [var_value] to [var_new]"
+	message_admins(msg)
+	admin_ticket_log(O, msg)
+	return TRUE

code/modules/admin/verbs/one_click_antag.dm

@@ -0,0 +1,458 @@
+/client/proc/one_click_antag()
+	set name = "Create Antagonist"
+	set desc = "Auto-create an antagonist of your choice"
+	set category = "Admin"
+
+	if(holder)
+		holder.one_click_antag()
+	return
+
+
+/datum/admins/proc/one_click_antag()
+
+	var/dat = {"
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=traitors'>Make Traitors</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=changelings'>Make Changelings</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=revs'>Make Revs</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=cult'>Make Cult</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=clockcult'>Make Clockwork Cult</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=blob'>Make Blob</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=wizard'>Make Wizard (Requires Ghosts)</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=nukeops'>Make Nuke Team (Requires Ghosts)</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=centcom'>Make CentCom Response Team (Requires Ghosts)</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=abductors'>Make Abductor Team (Requires Ghosts)</a><br>
+		<a href='?src=[REF(src)];[HrefToken()];makeAntag=revenant'>Make Revenant (Requires Ghost)</a><br>
+		"}
+
+	var/datum/browser/popup = new(usr, "oneclickantag", "Quick-Create Antagonist", 400, 400)
+	popup.set_content(dat)
+	popup.open()
+
+/datum/admins/proc/isReadytoRumble(mob/living/carbon/human/applicant, targetrole, onstation = TRUE, conscious = TRUE)
+	if(applicant.mind.special_role)
+		return FALSE
+	if(!(targetrole in applicant.client.prefs.be_special))
+		return FALSE
+	if(onstation)
+		var/turf/T = get_turf(applicant)
+		if(!is_station_level(T.z))
+			return FALSE
+	if(conscious && applicant.stat) //incase you don't care about a certain antag being unconcious when made, ie if they have selfhealing abilities.
+		return FALSE
+	if(!considered_alive(applicant.mind) || considered_afk(applicant.mind)) //makes sure the player isn't a zombie, brain, or just afk all together
+		return FALSE
+	return (!jobban_isbanned(applicant, targetrole) && !jobban_isbanned(applicant, ROLE_SYNDICATE))
+
+
+/datum/admins/proc/makeTraitors()
+	var/datum/game_mode/traitor/temp = new
+
+	if(CONFIG_GET(flag/protect_roles_from_antagonist))
+		temp.restricted_jobs += temp.protected_jobs
+
+	if(CONFIG_GET(flag/protect_assistant_from_antagonist))
+		temp.restricted_jobs += "Assistant"
+
+	var/list/mob/living/carbon/human/candidates = list()
+	var/mob/living/carbon/human/H = null
+
+	for(var/mob/living/carbon/human/applicant in GLOB.player_list)
+		if(isReadytoRumble(applicant, ROLE_TRAITOR))
+			if(temp.age_check(applicant.client))
+				if(!(applicant.job in temp.restricted_jobs))
+					candidates += applicant
+
+	if(candidates.len)
+		var/numTraitors = min(candidates.len, 3)
+
+		for(var/i = 0, i<numTraitors, i++)
+			H = pick(candidates)
+			H.mind.make_Traitor()
+			candidates.Remove(H)
+
+		return 1
+
+
+	return 0
+
+
+/datum/admins/proc/makeChangelings()
+
+	var/datum/game_mode/changeling/temp = new
+	if(CONFIG_GET(flag/protect_roles_from_antagonist))
+		temp.restricted_jobs += temp.protected_jobs
+
+	if(CONFIG_GET(flag/protect_assistant_from_antagonist))
+		temp.restricted_jobs += "Assistant"
+
+	var/list/mob/living/carbon/human/candidates = list()
+	var/mob/living/carbon/human/H = null
+
+	for(var/mob/living/carbon/human/applicant in GLOB.player_list)
+		if(isReadytoRumble(applicant, ROLE_CHANGELING))
+			if(temp.age_check(applicant.client))
+				if(!(applicant.job in temp.restricted_jobs))
+					candidates += applicant
+
+	if(candidates.len)
+		var/numChangelings = min(candidates.len, 3)
+
+		for(var/i = 0, i<numChangelings, i++)
+			H = pick(candidates)
+			H.mind.make_Changeling()
+			candidates.Remove(H)
+
+		return 1
+
+	return 0
+
+/datum/admins/proc/makeRevs()
+
+	var/datum/game_mode/revolution/temp = new
+	if(CONFIG_GET(flag/protect_roles_from_antagonist))
+		temp.restricted_jobs += temp.protected_jobs
+
+	if(CONFIG_GET(flag/protect_assistant_from_antagonist))
+		temp.restricted_jobs += "Assistant"
+
+	var/list/mob/living/carbon/human/candidates = list()
+	var/mob/living/carbon/human/H = null
+
+	for(var/mob/living/carbon/human/applicant in GLOB.player_list)
+		if(isReadytoRumble(applicant, ROLE_REV))
+			if(temp.age_check(applicant.client))
+				if(!(applicant.job in temp.restricted_jobs))
+					candidates += applicant
+
+	if(candidates.len)
+		var/numRevs = min(candidates.len, 3)
+
+		for(var/i = 0, i<numRevs, i++)
+			H = pick(candidates)
+			H.mind.make_Rev()
+			candidates.Remove(H)
+		return 1
+
+	return 0
+
+/datum/admins/proc/makeWizard()
+
+	var/list/mob/dead/observer/candidates = pollGhostCandidates("Do you wish to be considered for the position of a Wizard Foundation 'diplomat'?", ROLE_WIZARD, null)
+
+	var/mob/dead/observer/selected = pick_n_take(candidates)
+
+	var/mob/living/carbon/human/new_character = makeBody(selected)
+	new_character.mind.make_Wizard()
+	return TRUE
+
+
+/datum/admins/proc/makeCult()
+	var/datum/game_mode/cult/temp = new
+	if(CONFIG_GET(flag/protect_roles_from_antagonist))
+		temp.restricted_jobs += temp.protected_jobs
+
+	if(CONFIG_GET(flag/protect_assistant_from_antagonist))
+		temp.restricted_jobs += "Assistant"
+
+	var/list/mob/living/carbon/human/candidates = list()
+	var/mob/living/carbon/human/H = null
+
+	for(var/mob/living/carbon/human/applicant in GLOB.player_list)
+		if(isReadytoRumble(applicant, ROLE_CULTIST))
+			if(temp.age_check(applicant.client))
+				if(!(applicant.job in temp.restricted_jobs))
+					candidates += applicant
+
+	if(candidates.len)
+		var/numCultists = min(candidates.len, 4)
+
+		for(var/i = 0, i<numCultists, i++)
+			H = pick(candidates)
+			H.mind.make_Cultist()
+			candidates.Remove(H)
+
+		return 1
+
+	return 0
+
+
+/datum/admins/proc/makeClockCult()
+	var/datum/game_mode/clockwork_cult/temp = new
+	if(CONFIG_GET(flag/protect_roles_from_antagonist))
+		temp.restricted_jobs += temp.protected_jobs
+
+	if(CONFIG_GET(flag/protect_assistant_from_antagonist))
+		temp.restricted_jobs += "Assistant"
+
+	var/list/mob/living/carbon/human/candidates = list()
+	var/mob/living/carbon/human/H = null
+
+	for(var/mob/living/carbon/human/applicant in GLOB.player_list)
+		if(isReadytoRumble(applicant, ROLE_SERVANT_OF_RATVAR))
+			if(temp.age_check(applicant.client))
+				if(!(applicant.job in temp.restricted_jobs))
+					candidates += applicant
+
+	if(candidates.len)
+		var/numCultists = min(candidates.len, 4)
+
+		for(var/i = 0, i<numCultists, i++)
+			H = pick(candidates)
+			to_chat(H, "<span class='heavy_brass'>The world before you suddenly glows a brilliant yellow. You hear the whooshing steam and clanking cogs of a billion billion machines, and all at once \
+			you see the truth. Ratvar, the Clockwork Justiciar, lies derelict and forgotten in an unseen realm, and he has selected you as one of his harbringers. You are now a servant of \
+			Ratvar, and you will bring him back.</span>")
+			H.playsound_local(get_turf(H), 'sound/ambience/antag/clockcultalr.ogg', 100, FALSE, pressure_affected = FALSE)
+			add_servant_of_ratvar(H, TRUE)
+			SSticker.mode.equip_servant(H)
+			candidates.Remove(H)
+
+		return 1
+
+	return 0
+
+
+
+/datum/admins/proc/makeNukeTeam()
+	var/datum/game_mode/nuclear/temp = new
+	var/list/mob/dead/observer/candidates = pollGhostCandidates("Do you wish to be considered for a nuke team being sent in?", ROLE_OPERATIVE, temp)
+	var/list/mob/dead/observer/chosen = list()
+	var/mob/dead/observer/theghost = null
+
+	if(candidates.len)
+		var/numagents = 5
+		var/agentcount = 0
+
+		for(var/i = 0, i<numagents,i++)
+			shuffle_inplace(candidates) //More shuffles means more randoms
+			for(var/mob/j in candidates)
+				if(!j || !j.client)
+					candidates.Remove(j)
+					continue
+
+				theghost = j
+				candidates.Remove(theghost)
+				chosen += theghost
+				agentcount++
+				break
+		//Making sure we have atleast 3 Nuke agents, because less than that is kinda bad
+		if(agentcount < 3)
+			return 0
+
+		//Let's find the spawn locations
+		var/leader_chosen = FALSE
+		var/datum/team/nuclear/nuke_team
+		for(var/mob/c in chosen)
+			var/mob/living/carbon/human/new_character=makeBody(c)
+			if(!leader_chosen)
+				leader_chosen = TRUE
+				var/datum/antagonist/nukeop/N = new_character.mind.add_antag_datum(/datum/antagonist/nukeop/leader)
+				nuke_team = N.nuke_team
+			else
+				new_character.mind.add_antag_datum(/datum/antagonist/nukeop,nuke_team)
+		return 1
+	else
+		return 0
+
+
+
+
+
+/datum/admins/proc/makeAliens()
+	var/datum/round_event/ghost_role/alien_infestation/E = new(FALSE)
+	E.spawncount = 3
+	// TODO The fact we have to do this rather than just have events start
+	// when we ask them to, is bad.
+	E.processing = TRUE
+	return TRUE
+
+/datum/admins/proc/makeSpaceNinja()
+	new /datum/round_event/ghost_role/ninja()
+	return 1
+
+// DEATH SQUADS
+/datum/admins/proc/makeDeathsquad()
+	return makeEmergencyresponseteam(/datum/ert/deathsquad)
+
+// CENTCOM RESPONSE TEAM
+
+/datum/admins/proc/makeERTTemplateModified(list/settings)
+	. = settings
+	var/datum/ert/newtemplate = settings["mainsettings"]["template"]["value"]
+	if (isnull(newtemplate))
+		return
+	if (!ispath(newtemplate))
+		newtemplate = text2path(newtemplate)
+	newtemplate = new newtemplate
+	.["mainsettings"]["teamsize"]["value"] = newtemplate.teamsize
+	.["mainsettings"]["mission"]["value"] = newtemplate.mission
+	.["mainsettings"]["polldesc"]["value"] = newtemplate.polldesc
+	.["mainsettings"]["open_armory"]["value"] = newtemplate.opendoors ? "Yes" : "No"
+
+
+/datum/admins/proc/equipAntagOnDummy(mob/living/carbon/human/dummy/mannequin, datum/antagonist/antag)
+	for(var/I in mannequin.get_equipped_items(TRUE))
+		qdel(I)
+	if (ispath(antag, /datum/antagonist/ert))
+		var/datum/antagonist/ert/ert = antag
+		mannequin.equipOutfit(initial(ert.outfit), TRUE)
+	else if (ispath(antag, /datum/antagonist/official))
+		mannequin.equipOutfit(/datum/outfit/centcom_official, TRUE)
+
+/datum/admins/proc/makeERTPreviewIcon(list/settings)
+	// Set up the dummy for its photoshoot
+	var/mob/living/carbon/human/dummy/mannequin = generate_or_wait_for_human_dummy(DUMMY_HUMAN_SLOT_ADMIN)
+
+	var/prefs = settings["mainsettings"]
+	var/datum/ert/template = prefs["template"]["value"]
+	if (isnull(template))
+		return null
+	if (!ispath(template))
+		template = text2path(prefs["template"]["value"]) // new text2path ... doesn't compile in 511
+
+	template = new template
+	var/datum/antagonist/ert/ert = template.leader_role
+
+	equipAntagOnDummy(mannequin, ert)
+
+	COMPILE_OVERLAYS(mannequin)
+	CHECK_TICK
+	var/icon/preview_icon = icon('icons/effects/effects.dmi', "nothing")
+	preview_icon.Scale(48+32, 16+32)
+	CHECK_TICK
+	mannequin.setDir(NORTH)
+	var/icon/stamp = getFlatIcon(mannequin)
+	CHECK_TICK
+	preview_icon.Blend(stamp, ICON_OVERLAY, 25, 17)
+	CHECK_TICK
+	mannequin.setDir(WEST)
+	stamp = getFlatIcon(mannequin)
+	CHECK_TICK
+	preview_icon.Blend(stamp, ICON_OVERLAY, 1, 9)
+	CHECK_TICK
+	mannequin.setDir(SOUTH)
+	stamp = getFlatIcon(mannequin)
+	CHECK_TICK
+	preview_icon.Blend(stamp, ICON_OVERLAY, 49, 1)
+	CHECK_TICK
+	preview_icon.Scale(preview_icon.Width() * 2, preview_icon.Height() * 2) // Scaling here to prevent blurring in the browser.
+	CHECK_TICK
+	unset_busy_human_dummy(DUMMY_HUMAN_SLOT_ADMIN)
+	return preview_icon
+
+/datum/admins/proc/makeEmergencyresponseteam(var/datum/ert/ertemplate = null)
+	if (ertemplate)
+		ertemplate = new ertemplate
+	else
+		ertemplate = new /datum/ert/centcom_official
+
+	var/list/settings = list(
+		"preview_callback" = CALLBACK(src, .proc/makeERTPreviewIcon),
+		"mainsettings" = list(
+		"template" = list("desc" = "Template", "callback" = CALLBACK(src, .proc/makeERTTemplateModified), "type" = "datum", "path" = "/datum/ert", "subtypesonly" = TRUE, "value" = ertemplate.type),
+		"teamsize" = list("desc" = "Team Size", "type" = "number", "value" = ertemplate.teamsize),
+		"mission" = list("desc" = "Mission", "type" = "string", "value" = ertemplate.mission),
+		"polldesc" = list("desc" = "Ghost poll description", "type" = "string", "value" = ertemplate.polldesc),
+		"enforce_human" = list("desc" = "Enforce human authority", "type" = "boolean", "value" = "[(CONFIG_GET(flag/enforce_human_authority) ? "Yes" : "No")]"),
+		"open_armory" = list("desc" = "Open armory doors", "type" = "boolean", "value" = "[(ertemplate.opendoors ? "Yes" : "No")]"),
+		)
+	)
+
+	var/list/prefreturn = presentpreflikepicker(usr,"Customize ERT", "Customize ERT", Button1="Ok", width = 600, StealFocus = 1,Timeout = 0, settings=settings)
+
+	if (isnull(prefreturn))
+		return FALSE
+
+	if (prefreturn["button"] == 1)
+		var/list/prefs = settings["mainsettings"]
+
+		var/templtype = prefs["template"]["value"]
+		if (!ispath(prefs["template"]["value"]))
+			templtype = text2path(prefs["template"]["value"]) // new text2path ... doesn't compile in 511
+
+		if (ertemplate.type != templtype)
+			ertemplate = new templtype
+
+		ertemplate.teamsize = prefs["teamsize"]["value"]
+		ertemplate.mission = prefs["mission"]["value"]
+		ertemplate.polldesc = prefs["polldesc"]["value"]
+		ertemplate.enforce_human = prefs["enforce_human"]["value"] == "Yes" ? TRUE : FALSE
+		ertemplate.opendoors = prefs["open_armory"]["value"] == "Yes" ? TRUE : FALSE
+
+		var/list/mob/dead/observer/candidates = pollGhostCandidates("Do you wish to be considered for [ertemplate.polldesc] ?", "deathsquad", null)
+		var/teamSpawned = FALSE
+
+		if(candidates.len > 0)
+			//Pick the (un)lucky players
+			var/numagents = min(ertemplate.teamsize,candidates.len)
+
+			//Create team
+			var/datum/team/ert/ert_team = new ertemplate.team
+			if(ertemplate.rename_team)
+				ert_team.name = ertemplate.rename_team
+
+			//Asign team objective
+			var/datum/objective/missionobj = new
+			missionobj.team = ert_team
+			missionobj.explanation_text = ertemplate.mission
+			missionobj.completed = TRUE
+			ert_team.objectives += missionobj
+			ert_team.mission = missionobj
+
+			var/list/spawnpoints = GLOB.emergencyresponseteamspawn
+			while(numagents && candidates.len)
+				if (numagents > spawnpoints.len)
+					numagents--
+					continue // This guy's unlucky, not enough spawn points, we skip him.
+				var/spawnloc = spawnpoints[numagents]
+				var/mob/dead/observer/chosen_candidate = pick(candidates)
+				candidates -= chosen_candidate
+				if(!chosen_candidate.key)
+					continue
+
+				//Spawn the body
+				var/mob/living/carbon/human/ERTOperative = new ertemplate.mobtype(spawnloc)
+				chosen_candidate.client.prefs.copy_to(ERTOperative)
+				ERTOperative.key = chosen_candidate.key
+
+				if(ertemplate.enforce_human || ERTOperative.dna.species.dangerous_existence) // Don't want any exploding plasmemes
+					ERTOperative.set_species(/datum/species/human)
+
+				//Give antag datum
+				var/datum/antagonist/ert/ert_antag
+
+				if(numagents == 1)
+					ert_antag = new ertemplate.leader_role
+				else
+					ert_antag = ertemplate.roles[WRAP(numagents,1,length(ertemplate.roles) + 1)]
+					ert_antag = new ert_antag
+
+				ERTOperative.mind.add_antag_datum(ert_antag,ert_team)
+				ERTOperative.mind.assigned_role = ert_antag.name
+
+				//Logging and cleanup
+				log_game("[key_name(ERTOperative)] has been selected as an [ert_antag.name]")
+				numagents--
+				teamSpawned++
+
+			if (teamSpawned)
+				message_admins("[ertemplate.polldesc] has spawned with the mission: [ertemplate.mission]")
+
+			//Open the Armory doors
+			if(ertemplate.opendoors)
+				for(var/obj/machinery/door/poddoor/ert/door in GLOB.airlocks)
+					door.open()
+					CHECK_TICK
+			return TRUE
+		else
+			return FALSE
+
+	return
+
+//Abductors
+/datum/admins/proc/makeAbductorTeam()
+	new /datum/round_event/ghost_role/abductor
+	return 1
+
+/datum/admins/proc/makeRevenant()
+	new /datum/round_event/ghost_role/revenant(TRUE, TRUE)
+	return 1

code/modules/admin/verbs/onlyone.dm

@@ -0,0 +1,31 @@
+GLOBAL_VAR_INIT(highlander, FALSE)
+/client/proc/only_one() //Gives everyone kilts, berets, claymores, and pinpointers, with the objective to hijack the emergency shuttle.
+	if(!SSticker.HasRoundStarted())
+		alert("The game hasn't started yet!")
+		return
+	GLOB.highlander = TRUE
+
+	send_to_playing_players("<span class='boldannounce'><font size=6>THERE CAN BE ONLY ONE</font></span>")
+
+	for(var/obj/item/disk/nuclear/N in GLOB.poi_list)
+		var/datum/component/stationloving/component = N.GetComponent(/datum/component/stationloving)
+		if (component)
+			component.relocate() //Gets it out of bags and such
+
+	for(var/mob/living/carbon/human/H in GLOB.player_list)
+		if(H.stat == DEAD || !(H.client))
+			continue
+		H.make_scottish()
+
+	message_admins("<span class='adminnotice'>[key_name_admin(usr)] used THERE CAN BE ONLY ONE!</span>")
+	log_admin("[key_name(usr)] used THERE CAN BE ONLY ONE.")
+	addtimer(CALLBACK(SSshuttle.emergency, /obj/docking_port/mobile/emergency.proc/request, null, 1), 50)
+
+/client/proc/only_one_delayed()
+	send_to_playing_players("<span class='userdanger'>Bagpipes begin to blare. You feel Scottish pride coming over you.</span>")
+	message_admins("<span class='adminnotice'>[key_name_admin(usr)] used (delayed) THERE CAN BE ONLY ONE!</span>")
+	log_admin("[key_name(usr)] used delayed THERE CAN BE ONLY ONE.")
+	addtimer(CALLBACK(src, .proc/only_one), 420)
+
+/mob/living/carbon/human/proc/make_scottish()
+	mind.add_antag_datum(/datum/antagonist/highlander)

code/modules/admin/verbs/panicbunker.dm

@@ -0,0 +1,42 @@
+/client/proc/panicbunker()
+	set category = "Server"
+	set name = "Toggle Panic Bunker"
+	if (!CONFIG_GET(flag/sql_enabled))
+		to_chat(usr, "<span class='adminnotice'>The Database is not enabled!</span>")
+		return
+
+	var/new_pb = !CONFIG_GET(flag/panic_bunker)
+	CONFIG_SET(flag/panic_bunker, new_pb)
+
+	log_admin("[key_name(usr)] has toggled the Panic Bunker, it is now [new_pb ? "on" : "off"]")
+	message_admins("[key_name_admin(usr)] has toggled the Panic Bunker, it is now [new_pb ? "enabled" : "disabled"].")
+	if (new_pb && !SSdbcore.Connect())
+		message_admins("The Database is not connected! Panic bunker will not work until the connection is reestablished.")
+	SSblackbox.record_feedback("nested tally", "admin_toggle", 1, list("Toggle Panic Bunker", "[new_pb ? "Enabled" : "Disabled"]")) //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+	send2irc("Panic Bunker", "[key_name(usr)] has toggled the Panic Bunker, it is now [new_pb ? "enabled" : "disabled"].")
+
+/client/proc/addbunkerbypass(ckeytobypass as text)
+	set category = "Special Verbs"
+	set name = "Add PB Bypass"
+	set desc = "Allows a given ckey to connect despite the panic bunker for a given round."
+	if(!CONFIG_GET(flag/sql_enabled))
+		to_chat(usr, "<span class='adminnotice'>The Database is not enabled!</span>")
+		return
+
+	GLOB.bunker_passthrough |= ckey(ckeytobypass)
+	log_admin("[key_name(usr)] has added [ckeytobypass] to the current round's bunker bypass list.")
+	message_admins("[key_name_admin(usr)] has added [ckeytobypass] to the current round's bunker bypass list.")
+	send2irc("Panic Bunker", "[key_name(usr)] has added [ckeytobypass] to the current round's bunker bypass list.")
+
+/client/proc/revokebunkerbypass(ckeytobypass as text)
+	set category = "Special Verbs"
+	set name = "Revoke PB Bypass"
+	set desc = "Revoke's a ckey's permission to bypass the panic bunker for a given round."
+	if(!CONFIG_GET(flag/sql_enabled))
+		to_chat(usr, "<span class='adminnotice'>The Database is not enabled!</span>")
+		return
+
+	GLOB.bunker_passthrough -= ckey(ckeytobypass)
+	log_admin("[key_name(usr)] has removed [ckeytobypass] from the current round's bunker bypass list.")
+	message_admins("[key_name_admin(usr)] has removed [ckeytobypass] from the current round's bunker bypass list.")
+	send2irc("Panic Bunker", "[key_name(usr)] has removed [ckeytobypass] from the current round's bunker bypass list.")

code/modules/admin/verbs/playsound.dm

@@ -0,0 +1,203 @@
+/client/proc/play_sound(S as sound)
+	set category = "Fun"
+	set name = "Play Global Sound"
+	if(!check_rights(R_SOUNDS))
+		return
+
+	var/vol = input(usr, "What volume would you like the sound to play at?",, 100) as null|num
+	if(!vol)
+		return
+	var/freq = input(usr, "What frequency would you like the sound to play at?",, 1) as null|num
+	if(!freq)
+		freq = 1
+	vol = CLAMP(vol, 1, 100)
+
+	var/sound/admin_sound = new()
+	admin_sound.file = S
+	admin_sound.priority = 250
+	admin_sound.channel = CHANNEL_ADMIN
+	admin_sound.frequency = freq
+	admin_sound.wait = 1
+	admin_sound.repeat = 0
+	admin_sound.status = SOUND_STREAM
+	admin_sound.volume = vol
+
+	var/res = alert(usr, "Show the title of this song to the players?",, "Yes","No", "Cancel")
+	switch(res)
+		if("Yes")
+			to_chat(world, "<span class='boldannounce'>An admin played: [S]</span>")
+		if("Cancel")
+			return
+
+	log_admin("[key_name(src)] played sound [S]")
+	message_admins("[key_name_admin(src)] played sound [S]")
+
+	for(var/mob/M in GLOB.player_list)
+		if(M.client.prefs.toggles & SOUND_MIDI)
+			var/user_vol = M.client.chatOutput.adminMusicVolume
+			if(user_vol)
+				admin_sound.volume = vol * (user_vol / 100)
+			SEND_SOUND(M, admin_sound)
+			admin_sound.volume = vol
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Play Global Sound") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+
+/client/proc/play_local_sound(S as sound)
+	set category = "Fun"
+	set name = "Play Local Sound"
+	if(!check_rights(R_SOUNDS))
+		return
+
+	log_admin("[key_name(src)] played a local sound [S]")
+	message_admins("[key_name_admin(src)] played a local sound [S]")
+	playsound(get_turf(src.mob), S, 50, 0, 0)
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Play Local Sound") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/play_web_sound()
+	set category = "Fun"
+	set name = "Play Internet Sound"
+	if(!check_rights(R_SOUNDS))
+		return
+
+	var/ytdl = CONFIG_GET(string/invoke_youtubedl)
+	if(!ytdl)
+		to_chat(src, "<span class='boldwarning'>Youtube-dl was not configured, action unavailable</span>") //Check config.txt for the INVOKE_YOUTUBEDL value
+		return
+
+	var/web_sound_input = input("Enter content URL (supported sites only, leave blank to stop playing)", "Play Internet Sound via youtube-dl") as text|null
+	if(istext(web_sound_input))
+		var/web_sound_url = ""
+		var/stop_web_sounds = FALSE
+		var/pitch
+		if(length(web_sound_input))
+
+			web_sound_input = trim(web_sound_input)
+			if(findtext(web_sound_input, ":") && !findtext(web_sound_input, GLOB.is_http_protocol))
+				to_chat(src, "<span class='boldwarning'>Non-http(s) URIs are not allowed.</span>")
+				to_chat(src, "<span class='warning'>For youtube-dl shortcuts like ytsearch: please use the appropriate full url from the website.</span>")
+				return
+			var/shell_scrubbed_input = shell_url_scrub(web_sound_input)
+			var/list/output = world.shelleo("[ytdl] --format \"bestaudio\[ext=mp3]/best\[ext=mp4]\[height<=360]/bestaudio\[ext=m4a]/bestaudio\[ext=aac]\" --dump-single-json --no-playlist -- \"[shell_scrubbed_input]\"")
+			var/errorlevel = output[SHELLEO_ERRORLEVEL]
+			var/stdout = output[SHELLEO_STDOUT]
+			var/stderr = output[SHELLEO_STDERR]
+			if(!errorlevel)
+				var/list/data
+				try
+					data = json_decode(stdout)
+				catch(var/exception/e)
+					to_chat(src, "<span class='boldwarning'>Youtube-dl JSON parsing FAILED:</span>")
+					to_chat(src, "<span class='warning'>[e]: [stdout]</span>")
+					return
+
+				if (data["url"])
+					web_sound_url = data["url"]
+					var/title = "[data["title"]]"
+					var/webpage_url = title
+					if (data["webpage_url"])
+						webpage_url = "<a href=\"[data["webpage_url"]]\">[title]</a>"
+
+					var/freq = input(usr, "What frequency would you like the sound to play at?",, 1) as null|num
+					if(!freq)
+						freq = 1
+					pitch = freq
+
+					var/res = alert(usr, "Show the title of and link to this song to the players?\n[title]",, "No", "Yes", "Cancel")
+					switch(res)
+						if("Yes")
+							to_chat(world, "<span class='boldannounce'>An admin played: [webpage_url]</span>")
+						if("Cancel")
+							return
+					SSblackbox.record_feedback("nested tally", "played_url", 1, list("[ckey]", "[web_sound_input]"))
+					log_admin("[key_name(src)] played web sound: [web_sound_input]")
+					message_admins("[key_name(src)] played web sound: [web_sound_input]")
+			else
+				to_chat(src, "<span class='boldwarning'>Youtube-dl URL retrieval FAILED:</span>")
+				to_chat(src, "<span class='warning'>[stderr]</span>")
+
+		else //pressed ok with blank
+			log_admin("[key_name(src)] stopped web sound")
+			message_admins("[key_name(src)] stopped web sound")
+			web_sound_url = null
+			stop_web_sounds = TRUE
+
+		if(web_sound_url && !findtext(web_sound_url, GLOB.is_http_protocol))
+			to_chat(src, "<span class='boldwarning'>BLOCKED: Content URL not using http(s) protocol</span>")
+			to_chat(src, "<span class='warning'>The media provider returned a content URL that isn't using the HTTP or HTTPS protocol</span>")
+			return
+		if(web_sound_url || stop_web_sounds)
+			for(var/m in GLOB.player_list)
+				var/mob/M = m
+				var/client/C = M.client
+				if((C.prefs.toggles & SOUND_MIDI) && C.chatOutput && !C.chatOutput.broken && C.chatOutput.loaded)
+					if(!stop_web_sounds)
+						C.chatOutput.sendMusic(web_sound_url, pitch)
+					else
+						C.chatOutput.stopMusic()
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Play Internet Sound")
+
+/client/proc/set_round_end_sound(S as sound)
+	set category = "Fun"
+	set name = "Set Round End Sound"
+	if(!check_rights(R_SOUNDS))
+		return
+
+	SSticker.SetRoundEndSound(S)
+
+	log_admin("[key_name(src)] set the round end sound to [S]")
+	message_admins("[key_name_admin(src)] set the round end sound to [S]")
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Set Round End Sound") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/client/proc/play_web_sound_manual()
+	set category = "Fun"
+	set name = "Manual Play Internet Sound"
+	if(!check_rights(R_SOUNDS))
+		return
+
+	var/web_sound_input = input("Enter youtube-dl fetched content URL (supported sites only, leave blank to stop playing)", "Send youtube-dl media link") as text|null
+	if(!istext(web_sound_input))
+		return
+	web_sound_input = trim(web_sound_input)
+	if(!length(web_sound_input))
+		log_admin("[key_name(src)] stopped web sound")
+		message_admins("[key_name(src)] stopped web sound")
+		for(var/m in GLOB.player_list)
+			var/mob/M = m
+			var/client/C = M.client
+			if((C.prefs.toggles & SOUND_MIDI) && C.chatOutput && !C.chatOutput.broken && C.chatOutput.loaded)
+				C.chatOutput.stopMusic()
+		return
+	var/freq = input(usr, "What frequency would you like the sound to play at?",, 1) as null|num
+	if(!freq)
+		return
+	if(web_sound_input && !findtext(web_sound_input, GLOB.is_http_protocol))
+		to_chat(src, "<span class='boldwarning'>BLOCKED: Content URL not using http(s) protocol</span>")
+		to_chat(src, "<span class='warning'>The media provider returned a content URL that isn't using the HTTP or HTTPS protocol</span>")
+		return
+
+	SSblackbox.record_feedback("nested tally", "played_url_manual", 1, list("[ckey]", "[web_sound_input]"))
+	log_admin("[key_name(src)] manually played web sound: [web_sound_input]")
+	message_admins("[key_name(src)] manually played web sound: <a href='web_sound_input'>HREF</a>")
+	for(var/m in GLOB.player_list)
+		var/mob/M = m
+		var/client/C = M.client
+		if((C.prefs.toggles & SOUND_MIDI) && C.chatOutput && !C.chatOutput.broken && C.chatOutput.loaded)
+			C.chatOutput.sendMusic(web_sound_input, freq)
+
+/client/proc/stop_sounds()
+	set category = "Debug"
+	set name = "Stop All Playing Sounds"
+	if(!src.holder)
+		return
+
+	log_admin("[key_name(src)] stopped all currently playing sounds.")
+	message_admins("[key_name_admin(src)] stopped all currently playing sounds.")
+	for(var/mob/M in GLOB.player_list)
+		if(M.client)
+			SEND_SOUND(M, sound(null))
+			var/client/C = M.client
+			if(C && C.chatOutput && !C.chatOutput.broken && C.chatOutput.loaded)
+				C.chatOutput.stopMusic()
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Stop All Playing Sounds") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!

code/modules/admin/verbs/possess.dm

@@ -0,0 +1,53 @@
+/proc/possess(obj/O in world)
+	set name = "Possess Obj"
+	set category = "Object"
+
+	if((O.obj_flags & DANGEROUS_POSSESSION) && CONFIG_GET(flag/forbid_singulo_possession))
+		to_chat(usr, "[O] is too powerful for you to possess.")
+		return
+
+	var/turf/T = get_turf(O)
+
+	if(T)
+		log_admin("[key_name(usr)] has possessed [O] ([O.type]) at [AREACOORD(T)]")
+		message_admins("[key_name(usr)] has possessed [O] ([O.type]) at [AREACOORD(T)]")
+	else
+		log_admin("[key_name(usr)] has possessed [O] ([O.type]) at an unknown location")
+		message_admins("[key_name(usr)] has possessed [O] ([O.type]) at an unknown location")
+
+	if(!usr.control_object) //If you're not already possessing something...
+		usr.name_archive = usr.real_name
+
+	usr.loc = O
+	usr.real_name = O.name
+	usr.name = O.name
+	usr.reset_perspective(O)
+	usr.control_object = O
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Possess Object") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/proc/release()
+	set name = "Release Obj"
+	set category = "Object"
+	//usr.loc = get_turf(usr)
+
+	if(usr.control_object && usr.name_archive) //if you have a name archived and if you are actually relassing an object
+		usr.real_name = usr.name_archive
+		usr.name_archive = ""
+		usr.name = usr.real_name
+		if(ishuman(usr))
+			var/mob/living/carbon/human/H = usr
+			H.name = H.get_visible_name()
+
+
+	usr.loc = get_turf(usr.control_object)
+	usr.reset_perspective()
+	usr.control_object = null
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Release Object") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+/proc/givetestverbs(mob/M in GLOB.mob_list)
+	set desc = "Give this guy possess/release verbs"
+	set category = "Debug"
+	set name = "Give Possessing Verbs"
+	M.verbs += /proc/possess
+	M.verbs += /proc/release
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Give Possessing Verbs") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!

code/modules/admin/verbs/pray.dm

@@ -0,0 +1,75 @@
+/mob/verb/pray(msg as text)
+	set category = "IC"
+	set name = "Pray"
+
+	if(GLOB.say_disabled)	//This is here to try to identify lag problems
+		to_chat(usr, "<span class='danger'>Speech is currently admin-disabled.</span>")
+		return
+
+	msg = copytext(sanitize(msg), 1, MAX_MESSAGE_LEN)
+	if(!msg)
+		return
+	log_prayer("[src.key]/([src.name]): [msg]")
+	if(usr.client)
+		if(usr.client.prefs.muted & MUTE_PRAY)
+			to_chat(usr, "<span class='danger'>You cannot pray (muted).</span>")
+			return
+		if(src.client.handle_spam_prevention(msg,MUTE_PRAY))
+			return
+
+	var/mutable_appearance/cross = mutable_appearance('icons/obj/storage.dmi', "bible")
+	var/font_color = "purple"
+	var/prayer_type = "PRAYER"
+	var/deity
+	if(usr.job == "Chaplain")
+		cross.icon_state = "kingyellow"
+		font_color = "blue"
+		prayer_type = "CHAPLAIN PRAYER"
+		if(GLOB.deity)
+			deity = GLOB.deity
+	else if(iscultist(usr))
+		cross.icon_state = "tome"
+		font_color = "red"
+		prayer_type = "CULTIST PRAYER"
+		deity = "Nar'Sie"
+	else if(isliving(usr))
+		var/mob/living/L = usr
+		if(HAS_TRAIT(L, TRAIT_SPIRITUAL))
+			cross.icon_state = "holylight"
+			font_color = "blue"
+			prayer_type = "SPIRITUAL PRAYER"
+
+	var/msg_tmp = msg
+	msg = "<span class='adminnotice'>[icon2html(cross, GLOB.admins)]<b><font color=[font_color]>[prayer_type][deity ? " (to [deity])" : ""]: </font>[ADMIN_FULLMONTY(src)] [ADMIN_SC(src)]:</b> <span class='linkify'>[msg]</span></span>"
+
+	for(var/client/C in GLOB.admins)
+		if(C.prefs.chat_toggles & CHAT_PRAYER)
+			to_chat(C, msg)
+			if(C.prefs.toggles & SOUND_PRAYERS)
+				if(usr.job == "Chaplain")
+					SEND_SOUND(C, sound('sound/effects/pray.ogg'))
+	to_chat(usr, "<span class='info'>You pray to the gods: \"[msg_tmp]\"</span>")
+
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Prayer") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+	//log_admin("HELP: [key_name(src)]: [msg]")
+
+/proc/CentCom_announce(text , mob/Sender)
+	var/msg = copytext(sanitize(text), 1, MAX_MESSAGE_LEN)
+	msg = "<span class='adminnotice'><b><font color=orange>CENTCOM:</font>[ADMIN_FULLMONTY(Sender)] [ADMIN_CENTCOM_REPLY(Sender)]:</b> [msg]</span>"
+	to_chat(GLOB.admins, msg)
+	for(var/obj/machinery/computer/communications/C in GLOB.machines)
+		C.overrideCooldown()
+
+/proc/Syndicate_announce(text , mob/Sender)
+	var/msg = copytext(sanitize(text), 1, MAX_MESSAGE_LEN)
+	msg = "<span class='adminnotice'><b><font color=crimson>SYNDICATE:</font>[ADMIN_FULLMONTY(Sender)] [ADMIN_SYNDICATE_REPLY(Sender)]:</b> [msg]</span>"
+	to_chat(GLOB.admins, msg)
+	for(var/obj/machinery/computer/communications/C in GLOB.machines)
+		C.overrideCooldown()
+
+/proc/Nuke_request(text , mob/Sender)
+	var/msg = copytext(sanitize(text), 1, MAX_MESSAGE_LEN)
+	msg = "<span class='adminnotice'><b><font color=orange>NUKE CODE REQUEST:</font>[ADMIN_FULLMONTY(Sender)] [ADMIN_CENTCOM_REPLY(Sender)] [ADMIN_SET_SD_CODE]:</b> [msg]</span>"
+	to_chat(GLOB.admins, msg)
+	for(var/obj/machinery/computer/communications/C in GLOB.machines)
+		C.overrideCooldown()

code/modules/admin/verbs/reestablish_db_connection.dm

@@ -0,0 +1,30 @@
+/client/proc/reestablish_db_connection()
+	set category = "Special Verbs"
+	set name = "Reestablish DB Connection"
+	if (!CONFIG_GET(flag/sql_enabled))
+		to_chat(usr, "<span class='adminnotice'>The Database is not enabled!</span>")
+		return
+
+	if (SSdbcore.IsConnected())
+		if (!check_rights(R_DEBUG,0))
+			alert("The database is already connected! (Only those with +debug can force a reconnection)", "The database is already connected!")
+			return
+
+		var/reconnect = alert("The database is already connected! If you *KNOW* that this is incorrect, you can force a reconnection", "The database is already connected!", "Force Reconnect", "Cancel")
+		if (reconnect != "Force Reconnect")
+			return
+
+		SSdbcore.Disconnect()
+		log_admin("[key_name(usr)] has forced the database to disconnect")
+		message_admins("[key_name_admin(usr)] has <b>forced</b> the database to disconnect!")
+		SSblackbox.record_feedback("tally", "admin_verb", 1, "Force Reestablished Database Connection") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+	log_admin("[key_name(usr)] is attempting to re-established the DB Connection")
+	message_admins("[key_name_admin(usr)] is attempting to re-established the DB Connection")
+	SSblackbox.record_feedback("tally", "admin_verb", 1, "Reestablished Database Connection") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!
+
+	SSdbcore.failed_connections = 0
+	if(!SSdbcore.Connect())
+		message_admins("Database connection failed: " + SSdbcore.ErrorMsg())
+	else
+		message_admins("Database connection re-established")

code/modules/admin/verbs/spawnobjasmob.dm

@@ -0,0 +1,70 @@
+/datum/admins/proc/spawn_objasmob(object as text)
+	set category = "Debug"
+	set desc = "(obj path) Spawn object-mob"
+	set name = "Spawn object-mob"
+
+	if(!check_rights(R_SPAWN))
+		return
+
+	var/chosen = pick_closest_path(object, make_types_fancy(subtypesof(/obj)))
+
+	if (!chosen)
+		return
+
+	var/mob/living/simple_animal/hostile/mimic/copy/basemob = /mob/living/simple_animal/hostile/mimic/copy
+
+	var/obj/chosen_obj = text2path(chosen)
+
+	var/list/settings = list(
+    "mainsettings" = list(
+      "name" = list("desc" = "Name", "type" = "string", "value" = "Bob"),
+			"maxhealth" = list("desc" = "Max. health", "type" = "number", "value" = 100),
+      "access" = list("desc" = "Access ID", "type" = "datum", "path" = "/obj/item/card/id", "value" = "Default"),
+			"objtype" = list("desc" = "Base obj type", "type" = "datum", "path" = "/obj", "value" = "[chosen]"),
+			"googlyeyes" = list("desc" = "Googly eyes", "type" = "boolean", "value" = "No"),
+			"disableai" = list("desc" = "Disable AI", "type" = "boolean", "value" = "Yes"),
+			"idledamage" = list("desc" = "Damaged while idle", "type" = "boolean", "value" = "No"),
+			"dropitem" = list("desc" = "Drop obj on death", "type" = "boolean", "value" = "Yes"),
+			"mobtype" = list("desc" = "Base mob type", "type" = "datum", "path" = "/mob/living/simple_animal/hostile/mimic/copy", "value" = "/mob/living/simple_animal/hostile/mimic/copy"),
+			"ckey" = list("desc" = "ckey", "type" = "ckey", "value" = "none"),
+    )
+	)
+
+	var/list/prefreturn = presentpreflikepicker(usr,"Customize mob", "Customize mob", Button1="Ok", width = 450, StealFocus = 1,Timeout = 0, settings=settings)
+	if (prefreturn["button"] == 1)
+		settings = prefreturn["settings"]
+		var/mainsettings = settings["mainsettings"]
+		chosen_obj = text2path(mainsettings["objtype"]["value"])
+
+		basemob = text2path(mainsettings["mobtype"]["value"])
+		if (!ispath(basemob, /mob/living/simple_animal/hostile/mimic/copy) || !ispath(chosen_obj, /obj))
+			to_chat(usr, "Mob or object path invalid")
+
+		basemob = new basemob(get_turf(usr), new chosen_obj(get_turf(usr)), usr, mainsettings["dropitem"]["value"] == "Yes" ? FALSE : TRUE, (mainsettings["googlyeyes"]["value"] == "Yes" ? FALSE : TRUE))
+
+		if (mainsettings["disableai"]["value"] == "Yes")
+			basemob.toggle_ai(AI_OFF)
+
+		if (mainsettings["idledamage"]["value"] == "No")
+			basemob.idledamage = FALSE
+
+		if (mainsettings["access"])
+			var/newaccess = text2path(mainsettings["access"]["value"])
+			if (ispath(newaccess))
+				basemob.access_card = new newaccess
+
+		if (mainsettings["maxhealth"]["value"])
+			if (!isnum(mainsettings["maxhealth"]["value"]))
+				mainsettings["maxhealth"]["value"] = text2num(mainsettings["maxhealth"]["value"])
+			if (mainsettings["maxhealth"]["value"] > 0)
+				basemob.maxHealth = basemob.maxHealth =  mainsettings["maxhealth"]["value"]
+
+		if (mainsettings["name"]["value"])
+			basemob.name = basemob.real_name = html_decode(mainsettings["name"]["value"])
+
+		if (mainsettings["ckey"]["value"] != "none")
+			basemob.ckey = mainsettings["ckey"]["value"]
+
+
+		log_admin("[key_name(usr)] spawned a sentient object-mob [basemob] from [chosen_obj] at [AREACOORD(usr)]")
+		SSblackbox.record_feedback("tally", "admin_verb", 1, "Spawn object-mob") //If you are copy-pasting this, ensure the 2nd parameter is unique to the new proc!

code/modules/admin/verbs/tripAI.dm

@@ -0,0 +1,20 @@
+/client/proc/triple_ai()
+	set category = "Fun"
+	set name = "Create AI Triumvirate"
+
+	if(SSticker.current_state > GAME_STATE_PREGAME)
+		to_chat(usr, "This option is currently only usable during pregame. This may change at a later date.")
+		return
+
+	var/datum/job/job = SSjob.GetJob("AI")
+	if(!job)
+		to_chat(usr, "Unable to locate the AI job")
+		return
+	if(SSticker.triai)
+		SSticker.triai = 0
+		to_chat(usr, "Only one AI will be spawned at round start.")
+		message_admins("<span class='adminnotice'>[key_name_admin(usr)] has toggled off triple AIs at round start.</span>")
+	else
+		SSticker.triai = 1
+		to_chat(usr, "There will be an AI Triumvirate at round start.")
+		message_admins("<span class='adminnotice'>[key_name_admin(usr)] has toggled on triple AIs at round start.</span>")