More Makeshift Items/Weapons

code/game/objects/items.dm

@@ -1,3 +1,5 @@
+var/global/image/fire_overlay = image("icon" = 'icons/goonstation/effects/fire.dmi', "icon_state" = "fire")
+
 /obj/item
 	name = "item"
 	icon = 'icons/obj/items.dmi'

code/game/objects/items/weapons/clown_items.dm

@@ -105,4 +105,28 @@
 	desc = "Damn son, where'd you find this?"
 	icon_state = "air_horn"
 	honk_sound = 'sound/items/AirHorn2.ogg'
-	cooldowntime = 50
+	cooldowntime = 50
+
+/obj/item/weapon/bikehorn/golden
+	name = "golden bike horn"
+	desc = "Golden? Clearly, its made with bananium! Honk!"
+	icon_state = "gold_horn"
+	item_state = "gold_horn"
+
+/obj/item/weapon/bikehorn/golden/attack()
+	flip_mobs()
+	return ..()
+
+/obj/item/weapon/bikehorn/golden/attack_self(mob/user)
+	flip_mobs()
+	..()
+
+/obj/item/weapon/bikehorn/golden/proc/flip_mobs(mob/living/carbon/M, mob/user)
+	if (!spam_flag)
+		var/turf/T = get_turf(src)
+		for(M in ohearers(7, T))
+			if(istype(M, /mob/living/carbon/human))
+				var/mob/living/carbon/human/H = M
+				if(istype(H.l_ear, /obj/item/clothing/ears/earmuffs) || istype(H.r_ear, /obj/item/clothing/ears/earmuffs) || H.ear_deaf)
+					continue
+			M.emote("flip")

code/game/objects/items/weapons/defib.dm

@@ -69,7 +69,7 @@
 			ratio = Ceiling(ratio*4) * 25
 			overlays += "[icon_state]-charge[ratio]"
 
-/obj/item/weapon/defibrillator/CheckParts()
+/obj/item/weapon/defibrillator/CheckParts(list/parts_list)
 	..()
 	bcell = locate(/obj/item/weapon/stock_parts/cell) in contents
 	update_icon()

code/game/objects/items/weapons/flamethrower.dm

@@ -164,10 +164,13 @@
 	update_icon()
 	return
 
-/obj/item/weapon/flamethrower/CheckParts()
+/obj/item/weapon/flamethrower/CheckParts(list/parts_list)
 	..()
 	weldtool = locate(/obj/item/weapon/weldingtool) in contents
 	igniter = locate(/obj/item/device/assembly/igniter) in contents
+	weldtool.status = 0
+	igniter.secured = 0
+	status = 1
 	update_icon()
 
 //Called from turf.dm turf/dblclick

code/game/objects/items/weapons/grenades/ghettobomb.dm

@@ -93,7 +93,7 @@
 	else
 		range = pick(2,2,2,3,3,3,4)
 
-/obj/item/weapon/grenade/iedcasing/CheckParts()
+/obj/item/weapon/grenade/iedcasing/CheckParts(list/parts_list)
 	..()
 	var/obj/item/weapon/reagent_containers/food/drinks/cans/can = locate() in contents
 	if(can)

code/game/objects/items/weapons/storage/boxes.dm

@@ -705,3 +705,72 @@
 	new /obj/item/weapon/lipstick/green(src)
 	new /obj/item/weapon/lipstick/blue(src)
 	new /obj/item/weapon/lipstick/white(src)
