mirror of
https://github.com/ParadiseSS13/Paradise.git
synced 2026-08-29 06:57:42 +01:00
Converts Pirates, Soviets, and Drakehounds to basic mob AI (#29903)
* Converts pirates, soviets, and drakehounds to basic mob AI * Linters and fixes * Pirate fire rate adjustment * Merge fixes * Better ranged attack code * Even better ranged code --------- Signed-off-by: PollardTheDragon <144391971+PollardTheDragon@users.noreply.github.com> Signed-off-by: Burzah <116982774+Burzah@users.noreply.github.com> Co-authored-by: Burzah <116982774+Burzah@users.noreply.github.com>
This commit is contained in:
PollardTheDragon
co-authored by
Burzah
Burzah
parent
a6edafaa2e
commit
6701e12613
@@ -0,0 +1,27 @@
|
||||
/// Attack something which is already adjacent to us, without ending planning
|
||||
/datum/ai_planning_subtree/basic_melee_attack_subtree/opportunistic
|
||||
melee_attack_behavior = /datum/ai_behavior/basic_melee_attack/opportunistic
|
||||
end_planning = FALSE
|
||||
|
||||
/datum/ai_planning_subtree/basic_melee_attack_subtree/opportunistic/select_behaviors(datum/ai_controller/controller, seconds_per_tick)
|
||||
. = ..()
|
||||
var/atom/target = controller.blackboard[BB_BASIC_MOB_CURRENT_TARGET]
|
||||
if(QDELETED(target) || !controller.pawn.Adjacent(target))
|
||||
return
|
||||
controller.queue_behavior(melee_attack_behavior, BB_BASIC_MOB_CURRENT_TARGET, BB_TARGETING_STRATEGY, BB_BASIC_MOB_CURRENT_TARGET_HIDING_LOCATION)
|
||||
|
||||
/// Attack something which is already adjacent to us without moving
|
||||
/datum/ai_behavior/basic_melee_attack/opportunistic
|
||||
behavior_flags = AI_BEHAVIOR_CAN_PLAN_DURING_EXECUTION
|
||||
|
||||
/datum/ai_behavior/basic_melee_attack/opportunistic/setup(datum/ai_controller/controller, target_key, targeting_strategy_key, hiding_location_key)
|
||||
if(!controller.blackboard_key_exists(targeting_strategy_key))
|
||||
CRASH("No target datum was supplied in the blackboard for [controller.pawn]")
|
||||
return controller.blackboard_key_exists(target_key)
|
||||
|
||||
/datum/ai_behavior/basic_melee_attack/opportunistic/perform(seconds_per_tick, datum/ai_controller/controller, target_key, targeting_strategy_key, hiding_location_key)
|
||||
var/atom/movable/atom_pawn = controller.pawn
|
||||
if(!atom_pawn.can_reach(controller.blackboard[target_key]))
|
||||
return AI_BEHAVIOR_INSTANT | AI_BEHAVIOR_SUCCEEDED
|
||||
. = ..()
|
||||
return AI_BEHAVIOR_DELAY | AI_BEHAVIOR_SUCCEEDED
|
||||
@@ -0,0 +1,115 @@
|
||||
/// Step away if too close, or towards if too far
|
||||
/datum/ai_planning_subtree/maintain_distance
|
||||
/// Blackboard key holding atom we want to stay away from
|
||||
var/target_key = BB_BASIC_MOB_CURRENT_TARGET
|
||||
/// How far do we look for our target?
|
||||
var/view_distance = 11
|
||||
/// the run away behavior we will use
|
||||
var/run_away_behavior = /datum/ai_behavior/step_away
|
||||
|
||||
/datum/ai_planning_subtree/maintain_distance/select_behaviors(datum/ai_controller/controller, seconds_per_tick)
|
||||
. = ..()
|
||||
|
||||
var/atom/target = controller.blackboard[target_key]
|
||||
if(!isliving(target) || !can_see(controller.pawn, target, view_distance))
|
||||
return // Don't run away from cucumbers, they're not snakes
|
||||
var/range = get_dist(controller.pawn, target)
|
||||
|
||||
var/minimum_distance = controller.blackboard[BB_RANGED_SKIRMISH_MIN_DISTANCE] || 4
|
||||
var/maximum_distance = controller.blackboard[BB_RANGED_SKIRMISH_MAX_DISTANCE] || 6
|
||||
|
||||
if(range < minimum_distance)
|
||||
controller.queue_behavior(run_away_behavior, target_key, minimum_distance)
|
||||
return
|
||||
if(range > maximum_distance)
|
||||
controller.queue_behavior(/datum/ai_behavior/pursue_to_range, target_key, maximum_distance)
|
||||
return
|
||||
|
||||
/datum/ai_planning_subtree/maintain_distance/cover_minimum_distance
|
||||
run_away_behavior = /datum/ai_behavior/cover_minimum_distance
|
||||
|
||||
/// Take one step away
|
||||
/datum/ai_behavior/step_away
|
||||
behavior_flags = AI_BEHAVIOR_REQUIRE_MOVEMENT | AI_BEHAVIOR_CAN_PLAN_DURING_EXECUTION
|
||||
required_distance = 0
|
||||
action_cooldown = 0.2 SECONDS
|
||||
|
||||
/datum/ai_behavior/step_away/setup(datum/ai_controller/controller, target_key)
|
||||
. = ..()
|
||||
var/atom/current_target = controller.blackboard[target_key]
|
||||
if(QDELETED(current_target))
|
||||
return FALSE
|
||||
|
||||
var/mob/living/our_pawn = controller.pawn
|
||||
our_pawn.face_atom(current_target)
|
||||
|
||||
var/turf/next_step = get_step_away(controller.pawn, current_target)
|
||||
if(!isnull(next_step) && !next_step.is_blocked_turf(exclude_mobs = TRUE))
|
||||
set_movement_target(controller, target = next_step, new_movement = /datum/ai_movement/basic_avoidance/backstep)
|
||||
return TRUE
|
||||
|
||||
var/list/all_dirs = GLOB.alldirs.Copy()
|
||||
all_dirs -= get_dir(controller.pawn, next_step)
|
||||
all_dirs -= get_dir(controller.pawn, current_target)
|
||||
shuffle_inplace(all_dirs)
|
||||
|
||||
for(var/dir in all_dirs)
|
||||
next_step = get_step(controller.pawn, dir)
|
||||
if(!isnull(next_step) && !next_step.is_blocked_turf(exclude_mobs = TRUE))
|
||||
set_movement_target(controller, target = next_step, new_movement = /datum/ai_movement/basic_avoidance/backstep)
|
||||
return TRUE
|
||||
return FALSE
|
||||
|
||||
/datum/ai_behavior/step_away/perform(seconds_per_tick, datum/ai_controller/controller)
|
||||
return AI_BEHAVIOR_DELAY | AI_BEHAVIOR_SUCCEEDED
|
||||
|
||||
/datum/ai_behavior/step_away/finish_action(datum/ai_controller/controller, succeeded)
|
||||
. = ..()
|
||||
controller.change_ai_movement_type(initial(controller.ai_movement))
|
||||
|
||||
/// Pursue a target until we are within a provided range
|
||||
/datum/ai_behavior/pursue_to_range
|
||||
behavior_flags = AI_BEHAVIOR_REQUIRE_MOVEMENT | AI_BEHAVIOR_CAN_PLAN_DURING_EXECUTION | AI_BEHAVIOR_MOVE_AND_PERFORM
|
||||
|
||||
/datum/ai_behavior/pursue_to_range/setup(datum/ai_controller/controller, target_key, range)
|
||||
. = ..()
|
||||
var/atom/current_target = controller.blackboard[target_key]
|
||||
if(QDELETED(current_target))
|
||||
return FALSE
|
||||
if(get_dist(controller.pawn, current_target) <= range)
|
||||
return FALSE
|
||||
set_movement_target(controller, current_target)
|
||||
|
||||
/datum/ai_behavior/pursue_to_range/perform(seconds_per_tick, datum/ai_controller/controller, target_key, range)
|
||||
var/atom/current_target = controller.blackboard[target_key]
|
||||
if(!QDELETED(current_target) && get_dist(controller.pawn, current_target) > range)
|
||||
return AI_BEHAVIOR_INSTANT
|
||||
return AI_BEHAVIOR_INSTANT | AI_BEHAVIOR_SUCCEEDED
|
||||
|
||||
/// instead of taking a single step, we cover the entire distance
|
||||
/datum/ai_behavior/cover_minimum_distance
|
||||
behavior_flags = AI_BEHAVIOR_REQUIRE_MOVEMENT | AI_BEHAVIOR_CAN_PLAN_DURING_EXECUTION
|
||||
required_distance = 0
|
||||
action_cooldown = 0.2 SECONDS
|
||||
|
||||
/datum/ai_behavior/cover_minimum_distance/setup(datum/ai_controller/controller, target_key, minimum_distance)
|
||||
. = ..()
|
||||
var/atom/target = controller.blackboard[target_key]
|
||||
if(QDELETED(target))
|
||||
return FALSE
|
||||
var/required_distance = minimum_distance - get_dist(controller.pawn, target) // the distance we need to move
|
||||
var/distance = 0
|
||||
var/turf/chosen_turf
|
||||
for(var/turf/open/potential_turf in oview(required_distance, controller.pawn))
|
||||
var/new_distance_from_target = get_dist(potential_turf, target)
|
||||
if(potential_turf.is_blocked_turf())
|
||||
continue
|
||||
if(new_distance_from_target > distance)
|
||||
chosen_turf = potential_turf
|
||||
distance = new_distance_from_target
|
||||
if(isnull(chosen_turf))
|
||||
return FALSE
|
||||
set_movement_target(controller, target = chosen_turf)
|
||||
|
||||
/datum/ai_behavior/cover_minimum_distance/perform(seconds_per_tick, datum/ai_controller/controller, target_key)
|
||||
return AI_BEHAVIOR_DELAY | AI_BEHAVIOR_SUCCEEDED
|
||||
@@ -19,6 +19,8 @@
|
||||
/// How often will we try to perform our ranged attack?
|
||||
/datum/ai_behavior/ranged_skirmish
|
||||
action_cooldown = 0.5 SECONDS
|
||||
///do we care about avoiding friendly fire?
|
||||
var/avoid_friendly_fire = FALSE
|
||||
|
||||
/datum/ai_behavior/ranged_skirmish/setup(datum/ai_controller/controller, target_key, targeting_strategy_key, hiding_location_key, max_range, min_range)
|
||||
. = ..()
|
||||
@@ -43,8 +45,46 @@
|
||||
if(distance > max_range || distance < min_range)
|
||||
return AI_BEHAVIOR_DELAY | AI_BEHAVIOR_FAILED
|
||||
|
||||
if(avoid_friendly_fire && check_friendly_in_path(controller.pawn, target, targeting_strategy))
|
||||
return AI_BEHAVIOR_DELAY
|
||||
|
||||
controller.ai_interact(target = target, intent = INTENT_HARM)
|
||||
return AI_BEHAVIOR_DELAY | AI_BEHAVIOR_SUCCEEDED
|
||||
|
||||
/datum/ai_behavior/ranged_skirmish/proc/check_friendly_in_path(mob/living/source, atom/target, datum/targeting_strategy/targeting_strategy)
|
||||
var/list/turfs_list = calculate_trajectory(source, target)
|
||||
for(var/turf/possible_turf as anything in turfs_list)
|
||||
|
||||
for(var/mob/living/potential_friend in possible_turf)
|
||||
if(!targeting_strategy.can_attack(source, potential_friend))
|
||||
return TRUE
|
||||
|
||||
return FALSE
|
||||
|
||||
/datum/ai_behavior/ranged_skirmish/proc/calculate_trajectory(mob/living/source, atom/target)
|
||||
var/list/turf_list = get_line(source, target)
|
||||
var/list_length = length(turf_list) - 1
|
||||
for(var/i in 1 to list_length)
|
||||
var/turf/current_turf = turf_list[i]
|
||||
var/turf/next_turf = turf_list[i + 1]
|
||||
var/direction_to_turf = get_dir(current_turf, next_turf)
|
||||
if(!IS_DIR_DIAGONAL(direction_to_turf))
|
||||
continue
|
||||
|
||||
for(var/cardinal_direction in GLOB.cardinal)
|
||||
if(cardinal_direction & direction_to_turf)
|
||||
turf_list += get_step(current_turf, cardinal_direction)
|
||||
|
||||
turf_list -= get_turf(source)
|
||||
turf_list -= get_turf(target)
|
||||
|
||||
return turf_list
|
||||
|
||||
/datum/ai_planning_subtree/ranged_skirmish/no_minimum
|
||||
min_range = 0
|
||||
|
||||
/datum/ai_planning_subtree/ranged_skirmish/avoid_friendly
|
||||
attack_behavior = /datum/ai_behavior/ranged_skirmish/avoid_friendly
|
||||
|
||||
/datum/ai_behavior/ranged_skirmish/avoid_friendly
|
||||
avoid_friendly_fire = TRUE
|
||||
|
||||
Reference in New Issue
Block a user