Add in-game stickyban interface

code/modules/admin/IsBanned.dm

@@ -2,9 +2,11 @@
 world/IsBanned(key,address,computer_id)
 	if (!key || !address || !computer_id)
 		log_access("Failed Login (invalid data): [key] [address]-[computer_id]")
-		return list("reason"="invalid login data", "desc"="Your computer provided invalid or blank information to the server on connection (byond username, IP, and Computer ID.) Provided information for reference: Username:'[key]' IP:'[address]' Computer ID:'[computer_id]' If you continue to get this error, please restart byond or contact byond support.")
-	if(ckey(key) in admin_datums)
-		return ..()
+		return list("reason"="invalid login data", "desc"="Error: Could not check ban status, Please try again. Error message: Your computer provided invalid or blank information to the server on connection (byond username, IP, and Computer ID.) Provided information for reference: Username:'[key]' IP:'[address]' Computer ID:'[computer_id]'. (If you continue to get this error, please restart byond or contact byond support.)")
+	var/admin = 0
+	var/ckey = ckey(key)
+	if((ckey in admin_datums) || (ckey in deadmins))
+		admin = 1
 
 	//Guest Checking
 	if(!guests_allowed && IsGuestKey(key))
@@ -26,11 +28,13 @@ world/IsBanned(key,address,computer_id)
 		//Ban Checking
 		. = CheckBan( ckey(key), computer_id, address )
 		if(.)
-			log_access("Failed Login: [key] [computer_id] [address] - Banned [.["reason"]]")
-			message_admins("\blue Failed Login: [key] id:[computer_id] ip:[address] - Banned [.["reason"]]")
-			return .
-
-		return ..()	//default pager ban stuff
+			if (admin)
+				log_admin("The admin [key] has been allowed to bypass a matching ban on [.["key"]]")
+				message_admins("<span class='adminnotice'>The admin [key] has been allowed to bypass a matching ban on [.["key"]]</span>")
+				addclientmessage(ckey,"<span class='adminnotice'>You have been allowed to bypass a matching ban on [.["key"]]</span>")
+			else
+				log_access("Failed Login: [key] [computer_id] [address] - Banned [.["reason"]]")
+				return .
 
 	else
 
@@ -49,7 +53,7 @@ world/IsBanned(key,address,computer_id)
 		if(computer_id)
 			cidquery = " OR computerid = '[computer_id]' "
 
-		var/DBQuery/query = dbcon.NewQuery("SELECT ckey, ip, computerid, a_ckey, reason, expiration_time, duration, bantime, bantype FROM [format_table_name("ban")] WHERE (ckey = '[ckeytext]' [ipquery] [cidquery]) AND (bantype = 'PERMABAN'  OR (bantype = 'TEMPBAN' AND expiration_time > Now())) AND isnull(unbanned)")
+		var/DBQuery/query = dbcon.NewQuery("SELECT ckey, ip, computerid, a_ckey, reason, expiration_time, duration, bantime, bantype FROM [format_table_name("ban")] WHERE (ckey = '[ckeytext]' [ipquery] [cidquery]) AND (bantype = 'PERMABAN' OR bantype = 'ADMIN_PERMABAN' OR ((bantype = 'TEMPBAN' OR bantype = 'ADMIN_TEMPBAN') AND expiration_time > Now())) AND isnull(unbanned)")
 
 		query.Execute()
 
@@ -63,18 +67,46 @@ world/IsBanned(key,address,computer_id)
 			var/duration = query.item[7]
 			var/bantime = query.item[8]
 			var/bantype = query.item[9]