+
+#define NODESIGN "None"
+#define NANOTRASEN "NanotrasenStandard"
+#define SYNDI "SyndiSnacks"
+#define HEART "Heart"
+#define SMILE "SmileyFace"
+
+/obj/item/weapon/storage/box/papersack
+	name = "paper sack"
+	desc = "A sack neatly crafted out of paper."
+	icon_state = "paperbag_None"
+	item_state = "paperbag_None"
+	foldable = null
+	var/design = NODESIGN
+
+/obj/item/weapon/storage/box/papersack/update_icon()
+	if(contents.len == 0)
+		icon_state = "[item_state]"
+	else icon_state = "[item_state]_closed"
+
+/obj/item/weapon/storage/box/papersack/attackby(obj/item/weapon/W, mob/user, params)
+	if(istype(W, /obj/item/weapon/pen))
+		//if a pen is used on the sack, dialogue to change its design appears
+		if(contents.len)
+			to_chat(user, "<span class='warning'>You can't modify this [src] with items still inside!</span>")
+			return
+		var/list/designs = list(NODESIGN, NANOTRASEN, SYNDI, HEART, SMILE, "Cancel")
+		var/switchDesign = input("Select a Design:", "Paper Sack Design", designs[1]) in designs
+		if(get_dist(usr, src) > 1)
+			to_chat(usr, "<span class='warning'>You have moved too far away!</span>")
+			return
+		var/choice = designs.Find(switchDesign)
+		if(design == designs[choice] || designs[choice] == "Cancel")
+			return 0
+		to_chat(usr, "<span class='notice'>You make some modifications to the [src] using your pen.</span>")
+		design = designs[choice]
+		icon_state = "paperbag_[design]"
+		item_state = "paperbag_[design]"
+		switch(designs[choice])
+			if(NODESIGN)
+				desc = "A sack neatly crafted out of paper."
+			if(NANOTRASEN)
+				desc = "A standard Nanotrasen paper lunch sack for loyal employees on the go."
+			if(SYNDI)
+				desc = "The design on this paper sack is a remnant of the notorious 'SyndieSnacks' program."
+			if(HEART)
+				desc = "A paper sack with a heart etched onto the side."
+			if(SMILE)
+				desc = "A paper sack with a crude smile etched onto the side."
+		return 0
+	else if(is_sharp(W))
+		if(!contents.len)
+			if(item_state == "paperbag_None")
+				to_chat(user, "<span class='notice'>You cut eyeholes into the [src].</span>")
+				new /obj/item/clothing/head/papersack(user.loc)
+				qdel(src)
+				return 0
+			else if(item_state == "paperbag_SmileyFace")
+				to_chat(user, "<span class='notice'>You cut eyeholes into the [src] and modify the design.</span>")
+				new /obj/item/clothing/head/papersack/smiley(user.loc)
+				qdel(src)
+				return 0
+	return ..()
+
+#undef NODESIGN
+#undef NANOTRASEN
+#undef SYNDI
+#undef HEART
+#undef SMILE

code/game/objects/items/weapons/stunbaton.dm

@@ -23,7 +23,7 @@
 	update_icon()
 	return
 
-/obj/item/weapon/melee/baton/CheckParts()
+/obj/item/weapon/melee/baton/CheckParts(list/parts_list)
 	..()
 	bcell = locate(/obj/item/weapon/stock_parts/cell) in contents
 	update_icon()

code/game/objects/items/weapons/twohanded.dm

@@ -283,20 +283,90 @@
 	w_class = 4
 	slot_flags = SLOT_BACK
 	force_unwielded = 10
-	force_wielded = 18 // Was 13, Buffed - RR
+	force_wielded = 18
 	throwforce = 20
-	throw_speed = 3
+	throw_speed = 4
 	armour_penetration = 10
-	no_spin_thrown = 1 // Thrown spears that spin look dumb. -Fox
+	materials = list(MAT_METAL=1150, MAT_GLASS=2075)
+	hitsound = 'sound/weapons/bladeslice.ogg'
 	attack_verb = list("attacked", "poked", "jabbed", "torn", "gored")
+	sharp = 1
+	edge = 1
+	no_spin_thrown = 1
+	var/obj/item/weapon/grenade/explosive = null
+	var/war_cry = "AAAAARGH!!!"
 
 /obj/item/weapon/twohanded/spear/update_icon()
-	icon_state = "spearglass[wielded]"
-	return
+	if(explosive)
+		icon_state = "spearbomb[wielded]"
+	else
+		icon_state = "spearglass[wielded]"
 
