Adds Sandbags Reworks Security Barricades

code/game/objects/items/stacks/medical.dm

@@ -123,6 +123,19 @@
 	origin_tech = "biotech=2"
 	stop_bleeding = 1800
 
+/obj/item/stack/medical/bruise_pack/attackby(obj/item/I, mob/user, params)
+	if(I.sharp)
+		if(get_amount() < 2)
+			to_chat(user, "<span class='warning'>You need at least two gauzes to do this!</span>")
+			return
+		new /obj/item/stack/sheet/cloth(user.drop_location())
+		user.visible_message("[user] cuts [src] into pieces of cloth with [I].", \
+					 "<span class='notice'>You cut [src] into pieces of cloth with [I].</span>", \
+					 "<span class='italics'>You hear cutting.</span>")
+		use(2)
+	else
+		return ..()
+
 /obj/item/stack/medical/bruise_pack/attack(mob/living/M, mob/user)
 	if(..())
 		return 1

code/game/objects/items/stacks/sheets/mineral.dm

@@ -137,6 +137,44 @@ var/global/list/datum/stack_recipe/snow_recipes = list(
 	..()
 	recipes = sandstone_recipes
 
+/*
+ * Sandbags
+ */
+
+/obj/item/stack/sheet/mineral/sandbags
+	name = "sandbags"
+	icon_state = "sandbags"
+	singular_name = "sandbag"
+	layer = LOW_ITEM_LAYER
+	merge_type = /obj/item/stack/sheet/mineral/sandbags
+
+GLOBAL_LIST_INIT(sandbag_recipes, list ( \
+	new/datum/stack_recipe("sandbags", /obj/structure/barricade/sandbags, 1, time = 25, one_per_turf = 1, on_floor = 1), \
+	))
+
+/obj/item/stack/sheet/mineral/sandbags/New()
+	recipes = GLOB.sandbag_recipes
+	..()
+
+/obj/item/emptysandbag
+	name = "empty sandbag"
+	desc = "A bag to be filled with sand."
+	icon = 'icons/obj/items.dmi'
+	icon_state = "sandbag"
+	w_class = WEIGHT_CLASS_TINY
+
+/obj/item/emptysandbag/attackby(obj/item/I, mob/user, params)
+	if(istype(I, /obj/item/stack/ore/glass))
+		var/obj/item/stack/ore/glass/G = I
+		to_chat(user, "<span class='notice'>You fill the sandbag.</span>")
+		var/obj/item/stack/sheet/mineral/sandbags/S = new /obj/item/stack/sheet/mineral/sandbags(drop_location())
+		qdel(src)
+		if(Adjacent(user) && !issilicon(user))
+			user.put_in_hands(S)
+		G.use(1)
+	else
+		return ..()
+
 /obj/item/stack/sheet/mineral/diamond
 	name = "diamond"
 	icon_state = "sheet-diamond"

code/game/objects/items/stacks/sheets/sheet_types.dm

@@ -218,6 +218,7 @@ var/global/list/datum/stack_recipe/cloth_recipes = list ( \
 	null, \
 	new/datum/stack_recipe("rag", /obj/item/reagent_containers/glass/rag, 1), \
 	new/datum/stack_recipe("bedsheet", /obj/item/bedsheet, 3), \
+	new/datum/stack_recipe("empty sandbag", /obj/item/emptysandbag, 4), \
 	null, \
 	new/datum/stack_recipe("fingerless gloves", /obj/item/clothing/gloves/fingerless, 1), \
 	new/datum/stack_recipe("black gloves", /obj/item/clothing/gloves/color/black, 3), \

code/game/objects/items/weapons/storage/boxes.dm

@@ -1059,6 +1059,15 @@
 	desc = "A colorful cardboard box for the clown"
 	icon_state = "box_clown"
 
+/obj/item/storage/box/emptysandbags
+	name = "box of empty sandbags"
+
+/obj/item/storage/box/emptysandbags/New()
+	..()
+	contents = list()
+	for(var/i in 1 to 7)
+		new /obj/item/emptysandbag(src)
+
 /obj/item/storage/box/rndboards
 	name = "the Liberator's legacy"
 	desc = "A box containing a gift for worthy golems."

code/game/objects/structures/bedsheet_bin.dm

@@ -34,6 +34,15 @@ LINEN BINS
 	add_fingerprint(user)
 	return
 
+/obj/item/bedsheet/attackby(obj/item/I, mob/user, params)
+	if(I.sharp)
+		var/obj/item/stack/sheet/cloth/C = new (get_turf(src), 3)
+		transfer_fingerprints_to(C)
+		C.add_fingerprint(user)
+		qdel(src)
+		to_chat(user, "<span class='notice'>You tear [src] up.</span>")
+	else
+		return ..()
 
 /obj/item/bedsheet/blue
 	icon_state = "sheetblue"