-
+			if (bantype == "ADMIN_PERMABAN" || bantype == "ADMIN_TEMPBAN")
+				//admin bans MUST match on ckey to prevent cid-spoofing attacks
+				//	as well as dynamic ip abuse
+				if (pckey != ckey)
+					continue
+			if (admin)
+				if (bantype == "ADMIN_PERMABAN" || bantype == "ADMIN_TEMPBAN")
+					log_admin("The admin [key] is admin banned, and has been disallowed access")
+					message_admins("<span class='adminnotice'>The admin [key] is admin banned, and has been disallowed access</span>")
+				else
+					log_admin("The admin [key] has been allowed to bypass a matching ban on [pckey]")
+					message_admins("<span class='adminnotice'>The admin [key] has been allowed to bypass a matching ban on [pckey]</span>")
+					addclientmessage(ckey,"<span class='adminnotice'>You have been allowed to bypass a matching ban on [pckey]</span>")
+					continue
 			var/expires = ""
 			if(text2num(duration) > 0)
 				expires = "The ban is for [duration] minutes and expires on [expiration] (server time)."
-			if(istext(bantype) && (bantype == "PERMABAN"))
-				var/appealmsg = ""
-				if(config && config.banappeals)
-					appealmsg = " You may appeal it at <a href='[config.banappeals]'>[config.banappeals]</a>."
-				expires = "The ban is permanent.[appealmsg]"
+			else
+				expires = " The is a permanent ban."
 
 			var/desc = "\nReason: You, or another user of this computer or connection ([pckey]) is banned from playing here. The ban reason is:\n[reason]\nThis ban was applied by [ackey] on [bantime]. [expires]"
 
-			return list("reason"="[bantype]", "desc"="[desc]")
+			. = list("reason"="[bantype]", "desc"="[desc]")
 
-		return ..()	//default pager ban stuff
+
+			log_access("Failed Login: [key] [computer_id] [address] - Banned [.["reason"]]")
+			return .
+
+
+	. = ..()	//default pager ban stuff
+	if (.)
+		//byond will not trigger isbanned() for "global" host bans,
+		//ie, ones where the "apply to this game only" checkbox is not checked (defaults to not checked)
+		//So it's safe to let admins walk thru host/sticky bans here
+		if (admin)
+			log_admin("The admin [key] has been allowed to bypass a matching host/sticky ban")
+			message_admins("<span class='adminnotice'>The admin [key] has been allowed to bypass a matching host/sticky ban</span>")
+			addclientmessage(ckey,"<span class='adminnotice'>You have been allowed to bypass a matching host/sticky ban")
+			return null
+		else
+			log_access("Failed Login: [key] [computer_id] [address] - Banned [.["message"]]")
+
+	return .

code/modules/admin/admin_memo.dm

@@ -11,7 +11,7 @@
 		return
 	admin_memo_output(memotask)
 
-/client/proc/admin_memo_output(task, checkrights = 1)
+/client/proc/admin_memo_output(task, checkrights = 1, silent = 0)
 	if(checkrights && !check_rights(R_SERVER))
 		return
 	if(!task)
@@ -99,7 +99,7 @@
 				if(last_editor)
 					output += "<br><span class='memoedit'>Last edit by [last_editor] <A href='?_src_=holder;memoeditlist=[ckey]'>(Click here to see edit log)</A></span>"
 				output += "<br>[memotext]</span><br>"
-			if(!output)
+			if(!output && !silent)
 				src << "No memos found in database."
 				return
 			src << output

code/modules/admin/admin_verbs.dm

