diff --git a/code/game/machinery/constructable_frame.dm b/code/game/machinery/constructable_frame.dm
index 9b03727495a..70f0195ce5d 100644
--- a/code/game/machinery/constructable_frame.dm
+++ b/code/game/machinery/constructable_frame.dm
@@ -757,6 +757,17 @@ obj/item/weapon/circuitboard/rdserver
 							/obj/item/stack/cable_coil = 1,
 							/obj/item/weapon/stock_parts/console_screen = 1)
 
+/obj/item/weapon/circuitboard/quantumpad
+	name = "circuit board (Quantum Pad)"
+	build_path = /obj/machinery/quantumpad
+	board_type = "machine"
+	origin_tech = "programming=3;engineering=3;plasmatech=3;bluespace=4"
+	frame_desc = "Requires 1 Bluespace Crystal, 1 Capacitor, 1 piece of cable and 1 Manipulator."
+	req_components = list(
+							/obj/item/weapon/ore/bluespace_crystal = 1,
+							/obj/item/weapon/stock_parts/capacitor = 1,
+							/obj/item/weapon/stock_parts/manipulator = 1,
+							/obj/item/stack/cable_coil = 1)
 
 /obj/item/weapon/circuitboard/sleeper
 	name = "circuit board (Sleeper)"
diff --git a/code/game/machinery/quantum_pad.dm b/code/game/machinery/quantum_pad.dm
new file mode 100644
index 00000000000..809d0a9b09a
--- /dev/null
+++ b/code/game/machinery/quantum_pad.dm
@@ -0,0 +1,148 @@
+/obj/machinery/quantumpad
+	name = "quantum pad"
+	desc = "A bluespace quantum-linked telepad used for teleporting objects to other quantum pads."
+	icon = 'icons/obj/telescience.dmi'
+	icon_state = "qpad-idle"
+	anchored = 1
+	use_power = 1
+	idle_power_usage = 200
+	active_power_usage = 5000
+	var/teleport_cooldown = 400 //30 seconds base due to base parts
+	var/teleport_speed = 50
+	var/last_teleport //to handle the cooldown
+	var/teleporting = 0 //if it's in the process of teleporting
+	var/power_efficiency = 1
+	var/obj/machinery/quantumpad/linked_pad = null
+
+/obj/machinery/quantumpad/New()
+	..()
+	component_parts = list()
+	component_parts += new /obj/item/weapon/circuitboard/quantumpad(null)
+	component_parts += new /obj/item/weapon/ore/bluespace_crystal/artificial(null)
+	component_parts += new /obj/item/weapon/stock_parts/capacitor(null)
+	component_parts += new /obj/item/weapon/stock_parts/manipulator(null)
+	component_parts += new /obj/item/stack/cable_coil(null, 1)
+	RefreshParts()
+
+/obj/machinery/quantumpad/Destroy()
+	linked_pad = null
+	return ..()
+
+/obj/machinery/quantumpad/RefreshParts()
+	var/E = 0
+	for(var/obj/item/weapon/stock_parts/capacitor/C in component_parts)
+		E += C.rating
+	power_efficiency = E
+	E = 0
+	for(var/obj/item/weapon/stock_parts/manipulator/M in component_parts)
+		E += M.rating
+	teleport_speed = initial(teleport_speed)
+	teleport_speed -= (E*10)
+	teleport_cooldown = initial(teleport_cooldown)
+	teleport_cooldown -= (E * 100)
+
+/obj/machinery/quantumpad/attackby(obj/item/I, mob/user, params)
+	if(default_deconstruction_screwdriver(user, "pad-idle-o", "qpad-idle", I))
+		return
+
+	if(panel_open)
+		if(ismultitool(I))
+			var/obj/item/device/multitool/M = I
+			M.buffer = src
+			to_chat(user, "<span class='notice'>You save the data in the [I.name]'s buffer.</span>")
+			return 1
+	else if(ismultitool(I))
+		var/obj/item/device/multitool/M = I
+		if(istype(M.buffer, /obj/machinery/quantumpad))
+			linked_pad = M.buffer
+			to_chat(user, "<span class='notice'>You link the [src] to the one in the [I.name]'s buffer.</span>")
+			return 1
+
+	if(exchange_parts(user, I))
+		return
+
+	if(default_deconstruction_crowbar(I))
+		return
+
+	return ..()
+
+/obj/machinery/quantumpad/attack_hand(mob/user)
+	if(panel_open)
+		to_chat(user, "<span class='warning'>The panel must be closed before operating this machine!</span>")
+		return
+
+	if(!linked_pad || qdeleted(linked_pad))
+		to_chat(user, "<span class='warning'>There is no linked pad!</span>")
+		return
+
+	if(world.time < last_teleport + teleport_cooldown)
+		to_chat(user, "<span class='warning'>[src] is recharging power. Please wait [round((last_teleport + teleport_cooldown - world.time) / 10)] seconds.</span>")
+		return
+
+	if(teleporting)
+		to_chat(user, "<span class='warning'>[src] is charging up. Please wait.</span>")
+		return
+
+	if(linked_pad.teleporting)
+		to_chat(user, "<span class='warning'>Linked pad is busy. Please wait.</span>")
+		return
+
+	if(linked_pad.stat & NOPOWER)
+		to_chat(user, "<span class='warning'>Linked pad is not responding to ping.</span>")
+		return
+	add_fingerprint(user)
+	doteleport(user)
+
+/obj/machinery/quantumpad/proc/sparks()
+	var/datum/effect/system/spark_spread/s = new /datum/effect/system/spark_spread
+	s.set_up(5, 1, get_turf(src))
+	s.start()
+
+/obj/machinery/quantumpad/attack_ghost(mob/dead/observer/ghost)
+	if(linked_pad)
+		ghost.forceMove(get_turf(linked_pad))
+
+/obj/machinery/quantumpad/proc/doteleport(mob/user)
+	if(linked_pad)
+		playsound(get_turf(src), 'sound/weapons/flash.ogg', 25, 1)
+		teleporting = 1
+
+		spawn(teleport_speed)
+			if(!src || qdeleted(src))
+				teleporting = 0
+				return
+			if(stat & NOPOWER)
+				to_chat(user, "<span class='warning'>[src] is unpowered!</span>")
+				teleporting = 0
+				return
+			if(!linked_pad || qdeleted(linked_pad) || linked_pad.stat & NOPOWER)
+				to_chat(user, "<span class='warning'>Linked pad is not responding to ping. Teleport aborted.</span>")
+				teleporting = 0
+				return
+
+			teleporting = 0
+			last_teleport = world.time
+
+			// use a lot of power
+			use_power(10000 / power_efficiency)
+			sparks()
+			linked_pad.sparks()
+
+			flick("qpad-beam", src)
+			playsound(get_turf(src), 'sound/weapons/emitter2.ogg', 25, 1, extrarange = 3, falloff = 5)
+			flick("qpad-beam", linked_pad)
+			playsound(get_turf(linked_pad), 'sound/weapons/emitter2.ogg', 25, 1, extrarange = 3, falloff = 5)
+			for(var/atom/movable/ROI in get_turf(src))
+				// if is anchored, don't let through
+				if(ROI.anchored)
+					if(isliving(ROI))
+						var/mob/living/L = ROI
+						if(L.buckled)
+							// TP people on office chairs
+							if(L.buckled.anchored)
+								continue
+						else
+							continue
+					else if(!isobserver(ROI))
+						continue
+				do_teleport(ROI, get_turf(linked_pad))
diff --git a/code/modules/research/designs/machine_designs.dm b/code/modules/research/designs/machine_designs.dm
index b3cd74cc320..c1d3c64d6b9 100644
--- a/code/modules/research/designs/machine_designs.dm
+++ b/code/modules/research/designs/machine_designs.dm
@@ -62,6 +62,16 @@
 	build_path = /obj/item/weapon/circuitboard/power_turbine
 	category = list ("Engineering Machinery")
 
