diff --git a/code/game/machinery/vending.dm b/code/game/machinery/vending.dm
index 83cf9225bab..ea498f444cd 100644
--- a/code/game/machinery/vending.dm
+++ b/code/game/machinery/vending.dm
@@ -1058,6 +1058,9 @@
 					/obj/item/weapon/reagent_containers/food/drinks/drinkingglass = 8, /obj/item/clothing/suit/chef/classic = 2,
 					/obj/item/weapon/reagent_containers/food/condiment/pack/ketchup = 5,
 					/obj/item/weapon/reagent_containers/food/condiment/pack/hotsauce = 5,
+					/obj/item/weapon/reagent_containers/food/condiment/saltshaker =5,
+					/obj/item/weapon/reagent_containers/food/condiment/peppermill =5,
+					/obj/item/weapon/whetstone = 2,
 					/obj/item/weapon/kitchen/mould/bear = 1, /obj/item/weapon/kitchen/mould/worm = 1,
 					/obj/item/weapon/kitchen/mould/bean = 1, /obj/item/weapon/kitchen/mould/ball = 1,
 					/obj/item/weapon/kitchen/mould/cane = 1, /obj/item/weapon/kitchen/mould/cash = 1,
diff --git a/code/game/objects/items/weapons/whetstone.dm b/code/game/objects/items/weapons/whetstone.dm
new file mode 100644
index 00000000000..bc9fae1a118
--- /dev/null
+++ b/code/game/objects/items/weapons/whetstone.dm
@@ -0,0 +1,65 @@
+/obj/item/weapon/whetstone
+	name = "whetstone"
+	icon = 'icons/obj/kitchen.dmi'
+	icon_state = "whetstone"
+	desc = "A block of stone used to sharpen things."
+	w_class = 2
+	var/used = 0
+	var/increment = 4
+	var/max = 30
+	var/prefix = "sharpened"
+	var/requires_sharpness = 1
+
+
+/obj/item/weapon/whetstone/attackby(obj/item/I, mob/user, params)
+	if(used)
+		user << "<span class='notice'>The whetstone is too worn to use again.</span>"
+		return
+	if(I.force >= max || I.throwforce >= max)//no esword sharpening
+		user << "<span class='notice'>[I] is much too powerful to sharpen further.</span>"
+		return
+	if(requires_sharpness && !I.edge)
+		user << "<span class='notice'>You can only sharpen items that are already sharp, such as knives.</span>"
+		return
+	if(istype(I, /obj/item/weapon/twohanded))//some twohanded items should still be sharpenable, but handle force differently. therefore i need this stuff
+		var/obj/item/weapon/twohanded/TH = I
+		if(TH.force_wielded >= max)
+			user << "<span class='notice'>[TH] is much too powerful to sharpen further.</span>"
+			return
+		if(TH.wielded)
+			user << "<span class='notice'>[TH] must be unwielded before it can be sharpened.</span>"
+			return
+		if(TH.force_wielded > initial(TH.force_wielded))
+			user << "<span class='notice'>[TH] has already been refined before. It cannot be sharpened further.</span>"
+			return
+		TH.force_wielded = Clamp(TH.force_wielded + increment, 0, max)//wieldforce is increased since normal force wont stay
+	if(I.force > initial(I.force))
+		user << "<span class='notice'>[I] has already been refined before. It cannot be sharpened further.</span>"
+		return
+	user.visible_message("<span class='notice'>[user] sharpens [I] with [src]!</span>", "<span class='notice'>You sharpen [I], making it much more deadly than before.</span>")
+	if(!requires_sharpness)
+		I.edge = 1
+		I.sharp = 1
+	I.force = Clamp(I.force + increment, 0, max)
+	I.throwforce = Clamp(I.throwforce + increment, 0, max)
+	I.name = "[prefix] [I.name]"
+	playsound(get_turf(src), 'sound/items/Screwdriver.ogg', 50, 1)
+	name = "worn out [name]"
+	desc = "[desc] At least, it used to."
+	used = 1
+
+/obj/item/weapon/whetstone/attack_self(mob/user as mob) //This is just fluff for now. Species datums are global and not newly created instances, so we can't adjust unarmed damage on a per mob basis.
+	if(ishuman(user))
+		var/mob/living/carbon/human/H = user
+		var/datum/unarmed_attack/attack = H.species.unarmed
+		if(istype(attack, /datum/unarmed_attack/claws))
+			H.visible_message("<span class='notice'>[H] sharpens \his claws on the [src]!</span>", "<span class='notice'>You sharpen your claws on the [src].</span>")
+			playsound(get_turf(H), 'sound/items/Screwdriver.ogg', 50, 1)
+
+/obj/item/weapon/whetstone/super
+	name = "super whetstone block"
+	desc = "A block of stone that will make your weapon sharper than Einstein on adderall."
+	increment = 200
+	max = 200
+	prefix = "super-sharpened"
+	requires_sharpness = 0
\ No newline at end of file
diff --git a/icons/obj/kitchen.dmi b/icons/obj/kitchen.dmi
index 68ccb9f003e..328cc04d001 100644
Binary files a/icons/obj/kitchen.dmi and b/icons/obj/kitchen.dmi differ
diff --git a/paradise.dme b/paradise.dme
index b611994a112..b313ca1ab5f 100644
--- a/paradise.dme
+++ b/paradise.dme
@@ -755,6 +755,7 @@
 #include "code\game\objects\items\weapons\twohanded.dm"
 #include "code\game\objects\items\weapons\vending_items.dm"
 #include "code\game\objects\items\weapons\weaponry.dm"
+#include "code\game\objects\items\weapons\whetstone.dm"
 #include "code\game\objects\items\weapons\wires.dm"
 #include "code\game\objects\items\weapons\grenades\bananade.dm"
 #include "code\game\objects\items\weapons\grenades\chem_grenade.dm"