Remove spaces from module files

code/modules/procedural_mapping/mapGeneratorModules/helpers.dm

@@ -0,0 +1,41 @@
+//Helper Modules
+
+
+// Helper to repressurize the area in case it was run in space
+/datum/mapGeneratorModule/bottomLayer/repressurize
+	spawnableAtoms = list()
+	spawnableTurfs = list()
+
+/datum/mapGeneratorModule/bottomLayer/repressurize/generate()
+	if(!mother)
+		return
+	var/list/map = mother.map
+	for(var/turf/simulated/T in map)
+		air_master.remove_from_active(T)
+	for(var/turf/simulated/T in map)
+		if(T.air)
+			T.air.oxygen = T.oxygen
+			T.air.nitrogen = T.nitrogen
+			T.air.carbon_dioxide = T.carbon_dioxide
+			T.air.toxins = T.toxins
+			T.air.temperature = T.temperature
+		air_master.add_to_active(T)
+
+//Only places atoms/turfs on area borders
+/datum/mapGeneratorModule/border
+	clusterCheckFlags = CLUSTER_CHECK_NONE
+
+/datum/mapGeneratorModule/border/generate()
+	if(!mother)
+		return
+	var/list/map = mother.map
+	for(var/turf/T in map)
+		if(is_border(T))
+			place(T)
+
+/datum/mapGeneratorModule/border/proc/is_border(var/turf/T)
+	for(var/direction in list(SOUTH,EAST,WEST,NORTH))
+		if (get_step(T,direction) in mother.map)
+			continue
+		return 1
+	return 0