-/obj/item/weapon/twohanded/spear/attack(mob/living/carbon/M as mob, mob/living/carbon/user as mob)
-	playsound(loc, 'sound/weapons/bladeslice.ogg', 50, 1, -1)
-	return ..()
+/obj/item/weapon/twohanded/spear/afterattack(atom/movable/AM, mob/user, proximity)
+	if(!proximity)
+		return
+	if(isturf(AM)) //So you can actually melee with it
+		return
+	if(explosive && wielded)
+		user.say("[war_cry]")
+		explosive.loc = AM
+		explosive.prime()
+		qdel(src)
+
+/obj/item/weapon/twohanded/spear/throw_impact(atom/target)
+	. = ..()
+	if(explosive)
+		explosive.prime()
+		qdel(src)
+
+/obj/item/weapon/twohanded/spear/AltClick()
+	..()
+	if(!explosive)
+		return
+	if(ismob(loc))
+		var/mob/M = loc
+		var/input = stripped_input(M, "What do you want your war cry to be? You will shout it when you hit someone in melee.", ,"", 50)
+		if(input)
+			war_cry = input
+
+/obj/item/weapon/twohanded/spear/CheckParts(list/parts_list)
+	..()
+	if(explosive)
+		explosive.loc = get_turf(src.loc)
+		explosive = null
+	var/obj/item/weapon/grenade/G = locate() in contents
+	if(G)
+		explosive = G
+		name = "explosive lance"
+		desc = "A makeshift spear with [G] attached to it. Alt+click on the spear to set your war cry!"
+		return
+	update_icon()
+
+//GREY TIDE
+/obj/item/weapon/twohanded/spear/grey_tide
+	icon_state = "spearglass0"
+	name = "\improper Grey Tide"
+	desc = "Recovered from the aftermath of a revolt aboard Defense Outpost Theta Aegis, in which a seemingly endless tide of Assistants caused heavy casualities among Nanotrasen military forces."
+	force_unwielded = 15
+	force_wielded = 25
+	throwforce = 20
+	throw_speed = 4
+	attack_verb = list("gored")
+
+/obj/item/weapon/twohanded/spear/grey_tide/afterattack(atom/movable/AM, mob/living/user, proximity)
+	..()
+	if(!proximity)
+		return
+	user.faction |= "greytide(\ref[user])"
+	if(isliving(AM))
+		var/mob/living/L = AM
+		if(istype (L, /mob/living/simple_animal/hostile/illusion))
+			return
+		if(!L.stat && prob(50))
+			var/mob/living/simple_animal/hostile/illusion/M = new(user.loc)
+			M.faction = user.faction.Copy()
+			M.Copy_Parent(user, 100, user.health/2.5, 12, 30)
+			M.GiveTarget(L)
 
 //Putting heads on spears
 /obj/item/organ/external/head/attackby(var/obj/item/weapon/W, var/mob/living/user, params)
@@ -348,6 +418,53 @@
 	name = "Kidan spear"
 	desc = "A spear brought over from the Kidan homeworld."
 
+// DIY CHAINSAW
+/obj/item/weapon/twohanded/required/chainsaw
+	name = "chainsaw"
+	desc = "A versatile power tool. Useful for limbing trees and delimbing humans."
+	icon_state = "gchainsaw_off"
+	flags = CONDUCT
+	force = 13
+	w_class = 5
+	throwforce = 13
+	throw_speed = 2
+	throw_range = 4
+	materials = list(MAT_METAL=13000)
+	origin_tech = "materials=3;engineering=4;combat=2"
+	attack_verb = list("sawed", "cut", "hacked", "carved", "cleaved", "butchered", "felled", "timbered")
+	hitsound = "swing_hit"
+	sharp = 1
+	edge = 1
+	actions_types = list(/datum/action/item_action/startchainsaw)
+	var/on = 0
+
+/obj/item/weapon/twohanded/required/chainsaw/attack_self(mob/user)
+	on = !on
+	to_chat(user, "As you pull the starting cord dangling from [src], [on ? "it begins to whirr." : "the chain stops moving."]")
+	if(on)
+		playsound(loc, 'sound/weapons/chainsawstart.ogg', 50, 1)
+	force = on ? 21 : 13
+	throwforce = on ? 21 : 13
+	icon_state = "gchainsaw_[on ? "on" : "off"]"
+
+	if(hitsound == "swing_hit")
+		hitsound = 'sound/weapons/chainsaw.ogg'
+	else
+		hitsound = "swing_hit"
+
+	if(src == user.get_active_hand()) //update inhands
+		user.update_inv_l_hand()
+		user.update_inv_r_hand()
+	for(var/X in actions)
+		var/datum/action/A = X
+		A.UpdateButtonIcon()
+
+/obj/item/weapon/twohanded/required/chainsaw/doomslayer
+	name = "OOOH BABY"
+	desc = "<span class='warning'>VRRRRRRR!!!</span>"
+	armour_penetration = 100
+
+
 ///CHAINSAW///
 /obj/item/weapon/twohanded/chainsaw
 	icon_state = "chainsaw0"