Uploading all files.

2026-08-24 13:36:15 +01:00 · 2019-09-23 18:26:34 +02:00
commit 7091cdbe8c
7779 changed files with 2601004 additions and 0 deletions
@@ -0,0 +1,77 @@
+/obj/item/zombie_hand
+	name = "zombie claw"
+	desc = "A zombie's claw is its primary tool, capable of infecting \
+		humans, butchering all other living things to \
+		sustain the zombie, smashing open airlock doors and opening \
+		child-safe caps on bottles."
+	item_flags = ABSTRACT | DROPDEL
+	resistance_flags = INDESTRUCTIBLE | LAVA_PROOF | FIRE_PROOF | UNACIDABLE | ACID_PROOF
+	icon = 'icons/effects/blood.dmi'
+	icon_state = "bloodhand_left"
+	var/icon_left = "bloodhand_left"
+	var/icon_right = "bloodhand_right"
+	hitsound = 'sound/hallucinations/growl1.ogg'
+	force = 21 // Just enough to break airlocks with melee attacks
+	damtype = "brute"
+	total_mass = TOTAL_MASS_HAND_REPLACEMENT
+
+/obj/item/zombie_hand/Initialize()
+	. = ..()
+	ADD_TRAIT(src, TRAIT_NODROP, HAND_REPLACEMENT_TRAIT)
+
+/obj/item/zombie_hand/equipped(mob/user, slot)
+	. = ..()
+	//these are intentionally inverted
+	var/i = user.get_held_index_of_item(src)
+	if(!(i % 2))
+		icon_state = icon_left
+	else
+		icon_state = icon_right
+
+/obj/item/zombie_hand/afterattack(atom/target, mob/user, proximity_flag)
+	. = ..()
+	if(!proximity_flag)
+		return
+	else if(isliving(target))
+		if(ishuman(target))
+			try_to_zombie_infect(target)
+		else
+			check_feast(target, user)
+
+/proc/try_to_zombie_infect(mob/living/carbon/human/target)
+	CHECK_DNA_AND_SPECIES(target)
+
+	if(NOZOMBIE in target.dna.species.species_traits)
+		// cannot infect any NOZOMBIE subspecies (such as high functioning
+		// zombies)
+		return
+
+	var/obj/item/organ/zombie_infection/infection
+	infection = target.getorganslot(ORGAN_SLOT_ZOMBIE)
+	if(!infection)
+		infection = new()
+		infection.Insert(target)
+
+
+
+/obj/item/zombie_hand/suicide_act(mob/user)
+	user.visible_message("<span class='suicide'>[user] is ripping [user.p_their()] brains out! It looks like [user.p_theyre()] trying to commit suicide!</span>")
+	if(isliving(user))
+		var/mob/living/L = user
+		var/obj/item/bodypart/O = L.get_bodypart(BODY_ZONE_HEAD)
+		if(O)
+			O.dismember()
+	return (BRUTELOSS)
+
+/obj/item/zombie_hand/proc/check_feast(mob/living/target, mob/living/user)
+	if(target.stat == DEAD)
+		var/hp_gained = target.maxHealth
+		target.gib()
+		// zero as argument for no instant health update
+		user.adjustBruteLoss(-hp_gained, 0)
+		user.adjustToxLoss(-hp_gained, 0)
+		user.adjustFireLoss(-hp_gained, 0)
+		user.adjustCloneLoss(-hp_gained, 0)
+		user.updatehealth()
+		user.adjustBrainLoss(-hp_gained) // Zom Bee gibbers "BRAAAAISNSs!1!"
+		user.nutrition = min(user.nutrition + hp_gained, NUTRITION_LEVEL_FULL)
@@ -0,0 +1,96 @@
+/obj/item/organ/zombie_infection
+	name = "festering ooze"
+	desc = "A black web of pus and viscera."
+	zone = BODY_ZONE_HEAD
+	slot = ORGAN_SLOT_ZOMBIE
+	icon_state = "blacktumor"
+	var/causes_damage = TRUE
+	var/datum/species/old_species = /datum/species/human
+	var/living_transformation_time = 30
+	var/converts_living = FALSE
+
+	var/revive_time_min = 450
+	var/revive_time_max = 700
+	var/timer_id
+
+/obj/item/organ/zombie_infection/Initialize()
+	. = ..()
+	if(iscarbon(loc))
+		Insert(loc)
+	GLOB.zombie_infection_list += src
+
+/obj/item/organ/zombie_infection/Destroy()
+	GLOB.zombie_infection_list -= src
+	. = ..()
+
+/obj/item/organ/zombie_infection/Insert(var/mob/living/carbon/M, special = 0)
+	. = ..()
+	START_PROCESSING(SSobj, src)
+
+/obj/item/organ/zombie_infection/Remove(mob/living/carbon/M, special = 0)
+	. = ..()
+	STOP_PROCESSING(SSobj, src)
+	if(iszombie(M) && old_species)
+		M.set_species(old_species)
+	if(timer_id)
+		deltimer(timer_id)
+
+/obj/item/organ/zombie_infection/on_find(mob/living/finder)
+	to_chat(finder, "<span class='warning'>Inside the head is a disgusting black \
+		web of pus and viscera, bound tightly around the brain like some \
+		biological harness.</span>")
+
+/obj/item/organ/zombie_infection/process()
+	if(!owner)
+		return
+	if(!(src in owner.internal_organs))
+		Remove(owner)
+	if (causes_damage && !iszombie(owner) && owner.stat != DEAD)
+		owner.adjustToxLoss(1)
+		if (prob(10))
+			to_chat(owner, "<span class='danger'>You feel sick...</span>")
+	if(timer_id)
+		return
+	if(owner.suiciding)
+		return
+	if(owner.stat != DEAD && !converts_living)
+		return
+	if(!owner.getorgan(/obj/item/organ/brain))
+		return
+	if(!iszombie(owner))
+		to_chat(owner, "<span class='cultlarge'>You can feel your heart stopping, but something isn't right... \
+		life has not abandoned your broken form. You can only feel a deep and immutable hunger that \
+		not even death can stop, you will rise again!</span>")
+	var/revive_time = rand(revive_time_min, revive_time_max)
+	var/flags = TIMER_STOPPABLE
+	timer_id = addtimer(CALLBACK(src, .proc/zombify), revive_time, flags)
+
+/obj/item/organ/zombie_infection/proc/zombify()
+	timer_id = null
+
+	if(!converts_living && owner.stat != DEAD)
+		return
+
+	if(!iszombie(owner))
+		old_species = owner.dna.species.type
+		owner.set_species(/datum/species/zombie/infectious)
+
+	var/stand_up = (owner.stat == DEAD) || (owner.stat == UNCONSCIOUS)
+
+	//Fully heal the zombie's damage the first time they rise
+	owner.setToxLoss(0, 0)
+	owner.setOxyLoss(0, 0)
+	owner.heal_overall_damage(INFINITY, INFINITY, INFINITY, FALSE, FALSE, TRUE)
+
+	if(!owner.revive())
+		return
+
+	owner.grab_ghost()
+	owner.visible_message("<span class='danger'>[owner] suddenly convulses, as [owner.p_they()][stand_up ? " stagger to [owner.p_their()] feet and" : ""] gain a ravenous hunger in [owner.p_their()] eyes!</span>", "<span class='alien'>You HUNGER!</span>")
+	playsound(owner.loc, 'sound/hallucinations/far_noise.ogg', 50, 1)
+	owner.do_jitter_animation(living_transformation_time)
+	owner.Stun(living_transformation_time)
+	to_chat(owner, "<span class='alertalien'>You are now a zombie!</span>")
+
+/obj/item/organ/zombie_infection/nodamage
+	causes_damage = FALSE