diff --git a/code/datums/martial.dm b/code/datums/martial.dm
index 1388e088f8c..b2892b959a3 100644
--- a/code/datums/martial.dm
+++ b/code/datums/martial.dm
@@ -305,6 +305,128 @@
 	basic_hit(A,D)
 	return 1
 
+#define WRIST_WRENCH_COMBO "DD"
+#define BACK_KICK_COMBO "HG"
+#define STOMACH_KNEE_COMBO "GH"
+#define HEAD_KICK_COMBO "DHH"
+#define ELBOW_DROP_COMBO "HDHDH"
+/datum/martial_art/the_sleeping_carp
+	name = "The Sleeping Carp"
+
+/datum/martial_art/the_sleeping_carp/proc/check_streak(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	if(findtext(streak,WRIST_WRENCH_COMBO))
+		streak = ""
+		wristWrench(A,D)
+		return 1
+	if(findtext(streak,BACK_KICK_COMBO))
+		streak = ""
+		backKick(A,D)
+		return 1
+	if(findtext(streak,STOMACH_KNEE_COMBO))
+		streak = ""
+		kneeStomach(A,D)
+		return 1
+	if(findtext(streak,HEAD_KICK_COMBO))
+		streak = ""
+		headKick(A,D)
+		return 1
+	if(findtext(streak,ELBOW_DROP_COMBO))
+		streak = ""
+		elbowDrop(A,D)
+		return 1
+	return 0
+
+/datum/martial_art/the_sleeping_carp/proc/wristWrench(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	if(!D.stat && !D.stunned && !D.weakened)
+		D.visible_message("<span class='warning'>[A] grabs [D]'s wrist and wrenches it sideways!</span>", \
+						  "<span class='userdanger'>[A] grabs your wrist and violently wrenches it to the side!</span>")
+		playsound(get_turf(A), 'sound/weapons/thudswoosh.ogg', 50, 1, -1)
+		D.emote("scream")
+		D.drop_item()
+		D.apply_damage(5, BRUTE, pick("l_arm", "r_arm"))
+		D.Stun(2)
+		return 1
+	return basic_hit(A,D)
+
+/datum/martial_art/the_sleeping_carp/proc/backKick(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	if(A.dir == D.dir && !D.stat && !D.weakened)
+		D.visible_message("<span class='warning'>[A] kicks [D] in the back!</span>", \
+						  "<span class='userdanger'>[A] kicks you in the back, making you stumble and fall!</span>")
+		step_to(D,get_step(D,D.dir),1)
+		D.Weaken(4)
+		playsound(get_turf(D), 'sound/weapons/punch1.ogg', 50, 1, -1)
+		return 1
+	return basic_hit(A,D)
+
+/datum/martial_art/the_sleeping_carp/proc/kneeStomach(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	if(!D.stat && !D.weakened)
+		D.visible_message("<span class='warning'>[A] knees [D] in the stomach!</span>", \
+						  "<span class'userdanger'>[A] winds you with a knee in the stomach!</span>")
+		D.audible_message("<b>[D]</b> gags!")
+		D.losebreath += 3
+		D.Stun(1)
+		playsound(get_turf(D), 'sound/weapons/punch1.ogg', 50, 1, -1)
+		return 1
+	return basic_hit(A,D)
+
+/datum/martial_art/the_sleeping_carp/proc/headKick(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	if(!D.stat && !D.weakened)
+		D.visible_message("<span class='warning'>[A] kicks [D] in the head!</span>", \
+						  "<span class='userdanger'>[A] kicks you in the jaw!</span>")
+		D.apply_damage(20, BRUTE, "head")
+		D.drop_item()
+		playsound(get_turf(D), 'sound/weapons/punch1.ogg', 75, 1, -1)
+		return 1
+	return basic_hit(A,D)
+
+/datum/martial_art/the_sleeping_carp/proc/elbowDrop(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	if(D.weakened || D.resting || D.stat)
+		D.visible_message("<span class='warning'>[A] elbow drops [D]!</span>", \
+						  "<span class='userdanger'>[A] piledrives you with their elbow!</span>")
+		if(D.stat)
+			D.death() //FINISH HIM!
+		D.apply_damage(50, BRUTE, "chest")
+		playsound(get_turf(D), 'sound/weapons/punch1.ogg', 100, 1, -1)
+		return 1
+	return basic_hit(A,D)
+
+/datum/martial_art/the_sleeping_carp/grab_act(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	add_to_streak("G")
+	if(check_streak(A,D))
+		return 1
+	..()
+	var/obj/item/weapon/grab/G = A.get_active_hand()
+	if(G)
+		G.state = GRAB_AGGRESSIVE //Instant aggressive grab
+
+/datum/martial_art/the_sleeping_carp/harm_act(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	add_to_streak("H")
+	if(check_streak(A,D))
+		return 1
+	D.visible_message("<span class='danger'>[A] [pick("punches", "kicks", "chops", "hits", "slams")] [D]!</span>", \
+					  "<span class='userdanger'>[A] hits you!</span>")
+	D.apply_damage(10, BRUTE)
+	playsound(get_turf(D), 'sound/weapons/punch1.ogg', 50, 1, -1)
+	return 1
+
+
+/datum/martial_art/the_sleeping_carp/disarm_act(var/mob/living/carbon/human/A, var/mob/living/carbon/human/D)
+	add_to_streak("D")
+	if(check_streak(A,D))
+		return 1
+	return ..()
+
+/mob/living/carbon/human/proc/sleeping_carp_help()
+	set name = "Recall Teachings"
+	set desc = "Remember the martial techniques of the Sleeping Carp clan."
+	set category = "Sleeping Carp"
+
+	usr << "<b><i>You retreat inward and recall the teachings of the Sleeping Carp...</i></b>"
+	usr << "<span class='notice'>Wrist Wrench</span>: Disarm Disarm. Forces opponent to drop item in hand."
+	usr << "<span class='notice'>Back Kick</span>: Harm Grab. Opponent must be facing away. Knocks down."
+	usr << "<span class='notice'>Stomach Knee</span>: Grab Harm. Knocks the wind out of opponent and stuns."
+	usr << "<span class='notice'>Head Kick</span>: Disarm Harm Harm. Decent damage, forces opponent to drop item in hand."
+	usr << "<span class='notice'>Elbow Drop</span>: Harm Disarm Harm Disarm Harm. Opponent must be on the ground. Deals huge damage, instantly kills anyone in critical condition."
 
 //ITEMS
 
@@ -364,3 +486,100 @@
 		H << "<span class='notice'>You learn the PLASMA FIST style.</span>"
 		used = 1
 		desc += "It looks like it's magic was used up."
+
+/obj/item/weapon/sleeping_carp_scroll
+	name = "mysterious scroll"
+	desc = "A scroll filled with strange markings. It seems to be drawings of some sort of martial art."
+	icon = 'icons/obj/wizard.dmi'
+	icon_state = "scroll2"
+
+/obj/item/weapon/sleeping_carp_scroll/attack_self(mob/living/carbon/human/user as mob)
+	if(!istype(user) || !user)
+		return
+	user << "<span class='notice'>You begin to read the scroll...</span>"
+	user << "<span class='sciradio'><i>And all at once the secrets of the Sleeping Carp fill your mind. The ancient clan's martial teachings have been imbued into this scroll. As you read through it, \
+ 	these secrets flood into your mind and body. You now know the martial techniques of the Sleeping Carp. Your hand-to-hand combat has become much more effective, and you may now perform powerful \
+ 	combination attacks. To learn more about these combos, use the Recall Teachings ability in the Sleeping Carp tab.</i></span>"
+	user.verbs += /mob/living/carbon/human/proc/sleeping_carp_help
+	var/datum/martial_art/the_sleeping_carp/theSleepingCarp = new(null)
+	theSleepingCarp.teach(user)
+	user.drop_item()
+	visible_message("<span class='warning'>[src] lights up in fire and quickly burns to ash.</span>")
+	new /obj/effect/decal/cleanable/ash(get_turf(src))
+	qdel(src)
+
+
+/obj/item/weapon/twohanded/bostaff
+	name = "bo staff"
+	desc = "A long, tall staff made of polished wood. Traditionally used in ancient old-Earth martial arts. Can be wielded to both kill and incapacitate."
+	force = 8
+	w_class = 4
+	slot_flags = SLOT_BACK
+	force_unwielded = 8
+	force_wielded = 18
+	throwforce = 20
+	attack_verb = list("smashed", "slammed", "whacked", "thwacked")
+	icon = 'icons/obj/weapons.dmi'
+	icon_state = "bostaff0"
+
+/obj/item/weapon/twohanded/bostaff/update_icon()
+	icon_state = "bostaff[wielded]"
+	return
+
+/obj/item/weapon/twohanded/bostaff/attack(mob/target, mob/living/user)
+	add_fingerprint(user)
+	if((CLUMSY in user.disabilities) && prob(50))
+		user << "<span class ='warning'>You club yourself over the head with [src].</span>"
+		user.Weaken(3)
+		if(ishuman(user))
+			var/mob/living/carbon/human/H = user
+			H.apply_damage(2*force, BRUTE, "head")
+		else
+			user.take_organ_damage(2*force)
+		return
+	if(isrobot(target))
+		return ..()
+	if(!isliving(target))
+		return ..()
+	var/mob/living/carbon/C = target
+	if(C.stat)
+		user << "<span class='warning'>It would be dishonorable to attack a foe while they cannot retaliate.</span>"
+		return
+	switch(user.a_intent)
+		if("disarm")
+			if(!wielded)
+				return ..()
+			if(!ishuman(target))
+				return ..()
+			var/mob/living/carbon/human/H = target
+			var/list/fluffmessages = list("[user] clubs [H] with [src]!", \
+										  "[user] smacks [H] with the butt of [src]!", \
+										  "[user] broadsides [H] with [src]!", \
+										  "[user] smashes [H]'s head with [src]!", \
+										  "[user] beats [H] with front of [src]!", \
+										  "[user] twirls and slams [H] with [src]!")
+			H.visible_message("<span class='warning'>[pick(fluffmessages)]</span>", \
+								   "<span class='userdanger'>[pick(fluffmessages)]</span>")
+			playsound(get_turf(user), 'sound/effects/woodhit.ogg', 75, 1, -1)
+			H.adjustStaminaLoss(rand(13,20))
+			if(prob(10))
+				H.visible_message("<span class='warning'>[H] collapses!</span>", \
+									   "<span class='userdanger'>Your legs give out!</span>")
+				H.Weaken(4)
+			if(H.staminaloss && !H.sleeping)
+				var/total_health = (H.health - H.staminaloss)
+				if(total_health <= config.health_threshold_crit && !H.stat)
+					H.visible_message("<span class='warning'>[user] delivers a heavy hit to [H]'s head, knocking them out cold!</span>", \
+										   "<span class='userdanger'>[user] knocks you unconscious!</span>")
+					H.sleeping += 30
+					H.adjustBrainLoss(25)
+			return
+		else
+			return ..()
+	return ..()
+
+/obj/item/weapon/twohanded/bostaff/IsShield()
+	if(wielded)
+		return 1
+	else
+		return 0
\ No newline at end of file
diff --git a/icons/mob/in-hand/staff.dmi b/icons/mob/in-hand/staff.dmi
index 6d59d81ecfb..2309136a454 100644
Binary files a/icons/mob/in-hand/staff.dmi and b/icons/mob/in-hand/staff.dmi differ
diff --git a/icons/obj/weapons.dmi b/icons/obj/weapons.dmi
index 041703a632a..fa286d3e12b 100644
Binary files a/icons/obj/weapons.dmi and b/icons/obj/weapons.dmi differ