+/datum/design/quantumpad
+	name = "Machine Board (Quantum Pad Board)"
+	desc = "The circuit board for a quantum telepad."
+	id = "quantumpad"
+	req_tech = list("programming" = 4, "bluespace" = 4, "plasmatech" = 3, "engineering" = 4)
+	build_type = IMPRINTER
+	materials = list(MAT_GLASS = 1000, "sacid" = 20)
+	build_path = /obj/item/weapon/circuitboard/quantumpad
+	category = list ("Teleportation Machinery")
+
 /datum/design/telepad
 	name = "Machine Board (Telepad Board)"
 	desc = "Allows for the construction of circuit boards used to build a Telepad."
diff --git a/code/modules/shuttle/supply.dm b/code/modules/shuttle/supply.dm
index f7b5a36e1a9..e2ba439a0dd 100644
--- a/code/modules/shuttle/supply.dm
+++ b/code/modules/shuttle/supply.dm
@@ -246,7 +246,8 @@
 		/obj/machinery/teleport/station,
 		/obj/machinery/teleport/hub,
 		/obj/machinery/telepad,
-		/obj/machinery/clonepod
+		/obj/machinery/clonepod,
+		/obj/machinery/quantumpad
 	)
 	if(A)
 		if(is_type_in_list(A, blacklist))
diff --git a/icons/obj/telescience.dmi b/icons/obj/telescience.dmi
index b692f566df1..dfc41198913 100644
Binary files a/icons/obj/telescience.dmi and b/icons/obj/telescience.dmi differ
diff --git a/paradise.dme b/paradise.dme
index c703c23d96c..15d3c08f39d 100644
--- a/paradise.dme
+++ b/paradise.dme
@@ -526,6 +526,7 @@
 #include "code\game\machinery\portable_tag_turret.dm"
 #include "code\game\machinery\portable_turret.dm"
 #include "code\game\machinery\programmable_unloader.dm"
+#include "code\game\machinery\quantum_pad.dm"
 #include "code\game\machinery\recharger.dm"
 #include "code\game\machinery\rechargestation.dm"
 #include "code\game\machinery\recycler.dm"