@@ -74,7 +74,8 @@ var/list/admin_verbs_admin = list(
 )
 var/list/admin_verbs_ban = list(
 	/client/proc/unban_panel,
-	/client/proc/jobbans
+	/client/proc/jobbans,
+	/client/proc/stickybanpanel
 	)
 var/list/admin_verbs_sounds = list(
 	/client/proc/play_local_sound,

code/modules/admin/stickyban.dm

@@ -0,0 +1,207 @@
+/datum/admins/proc/stickyban(action,data)
+	if(!check_rights(R_BAN))
+		return
+
+	switch (action)
+		if ("show")
+			stickyban_show()
+		if ("add")
+			var/list/ban = list()
+			var/ckey
+			ban["admin"] = usr.key
+			ban["type"] = list("sticky")
+			ban["reason"] = "(InGameBan)([usr.key])" //this will be displayed in dd only
+
+			if (data["ckey"])
+				ckey = ckey(data["ckey"])
+			else
+				ckey = input(usr,"Ckey","Ckey","") as text|null
+				if (!ckey)
+					return
+				ckey = ckey(ckey)
+			if (get_stickyban_from_ckey(ckey))
+				usr << "<span class='adminnotice'>Error: Can not add a stickyban: User already has a current sticky ban</span>"
+
+			if (data["reason"])
+				ban["message"] = data["reason"]
+			else
+				var/reason = input(usr,"Reason","Reason","Ban Evasion") as text|null
+				if (!reason)
+					return
+				ban["message"] = "[reason]"
+
+			world.SetConfig("ban",ckey,list2stickyban(ban))
+
+			log_admin("[key_name(usr)] has stickybanned [ckey].\nReason: [ban["message"]]")
+			message_admins("<span class='adminnotice'>[key_name_admin(usr)] has stickybanned [ckey].\nReason: [ban["message"]]</span>")
+
+		if ("remove")
+			if (!data["ckey"])
+				return
+			var/ckey = data["ckey"]
+
+			var/ban = get_stickyban_from_ckey(ckey)
+			if (!ban)
+				usr << "<span class='adminnotice'>Error: No sticky ban for [ckey] found!</span>"
+				return
+			if (alert("Are you sure you want to remove the sticky ban on [ckey]?","Are you sure","Yes","No") == "No")
+				return
+			if (!get_stickyban_from_ckey(ckey))
+				usr << "<span class='adminnotice'>Error: The ban disappeared.</span>"
+				return
+			world.SetConfig("ban",ckey, null)
+
+			log_admin("[key_name(usr)] removed [ckey]'s stickyban")
+			message_admins("<span class='adminnotice'>[key_name_admin(usr)] removed [ckey]'s stickyban</span>")
+
+		if ("remove_alt")
+			if (!data["ckey"])
+				return
+			var/ckey = data["ckey"]
+			if (!data["alt"])
+				return
+			var/alt = ckey(data["alt"])
+			var/ban = get_stickyban_from_ckey(ckey)
+			if (!ban)
+				usr << "<span class='adminnotice'>Error: No sticky ban for [ckey] found!</span>"
+				return
+
+			var/found = 0
+			//we have to do it this way because byond keeps the case in its sticky ban matches WHY!!!
+			for (var/key in ban["keys"])
+				if (ckey(key) == alt)
+					found = 1
+					break
+
+			if (!found)
+				usr << "<span class='adminnotice'>Error: [alt] is not linked to [ckey]'s sticky ban!</span>"
+				return
+
+			if (alert("Are you sure you want to disassociate [alt] from [ckey]'s sticky ban? \nNote: Nothing stops byond from re-linking them","Are you sure","Yes","No") == "No")
+				return
+
+			//we have to do this again incase something changes
+			ban = get_stickyban_from_ckey(ckey)
+			if (!ban)
+				usr << "<span class='adminnotice'>Error: The ban disappeared.</span>"
+				return
+
+			found = 0
+			for (var/key in ban["keys"])
+				if (ckey(key) == alt)
+					ban["keys"] -= key
+					found = 1
+					break
+
+			if (!found)
+				usr << "<span class='adminnotice'>Error: [alt] link to [ckey]'s sticky ban disappeared.</span>"
+				return
+
+			world.SetConfig("ban",ckey,list2stickyban(ban))
+
+			log_admin("[key_name(usr)] has disassociated [alt] from [ckey]'s sticky ban")
+			message_admins("<span class='adminnotice'>[key_name_admin(usr)] has disassociated [alt] from [ckey]'s sticky ban</span>")
+
+		if ("edit")
+			if (!data["ckey"])
+				return
+			var/ckey = data["ckey"]
+			var/ban = get_stickyban_from_ckey(ckey)
+			if (!ban)
+				usr << "<span class='adminnotice'>Error: No sticky ban for [ckey] found!"
+				return
+			var/oldreason = ban["message"]
+			var/reason = input(usr,"Reason","Reason","[ban["message"]]") as text|null
+			if (!reason || reason == oldreason)
+				return
+			//we have to do this again incase something changed while we waited for input
+			ban = get_stickyban_from_ckey(ckey)
+			if (!ban)
+				usr << "<span class='adminnotice'>Error: The ban disappeared.</span>"
+				return
+			ban["message"] = "[reason]"
+
+			world.SetConfig("ban",ckey,list2stickyban(ban))
+
+			log_admin("[key_name(usr)] has edited [ckey]'s sticky ban reason from [oldreason] to [reason]")
+			message_admins("<span class='adminnotice'>[key_name_admin(usr)] has edited [ckey]'s sticky ban reason from [oldreason] to [reason]</span>")
+
+/datum/admins/proc/stickyban_gethtml(ckey, ban)
+	. = "<a href='?_src_=holder;stickyban=remove&ckey=[ckey]'>\[-\]</a><b>[ckey]</b><br />"
+	. += "[ban["message"]] <b><a href='?_src_=holder;stickyban=edit&ckey=[ckey]'>\[Edit\]</a></b><br />"
+	if (ban["admin"])
+		. += "[ban["admin"]]<br />"
+	else
+		. += "LEGACY<br />"
+	. += "Caught keys<br />\n<ol>"
+	for (var/key in ban["keys"])
+		if (ckey(key) == ckey)
+			continue
+		. += "<li><a href='?_src_=holder;stickyban=remove_alt&ckey=[ckey]&alt=[ckey(key)]'>\[-\]</a>[key]</li>"
+	. += "</ol>\n"
+
+/datum/admins/proc/stickyban_show()
+	if(!check_rights(R_BAN))
+		return
+		
+	var/list/bans = world.GetConfig("ban")
+	var/banhtml = ""
+	for(var/key in bans)
+		var/ckey = ckey(key)
+		var/ban = stickyban2list(world.GetConfig("ban",key))
+		banhtml += "<br /><hr />\n"
+		banhtml += stickyban_gethtml(ckey,ban)
+
+	var/html = {"
+	<head>
+		<title>Sticky Bans</title>
+	</head>
+	<body>
+		<h2>All Sticky Bans:</h2> <a href='?_src_=holder;stickyban=add'>\[+\]</a><br>
+		[banhtml]
+	</body>
+	"}
+	usr << browse(html,"window=stickybans;size=700x400")
+
+/proc/get_stickyban_from_ckey(var/ckey)
+	if (!ckey)
+		return null
+	ckey = ckey(ckey)
+	. = null
+	for (var/key in world.GetConfig("ban"))
+		if (ckey(key) == ckey)
+			. = stickyban2list(world.GetConfig("ban",key))
+			break
+
+/proc/stickyban2list(var/ban)
+	if (!ban)
+		return null
+	. = params2list(ban)
+	.["keys"] = text2list(.["keys"], ",")
+	.["type"] = text2list(.["type"], ",")
+	.["IP"] = text2list(.["IP"], ",")
+	.["computer_id"] = text2list(.["computer_id"], ",")
+
+/proc/list2stickyban(var/list/ban)
+	if (!ban || !islist(ban))
+		return null
+	. = ban.Copy()
+	if (.["keys"])
+		.["keys"] = list2text(.["keys"], ",")
+	if (.["type"])
+		.["type"] = list2text(.["type"], ",")
+	if (.["IP"])
+		.["IP"] = list2text(.["IP"], ",")
+	if (.["computer_id"])
+		.["computer_id"] = list2text(.["computer_id"], ",")
+	. = list2params(.)
+
+/client/proc/stickybanpanel()
+	set name = "Sticky Ban Panel"
+	set category = "Admin"
+
+	if(!check_rights(R_BAN))
+		return
+	
+	holder.stickyban_show()
+	

code/modules/admin/topic.dm

@@ -25,6 +25,9 @@
 
 		message_admins("[key_name_admin(usr)] rejected [key_name_admin(C.mob)]'s admin help")
 		log_admin("[key_name(usr)] rejected [key_name(C.mob)]'s admin help")
+		
+	if(href_list["stickyban"])
+		stickyban(href_list["stickyban"],href_list)
 
 	if(href_list["makeAntag"])
 		switch(href_list["makeAntag"])