New PVE Major Midround: Demonic Incursion (#29053)

* Initial commit. Event.

* Started converting mobs to basic mobs. Migo and Creature. Needs aggressiveness AI

* Makes CI happy

* Fixes some file names

* Ticks files

* Fixes file again

* Update code/modules/events/demon_incursion.dm

Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com>
Signed-off-by: PollardTheDragon <144391971+PollardTheDragon@users.noreply.github.com>

* Announcement sound, spawn adjustments

* Reduced spread when portals multiply

* Elite spawns when portal count gets high

* Fixes missing comma

* Converted migo, blank, and most of hellhounds to basic mobs. Added new controllers and behaviors

* Fixes

* Linters!

* Faithless moved to basic mob

* LINTERS

* Makes skeletons basic mobs

* Fixes, Ranged Attacks, Ranged variants of nether mobs

* Handles portal expansion chance

* Linters

* Fixes mobs not breaking shit

* Fixes ranged attacks

* Fixes ranged attacks

* oops

* Another oops. No config changes are needed here

* Twenty percent chance that a nether mob is a grappler

* Dimensional tear fixes

* Adjusts awaken distance for hostile mobs, makes variable melee attack rate for basic mobs

* Variable initial spawns, variable spread rates.

* Whole lot of fixes from merge, hellhound completion

* Updated lavaland winter biodome

* Makes basic mobs able to hurt other mobs

* Makes spawners properly rally basic mobs to beat up the attacker

* Extra line

* Removed comment

* Makes hellhounds stop resting when attacked or when they find a new target

* Fixed initial portal spawn amounts

* Borgs now affected by basic mobs

* Nerfs portal spawn rate, nerfs portal integrity, nerfs portal max mobs

* Grapplers now teleport to missed turfs

* Removes duplicate notices

* Buff portals a small bit

* Makes nether portals no longer RR - the body is now recoverable from the blank it became

* Makes portals layer above mobs

* Removed excess ranged attack var

* Changes list for determining start count to rely on mobs with client instead of all clients

* Nerfs portal max mobs

* Portals can no longer spread to within 3 tiles of another portal except on initial event start

* Adjusts target portal count for big mobs

* Spawners now properly remove nest values of basic mobs

* Portals now glow an evil red. When portals are destroyed, 50% chance per mob to slay the mob

* add prowling and return to home behaviors

* cut this down

* be a tiny bit smarter

* Some code cleanup

* Removes hostile base type, removing excess code

* Gives /obj/ a basic mob attack handler. Fixes turrets

* Gives basic mobs a HUD

* Fixes skeleton death flag

* Adjusted initial spawns

* Incursion portals now slowly convert turfs, up to range 3 of them, to hellish flooring

* Increases reward per destroyed portal

* Makes the final portal of an incursion play a sound on destruction, couple portal fixes

* Fixes basic mob xenobiology interactions

* Non-shit portal sprites

* Adds hostile machine element, mobs now actively target turrets and emitters

* Properly gibs things when they should gib

* Linter fix

* Portals now layer under living mobs but over dead ones

* Adds blackbox checking for demon incursion portal counts

* Increases mob sight range slightly to account for widescreen, adds alt-color for grappler, delays incursion announcement a bit more

* Portals now are more likely to spread the less there are

* Incursion portals now repair themselves after not being damaged for some time

* Grilles now shock basic mobs

* Portals will now clean up basic mob corpses near them by gibbing them

* Portal spread chance is now exponential regression

* Portal mob spawns now linearly scale in time

* Fixes some skeleton oversights in ruin mapping

* Demon incursions no longer can spread to tiles in a space area, such as near brig plating

* Moves corpse cleanup to mobs via component

* Portals now drop bodies that are being eaten when they're destroyed.

* Addresses code review

* Docs some vars

---------

Signed-off-by: PollardTheDragon <144391971+PollardTheDragon@users.noreply.github.com>
Co-authored-by: Luc <89928798+lewcc@users.noreply.github.com>
Co-authored-by: warriorstar-orion <orion@snowfrost.garden>

code/modules/mob/living/basic/basic_mob.dm

@@ -20,6 +20,7 @@ RESTRICT_TYPE(/mob/living/basic)
 	desc = "If you can see this, make an issue report on GitHub."
 	healable = TRUE
 	icon = 'icons/mob/animal.dmi'
+	hud_type = /datum/hud/simple_animal
 
 	var/basic_mob_flags
 
@@ -30,6 +31,8 @@ RESTRICT_TYPE(/mob/living/basic)
 	var/icon_living
 	/// Icon when the animal is dead.
 	var/icon_dead
+	/// Icon when the animal is resting
+	var/icon_resting
 	/// We only try to show a gibbing animation if this exists.
 	var/icon_gib
 	/// The sound played on death
@@ -129,14 +132,27 @@ RESTRICT_TYPE(/mob/living/basic)
 	var/melee_damage_upper = 0
 	/// How much damage this simple animal does to objects, if any
 	var/obj_damage = 0
+	/// What can this mob break?
+	var/environment_smash = ENVIRONMENT_SMASH_NONE
 	/// Flat armour reduction, occurs after percentage armour penetration.
 	var/armour_penetration_flat = 0
 	/// Percentage armour reduction, happens before flat armour reduction.
 	var/armour_penetration_percentage = 0
 	/// Damage type of a simple mob's melee attack, should it do damage.
 	var/melee_damage_type = BRUTE
-	/// How often can you melee attack?
-	var/melee_attack_cooldown = 2 SECONDS
+	/// Lower bound for melee attack cooldown
+	var/melee_attack_cooldown_min = 2 SECONDS
+	/// Upper bound for melee attack cooldown
+	var/melee_attack_cooldown_max = 2 SECONDS
+
+	/// Loot this mob drops on death.
+	var/list/loot = list()
+
+	/// Compatibility with mob spawners
+	var/datum/component/spawner/nest
+
+	/// Footsteps
+	var/step_type
 
 /mob/living/basic/Initialize(mapload)
 	. = ..()
@@ -146,6 +162,14 @@ RESTRICT_TYPE(/mob/living/basic)
 
 	apply_atmos_requirements()
 	apply_temperature_requirements()
+	if(step_type)
+		AddComponent(/datum/component/footstep, step_type)
+
+/mob/living/basic/Destroy()
+	if(nest)
+		nest.spawned_mobs -= src
+		nest = null
+	return ..()
 
 /mob/living/basic/movement_delay()
 	. = speed
@@ -198,6 +222,7 @@ RESTRICT_TYPE(/mob/living/basic)
 /mob/living/basic/proc/early_melee_attack(atom/target, list/modifiers, ignore_cooldown = FALSE)
 	face_atom(target)
 	if(!ignore_cooldown)
+		var/melee_attack_cooldown = rand(melee_attack_cooldown_min, melee_attack_cooldown_max)
 		changeNext_move(melee_attack_cooldown)
 	if(SEND_SIGNAL(src, COMSIG_HOSTILE_PRE_ATTACKINGTARGET, target, Adjacent(target), modifiers) & COMPONENT_HOSTILE_NO_ATTACK)
 		return FALSE
@@ -233,6 +258,10 @@ RESTRICT_TYPE(/mob/living/basic)
 	. = ..()
 	if(!.)
 		return FALSE
+	if(nest)
+		nest.spawned_mobs -= src
+		nest = null
+	drop_loot()
 	if(!gibbed)
 		if(death_sound)
 			playsound(get_turf(src), death_sound, 200, 1)
@@ -302,6 +331,24 @@ RESTRICT_TYPE(/mob/living/basic)
 		apply_damage(damage, damagetype, null, getarmor(null, armorcheck))
 		return TRUE
 
+
+/mob/living/basic/handle_basic_attack(mob/living/basic/attacker, modifiers)
+	. = ..()
+	if(.)
+		var/damage = rand(attacker.melee_damage_lower, attacker.melee_damage_upper)
+		return attack_threshold_check(damage, attacker.melee_damage_type)
+
+/mob/living/basic/on_lying_down(new_lying_angle)
+	..()
+	if(icon_resting && stat != DEAD)
+		icon_state = icon_resting
+	ADD_TRAIT(src, TRAIT_IMMOBILIZED, LYING_DOWN_TRAIT) //simple mobs cannot crawl (unless they can)
+
+/mob/living/basic/on_standing_up()
+	..()
+	if(icon_resting && stat != DEAD)
+		icon_state = icon_living
+
 // Health/Damage adjustment, cribbed straight from simplemobs
 
 /mob/living/basic/adjustHealth(amount, updating_health = TRUE)
@@ -333,3 +380,8 @@ RESTRICT_TYPE(/mob/living/basic)
 /mob/living/basic/adjustStaminaLoss(amount, updating_health = TRUE)
 	if(damage_coeff[STAMINA])
 		return ..(amount * damage_coeff[STAMINA], updating_health)
+
+/mob/living/basic/proc/drop_loot()
+	if(length(loot))
+		for(var/item in loot)
+			new item(get_turf(src))

code/modules/mob/living/basic/farm_animals/deer_ai.dm

@@ -145,3 +145,9 @@
 	controller.set_blackboard_key(BB_DEER_RESTING, world.time + 15 SECONDS)
 	controller.set_blackboard_key(BB_DEER_NEXT_REST_TIMER, world.time + rand(minimum_time, maximum_time))
 	return AI_BEHAVIOR_DELAY | AI_BEHAVIOR_SUCCEEDED
+
+/datum/ai_behavior/return_home/incursion_portal
+	behavior_flags = AI_BEHAVIOR_REQUIRE_MOVEMENT
+
+/datum/ai_behavior/return_home/incursion_portal/perform(seconds_per_tick, datum/ai_controller/controller, target_key)
+	return AI_BEHAVIOR_SUCCEEDED

code/modules/mob/living/basic/hostile/hellhound.dm

@@ -0,0 +1,151 @@
+/mob/living/basic/hellhound
+	// Sprites by FoS: https://www.paradisestation.org/forum/profile/335-fos
+	name = "lesser hellhound"
+	desc = "A demonic-looking black canine monster with glowing red eyes and sharp teeth. A firey, lava-like substance drips from it."
+	icon_state = "hellhound"
+	icon_living = "hellhound"
+	icon_dead = "hellhound_dead"
+	icon_resting = "hellhound_rest"
+	mob_biotypes = MOB_ORGANIC | MOB_BEAST
+	melee_damage_lower = 10 // slightly higher than araneus
+	melee_damage_upper = 30
+	melee_attack_cooldown_min = 1.5 SECONDS
+	melee_attack_cooldown_max = 2.5 SECONDS
+	environment_smash = ENVIRONMENT_SMASH_STRUCTURES
+	a_intent = INTENT_HARM
+	speed = 0
+	maxHealth = 250 // same as sgt araneus
+	health = 250
+	obj_damage = 50
+	attack_verb_continuous = "savages"
+	attack_verb_simple = "savage"
+	attack_sound = 'sound/effects/bite.ogg'
+	speak_emote = list("growls")
+	see_in_dark = 9
+	universal_understand = TRUE
+	ai_controller = /datum/ai_controller/basic_controller/simple/hellhound
+	step_type = FOOTSTEP_MOB_CLAW
+	faction = list("nether")
+	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
+	damage_coeff = list(BRUTE = 1, BURN = 1, TOX = 1, STAM = 0, OXY = 1)
+	gold_core_spawnable = HOSTILE_SPAWN
+	contains_xeno_organ = TRUE
+	surgery_container = /datum/xenobiology_surgery_container/hound
+	/// How many cycles has the hellhound rested
+	var/life_regen_cycles = 0
+	/// Trigger number for health regen
+	var/life_regen_cycle_trigger = 10
+	/// How much is healed when regenerating
+	var/life_regen_amount = -10 // negative, because negative = healing
+	/// When did the hellhound last use smoke
+	var/smoke_lastuse = 0
+	/// How often can the hellhound use smoke
+	var/smoke_freq = 30 SECONDS
+
+/mob/living/basic/hellhound/Initialize(mapload)
+	. = ..()
+	AddElement(/datum/element/ai_retaliate)
+
+/mob/living/basic/hellhound/examine(mob/user)
+	. = ..()
+	if(stat != DEAD)
+		var/list/msgs = list()
+		if(key)
+			msgs += "<span class='warning'>Its eyes have the spark of intelligence.</span>"
+		if(health > (maxHealth*0.95))
+			msgs += "<span class='notice'>It appears to be in excellent health.</span>"
+		else if(health > (maxHealth*0.75))
+			msgs += "<span class='notice'>It has a few injuries.</span>"
+		else if(health > (maxHealth*0.55))
+			msgs += "<span class='warning'>It has many injuries.</span>"
+		else if(health > (maxHealth*0.25))
+			msgs += "<span class='warning'>It is covered in wounds!</span>"
+		if(IS_HORIZONTAL(src))
+			if(getBruteLoss() || getFireLoss())
+				msgs += "<span class='warning'>It is currently licking its wounds, regenerating the damage to its body!</span>"
+			else
+				msgs += "<span class='notice'>It is currently resting.</span>"
+		. += msgs.Join("<BR>")
+
+/mob/living/basic/hellhound/Move(atom/newloc, direct, glide_size_override, update_dir)
+	. = ..()
+	if(IS_HORIZONTAL(src))
+		stand_up()
+
+/mob/living/basic/hellhound/Life(seconds, times_fired)
+	. = ..()
+	if(stat != DEAD && (getBruteLoss() || getFireLoss()))
+		if(IS_HORIZONTAL(src))
+			if(life_regen_cycles >= life_regen_cycle_trigger)
+				life_regen_cycles = 0
+				to_chat(src, "<span class='notice'>You lick your wounds, helping them close.</span>")
+				adjustBruteLoss(life_regen_amount)
+				adjustFireLoss(life_regen_amount)
+			else
+				life_regen_cycles++
+	if(ai_controller.blackboard_key_exists(BB_BASIC_MOB_CURRENT_TARGET))
+		stand_up()
+
+/mob/living/basic/hellhound/apply_damage(damage, damagetype, def_zone, blocked, sharp, used_weapon, spread_damage)
+	. = ..()
+	if(stat != DEAD && IS_HORIZONTAL(src))
+		stand_up()
+
+/mob/living/basic/hellhound/greater
+	name = "greater hellhound"
+	desc = "A demonic-looking black canine monster with glowing red eyes and sharp teeth. Greater hounds are far stronger than their lesser kin, and should be engaged with extreme caution."
+	icon_state = "hellhoundgreater"
+	icon_living = "hellhoundgreater"
+	icon_resting = "hellhoundgreater_sit"
+	maxHealth = 400
+	health = 400
+	force_threshold = 5 // no punching
+	universal_speak = TRUE
+	smoke_freq = 20 SECONDS
+	life_regen_cycle_trigger = 5
+	melee_damage_lower = 20
+	melee_damage_upper = 30
+
+/mob/living/basic/hellhound/greater/Initialize(mapload)
+	. = ..()
+	// Movement
+	AddSpell(new /datum/spell/ethereal_jaunt/shift)
+	var/datum/spell/area_teleport/teleport/telespell = new
+	telespell.clothes_req = FALSE
+	telespell.invocation_type = "none"
+	AddSpell(telespell)
+	var/datum/spell/aoe/knock/knockspell = new
+	knockspell.invocation_type = "none"
+	AddSpell(knockspell)
+	// Defense
+	var/datum/spell/forcewall/wallspell = new
+	wallspell.clothes_req = FALSE
+	wallspell.invocation_type = "none"
+	AddSpell(wallspell)
+	// Offense
+	var/datum/spell/aoe/conjure/creature/summonspell = new
+	summonspell.base_cooldown = 1
+	summonspell.invocation_type = "none"
+	summonspell.summon_type = list(/mob/living/basic/hellhound)
+	summonspell.summon_amt = 1
+	AddSpell(summonspell)
+
+/mob/living/basic/hellhound/greater/melee_attack(atom/target, list/modifiers, ignore_cooldown)
+	. = ..()
+	if(. && ishuman(target) && (!client || a_intent == INTENT_HARM))
+		special_aoe()
+
+/mob/living/basic/hellhound/greater/proc/special_aoe()
+	if(world.time < (smoke_lastuse + smoke_freq))
+		return
+	smoke_lastuse = world.time
+	var/datum/effect_system/smoke_spread/sleeping/smoke = new
+	smoke.set_up(10, FALSE, loc)
+	smoke.start()
+
+/mob/living/basic/hellhound/tear
+	name = "frenzied hellhound"
+	maxHealth = 300
+	health = 300
+	melee_damage_lower = 30
+	melee_damage_upper = 50

code/modules/mob/living/basic/hostile/hellhound_ai.dm

@@ -0,0 +1,45 @@
+/datum/ai_controller/basic_controller/simple/hellhound
+	blackboard = list(
+		BB_TARGETING_STRATEGY = /datum/targeting_strategy/basic,
+	)
+	planning_subtrees = list(
+		/datum/ai_planning_subtree/simple_find_target,
+		/datum/ai_planning_subtree/attack_obstacle_in_path,
+		/datum/ai_planning_subtree/basic_melee_attack_subtree,
+		/datum/ai_planning_subtree/hellhound_rest,
+		/datum/ai_planning_subtree/find_and_hunt_target/prowl,
+		/datum/ai_planning_subtree/attack_obstacle_in_path/prowl,
+	)
+
+/datum/ai_planning_subtree/hellhound_rest/select_behaviors(datum/ai_controller/controller, seconds_per_tick)
+	var/mob/living/pawn = controller.pawn
+	if(pawn.stat == DEAD)
+		return
+
+	if(pawn.getBruteLoss() || pawn.getFireLoss())
+		controller.queue_behavior(/datum/ai_behavior/hellhound_rest)
+		return SUBTREE_RETURN_FINISH_PLANNING
+	else
+		controller.queue_behavior(/datum/ai_behavior/hellhound_stand)
+
+/datum/ai_behavior/hellhound_rest
+	action_cooldown = 2 SECONDS
+
+/datum/ai_behavior/hellhound_rest/perform(seconds_per_tick, datum/ai_controller/controller, ...)
+	. = ..()
+	var/mob/living/basic/hellhound/hound = controller.pawn
+	if(!IS_HORIZONTAL(hound))
+		hound.lay_down()
+
+	return AI_BEHAVIOR_SUCCEEDED
+
+/datum/ai_behavior/hellhound_stand
+	action_cooldown = 2 SECONDS
+
+/datum/ai_behavior/hellhound_stand/perform(seconds_per_tick, datum/ai_controller/controller, ...)
+	. = ..()
+	var/mob/living/basic/hellhound/hound = controller.pawn
+	if(IS_HORIZONTAL(hound))
+		hound.stand_up()
+
+	return AI_BEHAVIOR_SUCCEEDED

code/modules/mob/living/basic/hostile/skeleton_mob.dm

@@ -0,0 +1,99 @@
+/mob/living/basic/skeleton
+	name = "reanimated skeleton"
+	desc = "A real bonefied skeleton, doesn't seem like it wants to socialize."
+	icon = 'icons/mob/simple_human.dmi'
+	icon_state = "skeleton"
+	icon_living = "skeleton"
+	speak_emote = list("rattles")
+	mob_biotypes = MOB_UNDEAD | MOB_HUMANOID
+	maxHealth = 40
+	health = 40
+	a_intent = INTENT_HARM
+	melee_damage_lower = 15
+	melee_damage_upper = 15
+	harm_intent_damage = 5
+	obj_damage = 50
+	melee_attack_cooldown_min = 1.5 SECONDS
+	melee_attack_cooldown_max = 2.5 SECONDS
+	environment_smash = ENVIRONMENT_SMASH_STRUCTURES
+	minimum_survivable_temperature = 0
+	maximum_survivable_temperature = 1500
+	healable = FALSE
+	attack_verb_simple = "slash"
+	attack_verb_continuous = "slashes"
+	attack_sound = 'sound/hallucinations/growl1.ogg'
+	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
+	damage_coeff = list(BRUTE = 1, BURN = 1, TOX = 1, STAM = 0, OXY = 1)
+	unsuitable_atmos_damage = 10
+	see_in_dark = 8
+	faction = list("skeleton")
+	lighting_alpha = LIGHTING_PLANE_ALPHA_MOSTLY_INVISIBLE
+	basic_mob_flags = DEL_ON_DEATH
+	speed = 1
+	step_type = FOOTSTEP_MOB_SHOE
+	gold_core_spawnable = HOSTILE_SPAWN
+	loot = list(/obj/effect/decal/remains/human)
+	ai_controller = /datum/ai_controller/basic_controller/simple/simple_hostile_obstacles/demonic_incursion
+
+/mob/living/basic/skeleton/Initialize(mapload)
+	. = ..()
+	AddElement(/datum/element/ai_retaliate)
+
+/mob/living/basic/skeleton/arctic
+	name = "undead arctic explorer"
+	desc = "The reanimated remains of some poor traveler."
+	icon_state = "arctic_skeleton"
+	icon_living = "arctic_skeleton"
+	maxHealth = 55
+	health = 55
+	weather_immunities = list("snow")
+	gold_core_spawnable = NO_SPAWN
+	melee_damage_lower = 17
+	melee_damage_upper = 20
+	death_message = "collapses into a pile of bones, its gear falling to the floor!"
+	loot = list(/obj/effect/decal/remains/human,
+				/obj/item/spear,
+				/obj/item/clothing/shoes/winterboots,
+				/obj/item/clothing/suit/hooded/wintercoat)
+
+/mob/living/basic/skeleton/warden
+	name = "skeleton warden"
+	desc = "The remains of a warden."
+	icon = 'icons/mob/simple_human.dmi'
+	icon_state = "skeleton_warden"
+	icon_living = "skeleton_warden"
+	loot = list(/obj/effect/decal/cleanable/shreds, /mob/living/basic/skeleton/angered_warden)
+	maxHealth = 300
+	health = 300
+	melee_damage_lower = 15
+	melee_damage_upper = 15
+	death_message = null
+	gold_core_spawnable = NO_SPAWN
+	ai_controller = /datum/ai_controller/basic_controller/simple/simple_hostile_obstacles/skeleton_warden
+
+/mob/living/basic/skeleton/warden/Process_Spacemove(movement_dir = 0, continuous_move = FALSE)
+	return TRUE
+
+/mob/living/basic/skeleton/angered_warden
+	name = "angered skeleton warden" // round 2
+	desc = "An angry skeleton."
+	icon = 'icons/mob/simple_human.dmi'
+	icon_state = "skeleton_warden_alt"
+	icon_living = "skeleton_warden_alt"
+	attack_verb_simple = "claw"
+	attack_verb_continuous = "claws"
+	attack_sound = 'sound/hallucinations/growl1.ogg'
+	maxHealth = 200
+	health = 200
+	speed = -1
+	melee_damage_lower = 30
+	melee_damage_upper = 30
+	loot = list(/obj/effect/decal/remains/human, /obj/item/clothing/head/warden, /obj/item/card/sec_shuttle_ruin)
+	gold_core_spawnable = NO_SPAWN
+	ai_controller = /datum/ai_controller/basic_controller/simple/simple_hostile_obstacles/skeleton_warden
+
+/mob/living/basic/skeleton/angered_warden/Process_Spacemove(movement_dir = 0, continuous_move = FALSE)
+	return TRUE
+
+/datum/ai_controller/basic_controller/simple/simple_hostile_obstacles/skeleton_warden
+	idle_behavior = null // Don't idly wander

code/modules/mob/living/basic/nether_mobs/blankbody.dm

@@ -0,0 +1,26 @@
+/mob/living/basic/netherworld/blankbody
+	name = "blank body"
+	desc = "This looks human enough, but its flesh has an ashy texture, and it's face is featureless save an eerie smile."
+	icon_state = "blank-body"
+	icon_living = "blank-body"
+	icon_dead = "blank-dead"
+	health = 100
+	maxHealth = 100
+	obj_damage = 50
+	melee_damage_lower = 5
+	melee_damage_upper = 10
+	attack_verb_continuous = "punches"
+	attack_verb_simple = "punch"
+	attack_sound = 'sound/weapons/bladeslice.ogg'
+	melee_attack_cooldown_min = 0.5 SECONDS
+	melee_attack_cooldown_max = 1.5 SECONDS
+	speak_emote = list("screams")
+	death_message = "falls apart into a fine dust."
+	/// The body/brain of the player turned into a blank, if the blank was turned
+	var/mob/living/held_body
+
+/mob/living/basic/netherworld/blankbody/death(gibbed)
+	. = ..()
+	if(held_body)
+		held_body.forceMove(loc)
+		qdel(src)

code/modules/mob/living/basic/nether_mobs/faithless.dm

@@ -0,0 +1,23 @@
+/mob/living/basic/netherworld/faithless
+	name = "Faithless"
+	desc = "The Wish Granter's faith in humanity, incarnate."
+	speak_emote = list("wails", "growls")
+	icon_state = "faithless"
+	icon_living = "faithless"
+	icon_dead = "faithless_dead"
+	mob_biotypes = MOB_ORGANIC | MOB_HUMANOID
+	maxHealth = 80
+	health = 80
+	melee_damage_lower = 15
+	melee_damage_upper = 15
+	harm_intent_damage = 10
+	obj_damage = 50
+	attack_verb_simple = "grip"
+	attack_verb_continuous = "grips"
+	attack_sound = 'sound/hallucinations/growl1.ogg'
+	speed = 0
+	gold_core_spawnable = HOSTILE_SPAWN
+	faction = "faithless"
+
+/mob/living/basic/netherworld/faithless/Process_Spacemove(movement_dir = 0, continuous_move = FALSE)
+	return TRUE

code/modules/mob/living/basic/nether_mobs/migo.dm

@@ -0,0 +1,197 @@
+/mob/living/basic/netherworld/migo
+	name = "mi-go"
+	desc = "A pinkish, fungoid crustacean-like creature with numerous pairs of clawed appendages and a head covered with waving antennae."
+	speak_emote = list("screams", "clicks", "chitters", "barks", "moans", "growls", "meows", "reverberates", "roars", "squeaks", "rattles", "exclaims", "yells", "remarks", "mumbles", "jabbers", "stutters", "seethes")
+	icon_state = "mi-go"
+	icon_living = "mi-go"
+	icon_dead = "mi-go-dead"
+	attack_verb_simple = "lacerate"
+	attack_verb_continuous = "lacerates"
+	speed = 0
+	death_message = "wails as its form turns into a pulpy mush."
+	death_sound = 'sound/voice/hiss6.ogg'
+	gold_core_spawnable = HOSTILE_SPAWN
+	/// List of sounds the migo can make
+	var/static/list/migo_sounds
+	/// Will the migo dodge?
+	var/dodge_prob = 10
+	surgery_container = /datum/xenobiology_surgery_container/migo
+
+/mob/living/basic/netherworld/migo/Initialize(mapload)
+	. = ..()
+	migo_sounds = list(
+		'sound/items/bubblewrap.ogg',
+		'sound/items/change_jaws.ogg',
+		'sound/items/crowbar.ogg',
+		'sound/items/drink.ogg',
+		'sound/items/deconstruct.ogg',
+		'sound/items/change_drill.ogg',
+		'sound/items/dodgeball.ogg',
+		'sound/items/eatfood.ogg',
+		'sound/items/screwdriver.ogg',
+		'sound/items/weeoo1.ogg',
+		'sound/items/wirecutter.ogg',
+		'sound/items/welder.ogg',
+		'sound/items/zip.ogg',
+		'sound/items/rped.ogg',
+		'sound/items/ratchet.ogg',
+		'sound/items/polaroid1.ogg',
+		'sound/items/pshoom.ogg',
+		'sound/items/airhorn.ogg',
+		'sound/voice/bcreep.ogg',
+		'sound/voice/biamthelaw.ogg',
+		'sound/voice/ed209_20sec.ogg',
+		'sound/voice/hiss3.ogg',
+		'sound/voice/hiss6.ogg',
+		'sound/voice/mpatchedup.ogg',
+		'sound/voice/mfeelbetter.ogg',
+		'sound/weapons/sear.ogg',
+		'sound/ambience/antag/tatoralert.ogg',
+		'sound/mecha/nominal.ogg',
+		'sound/mecha/weapdestr.ogg',
+		'sound/mecha/critdestr.ogg',
+		'sound/mecha/imag_enh.ogg',
+		'sound/effects/adminhelp.ogg',
+		'sound/effects/alert.ogg',
+		'sound/effects/attackblob.ogg',
+		'sound/effects/bamf.ogg',
+		'sound/effects/blobattack.ogg',
+		'sound/effects/break_stone.ogg',
+		'sound/effects/bubbles.ogg',
+		'sound/effects/bubbles2.ogg',
+		'sound/effects/clang.ogg',
+		'sound/effects/clownstep2.ogg',
+		'sound/effects/dimensional_rend.ogg',
+		'sound/effects/doorcreaky.ogg',
+		'sound/effects/empulse.ogg',
+		'sound/effects/explosionfar.ogg',
+		'sound/effects/explosion1.ogg',
+		'sound/effects/grillehit.ogg',
+		'sound/effects/genetics.ogg',
+		'sound/effects/heartbeat.ogg',
+		'sound/effects/hyperspace_begin.ogg',
+		'sound/effects/hyperspace_end.ogg',
+		'sound/goonstation/effects/screech.ogg',
+		'sound/effects/phasein.ogg',
+		'sound/effects/picaxe1.ogg',
+		'sound/effects/sparks1.ogg',
+		'sound/effects/smoke.ogg',
+		'sound/effects/splat.ogg',
+		'sound/effects/snap.ogg',
+		'sound/effects/tendril_destroyed.ogg',
+		'sound/effects/supermatter.ogg',
+		'sound/misc/desceration-01.ogg',
+		'sound/misc/desceration-02.ogg',
+		'sound/misc/desceration-03.ogg',
+		'sound/misc/bloblarm.ogg',
+		'sound/goonstation/misc/airraid_loop.ogg',
+		'sound/misc/interference.ogg',
+		'sound/misc/notice1.ogg',
+		'sound/misc/notice2.ogg',
+		'sound/misc/sadtrombone.ogg',
+		'sound/misc/slip.ogg',
+		'sound/weapons/armbomb.ogg',
+		'sound/weapons/chainsaw.ogg',
+		'sound/weapons/emitter.ogg',
+		'sound/weapons/emitter2.ogg',
+		'sound/weapons/blade1.ogg',
+		'sound/weapons/bladeslice.ogg',
+		'sound/weapons/blastcannon.ogg',
+		'sound/weapons/blaster.ogg',
+		'sound/weapons/bulletflyby3.ogg',
+		'sound/weapons/circsawhit.ogg',
+		'sound/weapons/cqchit2.ogg',
+		'sound/weapons/drill.ogg',
+		'sound/weapons/genhit1.ogg',
+		'sound/weapons/gunshots/gunshot_silenced.ogg',
+		'sound/weapons/gunshots/gunshot.ogg',
+		'sound/weapons/handcuffs.ogg',
+		'sound/weapons/homerun.ogg',
+		'sound/weapons/kenetic_accel.ogg',
+		'sound/machines/fryer/deep_fryer_emerge.ogg',
+		'sound/machines/airlock_alien_prying.ogg',
+		'sound/machines/airlock_close.ogg',
+		'sound/machines/airlockforced.ogg',
+		'sound/machines/airlock_open.ogg',
+		'sound/machines/alarm.ogg',
+		'sound/machines/blender.ogg',
+		'sound/machines/boltsdown.ogg',
+		'sound/machines/boltsup.ogg',
+		'sound/machines/buzz-sigh.ogg',
+		'sound/machines/buzz-two.ogg',
+		'sound/machines/chime.ogg',
+		'sound/machines/defib_charge.ogg',
+		'sound/machines/defib_failed.ogg',
+		'sound/machines/defib_ready.ogg',
+		'sound/machines/defib_zap.ogg',
+		'sound/machines/deniedbeep.ogg',
+		'sound/machines/ding.ogg',
+		'sound/machines/disposalflush.ogg',
+		'sound/machines/door_close.ogg',
+		'sound/machines/door_open.ogg',
+		'sound/machines/engine_alert1.ogg',
+		'sound/machines/engine_alert2.ogg',
+		'sound/machines/hiss.ogg',
+		'sound/machines/honkbot_evil_laugh.ogg',
+		'sound/machines/juicer.ogg',
+		'sound/machines/ping.ogg',
+		'sound/ambience/signal.ogg',
+		'sound/machines/synth_no.ogg',
+		'sound/machines/synth_yes.ogg',
+		'sound/machines/terminal_alert.ogg',
+		'sound/machines/twobeep.ogg',
+		'sound/machines/ventcrawl.ogg',
+		'sound/machines/warning-buzzer.ogg',
+		'sound/ai/outbreak5.ogg',
+		'sound/ai/outbreak7.ogg',
+		'sound/ai/alert.ogg',
+		'sound/ai/radiation.ogg',
+		'sound/ai/eshuttle_call.ogg',
+		'sound/ai/eshuttle_dock.ogg',
+		'sound/ai/eshuttle_recall.ogg',
+		'sound/ai/aimalf.ogg',
+		'sound/ambience/ambigen1.ogg',
+		'sound/ambience/ambigen3.ogg',
+		'sound/ambience/ambigen4.ogg',
+		'sound/ambience/ambigen5.ogg',
+		'sound/ambience/ambigen6.ogg',
+		'sound/ambience/ambigen10.ogg',
+		'sound/hallucinations/over_here1.ogg',
+		'sound/hallucinations/over_here2.ogg',
+		'sound/hallucinations/over_here3.ogg'
+	)
+
+/// Makes the migo more likely to dodge around the more damaged it is
+/mob/living/basic/netherworld/migo/proc/update_dodge_chance(health_ratio)
+	dodge_prob = LERP(50, 10, health_ratio)
+
+/mob/living/basic/netherworld/migo/proc/make_migo_sound()
+	playsound(src, pick(migo_sounds), 50, TRUE)
+
+/mob/living/basic/netherworld/migo/say(message, bubble_type, list/spans = list(), sanitize = TRUE, datum/language/language = null, ignore_spam = FALSE, forced = null)
+	..()
+	if(stat)
+		return
+	make_migo_sound()
+
+/mob/living/basic/netherworld/migo/Life()
+	..()
+	if(stat)
+		return
+	if(prob(10))
+		make_migo_sound()
+
+/mob/living/basic/netherworld/migo/Move(atom/newloc, dir, step_x, step_y)
+	if(!ckey && prob(dodge_prob) && moving_diagonally == 0 && isturf(loc) && isturf(newloc))
+		return dodge(newloc, dir)
+	else
+		return ..()
+
+/mob/living/basic/netherworld/migo/proc/dodge(moving_to, move_direction)
+	// Assuming we move towards the target we want to swerve toward them to get closer
+	var/cdir = turn(move_direction, 45)
+	var/ccdir = turn(move_direction, -45)
+	. = Move(get_step(loc, pick(cdir, ccdir)))
+	if(!.)// Can't dodge there so we just carry on
+		. = Move(moving_to, move_direction)
+

code/modules/mob/living/basic/nether_mobs/nether_mobs.dm

@@ -0,0 +1,38 @@
+/mob/living/basic/netherworld
+	name = "creature"
+	desc = "A sanity-destroying otherthing from the netherworld."
+	icon_state = "otherthing-pink"
+	icon_living = "otherthing-pink"
+	icon_dead = "otherthing-pink-dead"
+	health = 80
+	maxHealth = 80
+	obj_damage = 100
+	melee_damage_lower = 25
+	melee_damage_upper = 50
+	melee_attack_cooldown_min = 1.5 SECONDS
+	melee_attack_cooldown_max = 2.5 SECONDS
+	environment_smash = ENVIRONMENT_SMASH_STRUCTURES
+	ai_controller = /datum/ai_controller/basic_controller/simple/simple_hostile_obstacles/demonic_incursion
+	attack_verb_simple = "chomp"
+	attack_verb_continuous = "chomps"
+	attack_sound = 'sound/weapons/bladeslice.ogg'
+	speak_emote = list("screams")
+	gold_core_spawnable = HOSTILE_SPAWN
+	atmos_requirements = list("min_oxy" = 0, "max_oxy" = 0, "min_tox" = 0, "max_tox" = 0, "min_co2" = 0, "max_co2" = 0, "min_n2" = 0, "max_n2" = 0)
+	damage_coeff = list(BRUTE = 1, BURN = 1, TOX = 1, STAM = 0, OXY = 1)
+	faction = list("nether")
+	contains_xeno_organ = TRUE
+	surgery_container = /datum/xenobiology_surgery_container/sweating
+	step_type = FOOTSTEP_MOB_SHOE
+	/// The chance of it being a grappler variant
+	var/grappler_chance = 20
+
+/mob/living/basic/netherworld/Initialize(mapload)
+	. = ..()
+	if(prob(grappler_chance))
+		AddComponent(/datum/component/ranged_attacks, projectile_type = /obj/item/projectile/energy/demonic_grappler, projectile_sound = 'sound/weapons/wave.ogg')
+		name = "grappling " + name
+		ai_controller = new /datum/ai_controller/basic_controller/simple/simple_skirmisher/demon_incursion(src)
+		update_appearance(UPDATE_NAME)
+		color = "#5494DA"
+	AddElement(/datum/element/ai_retaliate)